_FTP_ProgressUpload Title und Text ändern

0cool

Hey Zusammen,

ich bin gerade dabei ein Skript zu schreiben, dass eine Datei auf einen Server Per FTP überträgt. Das klappt auch soweit. Was nicht klappt ist den Title und den Text der Progressbar anzupassen. Ich konnte kein Beispiel finden, das mein Vorhaben abdeckt. Auch die AutoIT Hilfe Funktion brachte mich nicht weiter.

Als erstes mein Skript

AutoIt: ftp_file_upload

#include <FTPEx.au3>
#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <ProgressConstants.au3>




Local $server = 'ftp.server.net'
Local $username = 'user'
Local $pass = 'passwd'
Local $i_Passive = 0
Local $i_ServerPort = 0




Local $s_LocalFile = 'Local Path\file.exe'
Local $s_RemoteFile = '/file.exe'


_FTP_Upload($server, $username, $pass, $i_Passive, $i_ServerPort, $s_LocalFile, $s_RemoteFile)


Func _FTP_Upload($server, $username, $pass, $i_Passive, $i_ServerPort, $s_LocalFile, $s_RemoteFile)
	$Open = _FTP_Open('MyFTP Control')
	;$ftp_open_err = @error


	if Not @error  Then
		ConsoleWrite("FTP Sitzung erfolgreich geöffnet" & @CRLF)
		$Conn = _FTP_Connect($Open, $server, $username, $pass, $i_Passive, $i_ServerPort)
		If Not @error Then
			ConsoleWrite("FTP Verbindung erfolgreich hergestellt" & @CRLF)
			ConsoleWrite("FTP upload wird gestartet." & @CRLF)
			_FTP_ProgressUpload($Conn, $s_LocalFile, $s_RemoteFile)
			if Not @error Then
				ConsoleWrite("Datei erfolgreich übertragen" & @CRLF)
			EndIf
		EndIf
	EndIf


	Local $Ftpc = _FTP_Close($Open)
	If Not @error Then ConsoleWrite("FTP Verbindung wurde erfolgreich geschlossen" & @CRLF)
EndFunc

Alles anzeigen

Wie bekomme ich es hin, den Title der Progressbar anzupassen und das nicht der komplette Pfad samt Dateinamen in der Progressbar angezeigt wird sondern nur der Dateiname die Übertragen wird.

Danke schon mal für eure Hilfe.

Gruß

0cool

**autoBert**

Mit dieser Fungtion eigentlich gar nicht, oder siehst du einen Parameter der dies zulässt?

Du kannst natürlich mit WinSetTitle bzw. ControlSetText das Fenster anpassen. Besser wäre aber die Funktion abändern und unter neuem Namen direkt ins Skript aufnehmen:

Code

; #FUNCTION# ====================================================================================================================
; Author ........: limette, Prog@ndy
; Modified.......: jchd
; Änderungsvorschlag autoBert
; ===============================================================================================================================
Func _MyFTP_ProgressUpload($hFTPSession, $sLocalFile, $sRemoteFile, $MyTitle = '', $MyText = '', $hFunctionToCall = 0)
	If $__g_hWinInet_FTP = -1 Then Return SetError(-2, 0, 0)


	Local $hFile = FileOpen($sLocalFile, $FO_BINARY)
	If @error Then Return SetError(-1, _WinAPI_GetLastError(), 0)


	Local $ai_FtpOpenfile = DllCall($__g_hWinInet_FTP, 'handle', 'FtpOpenFileW', 'handle', $hFTPSession, 'wstr', $sRemoteFile, 'dword', $GENERIC_WRITE, 'dword', $FTP_TRANSFER_TYPE_BINARY, 'dword_ptr', 0)
	If @error Or $ai_FtpOpenfile[0] = 0 Then Return SetError(-3, _WinAPI_GetLastError(), 0)
	If $MyTitle = '' Then $MyTitle = "FTP Upload"
	If $MyText = '' Then $MyText = "Uploading " & $sLocalFile
	If Not IsFunc($hFunctionToCall) Then ProgressOn($MyTitle, $MyText)


	Local $iLen = FileGetSize($sLocalFile)
	Local Const $iChunkSize = 256 * 1024
	Local $iLast = Mod($iLen, $iChunkSize)


	Local $iParts = Ceiling($iLen / $iChunkSize)
	Local $tBuffer = DllStructCreate("byte[" & $iChunkSize & "]")


	Local $aDone, $ai_FtpWrite, $iOut, $iRet, $iLasterror
	Local $x = $iChunkSize
	Local $iDone = 0
	For $i = 1 To $iParts
		If $i = $iParts And $iLast > 0 Then
			$x = $iLast
		EndIf
		DllStructSetData($tBuffer, 1, FileRead($hFile, $x))


		$ai_FtpWrite = DllCall($__g_hWinInet_FTP, 'bool', 'InternetWriteFile', 'handle', $ai_FtpOpenfile[0], 'struct*', $tBuffer, 'dword', $x, 'dword*', $iOut)
		If @error Or $ai_FtpWrite[0] = 0 Then
			$iLasterror = _WinAPI_GetLastError()
			$aDone = DllCall($__g_hWinInet_FTP, 'bool', 'InternetCloseHandle', 'handle', $ai_FtpOpenfile[0])
			; No need to test @error.
			FileClose($hFile)


			If Not IsFunc($hFunctionToCall) Then ProgressOff()
			Return SetError(-4, $iLasterror, 0)
		EndIf
		$iDone += $x


		If Not IsFunc($hFunctionToCall) Then
			ProgressSet(($iDone / $iLen) * 100)
		Else
			$iRet = $hFunctionToCall(($iDone / $iLen) * 100)
			If $iRet <= 0 Then
				$iLasterror = @error
				$aDone = DllCall($__g_hWinInet_FTP, 'bool', 'InternetCloseHandle', 'handle', $ai_FtpOpenfile[0])
				; No need to test @error.
				DllCall($__g_hWinInet_FTP, 'bool', 'FtpDeleteFileW', 'handle', $hFTPSession, 'wstr', $sRemoteFile)
				; No need to test @error.
				FileClose($hFile)
				If Not IsFunc($hFunctionToCall) Then ProgressOff()
				Return SetError(-6, $iLasterror, $iRet)
			EndIf
		EndIf
		Sleep(10)
	Next


	FileClose($hFile)


	If Not IsFunc($hFunctionToCall) Then ProgressOff()


	$aDone = DllCall($__g_hWinInet_FTP, 'bool', 'InternetCloseHandle', 'handle', $ai_FtpOpenfile[0])
	; No need to test @error.
	If @error Or $aDone[0] = 0 Then Return SetError(-5, _WinAPI_GetLastError(), 0)


	Return 1
EndFunc   ;==>_MyFTP_ProgressUpload

Alles anzeigen

du mußt natürlich noch dein Skript anpassen:

Code

_MyFTP_ProgressUpload($Conn, $s_LocalFile, $s_RemoteFile, "Mein Titel", "Mein Text")

0cool

Danke für die schnelle Hilfe.
Nachdem ich Deine Funktion in mein Skript reinkopiert hatte, lief mein Skript auf Fehler

AutoIt

If Not IsFunc($hFunctionToCall) Then ProgressOn($MyTitle, $MyText)
Error: IsFunc(): undefined function

Fällt dir etwas dazu ein?

[edit]
Durch ein Update auf die aktuelle AutoIT Version taucht der Fehler nicht mehr auf. Die Progressbar öffnet sich trotzdem nicht.

Deine Funktion wird bei der folgenden Prüfung beendet:

AutoIt

Local $ai_FtpOpenfile = DllCall($__g_hWinInet_FTP, 'handle', 'FtpOpenFileW', 'handle', $hFTPSession, 'wstr', $sRemoteFile, 'dword', $GENERIC_WRITE, 'dword', $FTP_TRANSFER_TYPE_BINARY, 'dword_ptr', 0)
If @error Or $ai_FtpOpenfile[0] = 0 Then Return SetError(-3, _WinAPI_GetLastError(), 0)

**autoBert**

Zitat von 0cool

Deine Funktion wird bei der folgenden Prüfung beendet

dann gilt meine Funktion ab in die Tonne und damit (Ursprungsversion) leben:

Zitat von autoBert

Mit dieser Fungtion eigentlich gar nicht, oder siehst du einen Parameter der dies zulässt?

0cool

Gibt es keine Möglichkeit, wie ich deine Funktion zum laufen bringen kann?
Bei meinem Ursprünglichen Versuch geht das so wie es vorhabe nicht. Ich kann zwar eine Funktion als Parameter übergeben das hat auch nicht so richtig funktioniert.

Das hab ich im Internet gefunden:
https://www.autoitscript.com/autoit3/docs/l…gressUpload.htm

Beide Beispiele funktionieren nicht. Die Variable $iPercent ist nicht deklariert und ich verstehe nicht, woher die Variable ihre Daten bekommen soll.

Es wäre net wenn Du mir weiter helfen könntest.

**autoBert**

Das von dir verlinkte Beispiel funktioniert bei mir wunderbar. Du mußt nur diesen Hinweis beachten:

Code

; This example NEED TO BE ADAPTED to valid $g_sRemoteFile/$sServer/$sUsername/$sPass

also gültige Werte für $g_sRemoteFile/$sServer/$sUsername/$sPass angeben. Der verwendete Server ist ein öffentlicher bei dem nur Downloads möglich sind.

Die Variable $iPercent ist in der Funktion _UpdateProgress als Parameter definiert. _UpdateProgress wird von _FTP_ProgressUpload mit Parameter aufgerufen.

0cool

Hey autoBert,

heute komme ich endlich dazu, die Beispiele mit der neusten AutoIT Version zu testen. Siehe da es funktioniert.
Danke für Deine Hilfe.

Gruß

ocool