Excel - Sortierreihenfolge benutzerdefiniert

leertaste

Hallo zusammen,

ich wollte heute die benutzerdefinierte Sortierreihenfolge von Excel in Autoit umsetzen.
Leider ohne Erfolg.

Daran scheitere ich schon.
Application.AddCustomList ListArray:=Array("A","B","C","AA","AB","AC")

Wie ist dies in AutoIt umzusetzen?
$oAppl.AddCustomList......

Vielen Dank.

Schöne Grüße

leertaste

**water**

Code

Global $aSortArray[] = ["A","B","C","AA","AB","AC"]
$oExcel.AddCustomList($aSortArray)

leertaste

Danke, aber trotzdem mache ich was falsch.
Die vorgegebene Sortierung wird nicht angewendet.

Eigentlich ist mein Ziel zuerst nach Spalte A und dann nach Spalte B zu sortieren.
Da aber die Sortierreihenfolge das größere Problem ist habe ich erst mich daran versucht.
Klappt aber nicht....

Das Ergebnis sollte so aussehen.

Name ID
Anton A
Anton B
Anton C
Anton AA
Anton AB
Anton AC
Berta A
Berta B
Berta C
Berta AA
Berta AB
Berta AC

Danke

AutoIt

#include <excel.au3>
Local $a[13][2] = [['Name', 'ID'], ['Anton', 'AB'], ['Anton', 'A'], ['Berta', 'AA'], _
['Anton','B'], ['Anton', 'C'], ['Anton', 'AC'], _
['Berta', 'AB'], ['Berta', 'A'], ['Anton', 'AA'], ['Berta', 'B'], ['Berta', 'C'], ['Berta', 'AC']]
Local $oAppl = _Excel_Open(Default, Default, Default, Default, True)
Local $sWorkbook = "C:\Temp\Excel_Sort_by_List.xlsx"
Local $oWorkbook = _Excel_BookNew($oAppl, 1)
_Excel_RangeWrite($oWorkbook, Default, $a, "A1")
Global $SortOrder[] = ["A","B","C","AA","AB","AC"]
$oAppl.AddCustomList($SortOrder)
$SortNum = $oAppl.CustomListCount
$iHeader = $xlYes
$bMatchcase = False
$iOrientation = $xlSortColumns
$iOrder1 = $xlAscending
$vWorksheet = $oWorkbook.ActiveSheet
$vRange = $vWorksheet.Usedrange
$vKey1 = $vWorksheet.Range("B2")
$vWorksheet.Sort.SortFields.Clear
$vWorksheet.Sort.SortFields.Add($vKey1, $xlSortOnValues, $iOrder1)
$vWorksheet.Sort.SetRange($vRange)
$vWorksheet.Sort.Header = $iHeader
$vWorksheet.Sort.MatchCase = $bMatchcase
$vWorksheet.Sort.Orientation = $iOrientation
$vWorksheet.Sort.CustomOrder = $SortNum + 1
$vWorksheet.Sort.DataOption = 0 ;xlSortNormal = 0 oder xlSortTextAsNumbers = 1
$vWorksheet.Sort.Apply
_Excel_BookSaveAs($oWorkbook, $sWorkbook, Default, True)
_Excel_Close($oAppl)
MsgBox(0, "", "Richtig sortiert?")

Alles anzeigen

**water**

Das sollte aber mit _Excel_RangeSort auch gehen.

leertaste

Meinst du so?

AutoIt

Global $SortOrder[] = ["A","B","C","AA","AB","AC"]
_Excel_RangeSort($oWorkbook, Default, "A:B", "A:A", $xlAscending, $xlSortNormal, $xlYes, False, $xlSortColumns, "B:B", $SortOrder)

Lasse ich Key2 weg wird nach Spalte A richtig sortiert. Nehme ich Key2 mit Spalte B und Order2 = default hinzu passt es auch noch.
Übergebe ich aber für die Order2 das Array wird sowohl Spalte A und Spalte B ohne klarer Reihenfolge sortiert.
In Excel wird aber unter Sortieren/Benutzerdefiniert Sortieren.../Reihenfolge/Benutzerdefinierte Liste das Array richtig angezeigt.

Was mache ich falsch?

Danke.

**water**

Parameter $iOrder2 muss (wie $iOrder1) entweder $xlAscending oder $xlDescending sein.

leertaste

Wie kann man dann die benutzerdefinierte Reihenfolge angeben?
$xlAscending oder $xlDescending sortiert nicht wie gewünscht.
Deshalb auch die vorgegebene Sortierreihenfolge.

**water**

Ops. Dann habe ich Deine Anforderung missverstanden. Die lässt sich leider nicht über das UDF umsetzen.
Hast Du mal an einen COM error handler für Dein Skript gedacht um zu prüfen, ob irgendwo ein Fehler auftritt?

leertaste

So, COM Error Handler eingebaut.

Bei $vWorksheet.Sort.CustomOrder = $SortNum + 1 bekomme ich die Meldung "unbekannter Name".
Es muß auch OrderCustom heißen anstatt CustomOrder. Aber trotzdem kommt die Meldung "unbekannter Name".

Weiter kommt die Meldung auch hier.
$vWorksheet.Sort.DataOption = 0

Aber wo mein Fehler liegt weiß ich trozdem nicht.

Vielen Dank für eure Hilfe.

**water**

So wie es aussieht,sollte CustomOrder der 4. Parameter für

Code

$vWorksheet.Sort.SortFields.Add(...)

sein.
https://msdn.microsoft.com/en-us/library/…office.14).aspx

leertaste

Hi,

danke, dass war der super Tipp.
Es funktioniert jetzt wie es soll.
Zuerst Spalte A und dann Spalte B nach Liste. Cool!

Und die benuterdefinierte Liste darf kein Array sein.
Weiter ist dies auch nicht notwendig:
$oExcel.AddCustomList($aSortArray)

Das funktionierende Script:

AutoIt

Local $a[][] = [['Name', 'ID'], ['Anton', 'AB'], ['Anton', 'A'], ['Berta', 'AA'], _
['Anton','B'], ['Anton', 'C'], ['Anton', 'AC'], _
['Berta', 'AB'], ['Berta', 'A'], ['Anton', 'AY'], ['Berta', 'B'], ['Berta', 'C'], ['Berta', 'AC']]


Local $oAppl = _Excel_Open(Default, Default, Default, Default, True)
Local $sWorkbook = "C:\Temp\Excel_Sort_by_CustomOrder.xlsx"
Local $oWorkbook = _Excel_BookNew($oAppl, 1)
_Excel_RangeWrite($oWorkbook, Default, $a, "A1")
Local $SortOrder1
Local $SortOrder2 = "A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z,AA,AB,AC,AD,AE,AF,AG,AH,AI,AJ,AK,AL,AM,AN,AO,AP,AQ,AR,AS,AT,AU,AV,AW,AX,AY,AZ"


$iHeader = $xlYes
$bMatchcase = False
$iOrientation = $xlSortColumns
$iOrder1 = $xlAscending
$iOrder2 = $xlAscending
$vWorksheet = $oWorkbook.ActiveSheet
$vRange = $vWorksheet.Usedrange
$vKey1 = $vWorksheet.Range("A:A")
$vKey2 = $vWorksheet.Range("B:B")
$DataOption1 = 0 ;xlSortNormal = 0 oder xlSortTextAsNumbers = 1
$DataOption2 = 0 ;xlSortNormal = 0 oder xlSortTextAsNumbers = 1
$vWorksheet.Sort.SortFields.Clear
$vWorksheet.Sort.SortFields.Add($vKey1, $xlSortOnValues, $iOrder1, $SortOrder1, $DataOption1)
$vWorksheet.Sort.SortFields.Add($vKey2, $xlSortOnValues, $iOrder2, $SortOrder2, $DataOption2)
$vWorksheet.Sort.SetRange($vRange)
$vWorksheet.Sort.Header = $iHeader
$vWorksheet.Sort.MatchCase = $bMatchcase
$vWorksheet.Sort.Orientation = $iOrientation
$vWorksheet.Sort.Apply


_Excel_BookSaveAs($oWorkbook, $sWorkbook, Default, True)
_Excel_Close($oAppl)


MsgBox(0, "", "Richtig sortiert?")

Alles anzeigen

**water**