Absturz ListView-Bewegung

Gremlin78

Hallo Leute,
wenn ich in meiner ListView-Ansicht Einträge verschieben möchte, funktioniert das, bis ich einen neuen Eintrag hinzufüge.
Danach stürzt das Programm leider beim Verschieben ab.
Warum? Wo liegt mein Fehler?
Hier ein Beispiel-Script:

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIListViewEx.au3>
Example()
Func Example()
GUICreate("listview items", 220, 250, 100, 200)
Local $idListview = GUICtrlCreateListView("col1 |col2|col3 ", 10, 10, 200, 200)
Local $idItem1 = GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
Local $idItem2 = GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
Local $idItem3 = GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
Local $idButton= GUICtrlCreateButton("1 more",10,220,200,20)
GUISetState(@SW_SHOW)
_GUIListViewEx_MsgRegister()
_GUIListViewEx_Init($idListview,0,0,0,TRUE)
While 1
   Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE
         ExitLoop
      Case $idButton
         GUICtrlCreateListViewItem("item4|col42|col43", $idListview)
         _GUIListViewEx_Init($idListview,0,0,0,TRUE)
   EndSwitch
WEnd
EndFunc ;==>Example

Alles anzeigen

MfG Gremlin

**Oscar**

Wenn Du externe UDFs (GUIListViewEx.au3) verwendest, dann solltest Du diese posten.
Ich könnte danach suchen, aber dann weiß ich nicht, welche Version Du verwendest.

Gremlin78

Sorry,
so hängt nun am 1. Beitrag an.

MfG Gremlin

**Oscar**

Zitat von Gremlin78

Danach stürzt das Programm leider beim Verschieben ab.

Einen Absturz konnte ich nicht beobachten (AutoIt v3.3.14.2), aber wenn Du nicht die Befehle der UDF verwendest, dann musst Du vorher den Speicher leeren (_GUIListViewEx_Close).

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIListViewEx.au3>
Example()
Func Example()
	GUICreate("listview items", 220, 250, 100, 200)
	Local $idListview = GUICtrlCreateListView("col1 |col2|col3 ", 10, 10, 200, 200)
	Local $idItem1 = GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
	Local $idItem2 = GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
	Local $idItem3 = GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
	Local $idButton = GUICtrlCreateButton("1 more", 10, 220, 200, 20)
	GUISetState(@SW_SHOW)
	_GUIListViewEx_MsgRegister()
	Local $idLV = _GUIListViewEx_Init($idListview, '', 0, 0, True)
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton
				_GUIListViewEx_Close($idLV)
				GUICtrlCreateListViewItem("item4|col42|col43", $idListview)
				$idLV = _GUIListViewEx_Init($idListview, '', 0, 0, True)
		EndSwitch
	WEnd
EndFunc   ;==>Example

Alles anzeigen

Gremlin78

Vielen Dank Oscar,
das ist die Lösung. Mir hat leider der Durchblick in der UDF gefehlt.

Nochmals vielen Dank.

MfG Gremlin