ADO - XLS -> Array - Probleme

**autoiter**

Hallo Leute,

ich habe ein Problem mit meiner Copy/Paste-Programmierung. Ich bin jetzt schon länger am Werkeln und dennoch komme ich nicht zum Ergebnis. Also fürchte ich, ich brauche nun die Hilfe von Leuten, die wissen was sie tun. Das ganze soll Teil eines größeren C&P-Programms werden, allerdings verstehe ich es gerade nicht mehr..

Folgendes Setting: Ich möchte ohne vorhandene Excel-Installation XLS-Dateien auslesen.
Folgendes Problem: Die erste Spalte stimmt nicht. Auch die erste Zeile stimmt nicht, wenn Strings enthalten sind.

Im Anhang findet ihr ein Archiv, in dem das Skript und einige Beispiel-XLS liegen.

~~Hier mal das Skript zur direkten Ansicht~~. Für jede Hilfe bin ich euch dankbar
Edit: Entfernt. Ist nun im letzten Beitrag

**autoiter**

Hallo Leute,

ich habe einige Fehler korrigieren können und das Skript nun auch etwas kommentiert. Die Fehler in der ersten Spalte kamen durch meine unfähige Umwandlung des Strings in ein Array (das mache ich wahrscheinlich eh suboptimal).

Jedenfalls werden jetzt relativ unfallfrei alle Beispiele abgearbeitet. Leider bleibt ein großes Problem: In meinen Beispielen habe ich in den Überschriften zwischen Zahlen und Worten variiert. Die Worte werden in den Tabellen nicht angezeigt!

In bsp1 (1|2|Fu|Ba|3|4) kommt |||3|4 heraus. 1 und 2 werden also auch verschluckt.

in bsp 2 fehlen dann einfach die Namen:
bsp2.xls-Namen als Überschriften.PNG bsp2.xls-Arrayansicht - Namen fehlen.PNG

Hat das etwas mit den Datentypen zu tun, die man laut dem MS-Artikel nicht auswählen kann? Auch MAXSCANROWS=1 in der Verbindungszeichenfolge brachte mir da nichts. Eigentlich dürften die Inhalte doch dennoch nicht leer sein. Weiß da jemand etwas?

Ergänzung: Es liegt am Datentyp. In bsp1.xls sind in der Überschrift die Zellen 1 und 2 als Text formatiert. Daher fehlen auch die als Text formatierten Ziffern 1 und 2. Hm, was kann ich tun, damit ich alle Felder bekomme?

~~Hier das aktuelle kommentierte Skript, bei dem es sich um eine angepasste Version ADO Example Excel handelt~~

Edit: Entfernt. Ist nun im letzten Beitrag

Im Anhang das Ganze noch einmal mit den Testdateien.

**autoiter**

Hallo Leute,

ich konnte mein Problem lösen. In den Verbindungstext musste zu den Extended Properties IMEX=1 ergänzt werden. Dies führt beim Auslesen zum Konvertieren in Text.

Der Vollständigkeit halber hier das endgültige Skript.

Spoiler anzeigen

AutoIt

#include <Array.au3>


; https://www.autoitscript.com/wiki/ADO_Example_Excel


Global $aFiles[5] = [@ScriptDir & "\bsp1.xls", _
		@ScriptDir & "\bsp2.xls", _
		@ScriptDir & "\bsp3.xls", _
		@ScriptDir & "\bsp4.xls", _
		@ScriptDir & "\bsp5.xls"]




_Loop()




Func _Loop()
	For $i = 0 To UBound($aFiles) - 1
		Local $aExcelSheets = _XLSReadToArray($aFiles[$i])
		_ArrayDisplay($aExcelSheets, "returned: " & $aFiles[$i])
		For $ii = 0 To UBound($aExcelSheets) - 1
			_ArrayDisplay($aExcelSheets[$ii], "returned: " & $aFiles[$i] & " - Sheet: " & $ii + 1)
		Next
	Next
EndFunc   ;==>_Loop




Func _XLSReadToArray($sFullPath)


	Local Const $ADO_adSchemaTables = 20
	Local Const $iCursorType = 0
	Local Const $iLockType = 1
	Local Const $iOptions = 512


	; Eine Verbindung, zum Auslesen der Tabellennamen.
	Local $oADOConnection = ObjCreate("ADODB.Connection") ; Das ADODB-Verbindungsobjekt


	; Hier folgt die Verbindungszeichenkette. Infos dazu im ersten Link. Im zweiten Link Erklärung für den hier notwendigen Parameter IMEX=1.
	; https://support.microsoft.com/de-de/kb/278973
	; https://support.microsoft.com/de-de/kb/509360
	Local $sADOConnectionString = 'Provider=Microsoft.Jet.OLEDB.4.0' & _
								  ';Data Source=' & $sFullPath & _
								  ';Extended Properties="Excel 8.0' & _
								  ';HDR=NO' & _
								  ';IMEX=1"'


	$oADOConnection.Open($sADOConnectionString)




	Local $aSheetnames[0] ; Array, in dem die Tabellennamen gespeichert werden.


	; Beginn: Hier werden die Tabellen-Namen ausgelesen
	Local $oTablesSchema = $oADOConnection.OpenSchema($ADO_adSchemaTables)


	While Not $oTablesSchema.EOF
		_ArrayAdd($aSheetnames, $oTablesSchema.Fields("TABLE_NAME").Value)
		$oTablesSchema.MoveNext
	WEnd
	; Ende: Hier werden die Tabellen-Namen ausgelesen




	Local $iNrOfSheets = UBound($aSheetnames)


	Local $aExcelSheets[$iNrOfSheets] ; Das Rückgabe Array. In jedem Element soll ein Tabellenblatt gespeichert werden. Daher bekommt das Array die Ubound-Größe von $aSheetnames als Elementeanzahl




	; Nun werden in einer Schleife alle Tabellenblätter der Excel-Datei ausgelesen.
	For $i = 0 To $iNrOfSheets - 1


		$sSNReplace = StringReplace($aSheetnames[$i], "'", "")
		If StringRight($sSNReplace, 1) <> "$" Then ContinueLoop ; Zur Absturzvermeidung: Ist das letzte Zeichen kein $, kommt es zum Absturz nach dem Select Statement.


		Local $oADORecordset = ObjCreate("ADODB.Recordset") ; Das Rekordset-Objekt für das jeweilige Tabellenblatt


		Local $sSheet = "", $iSheetRows = 0


		Local $sADOSQL = "Select * FROM [" & $aSheetnames[$i] & "]" ; Hier wird in Schleife verwendet zeilenweise alles aus dem Tabellenblatt ausgelesen (Select *).
		$oADORecordset.Open($sADOSQL, $oADOConnection, $iCursorType, $iLockType, $iOptions)


		With $oADORecordset
			While Not .EOF
				For $oField In .Fields
					$sSheet &= $oField.Value & "|"
				Next
				$sSheet = StringTrimRight($sSheet, 1) & @LF
				$iSheetRows += 1
				.MoveNext
			WEnd
		EndWith


		Local $iSheetCols = 500
		Local $aSheets[$iSheetRows][$iSheetCols] ; Einfach ein großes Array, das alle Einträge der aktuellen Tabelle fassen können sollte. Dabei wird mal von 500 Spaten ausgegangen.


		; $sSheet ist jetzt ein String mit @LF Umbrüchen nach jeder Zeile und dem Verkettungszeichen | als Trenner zwischen den Spalten.
		; Das wird nun in einigen Umständlichen Operationen zu einem Array gewandelt.
		$sSheet = StringTrimRight($sSheet, 1)
		$aSheet = StringSplit($sSheet, @LF, 2)
		$iColCount = 0
		For $ii = 0 To $iSheetRows - 1
			$aColValues = StringSplit($aSheet[$ii], "|")
			If $aColValues[0] > $iSheetRows Then
				$iSheetCols = $aColValues[0]
				ReDim $aSheets[$iSheetRows][$iSheetCols] ; Je Zeile wird geprüft, ob das Array auch genügend Spalten hat, sonst erfolg ein ReDim auf die notwendige Anzahl.
			EndIf
			If $aColValues[0] > $iColCount Then $iColCount = $aColValues[0]
			For $iii = 1 To $aColValues[0]
				$aSheets[$ii][$iii - 1] = $aColValues[$iii]
			Next
		Next


		$oADORecordset.Close ; Recordset Objekt wird geschlossen.
		$oADORecordset = 0


		ReDim $aSheets[$iSheetRows][$iColCount] ; Das große Array wird auf die ermittelte, nötige Größe geschrumpft und in der folgenden Zeile zu einem $aExcelSheets-Element.
		$aExcelSheets[$i] = $aSheets
	Next
	$oADOConnection.Close ; Abschließend wird das Verbindungsobjekt Objekt geschlossen.
	$oADOConnection = 0


	Return $aExcelSheets
EndFunc   ;==>_XLSReadToArray

Alles anzeigen

**autoiter**

Hallo Leute,

Ich habe den Code in einem Programm zum Auslesen von Office Dateien benutzt, das ich hier auch gepostet habe. Dieses Programm habe ich nun auf einigen Rechnern testen können.
Dabei ist ein Absturzproblem zu Tage getreten. Bei einem Rechner, der mit Windows 10 Home Lizenz gekauft wurde, stürzt das Programm ab. Bei allen anderen Rechnern, die Upgrades von Windows 7 Pro und 8.1 Por waren gibt es keine Probleme.

AutoIt

Local $oADOConnection = ObjCreate("ADODB.Connection") ; Das ADODB-Verbindungsobjekt

Das zeigt noch keinen @error. Dennoch stürzt das Programm dann in der Zeile 45 ab:

AutoIt

$oADOConnection.Open($sADOConnectionString)

Die Meldung lautet in Etwa: Die Aktion kann mit dem Objekt nicht durchgeführt werden.

Ich habe nirgends etwas von einem grundsätzlichem Problem mit Windows Home und dem Jet OLE DB Provider finden können. Kann ich den Fehler irgendwie abfangen, damit das Programm nicht gleich abschmiert?

Für jeden eurer Tipps bin ich wie immer sehr dankbar.

**water**

Um das Problem abzufangen brauchst Du einen COM Error Handler. Siehe unter ObjEvent in der Hilfe.

**autoiter**

In dem Hinweis in der Hilfe steht sogar fett always.
..Und ich habe gestern jemanden aufgefordert, die Hilfe genauer zu studieren.
Danke dir @water

**water**