Mit IF funktion Bilder Wechseln

McRau

Hallo zusammen,

ich versuche mir grade ein Script zu basteln, der 4 Rechner immer wieder anpingt um anzuzeigen ob die Rechner Online oder Offline sind.
Der Script soll immer in einer Schleife laufen und mir hinter dem Rechnernamen entweder Bild 1 für Online oder Bild 2 für Offline anzeigen.
Ich denke am einfachsten wäre das Ganze mit

$Rechner1 = ping („Rechner1“)
If $ Rechner1 > 0 then
Bild1
Else
Bild2
Endif

Ich bin mir nur nicht im Klaren, wie ich an einer Bestimmten Position in ein GUI entweder das eine oder das andere Bild anzeigen lasse.

Schon mal Danke im Voraus
Gruß

**Oscar**

Mit GUICtrlCreatePic kannst Du Bild-Control auf der GUI erstellen und mit GUICtrlSetImage kannst Du dem Control-Element ein Bild zuweisen.
Handelt es sich um externe (Internet) oder interne (lokales Netzwerk) Rechner?
Für das lokale Netzwerk gäbe es noch eine andere Möglichkeit als Ping.

McRau

Hallo,

Danke für deine Antwort.

Ich habe das ganze jetzt mal so probiert, aber das funktioniert nicht

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 615, 437, 192, 124)
$Group1 = GUICtrlCreateGroup("Group1", 96, 48, 337, 281)
$Rechner1 = GUICtrlCreateLabel("Rechner1", 128, 88, 51, 17)
$Pic1 = GUICtrlCreatePic("", 208, 80, 36, 28)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
	$nMsg = GUIGetMsg()
	$PRechner1 = ping ("RECHNER1")
	If $PRechner1 > 0 Then
	   $Pic1 = GUICtrlSetImage (-1, "PFAD\BILD1", "")
	Else
	   $Pic1 = GUICtrlSetImage (-1, "PFAD\BILD2", "")
    EndIf
	Sleep (100)
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


	EndSwitch
WEnd

Alles anzeigen

Die Rechner sind im lokalen Netzwerk, was wäre den die Alternative zu Ping?

Vielen Dank

Gruß

**Kanashius**

Ersetz $Pic1 = GUICtrlSetImage (-1, "PFAD\BILD1", "") mal durch GUICtrlSetImage ($Pic1, "PFAD\BILD1", "")
Du versuchst dem letzten erstellten Control, also der Group (Durch die -1 wird das zuletzt erstellte Control angesprochen) ein Bild zu setzen und überschreibst dein Control $Pic1 mit dem Ergebnis, also 0 oder 1, jenachdem, obs geklappt hat oder nicht. Also hier 0, da man einer Group kein Bild zuweisen kann. Der 3te Parameter ist optional, kann also weggelassen werden.

**Oscar**

Zitat von McRau

Die Rechner sind im lokalen Netzwerk, was wäre den die Alternative zu Ping?

Die Alternative ist NetServerEnum (listet alle aktiven Rechner im Netzwerk auf):

AutoIt

#include <Array.au3>


Global Const $SV_TYPE_WORKSTATION = 0x1
Global Const $SV_TYPE_SERVER = 0x2
Global Const $SV_TYPE_SQLSERVER = 0x4
Global Const $SV_TYPE_DOMAIN_CTRL = 0x8
Global Const $SV_TYPE_DOMAIN_BAKCTRL = 0x10
Global Const $SV_TYPE_TIME_SOURCE = 0x20
Global Const $SV_TYPE_AFP = 0x40
Global Const $SV_TYPE_NOVELL = 0x80
Global Const $SV_TYPE_DOMAIN_MEMBER = 0x100
Global Const $SV_TYPE_PRINTQ_SERVER = 0x200
Global Const $SV_TYPE_DIALIN_SERVER = 0x400
Global Const $SV_TYPE_XENIX_SERVER = 0x800
Global Const $SV_TYPE_NT = 0x1000
Global Const $SV_TYPE_WFW = 0x2000
Global Const $SV_TYPE_SERVER_MFPN = 0x4000
Global Const $SV_TYPE_SERVER_NT = 0x8000
Global Const $SV_TYPE_POTENTIAL_BROWSER = 0x10000
Global Const $SV_TYPE_BACKUP_BROWSER = 0x20000
Global Const $SV_TYPE_MASTER_BROWSER = 0x40000
Global Const $SV_TYPE_DOMAIN_MASTER = 0x80000
Global Const $SV_TYPE_WINDOWS = 0x400000
Global Const $SV_TYPE_CLUSTER_NT = 0x1000000
Global Const $SV_TYPE_TERMINALSERVER = 0x2000000
Global Const $SV_TYPE_CLUSTER_VS_NT = 0x4000000
Global Const $SV_TYPE_LOCAL_LIST_ONLY = 0x40000000
Global Const $SV_TYPE_DOMAIN_ENUM = 0x80000000
Global Const $SV_TYPE_ALL = 0xFFFFFFFF


$aCompList = _NetServerEnum($SV_TYPE_WORKSTATION)


_ArrayDisplay($aCompList)


Func _NetServerEnum($iSrvType = -1, $sDomain = '')
	Local $uBufPtr = DllStructCreate("ptr;int;int"), $res[1] = [0], $i
	Local $uRecord = DllStructCreate("dword;ptr"), $iRecLen = DllStructGetSize($uRecord)
	Local $uString = DllStructCreate("char[16]")
	Local $uDomain = DllStructCreate("byte[32]"), $pDomain = 0
	If Not ($sDomain = '' Or $sDomain = '*') Then
		DllStructSetData($uDomain, 1, StringToBinary($sDomain, 2))
		$pDomain = DllStructGetPtr($uDomain)
	EndIf
	Local $ret = DllCall("netapi32.dll", "int", "NetServerEnum", _
			"ptr", 0, "int", 100, _
			"ptr", DllStructGetPtr($uBufPtr, 1), "int", -1, _
			"ptr", DllStructGetPtr($uBufPtr, 2), _
			"ptr", DllStructGetPtr($uBufPtr, 3), _
			"int", $iSrvType, "ptr", $pDomain, "int", 0)
	If $ret[0] Then Return SetError(1, $ret[0], '')
	Local $res[DllStructGetData($uBufPtr, 3) + 1] = [DllStructGetData($uBufPtr, 3)]
	For $i = 1 To DllStructGetData($uBufPtr, 3)
		Local $uRecord = DllStructCreate("dword;ptr", DllStructGetData($uBufPtr, 1) + ($i - 1) * $iRecLen)
		Local $sNBName = DllStructCreate("byte[32]", DllStructGetData($uRecord, 2))
		DllStructSetData($uString, 1, BinaryToString(DllStructGetData($sNBName, 1), 2))
		$res[$i] = DllStructGetData($uString, 1)
	Next
	$ret = DllCall("netapi32.dll", "int", "NetApiBufferFree", "ptr", DllStructGetData($uBufPtr, 1))
	Return $res
EndFunc   ;==>_NetServerEnum

Alles anzeigen