GUISetonEvent, Close clicked bei GUI

Mikki

Hallo zusammen,

ich habe folgendes Problem:
Bei meinem Programm habe ich wie üblich das GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked_Systemauswahl") gewählt, damit beim klicken vom "Schliessen" Button sich das Fenster auch schließt.

Hierzu der Code: (Die restlichen Dateien die eigentlich eingeladen werden, habe ich weg gelassen aufgrund der Übersicht. Es geht nur um´s Prinzip)

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>




Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus


Global $Window_Auswahl_System, $Pic_Eingabehilfe


Global $Button_Traeger_auf_zwei_Stuetzen_Linienlast


Global $Window_System_1


Global $Button_Berechnung_System_1


Global $Inputbox_Window_System_1_L, $Inputbox_Window_System_1_q


Global $Radio_I_System_1, $Radio_U_System_1, $Radio_L_System_1, $Radio_O_System_1, $Radio_QR_System_1, $Radio_RR_System_1
Global $Radio_Werkstoff_S235_System_1, $Radio_Werkstoff_S355_System_1, $Radio_Werkstoff_S460_System_1


Global $Combobox_I_Profil_System_1, $Combobox_U_Profil_System_1, $Combobox_Achse_Durchbiegung_System_1, $Combobox_Durchbiegung_System_1, $Combobox_Werkstoff_System_1






$Window_Auswahl_System = GUICreate("Statiktool - Systemauswahl", 900, 600)
GUISetBkColor(0xffffff)




GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked_Systemauswahl")
GUISetState(@SW_SHOW)


$Button_Traeger_auf_zwei_Stuetzen_Linienlast = GUICtrlCreateButton("System 1", 100, 220, 100, 30)
GUICtrlSetOnEvent($Button_Traeger_auf_zwei_Stuetzen_Linienlast, "System_1")
GUISetState(@SW_SHOW)






;Leerlauf und auf Event warten
While 1
	Sleep(1000)
WEnd








Func System_1()


	$Window_System_1 = GUICreate("Systemdaten Träger auf zwei Stützen mit Linienlast", 800, 600)
	GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked_System_1")
	GUISetState(@SW_SHOW)


	GUICtrlCreateLabel("Länge L [m]", 10, 20, 100)
	$Inputbox_Window_System_1_L = GUICtrlCreateInput("", 10, 40, 80)
	GUISetState(@SW_SHOW)


	GUICtrlCreateLabel("Last q [kN/m]", 10, 80, 100)
	$Inputbox_Window_System_1_q = GUICtrlCreateInput("", 10, 100, 80)
	GUISetState(@SW_SHOW)


	GUICtrlCreateGroup("Trägerprofil", 120, 20, 180, 160)


	$Radio_I_System_1 = GUICtrlCreateRadio(" I ", 130, 50, 50)
	GUICtrlSetOnEvent($Radio_I_System_1, "Combobox_I")
	$Radio_U_System_1 = GUICtrlCreateRadio(" U ", 130, 70, 50)
	GUICtrlSetOnEvent($Radio_U_System_1, "Combobox_U")
	$Radio_L_System_1 = GUICtrlCreateRadio(" L ", 130, 90, 50)
	$Radio_O_System_1 = GUICtrlCreateRadio(" I ", 130, 110, 50)
	$Radio_QR_System_1 = GUICtrlCreateRadio(" QR ", 130, 130, 50)
	$Radio_RR_System_1 = GUICtrlCreateRadio(" RR ", 130, 150, 50)


	GUICtrlCreateGroup("Biegung um welche Achse?", 320, 20, 150, 160)
	$Combobox_Achse_Durchbiegung_System_1 = GUICtrlCreateCombo(" ", 330, 50, 120)




	GUICtrlCreateGroup("max. zul. Durchbiegung", 490, 20, 130, 160)
	$Combobox_Durchbiegung_System_1 = GUICtrlCreateCombo(" ", 500, 50, 100)




	GUICtrlCreateGroup("Werkstoff", 640, 20, 130, 160)
	$Combobox_Werkstoff_System_1 = GUICtrlCreateCombo(" ", 650, 50, 75)




	$Button_Berechnung_System_1 = GUICtrlCreateButton("Berechnen", 250, 560, 100, 30)
	GUICtrlSetOnEvent($Button_Berechnung_System_1, "Berechnung_System_1")
	GUISetState(@SW_SHOW)
EndFunc   ;==>System_1




Func CLOSEClicked_Systemauswahl()
	Exit
EndFunc   ;==>CLOSEClicked_Systemauswahl


Func CLOSEClicked_System_1()
	GUIDelete($Window_System_1)
	GUISwitch($Window_Auswahl_System)
EndFunc   ;==>CLOSEClicked_System_1

Alles anzeigen

Das Problem ist, wenn ich zwei mal auf den Button: "$Button_Traeger_auf_zwei_Stuetzen_Linienlast" klicke erscheinen auch zwei Fenster. So weit so gut.
Aber ich kann nur ein Fester wieder schließen.

Woran liegt das? Hat jemand eine Lösung wie man das Problem umgehen kann?

Ich hoffe Ihr könnt mir weiterhelfen

LG Mikki

**Oscar**

Was ja auch kein Wunder ist, denn Du überschreibst ja die Variable "$Window_System_1" beim zweiten Aufruf.
Wenn Du mehrere Fenster öffnen willst, dann musst Du ein Array für die Fenster-Handle anlegen und den Index jedes Mal erhöhen.

Mikki

Hallo Oscar,

okay vielen Dank versuche es direkt mal

LG Mikki

Mikki

Ich bekomme es leider nicht hin. Kannst du mir ein Beispiel zeigen oder mir zeigen was ich genau machen kann?

LG Mikki

**autoiter**

Hallo @Mikki,

Schau dir mal das Tutorial von BugFix an. http://www.bug-fix.info/array_tut.htm

Stichwort: Vergleichscode ohne/mit Array

**Oscar**

Zitat von Mikki

Ich bekomme es leider nicht hin. Kannst du mir ein Beispiel zeigen oder mir zeigen was ich genau machen kann?

LG Mikki

Es ist nie so gut, Fenster derart dynamisch zu erzeugen. Im allgemeinen braucht man ja nicht unendlich viele dieser Fenster.
Wenn Du nur zwei oder drei Client-GUIs benötigst, dann wäre es besser diese im Voraus zu erstellen und nur bei Bedarf anzuzeigen.
Hier aber mal ein Beispiel, wie man "unendlich" viele Fenster erstellen kann:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>




Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus


Global $Window_Auswahl_System, $Pic_Eingabehilfe


Global $Button_Traeger_auf_zwei_Stuetzen_Linienlast


Global $Window_System_1


Global $Button_Berechnung_System_1


Global $Inputbox_Window_System_1_L, $Inputbox_Window_System_1_q


Global $Radio_I_System_1, $Radio_U_System_1, $Radio_L_System_1, $Radio_O_System_1, $Radio_QR_System_1, $Radio_RR_System_1
Global $Radio_Werkstoff_S235_System_1, $Radio_Werkstoff_S355_System_1, $Radio_Werkstoff_S460_System_1


Global $Combobox_I_Profil_System_1, $Combobox_U_Profil_System_1, $Combobox_Achse_Durchbiegung_System_1, $Combobox_Durchbiegung_System_1, $Combobox_Werkstoff_System_1


Global $iClientCount = 0, $ahClientGui[$iClientCount + 1][13]


$Window_Auswahl_System = GUICreate("Statiktool - Systemauswahl", 900, 600)
GUISetBkColor(0xffffff)




GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked_Systemauswahl")
GUISetState(@SW_SHOW)


$Button_Traeger_auf_zwei_Stuetzen_Linienlast = GUICtrlCreateButton("System 1", 100, 220, 100, 30)
GUICtrlSetOnEvent($Button_Traeger_auf_zwei_Stuetzen_Linienlast, "System_1")
GUISetState(@SW_SHOW)






;Leerlauf und auf Event warten
While 1
	Sleep(1000)
WEnd








Func System_1()
	$ahClientGui[$iClientCount][0] = GUICreate("Systemdaten Träger auf zwei Stützen mit Linienlast", 800, 600)
	GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked_System_1")


	GUICtrlCreateLabel("Länge L [m]", 10, 20, 100)
	$ahClientGui[$iClientCount][1] = GUICtrlCreateInput("", 10, 40, 80)


	GUICtrlCreateLabel("Last q [kN/m]", 10, 80, 100)
	$ahClientGui[$iClientCount][2] = GUICtrlCreateInput("", 10, 100, 80)


	GUICtrlCreateGroup("Trägerprofil", 120, 20, 180, 160)


	$ahClientGui[$iClientCount][3] = GUICtrlCreateRadio(" I ", 130, 50, 50)
;~ 	GUICtrlSetOnEvent($Radio_I_System_1, "Combobox_I")
	$ahClientGui[$iClientCount][4] = GUICtrlCreateRadio(" U ", 130, 70, 50)
;~ 	GUICtrlSetOnEvent($Radio_U_System_1, "Combobox_U")
	$ahClientGui[$iClientCount][5] = GUICtrlCreateRadio(" L ", 130, 90, 50)
	$ahClientGui[$iClientCount][6] = GUICtrlCreateRadio(" I ", 130, 110, 50)
	$ahClientGui[$iClientCount][7] = GUICtrlCreateRadio(" QR ", 130, 130, 50)
	$ahClientGui[$iClientCount][8] = GUICtrlCreateRadio(" RR ", 130, 150, 50)


	GUICtrlCreateGroup("Biegung um welche Achse?", 320, 20, 150, 160)
	$ahClientGui[$iClientCount][9] = GUICtrlCreateCombo(" ", 330, 50, 120)




	GUICtrlCreateGroup("max. zul. Durchbiegung", 490, 20, 130, 160)
	$ahClientGui[$iClientCount][10] = GUICtrlCreateCombo(" ", 500, 50, 100)




	GUICtrlCreateGroup("Werkstoff", 640, 20, 130, 160)
	$ahClientGui[$iClientCount][11] = GUICtrlCreateCombo(" ", 650, 50, 75)




	$ahClientGui[$iClientCount][12] = GUICtrlCreateButton("Berechnen", 250, 560, 100, 30)
;~ 	GUICtrlSetOnEvent($Button_Berechnung_System_1, "Berechnung_System_1")
	GUISetState(@SW_SHOW, $ahClientGui[$iClientCount][0])
	$iClientCount += 1
	ReDim $ahClientGui[$iClientCount + 1][13]
EndFunc   ;==>System_1




Func CLOSEClicked_Systemauswahl()
	Exit
EndFunc   ;==>CLOSEClicked_Systemauswahl


Func CLOSEClicked_System_1()
	GUIDelete(@GUI_WinHandle)
	GUISwitch($Window_Auswahl_System)
EndFunc   ;==>CLOSEClicked_System_1

Alles anzeigen

Da ich den übrigen Code nicht kenne, kann ich Dir auch keine Hilfe dazu geben, wie Du die einzelnen GUI-Controls ansprechen kannst.
Nur soviel:
@GUI_WinHandle enthält das Handle zum zuletzt angeklickten Fenster
@GUI_CtrlId enthält die Control-ID zum angeklickten Control-Element

Damit kannst Du dann in Deinen Event-Funktionen die Fenster/Control-Elemente auseinanderhalten.

Mikki

Hallo Oscar,

vielen lieben Dank für deine Hilfe

Das Beispiel werde ich mir mal merken.

Ja ist richtig, ich gebe dir Recht, dass man die Fenster vorher erstellen sollte, aber da hier noch 5 weitere Systeme auf System 1 folgen, wäre es schwierig für jedes der Systeme ein Fenster unter zu bringen. Also vom Platz her gesehen.
Deshalb habe ich mich dafür entschieden.

Lg Mikki.