GuiCtrlCreate / GuiCtrlSetData programmatisch erstellen / beschreiben

AutoTim

Hallo Autoit Forum und deren Mitgleider ;),

gibt es eine Möglichkeit eine, oder sogar beide, oben genannten Funktionen in einer for Schleife auszuführen?
Hier ein einfaches Beispiel um zu erklären um was es mir geht:

AutoIt

for $i = 0 to 5
   GuiCtrlSetData("$test"&$i,"Beispiel")
next


oder


for $i = 0 to 5
"$Label"&$i = GuiCtrlCreateLabel("Beispiel")
next

Alles anzeigen

Grüße
Tim

**BugFix**

Hier mal aus meiner Beispielsammlung: Erstellung Dynamischer Control.
Wenn du das in eine Schleife packst kannst du eine definierte Anzahl Control erstellen. Das Resizing benötigst du dann sicher nicht.

AutoIt

Global $GUI, $aInput[2] = [1], $btAdd


$GUI = GUICreate('Test', 400, 50)
$aInput[1] = GUICtrlCreateInput('', 10, 10, 300, 21)
GUICtrlSetResizing(-1, 802) ; $GUI_DOCKALL
$btAdd = GUICtrlCreateButton('Add Input', 320, 10, 70, 21)
GUICtrlSetResizing(-1, 802) ; $GUI_DOCKALL
GUISetState()


While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $btAdd
			_NewCtrl()
	EndSwitch
WEnd


Func _NewCtrl()
	Local $iDiff = 31     ; == Abstand + Höhe ==> 10 + 21
	Local Static $iY = 10 ; == Startwert vom ersten Ctrl
	$iY += $iDiff
	$aInput[0] += 1
	ReDim $aInput[$aInput[0]+1]
	Local $aWin = WinGetPos($GUI)
	WinMove($GUI, '', $aWin[0], $aWin[1], $aWin[2], $aWin[3] + 31)
	$aInput[$aInput[0]] = GUICtrlCreateInput('', 10, $iY, 300, 21)
	GUICtrlSetResizing(-1, 802) ; $GUI_DOCKALL
EndFunc

Alles anzeigen

AutoTim

Vielen Dank BugFix!

Dein Script ist gefuchst, ich verstehe auch das du in $aInput[0] die Anzahl der Controls speicherst, aber folgender Ausdruck ist mir nicht verständlich. Was bedeutet es, wenn man ein eindimensionales Array mit drei elementen 0,1,2 erstellt, und dem letzten (2) den Wert [1] zuweist?

AutoIt

Global $aInput[2] = [1]

**BugFix**

Global $aInput[2] = [1]
Das ist nicht die Zuweisung für den INdex "2", sondern Deklaration mit Zuweisung. Linke Seite Deklaration mit Anzahl der Elemente (2), rechte Seite die Werte. Da nur ein Wert eingetragen ist, wird dieser dem Index "0" zugeordnet. Kannst ja mal in mein Array-Tut (s. Signatur) schauen.

AutoTim

Geht klar, vielen Dank!
Problem gelöst