[gelöst] SQLite - Ergebniswerte entsprechen nicht den Spalten, keine Sortierung

**BugFix** · 2. September 2017

Ich habe eine kleine GUI zum Filtern von PLZ nach PLZ oder Ort oder Bundesland oder Landkreis erstellt.

Bei PLZ und ORT ist die Sortierung: PLZ/Ort-Ort/PLZ-Bundesland-Landkreis.

Über die Radio-Ctrl wird die Filterung und bei Bundesland und Landkreis zusätzlich die Sortierung gewählt. Anhand dieser Auswahl wird in Verbindung mit der Usereingabe eine SQL-Abfrage durchgeführt und das Ergebnis in das Listview geladen.

Bei der PLZ-Filterung passt auch alles. Wähle ich aber eine andere Variante, ist zwar die Spalten-Namen-Reihenfolge des Ergebnisarrays identisch mit der Abfrage, aber der Zeileninhalt ist falsch zugeordnet und auch die Sortierung findet nicht statt.

Ich habe mich jetzt 1 Tag damit rumgequält ohne einen Fehler zu finden. Habt ihr eine Ahnung?

Btw.: Führe ich die SQL-Statements im SQLiteDatabaseBrowser aus, erhalte ich die Ergebnisse, wie gewünscht.

Die Datenbank SQLite3.dll und das Skript im Anhang.

AutoIt: PLZ_Auswahl.au3

;-- TIME_STAMP   2017-09-02 16:24:24

#include <SQLite.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <GuiListView.au3>

Opt('GUIOnEventMode', 1)

_SQLite_Startup()

Global $DB = @ScriptDir & '\plz_brd.db'
Global $hSQL = _SQLite_Open($DB)
Global $sUserSearchField = 'plz', $sUserValue

Global $hGui = GUICreate('PLZ der BRD', 480, 300)
GUISetOnEvent(-3, '_Exit')

GUIStartGroup()
Global $rPLZ = GUICtrlCreateRadio('  PLZ', 10, 15, 80)
GUICtrlSetState(-1, $GUI_CHECKED)
Global $rORT = GUICtrlCreateRadio('  Ort', 133, 15, 80)
Global $rBULA = GUICtrlCreateRadio('  Bundesland', 256, 15, 80)
Global $rKREIS = GUICtrlCreateRadio('  Landreis', 379, 15, 80)

GUIStartGroup()
Global $lbOrder = GUICtrlCreateLabel('Sortierung nach:', 155, 43)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $rOrderPlz = GUICtrlCreateRadio('  PLZ', 256, 40, 80)
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $rOrderOrt = GUICtrlCreateRadio('  Ort', 379, 40, 80)
GUICtrlSetState(-1, $GUI_DISABLE)

GUICtrlSetOnEvent($rPLZ, '_RadioClick')
GUICtrlSetOnEvent($rORT, '_RadioClick')
GUICtrlSetOnEvent($rBULA, '_RadioClick')
GUICtrlSetOnEvent($rKREIS, '_RadioClick')
GUICtrlSetOnEvent($rOrderPlz, '_SubRadioClick')
GUICtrlSetOnEvent($rOrderOrt, '_SubRadioClick')

GUICtrlCreateLabel('Suchbegriff', 32, 73)
Global $inSearchWord = GUICtrlCreateInput('', 133, 70, 330)

Global $hListview = GuiCtrlCreateListView('PLZ|Ort|Bundesland|Landkreis', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
_GUICtrlListView_SetColumnWidth($hListview, 0, 60)
_GUICtrlListView_SetColumnWidth($hListview, 1, 135)
_GUICtrlListView_SetColumnWidth($hListview, 2, 135)
_GUICtrlListView_SetColumnWidth($hListview, 3, $LVSCW_AUTOSIZE_USEHEADER)


GUISetState()
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While True
    Sleep(50)
WEnd

Func _Exit()
    _ExitSQLite()
    Exit
EndFunc

Func _RadioClick()
    _ClearListview()
    Switch @GUI_CtrlId
        Case $rPLZ
            _EnDisAbleSortOrder($GUI_DISABLE)
            $sUserSearchField = 'plz'
            _GUICtrlListView_SetColumnOrder($hListview, '0|1|2|3')
        Case $rORT
            _EnDisAbleSortOrder($GUI_DISABLE)
            $sUserSearchField = 'ort'
            _GUICtrlListView_SetColumnOrder($hListview, '1|0|2|3')
        Case $rKREIS, $rBULA
            _EnDisAbleSortOrder($GUI_ENABLE)
            $sUserSearchField = @GUI_CtrlId = $rKREIS ? 'kreis' : 'bula'
            $sUserSearchField &= (BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) ? '-plz-ort' : '-ort-plz')
            If BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) Then
                _SetColumnOrder(@GUI_CtrlId, $rOrderPlz)
            Else
                _SetColumnOrder(@GUI_CtrlId, $rOrderOrt)
            EndIf
    EndSwitch
EndFunc

Func _SubRadioClick()
    _ClearListview()
    $sUserSearchField = BitAND(GUICtrlRead($rKREIS),$GUI_CHECKED) ? 'kreis' : 'bula'
    $sUserSearchField &= (BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) ? '-plz-ort' : '-ort-plz')
    If BitAND(GUICtrlRead($rKREIS),$GUI_CHECKED) Then
        _SetColumnOrder($rKREIS, @GUI_CtrlId)
    Else
        _SetColumnOrder($rBULA, @GUI_CtrlId)
    EndIf
EndFunc

Func _SetColumnOrder($rMain, $rSub)
    If $rMain = $rKREIS And BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) Then ; 'kreis-plz-ort-bula'
        _GUICtrlListView_SetColumnOrder($hListview, '3|0|1|2')
    ElseIf $rMain = $rKREIS And BitAND(GUICtrlRead($rOrderOrt),$GUI_CHECKED) Then ; 'kreis-ort-plz-bula'
        _GUICtrlListView_SetColumnOrder($hListview, '3|1|0|2')
    ElseIf $rMain = $rBULA And BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) Then ; 'bula-plz-ort-kreis'
        _GUICtrlListView_SetColumnOrder($hListview, '2|0|1|3')
    ElseIf $rMain = $rBULA And BitAND(GUICtrlRead($rOrderOrt),$GUI_CHECKED) Then ; 'bula-ort-plz-kreis'
        _GUICtrlListView_SetColumnOrder($hListview, '2|1|0|3')
    EndIf
EndFunc

Func _EnDisAbleSortOrder($iState)
    GUICtrlSetState($lbOrder,$iState)
    GUICtrlSetState($rOrderOrt,$iState)
    GUICtrlSetState($rOrderPlz,$iState)
    GUICtrlSetData($inSearchWord, '')
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iIDFrom, $iCode, $hWndEdit, $sRead, $index
    $hWndEdit = GUICtrlGetHandle($inSearchWord)
    $iIDFrom = BitAND($iwParam, 0xFFFF) ; Low Word
    $iCode = BitShift($iwParam, 16) ; Hi Word
    Switch $ilParam
        Case $hWndEdit
            Switch $iCode
                Case $EN_CHANGE
                    _ClearListview()
                    $sUserValue = GUICtrlRead($iIDFrom)
                    If ($sUserValue = '')  Or _
                       ($sUserSearchField = 'ort' And StringLen($sUserValue) < 3) Then Return $GUI_RUNDEFMSG
                    _PLZSearch_CreateLVItem($sUserValue, $sUserSearchField)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _ClearListview()
    _GUICtrlListView_DeleteAllItems($hListview)
EndFunc

Func _FillListview(ByRef $aItem)
    Local $iUbound = UBound($aItem)
    If $iUbound = 1 Then Return
    _GUICtrlListView_BeginUpdate($hListview)
    For $i = 1 To $iUbound -1
        GUICtrlCreateListViewItem(StringFormat('%s|%s|%s|%s', $aItem[$i][0], $aItem[$i][1], $aItem[$i][2], $aItem[$i][3]), $hListview)
    Next
    _GUICtrlListView_EndUpdate($hListview)
EndFunc

Func _PLZSearch_CreateLVItem($sSearch, $sFieldOrder)
    Local $sQuery = ''
    Switch $sFieldOrder
        Case 'plz'
            $sQuery = "SELECT plz,ort,bula,kreis FROM plz WHERE plz LIKE '" & $sSearch & "%' ORDER BY plz,ort,bula,kreis;"
        Case 'ort'
            $sQuery = "SELECT ort,plz,bula,kreis FROM plz WHERE ort LIKE '" & $sSearch & "%' ORDER BY ort,plz,bula,kreis;"
        Case 'bula-plz-ort'
            $sQuery = "SELECT bula,plz,ort,kreis FROM plz WHERE bula LIKE '" & $sSearch & "%' ORDER BY bula,plz,ort,kreis;"
        Case 'bula-ort-plz'
            $sQuery = "SELECT bula,ort,plz,kreis FROM plz WHERE bula LIKE '" & $sSearch & "%' ORDER BY bula,ort,plz,kreis;"
        Case 'kreis-plz-ort'
            $sQuery = "SELECT kreis,plz,ort,bula FROM plz WHERE kreis LIKE '" & $sSearch & "%' ORDER BY kreis,plz,ort,bula;"
        Case 'kreis-ort-plz'
            $sQuery = "SELECT kreis,ort,plz,bula FROM plz WHERE kreis LIKE '" & $sSearch & "%' ORDER BY kreis,ort,plz,bula;"
    EndSwitch

    _GUICtrlListView_BeginUpdate($hListview)
    Local $hQuery, $aRow, $aColumns
    _SQLite_Query($hSQL, $sQuery, $hQuery)

#region - DEGUG Spaltenreihenfolge
    _SQLite_FetchNames($hQuery, $aColumns)
    Local $sCol = StringFormat('%s-%s-%s-%s', $aColumns[0], $aColumns[1], $aColumns[2], $aColumns[3])
    ConsoleWrite("@@ DEBUG Spaltenreihenfolge Ergebnisarray: " & @TAB & $sCol & @LF)
;~     GUICtrlCreateListViewItem(StringFormat('%s|%s|%s|%s', $aColumns[0], $aColumns[1], $aColumns[2], $aColumns[3]), $hListview)
#endregion - DEGUG Spaltenreihenfolge

    While _SQLite_FetchData($hQuery, $aRow, False, False) = $SQLITE_OK
        GUICtrlCreateListViewItem(StringFormat('%s|%s|%s|%s', $aRow[0], $aRow[1], $aRow[2], $aRow[3]), $hListview)
    WEnd

    _SQLite_QueryFinalize($hQuery)
    _GUICtrlListView_EndUpdate($hListview)
EndFunc


Func _ExitSQLite()
    _SQLite_Close()
    _SQLite_Shutdown()
EndFunc

Alles anzeigen

**AspirinJunkie** · 2. September 2017

Das Problem liegt beim _GUICtrlListView_SetColumnOrder.

Entferne ich die beiden Aufrufe in Zeile 71, 75, 101, 103, 105 und 107 und ändere deine #region - DEGUG Spaltenreihenfolge folgendermaßen:

AutoIt

#region - DEGUG Spaltenreihenfolge
    _SQLite_FetchNames($hQuery, $aColumns)
    Local $sCol = StringFormat('%s|%s|%s|%s', $aColumns[0], $aColumns[1], $aColumns[2], $aColumns[3])

    GUICtrlSetData($hListview, $sCol)
#endregion - DEGUG Spaltenreihenfolge

dann klappt es bei mir.

Übrigens: Wenn du User-Eingaben in SQl-Queries verwendest wie z. B. deinem $sSearch dann solltest du hierfür prinzipiell _SQLite_Escape verwenden damit keine SQL-Injections zu Problemen führen.

Kanashius · 2. September 2017

Das Problem liegt nicht beim SQL. Ich hab mal Testweise die Zeileninhalte ausgegeben und dabei war die Reihenfolge richtig.

Dann hab ich beim ListView geschaut und dort getestet.

Das Problem liegt bei _GUICtrlListView_SetColumnOrder. Das ändert die Reihenfolge der Spalten. Auch der Zeilen, die später hinzugefügt werden.

Also entweder bei der Query nicht die Spaltenreihenfolge ändern, oder die Spaltennamen manuell ändern

PS: Sieh dir mal den Befehl _SQLite_GetTable2d an, der spart dir bei SQL einige Zeilen ein

Was performence angeht aber vermutlich nicht ganz so schnell.

MfG Kanashius

**BugFix** · 2. September 2017

Ah, OK - Danke euch. Dann muss ich das etwas umbauen.

Ich hatte auch zuerst mit _SQLite_GetTable2d gearbeitet. Aber die Zeit, die ich dabei spare, verliere ich anschliessend, weil ich durch das Array iterieren muss um die ListviewItem zu erstellen. Beim Fetchen mache ich das sofort.

_SQLite_Escape zu verwenden ist ein guter Hinweis. Denke ich meist nicht dran, weil ich SQLite fast nur für mich nutze.

**BugFix** · 2. September 2017

Nachtrag:

Ich habe jetzt im Vorfeld für jede Abfragevariante ein eigenes Listview erstellt, das entsprechend eingeblendet wird. Nun läuft alles geschmeidig.

So schaut's jetzt aus:

AutoIt: PLZ_Auswahl.au3

;-- TIME_STAMP   2017-09-02 20:39:02

#include <SQLite.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <GuiListView.au3>

Opt('GUIOnEventMode', 1)

_SQLite_Startup()

Global $DB = @ScriptDir & '\plz_brd.db'
Global $hSQL = _SQLite_Open($DB)
Global $sUserSearchField = 'plz', $sUserValue

Global $hGui = GUICreate('PLZ der BRD', 480, 300)
GUISetOnEvent(-3, '_Exit')

GUIStartGroup()
Global $rPLZ = GUICtrlCreateRadio('  PLZ', 10, 15, 80)
GUICtrlSetState(-1, $GUI_CHECKED)
Global $rORT = GUICtrlCreateRadio('  Ort', 133, 15, 80)
Global $rBULA = GUICtrlCreateRadio('  Bundesland', 256, 15, 80)
Global $rKREIS = GUICtrlCreateRadio('  Landreis', 379, 15, 80)

GUIStartGroup()
Global $lbOrder = GUICtrlCreateLabel('Sortierung nach:', 155, 43)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $rOrderPlz = GUICtrlCreateRadio('  PLZ', 256, 40, 80)
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $rOrderOrt = GUICtrlCreateRadio('  Ort', 379, 40, 80)
GUICtrlSetState(-1, $GUI_DISABLE)

GUICtrlSetOnEvent($rPLZ, '_RadioClick')
GUICtrlSetOnEvent($rORT, '_RadioClick')
GUICtrlSetOnEvent($rBULA, '_RadioClick')
GUICtrlSetOnEvent($rKREIS, '_RadioClick')
GUICtrlSetOnEvent($rOrderPlz, '_RadioClick')
GUICtrlSetOnEvent($rOrderOrt, '_RadioClick')

GUICtrlCreateLabel('Suchbegriff', 32, 73)
Global $inSearchWord = GUICtrlCreateInput('', 133, 70, 330)

Global $hListview_plz = GuiCtrlCreateListView('PLZ|Ort|Bundesland|Landkreis', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
_GUICtrlListView_SetColumnWidth($hListview_plz, 0, 60)
_GUICtrlListView_SetColumnWidth($hListview_plz, 1, 135)
_GUICtrlListView_SetColumnWidth($hListview_plz, 2, 135)
_GUICtrlListView_SetColumnWidth($hListview_plz, 3, $LVSCW_AUTOSIZE_USEHEADER)

Global $hListview_ort = GuiCtrlCreateListView('Ort|PLZ|Bundesland|Landkreis', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
GUICtrlSetState(-1, $GUI_HIDE)
_GUICtrlListView_SetColumnWidth($hListview_ort, 0, 135)
_GUICtrlListView_SetColumnWidth($hListview_ort, 1, 60)
_GUICtrlListView_SetColumnWidth($hListview_ort, 2, 135)
_GUICtrlListView_SetColumnWidth($hListview_ort, 3, $LVSCW_AUTOSIZE_USEHEADER)

Global $hListview_bula_plz_ort = GuiCtrlCreateListView('Bundesland|PLZ|Ort|Landkreis', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
GUICtrlSetState(-1, $GUI_HIDE)
_GUICtrlListView_SetColumnWidth($hListview_bula_plz_ort, 0, 135)
_GUICtrlListView_SetColumnWidth($hListview_bula_plz_ort, 1, 60)
_GUICtrlListView_SetColumnWidth($hListview_bula_plz_ort, 2, 135)
_GUICtrlListView_SetColumnWidth($hListview_bula_plz_ort, 3, $LVSCW_AUTOSIZE_USEHEADER)

Global $hListview_bula_ort_plz = GuiCtrlCreateListView('Bundesland|Ort|PLZ|Landkreis', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
GUICtrlSetState(-1, $GUI_HIDE)
_GUICtrlListView_SetColumnWidth($hListview_bula_ort_plz, 0, 135)
_GUICtrlListView_SetColumnWidth($hListview_bula_ort_plz, 1, 135)
_GUICtrlListView_SetColumnWidth($hListview_bula_ort_plz, 2, 60)
_GUICtrlListView_SetColumnWidth($hListview_bula_ort_plz, 3, $LVSCW_AUTOSIZE_USEHEADER)

Global $hListview_kreis_plz_ort = GuiCtrlCreateListView('Landkreis|PLZ|Ort|Bundesland', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
GUICtrlSetState(-1, $GUI_HIDE)
_GUICtrlListView_SetColumnWidth($hListview_kreis_plz_ort, 0, 135)
_GUICtrlListView_SetColumnWidth($hListview_kreis_plz_ort, 1, 60)
_GUICtrlListView_SetColumnWidth($hListview_kreis_plz_ort, 2, 135)
_GUICtrlListView_SetColumnWidth($hListview_kreis_plz_ort, 3, $LVSCW_AUTOSIZE_USEHEADER)

Global $hListview_kreis_ort_plz = GuiCtrlCreateListView('Landkreis|Ort|PLZ|Bundesland', 10, 100, 460, 190, -1, BitOR($LVS_EX_DOUBLEBUFFER,$LVS_EX_GRIDLINES))
GUICtrlSetState(-1, $GUI_HIDE)
_GUICtrlListView_SetColumnWidth($hListview_kreis_ort_plz, 0, 135)
_GUICtrlListView_SetColumnWidth($hListview_kreis_ort_plz, 1, 135)
_GUICtrlListView_SetColumnWidth($hListview_kreis_ort_plz, 2, 60)
_GUICtrlListView_SetColumnWidth($hListview_kreis_ort_plz, 3, $LVSCW_AUTOSIZE_USEHEADER)


GUISetState()
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While True
    Sleep(50)
WEnd

Func _Exit()
    _ExitSQLite()
    Exit
EndFunc

Func _RadioClick()
    Local $hLV = _CurrentListview()
    _ClearListview($hLV)
    GUICtrlSetData($inSearchWord, '')
    _ShowHideLV($hLV)
    Switch @GUI_CtrlId
        Case $rPLZ
            _EnDisAbleSortOrder($GUI_DISABLE)
            $sUserSearchField = 'plz'
        Case $rORT
            _EnDisAbleSortOrder($GUI_DISABLE)
            $sUserSearchField = 'ort'
        Case $rKREIS, $rBULA
            _EnDisAbleSortOrder($GUI_ENABLE)
            $sUserSearchField = @GUI_CtrlId = $rKREIS ? 'kreis' : 'bula'
            $sUserSearchField &= (BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) ? '-plz-ort' : '-ort-plz')
        Case $rOrderPlz, $rOrderOrt
            $sUserSearchField = BitAND(GUICtrlRead($rKREIS),$GUI_CHECKED) ? 'kreis' : 'bula'
            $sUserSearchField &= (BitAND(GUICtrlRead($rOrderPlz),$GUI_CHECKED) ? '-plz-ort' : '-ort-plz')
    EndSwitch
EndFunc

Func _EnDisAbleSortOrder($iState)
    GUICtrlSetState($lbOrder,$iState)
    GUICtrlSetState($rOrderOrt,$iState)
    GUICtrlSetState($rOrderPlz,$iState)
EndFunc

Func _ShowHideLV($hLV_show)
    Local Static $aLV[] = [$hListview_plz,$hListview_ort,$hListview_bula_plz_ort,$hListview_bula_ort_plz,$hListview_kreis_plz_ort,$hListview_kreis_ort_plz]
    For $i = 0 To 5
        GUICtrlSetState($aLV[$i], $GUI_HIDE)
    Next
    GUICtrlSetState($hLV_show, $GUI_SHOW)
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iIDFrom, $iCode, $hWndEdit, $sRead, $index
    $hWndEdit = GUICtrlGetHandle($inSearchWord)
    $iIDFrom = BitAND($iwParam, 0xFFFF) ; Low Word
    $iCode = BitShift($iwParam, 16) ; Hi Word
    Switch $ilParam
        Case $hWndEdit
            Switch $iCode
                Case $EN_CHANGE
                    _ClearListview(_CurrentListview())
                    $sUserValue = GUICtrlRead($iIDFrom)
                    If ($sUserValue = '')  Or _
                       ($sUserSearchField = 'ort' And StringLen($sUserValue) < 3) Then Return $GUI_RUNDEFMSG
                    _PLZSearch_CreateLVItem($sUserValue, $sUserSearchField)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _ClearListview($hLV)
    _GUICtrlListView_DeleteAllItems($hLV)
EndFunc

Func _CurrentListview()
    Select
        Case BitAND(GUICtrlRead($rPLZ), $GUI_CHECKED)
            Return $hListview_plz
        Case BitAND(GUICtrlRead($rORT), $GUI_CHECKED)
            Return $hListview_ort
        Case BitAND(GUICtrlRead($rBULA), $GUI_CHECKED)
            If BitAND(GUICtrlRead($rOrderPlz), $GUI_CHECKED) Then
                Return $hListview_bula_plz_ort
            Else
                Return $hListview_bula_ort_plz
            EndIf
        Case BitAND(GUICtrlRead($rKREIS), $GUI_CHECKED)
            If BitAND(GUICtrlRead($rOrderPlz), $GUI_CHECKED) Then
                Return $hListview_kreis_plz_ort
            Else
                Return $hListview_kreis_ort_plz
            EndIf
    EndSelect
EndFunc

Func _PLZSearch_CreateLVItem($sSearch, $sFieldOrder)
    Local $sQuery = ''
    Switch $sFieldOrder
        Case 'plz'
            $sQuery = "SELECT plz,ort,bula,kreis FROM plz WHERE plz LIKE " & _SQLite_Escape($sSearch & '%') & " ORDER BY plz,ort,bula,kreis;"
        Case 'ort'
            $sQuery = "SELECT ort,plz,bula,kreis FROM plz WHERE ort LIKE " & _SQLite_Escape($sSearch & '%') & " ORDER BY ort,plz,bula,kreis;"
        Case 'bula-plz-ort'
            $sQuery = "SELECT bula,plz,ort,kreis FROM plz WHERE bula LIKE " & _SQLite_Escape($sSearch & '%') & " ORDER BY bula,plz,ort,kreis;"
        Case 'bula-ort-plz'
            $sQuery = "SELECT bula,ort,plz,kreis FROM plz WHERE bula LIKE " & _SQLite_Escape($sSearch & '%') & " ORDER BY bula,ort,plz,kreis;"
        Case 'kreis-plz-ort'
            $sQuery = "SELECT kreis,plz,ort,bula FROM plz WHERE kreis LIKE " & _SQLite_Escape($sSearch & '%') & " ORDER BY kreis,plz,ort,bula;"
        Case 'kreis-ort-plz'
            $sQuery = "SELECT kreis,ort,plz,bula FROM plz WHERE kreis LIKE " & _SQLite_Escape($sSearch & '%') & " ORDER BY kreis,ort,plz,bula;"
    EndSwitch

    _GUICtrlListView_BeginUpdate(_CurrentListview())
    Local $hQuery, $aRow, $aColumns
    _SQLite_Query($hSQL, $sQuery, $hQuery)

    While _SQLite_FetchData($hQuery, $aRow, False, False) = $SQLITE_OK
        GUICtrlCreateListViewItem(StringFormat('%s|%s|%s|%s', $aRow[0], $aRow[1], $aRow[2], $aRow[3]), _CurrentListview())
    WEnd

    _SQLite_QueryFinalize($hQuery)
    _GUICtrlListView_EndUpdate(_CurrentListview())
EndFunc


Func _ExitSQLite()
    _SQLite_Close()
    _SQLite_Shutdown()
EndFunc

Alles anzeigen

**AspirinJunkie** · 2. September 2017

Warum nicht das _GUICtrlListView_SetColumnOrder durch ein GUICtrlSetData austauschen?
Dann kannst du die Spaltenreihenfolge neu festlegen und hast immer noch das selbe ListView. Sollte meiner Meinung nach deutlich sauberer sein.

**BugFix** · 2. September 2017

Zitat von AspirinJunkie

Dann kannst du die Spaltenreihenfolge neu festlegen und hast immer noch das selbe ListView.

Ich habe diese Variante mal durchgespielt.

Dann erfolgt die Spaltenumbenennung erst beim Befüllen mit Daten (finde ich dann nicht gelungen, die Feldnamen sind auch noch in die gewünschte Spaltenbezeichnung umzuwandeln), die Spaltenbreite muss auch noch angepasst werden. Insofern bevorzuge ich doch die Variante mit vordefinierten Listview.

**AspirinJunkie** · 2. September 2017

Nur wenn du es so machst wie in meinem Beispiel oben.
Wenn du stattdessen in deinem alten Aufbau die _GUICtrlListView_SetColumnOrder durch die GuiCtrlSetData ersetzt sollte sich die Spaltenreihenfolge in dem Moment ändern wenn du die umschaltest - und nicht erst sobald Suchergebnisse vorliegen.

Teilen