Alt tab in AutoIt nachbauen für ein Programm - Windows

#include <GDIPlus.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <WinAPIProc.au3>
#include <WinAPIDiag.au3>
#include <GDIPlus.au3>
#include <Math.au3>
;prevent autoit BUG
DllCall("user32.dll", "bool", "SetProcessDPIAware")
Opt("MustDeclareVars", True)
_GDIPlus_Startup()
Global $ahCaptures[4]
Global $hMainWnd = GUICreate("Browser Screen Preview", 600, 400)
Global $hGfx = _GDIPlus_GraphicsCreateFromHWND($hMainWnd)
Global $hBmp = _GDIPlus_BitmapCreateFromGraphics(600, 400, $hGfx)
Global $hBuf = _GDIPlus_ImageGetGraphicsContext($hBmp)
;register handlers
OnAutoItExitRegister(exitProgram)
AdlibRegister(updateWindowPreviews, 2000)
updateWindowPreviews() ;initial call
GUISetState()
While True
Switch GUIGetMsg()
Case -3
Exit
EndSwitch
_GDIPlus_GraphicsClear($hBuf, 0xffffffff) ;white background
If $ahCaptures[0] Then _GDIPlus_GraphicsDrawImageRect($hBuf, $ahCaptures[0], 0, 0, 300, 200)
If $ahCaptures[1] Then _GDIPlus_GraphicsDrawImageRect($hBuf, $ahCaptures[1], 300, 0, 300, 200)
If $ahCaptures[2] Then _GDIPlus_GraphicsDrawImageRect($hBuf, $ahCaptures[2], 0, 200, 300, 200)
If $ahCaptures[3] Then _GDIPlus_GraphicsDrawImageRect($hBuf, $ahCaptures[3], 300, 200, 300, 200)
_GDIPlus_GraphicsDrawImage($hGfx, $hBmp, 0, 0)
WEnd
Func updateWindowPreviews()
Local $aWndList, $iWinCount, $hWnd, $i
$aWndList = getProcessWindows("firefox.exe", "^MozillaWindowClass$")
$iWinCount = _Min(4, UBound($aWndList)) ;maximum of four windows
For $i = 0 To 3
$ahCaptures[$i] = Null
Next
For $i = 0 To $iWinCount - 1
$hWnd = $aWndList[$i]
$ahCaptures[$i] = captureWindow($hWnd)
$ahCaptures[$i] = _GDIPlus_BitmapCreateFromHBITMAP($ahCaptures[$i]) ;gdiplus workaround
Next
EndFunc   ;==>updateWindowPreviews
Func exitProgram()
;dispose gdi resources
_GDIPlus_GraphicsDispose($hBuf)
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_Shutdown()
;make sure to re-enable window animations
setMinAnimation(True)
EndFunc   ;==>exitProgram
; - - - MULTI PURPOSE FUNCTIONS - - -
Func getProcessWindows($sWantedProcess, $sClassFilter = ".*")
;by chesstiger
Local $iPID, $oRet, $ahWindows, $i
$oRet = ObjCreate("System.Collections.ArrayList")
$ahWindows = _WinAPI_EnumWindows()
For $i = 1 To $ahWindows[0][0]
_WinAPI_GetWindowThreadProcessId($ahWindows[$i][0], $iPID) ;byref!
If _WinAPI_GetProcessName($iPID) = $sWantedProcess Then
If StringRegExp($ahWindows[$i][1], $sClassFilter) Then $oRet.add($ahWindows[$i][0])
EndIf
Next
Return $oRet.toArray()
EndFunc   ;==>getProcessWindows
Func captureWindow($hWnd, $iWidth = -1, $iHeight = -1)
;by chesstiger
;with minimized window workaround
Local $hDDC, $hCDC, $hBmp
Local $tWindowPlacement, $bMinimized, $iOldLong
$tWindowPlacement = _WinAPI_GetWindowPlacement($hWnd)
$bMinimized = ($tWindowPlacement.showCmd = @SW_SHOWMINIMIZED)
If $bMinimized Then
setMinAnimation(False) ;disable animations
$iOldLong = _WinAPI_GetWindowLong($hWnd, $GWL_EXSTYLE) ;make window invisible
_WinAPI_SetWindowLong($hWnd, $GWL_EXSTYLE, BitOR($iOldLong, $WS_EX_LAYERED))
_WinAPI_SetLayeredWindowAttributes($hWnd, 0, 0, $LWA_ALPHA)
_WinAPI_ShowWindow($hWnd, @SW_RESTORE) ;restore window
EndIf
;real screenshot
If $iWidth = -1 Then $iWidth = _WinAPI_GetWindowWidth($hWnd)
If $iHeight = -1 Then $iHeight = _WinAPI_GetWindowHeight($hWnd)
$hDDC = _WinAPI_GetDC($hWnd)
$hCDC = _WinAPI_CreateCompatibleDC($hDDC)
$hBmp = _WinAPI_CreateCompatibleBitmap($hDDC, $iWidth, $iHeight)
_WinAPI_SelectObject($hCDC, $hBmp)
_WinAPI_PrintWindow($hWnd, $hCDC)
_WinAPI_BitBlt($hCDC, 0, 0, 0, 0, $hDDC, 0, 0, 0x00330008)
_WinAPI_ReleaseDC($hWnd, $hDDC)
_WinAPI_DeleteDC($hCDC)
If $bMinimized Then
_WinAPI_ShowWindow($hWnd, @SW_MINIMIZE) ;minimize window
_WinAPI_SetWindowLong($hWnd, $GWL_EXSTYLE, $iOldLong) ;make window visible again
setMinAnimation(True) ;re-enable animations
EndIf
Return $hBmp
EndFunc   ;==>captureWindow
Func setMinAnimation($bState)
;by chesstiger
Local Const $SPI_SETANIMATION = 0x0049
Local Const $tagANIMATIONINFO = "uint cbSize;int iMinAnimate"
Local $tAnimInfo
$tAnimInfo = DllStructCreate($tagANIMATIONINFO)
$tAnimInfo.iMinAnimate = $bState
$tAnimInfo.cbSize = DllStructGetSize($tAnimInfo)
_WinAPI_SystemParametersInfo($SPI_SETANIMATION, $tAnimInfo.cbSize, DllStructGetPtr($tAnimInfo))
EndFunc   ;==>setMinAnimation