Array aus Fileopendialog

Sascha123456

Hi,

bin grad am rätseln ob das so überhaupt gehen kann?

Ich öffne über fileopendialog einen ordner indem dann dateien gewählt werden und anschließend möchte ich abfragen wie viele dateien gewählt wurden. (denn eine bestimmte menge muss hier gewählt werden)

Code

$sFileName = FileOpenDialog("Bitte wähle die Dateien", "Pfad" , $FD_FILEMUSTEXIST + $FD_PATHMUSTEXIST + $FD_MULTISELECT)

Global $dateimenge
$dateimenge = DirGetSize($sFileName, BitOR($DIR_EXTENDED, $DIR_NORECURSE))
If $dateimenge[1] < 5 Then
   MsgBox(16+262144, "Fehler", "Es wurden zu wenig Dateien ausgewählt!")
   $sFileName = FileOpenDialog("Bitte wähle die Dateien.", "Pfad" , $FD_FILEMUSTEXIST + $FD_PATHMUSTEXIST + $FD_MULTISELECT)
   EndIf

Aber kann ich überhaupt mir aus Fileopendialog die Menge als array zurück geben lassen? Denn ich erhalte ich den Fehler das meine variable wohl keine Menge liefert, wenn ich das richtig verstehe.

**Oscar**

Du kannst bei FileOpenDialog nicht einfach Parameter weglassen (Filter) und bei "Init Dir" sollte ein Pfad stehen und nicht der String "Pfad". Alternativ darf es dort ein Leerstring sein (es wird dann das aktuelle WorkingDir benutzt).

Außerdem gibt FileOpenDialog bei einer Mehrfachauswahl die Dateien durch eine Pipe ("|") getrennt zurück. Wobei am Anfang das Verzeichnis steht und dahinter nur jeweils die Dateinamen.

Will man alle Dateien in einem Array haben, muss man die Rückgabe etwas bearbeiten:

AutoIt

#include <Array.au3>
#include <FileConstants.au3>

Global $aFiles = _SelectFiles(5)
_ArrayDisplay($aFiles)

Func _SelectFiles($iSelectCount)
    Do
        Local $sFiles = FileOpenDialog("Bitte wähle die Dateien", '', 'All (*.*)', BitOR($FD_FILEMUSTEXIST, $FD_PATHMUSTEXIST, $FD_MULTISELECT))
        If @error Then Return
        If StringInStr($sFiles, '|') Then
            Local $aTmp = StringSplit($sFiles, '|', 2)
            Local $aFiles[UBound($aTmp) - 1]
            For $i = 1 To UBound($aTmp) - 1
                $aFiles[$i - 1] = $aTmp[0] & $aTmp[$i]
            Next
        Else
            Local $aFiles[1] = [$sFiles]
        EndIf
        If UBound($aFiles) < $iSelectCount Then MsgBox($MB_ICONERROR + $MB_TOPMOST, "Fehler", "Es wurden zu wenig Dateien ausgewählt!")
    Until UBound($aFiles) >= $iSelectCount
    Return $aFiles
EndFunc

Alles anzeigen

NO1 :-)

Fileopendialog gibt einen String zurück, der Dateinamen enthält.

Wenn du 1 Datei auswählst schaut der Pfad in etwa so aus:

Laufwerk:\Ordner\...\Ordner\Datei

Wenn mehrere Dateien gewählt werden wird

Laufwerk:\Ordner\...\Ordner|Datei 1|Datei 2|...

zurückgegeben.

Mit FileSelectFolder kannst du einen Ordner auswählen.

In jedem Fall benötigt DirGetSize als Parameter einen Ordner und keine Datei!

Du kannst also entweder FileSelectFolder verwenden oder du musst aus deinem FileOpenDialog den Ordnerpfad extrahieren.

EDIT: Da war wohl jemand schneller

Sascha123456

super vielen dank, das mit der pipe wusste ich nicht. Danke, wieder was gelernt