Pfadangabe mit Variable

pillic

Hallo zusammen,

ich brauche eine kleine rename.exe der man via Kommandozeile einen Dateinamen mitgeben kann und die dann diese Datei umbenennt.

Beispiel: via Kommandozeile "rename.exe test.txt "-> damit wird aus der test.txt " 2020-02-06-15-27-39-test.txt"

Ohne Variable hab ich es auch hinbekommen, aber jetzt komm ich nicht weiter.

Fehlermeldung:

Line 5 (File "C:\temp\Wasserzeichen-Copyright\filerenamer2.au3"):

$dest = C:\temp\Wasserzeichen-Copyright\

$dest = C:^ Error

Error:

C

#Include <File.au3>
#include <Date.au3>

#################################### hier liegt das Problem
$path = "C:\temp\Wasserzeichen-Copyright\" & $CmdLineRaw
$dest = C:\temp\Wasserzeichen-Copyright\

FileMove($path, $dest @YEAR & "-" & @MON & "-" & @MDAY & "-" & @HOUR & "-" & @MIN & "-" & @SEC & "-" & $CmdLineRaw,1)

Ich würde mich freuen, wenn wenn ein Wissender hier den entscheidenden Tip geben kann.

Vielen Dank im Vorraus

**Musashi**

C

#Include <File.au3>
#include <FileConstants.au3>

Global $g_sSourcePath = "C:\Temp\Wasserzeichen-Copyright\"
Global $g_sDestPath   = "C:\Temp\Wasserzeichen-Copyright\"

Global $g_sFilename, $g_sPrefix

If $CMDLINE[0] Then
    $g_sPrefix = @YEAR & "-" & @MON & "-" & @MDAY & "-" & @HOUR & "-" & @MIN & "-" & @SEC & "-"
    $g_sFilename = $CMDLINE[1]
    FileMove($g_sSourcePath & $g_sFilename, $g_sDestPath & $g_sPrefix & $g_sFilename, $FC_OVERWRITE)
Else
    ConsoleWrite("! @@ERROR : $CMDLINE" & @CRLF)
    Exit
EndIf

Alles anzeigen

Gruß Musashi

pillic

Hey Musashi,

perfekt. So läuft es wie es soll.

Vielen Dank

pillic

Ich stelle gerade fest, dass die .exe auf dem Server ja andere Pfade benutzt.

DIe .exe wird in D:\Scripte\renamer.exe liegen.

Und dann ist die Quelle der umzubenennen Datei D:\WEBSERVER\NW\ - wie auch der Zielpfad.

Konkret lautet der Aufruf von "freepdf":

D:\Scripte\renamer.exe D:\WEBSERVER\NW\Mischungsberechnung.pdf.

Ich hatte gedacht mit $CMDLINE = StringTrimLeft($CMDLINE,16) kann ich nur den Dateinamen ändern lassen, aber das gibt immer einen Fehler:

Line 3065 (File "C:\temp\Wasserzeichen-Copyright\filerenamer2.exe"):

Error: Subscript used on non-accessible variable.

Hast Du hier noch eine Idee?

**Musashi**

Zitat von pillic

Hast Du hier noch eine Idee?

Bin gerade etwas abgelenkt, da ich selbst an einem Projekt arbeite .

Dein Programm liegt also auf D:\Scripte\renamer.exe und wird auch dort gestartet, korrekt ?

Startest Du das Programm direkt, oder per CMD (Batch) ?

Quelle und Ziel der umzubenennenden Datei ist D:\WEBSERVER\NW\ , korrekt ?

Was macht den folgendes Skript ? :

C

#Include <File.au3>
#include <FileConstants.au3>

Global $g_sSourcePath = "D:\WEBSERVER\NW\"
Global $g_sDestPath   = "D:\WEBSERVER\NW\"

Global $g_sFilename, $g_sPrefix, $g_iMoveOk

If $CMDLINE[0] Then
    $g_sPrefix = @YEAR & "-" & @MON & "-" & @MDAY & "-" & @HOUR & "-" & @MIN & "-" & @SEC & "-"
    $g_sFilename = $CMDLINE[1]
    $g_iMoveOk = FileMove($g_sSourcePath & $g_sFilename, $g_sDestPath & $g_sPrefix & $g_sFilename, $FC_OVERWRITE)
    If Not $g_iMoveOk Then
        ConsoleWrite("! @@ERROR : FileMove" & @CRLF)
    Else
        ConsoleWrite("+ @@OK : FileMove" & @CRLF)
    EndIf
Else
    ConsoleWrite("! @@ERROR : $CMDLINE" & @CRLF)
    Exit
EndIf

Alles anzeigen

pillic

Kein Problem, ich bin ja für jede Hilfe Dankbar.

Folgendes Setup: Auf dem Server (MS2003) wird von den Usern via Freepdf gedruckt. Die pdf Dateien landen im Ordner D:\WEBSERVER\NW\.

In Freepdf kann ich eine Aktion nach PDF Erstellung definieren. Das wäre dann die Befehlszeile D:\Scripte\renamer.exe %pdfFile und noch Variablen mitgeben, wie Name, Datum, Uhrzeit. In meinem Fall nur der Name (%pdfFile).

In freepdf seh ich dann folgenden Aufruf:

D:\Scripte\filerenamer.exe D:\WEBSERVER\NW\Mix Design - Mischungsberechnung.pdf

Warum jetzt via AutoIt - weil ich auch den angemeldeten User (@UserName) in den Namen schreiben muss.

Bei dem 2.Script passiert leider gar nichts.Keine Fehlermeldung und auch keine Dateiumbenennung.

**Musashi**

Zitat von pillic

In Freepdf kann ich eine Aktion nach PDF Erstellung definieren. Das wäre dann die Befehlszeile

Ah ok, der Aufruf wird also von Freepdf generiert.

Aber warum heißt es einmal D:\Scripte\renamer.exe und dann D:\Scripte\filerenamer.exe , und der Dateiname lautet wirklich Mix Design - Mischungsberechnung.pdf ?

Muss gleich mal weg, antworte aber später.

pillic

Ich habe die .exe umbenannt und dann nicht wieder zurück, um es hier zu posten.

Ja, so heißt eine der möglichen Dateien ("Durchgeführte Prüfungen.pdf", "BSV als Kostenliste (EN - Sorten).pdf") - wenn es einfacher ist, können auch alle Leerzeichen durch Unterstriche ersetzt werden.

Keine Eile

Vielen Dank

**Musashi**

Starte bitte mal folgendes Skript mit dem Parameter und poste das Ergebnis :

Code

MsgBox(0, "Parameter", $CMDLINERAW & @CRLF)

(dies ist quasi ein Dummy für die renamer.exe)

EDIT : pillic

Zitat von pillic

Ja, so heißt eine der möglichen Dateien

Aus z.B. Durchgeführte Prüfungen.pdf soll dann 2020-02-06-15-27-39-Durchgeführte Prüfungen.pdf werden, korrekt ?

Zitat von pillic

wenn es einfacher ist, können auch alle Leerzeichen durch Unterstriche ersetzt werden

Nicht zwingend erforderlich, aber etwas einfacher wäre es schon .

pillic

In der Box steht:

D:\WEBSERVER\NW\Mix Design - Mischungsberechnung.pdf

Zitat

Aus z.B. Durchgeführte Prüfungen.pdf soll dann 2020-02-06-15-27-39-Durchgeführte Prüfungen.pdf werden, korrekt ?

+ der Username vorangestellt, also: user1-2020-02-06-15-27-39-Durchgeführte Prüfungen.pdf ... Die User arbeiten per Terminalsession in der APP auf dem Server, drucken aber alle in einen Webordner (historisch bedingt).

Zitat

Nicht zwingend erforderlich, aber etwas einfacher wäre es schon .

Dann so simple wie möglich - falls man das so sagen kann - soll heißen, da bin ich absolut flexibel.

Vielen Dank!

**Musashi**

Zitat von pillic

+ der Username vorangestellt, also: user1-2020-02-06-15-27-39-Durchgeführte Prüfungen.pdf

Für den Usernamen habe ich hier das Makro @UserName verwendet :

C

#Include <File.au3>
#include <FileConstants.au3>

Global $g_sParam, $g_sFileOld, $g_sFileNew, $g_sPrefix
Global $g_aPathSplit, $g_sDrive = "", $g_sDir = "", $g_sFileName = "", $g_sExtension = ""

; Hinweis : Startet man das Skript aus dem SciTE-Editor (also nicht die kompilierte .exe),
;           dann enthält $CMDLINERAW : /ErrorStdOut "[ScriptFullPath]" ==> ENTFERNEN
If Not @Compiled Then
    $g_sParam = StringStripWS(StringReplace($CMDLINERAW,'/ErrorStdOut "' & @ScriptFullPath & '" ', ""), 3)
Else
    $g_sParam = StringStripWS($CMDLINERAW, 3)
EndIf

If $g_sParam <> '' Then
    $g_sPrefix    = @UserName & "-"& @YEAR & "-" & @MON & "-" & @MDAY & "-" & @HOUR & "-" & @MIN & "-" & @SEC & "-"
    $g_aPathSplit = _PathSplit($g_sParam, $g_sDrive, $g_sDir, $g_sFileName, $g_sExtension)
    $g_sFileOld   = $g_aPathSplit[1] & $g_aPathSplit[2] & $g_aPathSplit[3] & $g_aPathSplit[4]
    $g_sFileNew   = $g_aPathSplit[1] & $g_aPathSplit[2] & $g_sPrefix & $g_aPathSplit[3] & $g_aPathSplit[4]
    If Not FileMove($g_sFileOld, $g_sFileNew, $FC_OVERWRITE) Then MsgBox(16, "Meldung", "FileMove fehlgeschlagen")
Else
    MsgBox(48, "Meldung", "Übergabeparameter ist leer")
    Exit
EndIf

Alles anzeigen

Gruß Musashi

pillic

Wow, vielen Dank für die Mühe. Ich hätte nicht gedacht, dass es so aufwendig wird (so sieht es für mich zumindest aus).

Ich werd' jetzt erst am am Montag zum Testen kommen. Gebe aber dann umgehend Bescheid.

Schönes WE

**Musashi**

Zitat von pillic

Wow, vielen Dank für die Mühe. Ich hätte nicht gedacht, dass es so aufwendig wird (so sieht es für mich zumindest aus).

Na ja, sooo aufwendig ist es nun auch nicht (24 Zeilen ). Man könnte sogar einiges kürzen bzw. weglassen, aber ich wollte, dass es für Dich nachvollziehbar bleibt. Da kommen sicher noch Dinge hinzu.

Gruß Musashi

**Bitnugger**

Zitat von Musashi

Na ja, sooo aufwendig ist es nun auch nicht (24 Zeilen ). Man könnte sogar einiges kürzen bzw. weglassen, aber ich wollte, dass es für Dich nachvollziehbar bleibt.

Hihi... ja, mit viel Mühe kann man da sicher auch einen Einzeiler draus machen, den dann aber keiner mehr lesen kann.

Hier mal meine etwas kürzere Version:

C++

#Include <File.au3>

Global $g_sParam, $g_sPrefix, $g_sDrive = "", $g_sDir = "", $g_sFileName = "", $g_sExtension = ""

; Wird das Skript aus dem SciTE-Editor (also nicht die kompilierte .exe) gestartet, enthält $CMDLINERAW : /ErrorStdOut "[ScriptFullPath]" ==> ENTFERNEN
$g_sParam = StringStripWS(@Compiled ? $CMDLINERAW : StringReplace($CMDLINERAW, '/ErrorStdOut "' & @ScriptFullPath & '" ', ""), 3)
If $g_sParam = '' Then Exit MsgBox(48, "Meldung", "Übergabeparameter ist leer")
$g_sPrefix    = @UserName & "-"& @YEAR & "-" & @MON & "-" & @MDAY & "-" & @HOUR & "-" & @MIN & "-" & @SEC & "-"
_PathSplit($g_sParam, $g_sDrive, $g_sDir, $g_sFileName, $g_sExtension)
If Not FileMove($g_sDrive & $g_sDir & $g_sFileName & $g_sExtension, $g_sDrive & $g_sDir & $g_sPrefix & $g_sFileName & $g_sExtension, $FC_OVERWRITE) Then _
    MsgBox(16, "Meldung", "FileMove fehlgeschlagen" & @CRLF & "$g_sParam = " & $g_sParam)

Alles anzeigen

pillic

PERFEKT! beide Scripte laufen auf dem Server in den Ordnern und machen genau das, wofür ich sie brauche.

Vielen Dank Musashi und Bitnugger , wenn auch nicht für die Mühe , dann für die investierte Zeit.

Pfadangabe mit Variable

Ähnliche Themen

Compiler Output-Zeilen ermitteln und bearbeiten - Vorschläge und Meinungen?