Font size ist irgendwie komisch

**Oscar**

Zitat von Professor Bernd

Am Ende deines Code werden viele Sachen freigegeben. Wenn ich das in meinem Programm übernehme, muss ich dann am Ende des Programms noch etwas freigeben, oder ist schon alles freigegeben?

Nee, ist alles schon wieder freigegeben. Wird nur temporär gebraucht.

Die TABs musst Du natürlich selbst festlegen. Wenn z.B. ein TAB vier Leerzeichen entsprechen soll, dann musst Du die entsprechend ersetzen:

AutoIt

 #include <AutoItConstants.au3>
#include <GDIPlus.au3>
#include <SendMessage.au3>
#include <StaticConstants.au3>
#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>
#include <GUIConstantsEx.au3> ; Für $GUI_EVENT_CLOSE.

Example1()

Func Example1()
    Local $hGui = GUICreate("My GUI", 400, 800)
    Local $iTop = 0

    ; Labels mit verschiedener Schriftgöße erstellen.
    For $i = 4 To 27
        $iTop += 15 + $i
        GUICtrlCreateLabel("fontsize " & $i, 10, $iTop, 0, 0, $SS_BITMAP) ; Wichtig! $SS_BITMAP als Style
        _GUICtrlSetFont(-1, "fontsize" & $i, $i, 0, "Courier New", 0xFF00007F)
        GUICtrlSetBkColor(-1, 0xCCCCFF)  ; <== Um zu erkennen, wenn sich die Größe des Labels ändert.
    Next
    GUISetState(@SW_SHOW)


    Local $idBtn_1 = GUICtrlCreateButton("Change Label 7 Text", 200, 130, 120)
    Local $sNewText = "    This is a        sample text to fill the label."

    While 1
        Switch GUIGetMsg()

            Case $idBtn_1
                $sNewText = StringReplace($sNewText, @TAB, '    ') ; TABs in 4 Leerzeichen umwandeln
                _GUICtrlSetFont(7, $sNewText, 8, 0, "Courier New", 0xFF00007F)
                GUICtrlSetBkColor(7, 0xCCCCAA) ; <== Nur um zu sehen, ob das hier einen Einfluss hat.

            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd
EndFunc   ;==>Example1


Func _GUICtrlSetFont($idCtrl, $sString, $iSize, $iStyle, $sFontname, $iColor = 0xFF000000)
    Local $hWnd, $hBitmap, $hGfxCtx, $hBrush, $hFormat, $hFamily, $hFont, $tLayout, $aInfo
    Local $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    If $iStyle = Default Or $iStyle <= 0 Then $iStyle = 0
    $hWnd = GUICtrlGetHandle($idCtrl)
    If Not IsHWnd($hWnd) Then Return SetError(1)
    Local $iW = 1000, $iH = 100
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $hBrush = _GDIPlus_BrushCreateSolid($iColor)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname)
    $hFont = _GDIPlus_FontCreate($hFamily, $iSize, $iStyle)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    $iW = Ceiling($aInfo[0].Width)
    $iH = Ceiling($aInfo[0].Height)
;~     ConsoleWrite(StringFormat('Width x Height = %i x %i\r\n', $iW, $iH))
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDrawStringEx($hGfxCtx, $sString, $hFont, $aInfo[0], $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    _WinAPI_SetWindowPos($hWnd, $HWND_NOTOPMOST, 0, 0, $iW, $iH, BitOR($SWP_FRAMECHANGED, $SWP_NOMOVE))
    $hPrevImage = _SendMessage($hWnd, $STM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    If $hPrevImage Then _WinAPI_DeleteObject($hPrevImage)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc   ;==>_GUICtrlSetFont

Alles anzeigen

**Oscar**

Ich habe die Funktion jetzt noch etwas verändert und sie auch umbenannt ("_GUICtrlSetText").

Man sollte ein Pic-Control verwenden, weil das beim Label mit der Transparenz nicht klappt.

Außerdem gebe ich jetzt ein Array zurück mit den neuen Abmessungen ([0] = Width und [1] = Height).

Spoiler anzeigen

AutoIt

#include <AutoItConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <StaticConstants.au3>
#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>


Global $sPicfile = StringRegExpReplace(@AutoItExe, '(.+\\).+', '$1') & 'Examples\Helpfile\Extras\Pattern.bmp'

Example1()

Func Example1()
    Local $iTop = 10, $aidPic[24], $aSize
    Local $hGui = GUICreate("My GUI", 500, 800)
    GUICtrlCreatePic($sPicfile, 0, 0, 500, 800) ; Hintergrundgrafik, zum demonstrieren der Transparenz
    ; Labels mit verschiedener Schriftgöße erstellen.
    For $i = 4 To 27
        $aidPic[$i - 4] = GUICtrlCreatePic('', 10, $iTop, 0, 0) ; Ein Pic-Control, weil mit einem Label die Transparenz nicht funktioniert
        $aSize = _GUICtrlSetText(-1, 'gp | Fontsize ' & $i, $i, 0, 'Courier New', 0xFF000000)
        If Not @error Then
            $iTop += $aSize[1] + 2 ; das Array "$aSize" enthaelt: [0] = Width und [1] = Height
        EndIf
    Next
    GUISetState(@SW_SHOW)
    MsgBox(0, 'Test', 'Einen Text ersetzen.')
    _GUICtrlSetText($aidPic[18], 'New Text: _öäü²', 22, 1, 'Courier New', 0xFFEEEE00, 0xFF000044)
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example1

;===============================================================================
; Name:             : _GUICtrlSetText
; Description:        : Funktion zum einfuegen von Text in ein Pic-Control.
;                      Das Pic-Control wird automatisch an die Textlaenge/-hoehe angepasst.
; Syntax:           : _GUICtrlSetText($idCtrl, $sString, $iSize, $iStyle, $sFontname[, $iColor][, $iBkColor])
; Parameter(s):        : $idCtrl = die Control-ID von GUICtrlCreatePic
;                      $sString = der Text, der eingefuegt werden soll
;                      $iSize = die Fontgroesse
;                      $iStyle = der Fontstyle (0 = Normal, 1 = Fett, 2 = Kursiv, 4 = Unterstrichen, 8 = Durchgestrichen)
;                      $sFontname = der Fontname
;                      $iColor = die Schriftfarbe (im ARGB-Format)
;                      $iBkColor = die Hintergrundfarbe (im ARGB-Format) Standard ist transparent.
; Return Value(s):    : Im Erfolgsfall wird ein Array zurueckgegeben mit den neuen Abmessungen ([0] = Width und [1] = Height)
; Author(s):        : Oscar (www.autoit.de)
; Version / Date:   : 1.0.0.0 / 16.04.2020
Func _GUICtrlSetText($idCtrl, $sString, $iSize, $iStyle, $sFontname, $iColor = 0xFF000000, $iBkColor = Default)
    Local $hWnd, $hParent, $tRect, $hBitmap, $hGfxCtx, $hBrush, $hFormat, $hFamily, $hFont, $tLayout, $aInfo
    Local $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    If $iStyle = Default Or $iStyle <= 0 Then $iStyle = 0
    $hWnd = GUICtrlGetHandle($idCtrl)
    If Not IsHWnd($hWnd) Then Return SetError(1)
    $hParent = _WinAPI_GetParent($hWnd)
    $tRect = _WinAPI_GetClientRect($hParent)
    $hPrevImage = _SendMessage($hWnd, $STM_GETIMAGE)
    If $hPrevImage Then
        _WinAPI_DeleteObject($hPrevImage)
        _WinAPI_InvalidateRect($hParent, $tRect)
    EndIf
    Local $iW = $tRect.Right - $tRect.Left, $iH = $tRect.Bottom - $tRect.Top
;~     ConsoleWrite(StringFormat('Width x Height = %i x %i\r\n', $iW, $iH))
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $hBrush = _GDIPlus_BrushCreateSolid($iColor)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname)
    $hFont = _GDIPlus_FontCreate($hFamily, $iSize, $iStyle)
    $hGfxCtx = _GDIPlus_GraphicsCreateFromHWND($hParent)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    Local $aSize[2] = [Ceiling($aInfo[0].Width), Ceiling($aInfo[0].Height)]
;~     ConsoleWrite(StringFormat('Width x Height = %i x %i\r\n', $aSize[0], $aSize[1]))
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($aSize[0], $aSize[1])
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    If $iBkColor <> Default Then _GDIPlus_GraphicsClear($hGfxCtx, $iBkColor)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $aSize[0], $aSize[1])
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDrawStringEx($hGfxCtx, $sString, $hFont, $aInfo[0], $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    _WinAPI_SetWindowPos($hWnd, $hParent, 0, 0, $aSize[0], $aSize[1], BitOR($SWP_FRAMECHANGED, $SWP_NOZORDER, $SWP_NOMOVE))
    _SendMessage($hWnd, $STM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
    Return $aSize
EndFunc   ;==>_GUICtrlSetText

Alles anzeigen

Professor Bernd

Oscar Du bist ja schneller als die Feuerwehr!

Deinen neuen Code habe ich noch nicht angesehen, bin noch auf dem alten Stand. Kannst du den Code noch so anpassen, dass er "rattenscharf" an der Schrift abschneidet?

Im CallTipViewer werden 2 Labels übereinander gelegt, um den aktuellen Parameter rot hervorzuheben. Dabe ist es wichtig, dass nichts ungewolltes vom anderen Label überdeckt wird. Im Beispiel-Screenshot oben habe ich die Labels mit verschiedenen Backcolor dargestellt. Das ist NUR fürs Demo. Im Screenshot sieht man z. B. am Pfeil, dass dort ein Komma steht, das nicht verdeckt werden darf.

Ist es möglich, deinen Code entsprechend zu modifizieren, dass er links und rechts ganz eng an der Schrift endet? Das wäre cool!

Wie gesagt, ich bin noch beim alten Stand deines Codes. Falls das in deinem neuen Code schon so ist, vergiss meine Anfrage.

Bernd.