XML selectSingleNode

Lashandan

Hallo in die Runde,

ich beschäftige mich seit kurzer Zeit mit SOAP.

Die Schnittstelle etc. ist abgestimmt, ich bekomme auch bereits ein Ergebnis.

Nun möchte ich aber einen ganz speziellen Wert aus dem return ausgeben.

Folgendes erhalte ich zurück:

Code

<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:wsa="http://schemas.xmlsoap.org/ws/2004/08/addressing">
   <SOAP-ENV:Header>
      <wsa:MessageID SOAP-ENV:mustUnderstand="0">uuid:21110c70-a727-11ea-8274-ce09341d2009</wsa:MessageID>
      <wsa:To SOAP-ENV:mustUnderstand="0">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</wsa:To>
   </SOAP-ENV:Header>
   <SOAP-ENV:Body>
      <ns1:onhandResponse xmlns:ns1="urn:mwm-org:soap:soap">
         <ns1:result xsi:nil="true"/>
         <opcAntwort xmlns="urn:mwm-org:soap:soap">Fischer, Lars</opcAntwort>
      </ns1:onhandResponse>
   </SOAP-ENV:Body>
</SOAP-ENV:Envelope>

Alles anzeigen

Wie gelingt es mir nun, genau den Inhalt von opcAntwort auszugeben?

Habe es hiermit versucht:

AutoIt

; Load the return envelope into a DOM
$loadXML = $objReturn.loadXML ($strReturn)


; Query the return envelope
$strQuery = "SOAP-ENV:Envelope/SOAP-ENV:Body/opcAntwort"

$objReturn.selectSingleNode($strQuery)
$Soap = $objReturn.Text

MsgBox(0, "Soap", $Soap)

Alles anzeigen

aber hier erhalte ich:

Code

uuid:93098820-a727-11ea-8274-ce09341d2009 http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous Nachname, Vorname

Kann mir jemand weiterhelfen?

Lottich

Hallo.

Letztlich ist der Returnwert ja ein String. Ergo würde ICH mir durch stringsplit bzw stringbetween das gewünschte herausfiltern. Ich schreib dass grad vom Handy, darum kann ich dir kein beispiel posten. Das ist mir zu umständlich.

Sollte aber kein problem sein, denn die beiden Schlagwörter sind ausführlich in der Hilfe dokumentiert 🙂

**AspirinJunkie**

AutoIt

$s_XML = '<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:wsa="http://schemas.xmlsoap.org/ws/2004/08/addressing">' & @CRLF & _
   '<SOAP-ENV:Header>' & @CRLF & _
      '<wsa:MessageID SOAP-ENV:mustUnderstand="0">uuid:21110c70-a727-11ea-8274-ce09341d2009</wsa:MessageID>' & @CRLF & _
      '<wsa:To SOAP-ENV:mustUnderstand="0">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</wsa:To>' & @CRLF & _
   '</SOAP-ENV:Header>' & @CRLF & _
   '<SOAP-ENV:Body>' & @CRLF & _
      '<ns1:onhandResponse xmlns:ns1="urn:mwm-org:soap:soap">' & @CRLF & _
         '<ns1:result xsi:nil="true"/>' & @CRLF & _
         '<opcAntwort xmlns="urn:mwm-org:soap:soap">Fischer, Lars</opcAntwort>' & @CRLF & _
      '</ns1:onhandResponse>' & @CRLF & _
   '</SOAP-ENV:Body>' & @CRLF & _
'</SOAP-ENV:Envelope>'

; XMLDOM-Objekt laden
Local $o_XML = ObjCreate("Microsoft.XMLDOM")

; XML parsen
If Not $o_XML.loadXML($s_XML) Then Exit MsgBox(48, "Fehler", "Fehler beim Laden des XML-Strings")

; Element extrahieren (Auswahl über XPath-Selektoren)
$s_opcAntwort = $o_XML.SelectSingleNode('//opcAntwort')

MsgBox(0,"opcAntwort", $s_opcAntwort.text)

Alles anzeigen

Lashandan

Lottich vielen Dank für deine Antwort, mit stringsplit bzw. stringbetween kann ich aber nicht alle Möglichkeiten abfangen da es meist alphanumerische Felder sind die ich abfrage.

AspirinJunkie genau danach habe ich gesucht und mein Ansatz war ja dann schonmal nicht ganz falsch
Besten Dank -

Lashandan

Und natürlich noch der Code, finde es ja selbst immer schrecklich wenn man keine Lösung zur eingehenden Frage findet.

AutoIt

; COM-Fehlerbehandlungsroutine initialisieren
Local $oMyError = ObjEvent("AutoIt.Error","MyErrFunc")

; Objekt für den HTTP-Post-Request
Local $objHTTP = ObjCreate("Microsoft.XMLHTTP")

; Objekt für die XML-Datei in DOM
Local $o_XML = ObjCreate("Microsoft.XMLDOM")

; Iput-Box für die Eingabe
$strValue = InputBox("Eingabemaske", "Bitte Personalnummer eingeben!", "4230")

; Erstellen der SOAP-Hülle
$strEnvelope = '<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:urn="urn:mwm-org:soap:soap">' & _
   '<soapenv:Header/>' & _
   '<soapenv:Body>'   & _
      '<urn:onhand>' & _
         '<urn:piPersNr>'&$strValue&'</urn:piPersNr>' & _
         '<urn:gpcBCR_Connection_Obj>?</urn:gpcBCR_Connection_Obj>' & _
      '</urn:onhand>' & _
   '</soapenv:Body>' & _
'</soapenv:Envelope>'

; Soapadresse
$objHTTP.Open('POST', 'http://ADRESSE:PORT/soap?wsdl', False)

; Standard-SOAP/XML-Header für den Content-Typ
$objHTTP.setRequestHeader ("Content-Type", "text/xml")

; Header für die aufzurufende Methode
$objHTTP.setRequestHeader ("onhand", "urn:mwm-org:soap:soap#opcAntwort")

; SOAP-Aufruf
$objHTTP.send ($strEnvelope)

; Response-Text
$strReturn = $objHTTP.responseText

; XML parsen
If Not $o_XML.loadXML($strReturn) Then Exit MsgBox(48, "Fehler", "Fehler beim Laden des XML-Strings")

; Element extrahieren (Auswahl über XPath-Selektoren)
$s_opcAntwort = $o_XML.SelectSingleNode('//opcAntwort')

; Antwort
MsgBox(0,"opcAntwort", $s_opcAntwort.text)


Func MyErrFunc()
$HexNumber=hex($oMyError.number,8)
ConsoleWrite("We intercepted a COM Error !" & @CRLF & @CRLF & _
             "err.description is: " & @TAB & $oMyError.description & @CRLF & _
             "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _
             "err.number is: " & @TAB & $HexNumber & @CRLF & _
             "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _
             "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _
             "err.source is: " & @TAB & $oMyError.source & @CRLF & _
             "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _
             "err.helpcontext is: " & @TAB & $oMyError.helpcontext & @CRLF & _
            "" _
            )
SetError(1) ; die nach Antwort dieser Funktion zu prüfen ist
Endfunc; MyErrFunc()

Alles anzeigen

der nächste wird auch darüber stolpern also noch ein weiterer Hinweis.
Um den evelope-string zu definieren, kann man SoapUI (und anderen Alternativen) zur Hilfe nehmen:

Man ruft dazu also die WSDL-URL auf und bindet diese ins SoapUI ein.

Danach erhält man folgende Information.

Hier finde ich also die Funktion(en)

In Request 1 finde ich dann denn gesamten String für $strEnvelope.

Die entsprechende Antwort auf die gesendete Personalnummer erhalte ich ebenfalls.

Alles andere ergibt sich dann mit dem o.g. Code und sieht als Antwort so aus:

Vielen Dank nochmal an alle!

Lashandan 9. Juni 2020 um 07:24