Nabend.
Ich bräuchte mal Hilfe, oder zumindest ein paar Anregungen.
Ich habe 1440 .bmp Bilder, die ich beschneiden muss. Soll heißen, aus jedem Bild soll ein Ausschnitt ausgeschnitten und gespeichert werden.
Ich bin mir sicher, dass sich das mit GDI+ bewerkstelligen lässt, jedoch hab ich mich nie wirklich mit dem Thema beschäftigt.
Ein paar Anregungen und Tipps, welche Funktionen ich dazu brauche wären da schon super hilfreich. Den Rest würd ich dann über die Hilfe Datei machen.
LG
Commander
aus jedem Bild soll ein Ausschnitt ausgeschnitten und gespeichert werden.
Immer der gleiche Ausschnitt? Also z.B. immer von 20, 60 (x,y) ein Ausschnitt von 240 x 120 (w, h).
Geht mit GDI+ auf jeden Fall.
Das brauchst Du dafür:
_GDIPlus_Startup
_GDIPlus_BitmapCreateFromFile
_GDIPlus_BitmapCreateFromScan0
_GDIPlus_ImageGetGraphicsContext
_GDIPlus_GraphicsDrawImageRectRect
_GDIPlus_ImageSaveToFile
_GDIPlus_Shutdown
Edit: Ich hab mal schnell eine Funktion geschrieben:
#include <GDIPlus.au3>
_GDIPlus_Startup()
Global $hImg = _GDIPlus_BitmapCreateFromFile(@ScriptDir & '\test.jpg')
_GDIPlus_ImageSaveRect($hImg, @ScriptDir & '\new.jpg', 560, 288, 540, 440)
_GDIPlus_BitmapDispose($hImg)
_GDIPlus_Shutdown()
Func _GDIPlus_ImageSaveRect(ByRef $hImage, $sFilename, $iX, $iY, $iW, $iH, $iQuality = 90)
Local $hBitmap, $hGraphic, $sExt, $sCLSID, $tParams, $tData
$hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetInterpolationMode($hGraphic, 7)
_GDIPlus_GraphicsSetSmoothingMode($hGraphic, 2)
_GDIPlus_GraphicsDrawImageRectRect($hGraphic, $hImage, $iX, $iY, $iW, $iH, 0, 0, $iW, $iH)
$sExt = StringRegExpReplace($sFilename, '.+\.(.+)', '$1')
Switch $sExt
Case 'jpg', 'jpeg'
$sCLSID = _GDIPlus_EncodersGetCLSID('JPG')
$tParams = _GDIPlus_ParamInit(1)
$tData = DllStructCreate('int Quality') ; Struktur fuer die JPG-Qualitaet erstellen
DllStructSetData($tData, 'Quality', $iQuality) ; JPG-Qualitaet entsprechend setzen (von 0 = schlechteste bis 100 = beste)
_GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, 'Quality'))
_GDIPlus_ImageSaveToFileEx($hBitmap, $sFilename, $sCLSID, $tParams)
Case Else
_GDIPlus_ImageSaveToFile($hBitmap, $sFilename)
EndSwitch
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_BitmapDispose($hBitmap)
EndFuncHey cool. Vielen Dank. Ich werd mir das ganze gleich mal durchsehn. Vllt. lern ich ja noch was dabei 