txt Log Auswerten

Speedy86

Hallo,

Ich komm da nicht so ganz weiter.
Die Grund Funktion will nicht mal bei mir.

Ich habe folgendes als bsp in ein txt Log stehen:

Code

2020-10-01 19:53:13.360     [BBS] Input_coin_NW
2020-10-01 19:53:13.360     [BBS] addCoin: 10000 von 4
2020-10-01 19:53:13.371     [BBS] updateAcceptance cashmode: 0
2020-10-01 19:53:13.371     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 19:53:20.250     [BBS] Sys_coin_NW
2020-10-01 19:53:20.250     [BBS] addCoin: -10000 von 5
2020-10-01 19:53:20.257     [BBS] updateAcceptance cashmode: 0
2020-10-01 19:53:20.258     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 20:56:46.419     [BBS] Input_coin_NW
2020-10-01 20:56:46.419     [BBS] addCoin: 20000 von 4
2020-10-01 20:56:46.429     [BBS] updateAcceptance cashmode: 0
2020-10-01 20:56:46.429     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 20:56:53.961     [BBS] Sys_coin_NW
2020-10-01 20:56:53.961     [BBS] addCoin: -20000 von 5
2020-10-01 20:56:53.967     [BBS] updateAcceptance cashmode: 0
2020-10-01 20:56:53.968     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 20:58:21.829     [BBS] Input_coin_NW
2020-10-01 20:58:21.829     [BBS] addCoin: 1000 von 3
2020-10-01 20:58:21.840     [BBS] updateAcceptance cashmode: 0
2020-10-01 20:58:21.840     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 20:58:21.840     [BBS] WM_INTCON_FLOAT_LEVEL
2020-10-01 20:58:21.840     [BBS] updateAcceptance cashmode: 0
2020-10-01 20:58:21.840     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 20:58:23.196     [BBS] Sys_coin_NW
2020-10-01 20:58:23.196     [BBS] addCoin: -1000 von 5
2020-10-01 20:58:23.201     [BBS] updateAcceptance cashmode: 0
2020-10-01 20:58:23.201     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 21:10:44.222     [BBS] Input_coin_NW
2020-10-01 21:10:44.222     [BBS] addCoin: 20000 von 4
2020-10-01 21:10:44.232     [BBS] updateAcceptance cashmode: 0
2020-10-01 21:10:44.232     [BBS]     SendD BS_AA_COINACCEPT
2020-10-01 21:11:09.492     [BBS] Sys_coin_NW
2020-10-01 21:11:09.492     [BBS] addCoin: -2000 von 5
2020-10-01 21:11:09.499     [BBS] updateAcceptance cashmode: 0
2020-10-01 21:11:09.499     [BBS]     SendD BS_AA_COINACCEPT

Alles anzeigen

Ich würde hier gern ein Script schreiben wo ich das Log so ausgelesen bekomm das mir ein Excel, CSV nur die wichtigsten Daten angezeigt werden.

zb.:

10000 , 4

-10000 , 5

20000 , 4

Hier mal mein Script:

C

#include <Array.au3>
#include <File.au3>
#include <String.au3>

Global $sFileName = @ScriptDir & "\Log_test.txt"

Example()


Func Example()
    Local $aFileRead
    Local $aFileLine[0][2]
    _FileReadToArray($sFileName, $aFileRead)
    If @error Then Exit MsgBox(16, "Error", "Unable to read: " & $sFileName)
    ReDim $aFileLine [UBound($aFileRead)][2]
    For $i = 0 To UBound($aFileRead)
        $aFileLine[$i][0] = _StringBetween($aFileRead[$i], "addCoin: ", " von")
        If Not @error Then ExitLoop
    Next
_ArrayDisplay($aFileLine)
EndFunc

Alles anzeigen

Bekomm nur Blödsinn heraus.

lg

Speedy

**AspirinJunkie**

Für sowas sind reguläre Ausdrücke ideal.

Ein Tutorial hierzu findest du >>hier<<.

Dann sollte dich folgendes ein Stück weiter bringen:

AutoIt

#include <Array.au3>

Global $sFile = FileRead("Test.log")

For $aMatch In StringRegExp($sFile, "addCoin: (-?\d+) von (\d+)", 4)
    _ArrayDisplay($aMatch)
Next

Speedy86

Danke

Musashi

Zitat von Speedy86

zb.:
10000 , 4
-10000 , 5

Versuche es mal damit :

AutoIt

#include <Array.au3>
Global $g_sFile, $g_aMatches
$g_sFile    = FileRead(@ScriptDir & "\Log_test.txt")
$g_aMatches = StringRegExp($g_sFile, "(?i)[-\s]\d+ von \d+", 3)
If Not @error Then
    For $i = 0 To UBound($g_aMatches) - 1
        $g_aMatches[$i] = StringReplace(StringStripWS($g_aMatches[$i], 8), 'von', ',')
    Next
    _ArrayDisplay($g_aMatches, "Matches :")
EndIf

Speedy86

Hey Musashi Danke,

die Zahl nach dem von sollten noch in einer eigenen Spalte kommen.

Damit ich das auch besser sortieren kann.

hab es so umgebaut:

Code

#include <Array.au3>
Global $g_sFile, $g_aMatches
$g_sFile    = FileRead(@ScriptDir & "\Log_test.txt")
$g_aMatches = StringRegExp($g_sFile, "(?i)[-\s]\d+ von \d+", 3)
Global $g_aMatchesfinal[UBound($g_aMatches)][2]
_ArrayDisplay($g_aMatches)
If Not @error Then
    For $i = 0 To UBound($g_aMatches) - 1
        $g_aMatchesfinal[$i][0] = StringReplace(StringStripWS($g_aMatches[$i], 8), 'von', ',')
        $g_aMatchesfinal[$i][1] = StringReplace(StringStripWS($g_aMatches[$i], 8), 'von', ',')
    Next
    _ArrayDisplay($g_aMatchesfinal, "Matches :")
EndIf

Alles anzeigen

Wie muss ich den zweiten such Befehl der 2 Spalte ändern ?

Das Tut von AspirinJunkie werd ich mir heut oder morgen durchmachen.

hoff das ich mich mit Regexp dann auch besser auskenne, hab in den Bereich noch gar nix gemacht.

Musashi

Zitat von Speedy86

die Zahl nach dem von sollten noch in einer eigenen Spalte kommen.

AutoIt

#include <Array.au3>
Global $g_sFile, $g_aMatches, $g_aLine, $g_aMatchesFinal[0][2]

$g_sFile    = FileRead(@ScriptDir & "\Log_test.txt")
$g_aMatches = StringRegExp($g_sFile, "(?i)[-\s]\d+ von \d+", 3)
If Not @error Then
    Redim $g_aMatchesFinal[UBound($g_aMatches)][2]
    For $i = 0 To UBound($g_aMatches) - 1
        $g_aLine = StringSplit(StringStripWS($g_aMatches[$i], 8), 'von', 3)
        $g_aMatchesFinal[$i][0] = $g_aLine[0]
        $g_aMatchesFinal[$i][1] = $g_aLine[1]
    Next
    _ArrayDisplay($g_aMatchesFinal, "Matches :")
EndIf

Alles anzeigen

(man kann es sicher auch noch etwas kürzer schreiben )

Zitat von Speedy86

Das Tut von AspirinJunkie werd ich mir heut oder morgen durchmachen.

Sehr gute Idee (das Tutorial stammt übrigens von SEuBo )

Musashi

Nachtrag :

Ich habe den regulären Ausdruck etwas überarbeitet.

Außerdem brauchst Du kein extra Array $g_aMatchesFinal mehr anlegen.

AutoIt

#include <Array.au3>
Global $g_sFile, $g_aMatches, $g_aLine
$g_sFile    = FileRead(@ScriptDir & "\Log_test.txt")
$g_aMatches = StringRegExp($g_sFile, "(?i)(-?\d+ von \d+)", 3)
If Not @error Then
    _ArrayColInsert($g_aMatches, 1) ; Array um eine Spalte erweitern
    For $i = 0 To UBound($g_aMatches) - 1
        $g_aLine = StringSplit($g_aMatches[$i][0], ' von ', 3)
        $g_aMatches[$i][0] = $g_aLine[0]
        $g_aMatches[$i][1] = $g_aLine[1]
    Next
    _ArrayDisplay($g_aMatches, "Matches :")
EndIf

Alles anzeigen

txt Log Auswerten

Ähnliche Themen

Problem mit Übergabe Datumsfunktion

Hilfe bei hotkey und timer funktion

Include von .au3 Dateien in das GUI

Drag and Drop erkennen

Listview & Multiauswahl