Viewlist Checkboxen, Array Container

MojoeB

Hallo zusammen ich hoffe Ihr könnt mir ein wenig helfen, leider komme ich selber nicht weiter.

Ich lese oft in diesem Forum & habe mich jetzt mal angemeldet.

Ich versuche mal schnell zu erklären.

Ich benötige das für die Arbeit.

Möchte so unseren Mitarbeitern die Arbeit etwas erleichtern.

Ich lasse, erst auf einer (internen)Homepage, die Datenbank auslesen, das klappt auch & lass mir eine Datenbank in einer Datei erstellen.

Im Beispiel habe ich mal die Dateiendung .bbdb genommen.

Der Inhalt der Test.bbdb wird mit StringRegExp ausgelesen & dabei in einer For schleife erstellt.

Ich habe einige testzeilen gelöscht vor dem Post, nun bekomm ich nur noch einen Fehler x: & kann die Viewlist nicht mehr öffnen.

Aber warum ich eigentlich schreibe ist bekomm die ausgelesenen Variablen in der For Schleife einfach nicht in die While schleife um diese dort mit einer Funktion dann dort weiter zu arbeiten.

Ich habe zwar schon hinbekommen mit GUICtrlRead($listview, 2) den letzten Wert in der Datenbank bzw. Viewlist auszugeben.

Aber eigentlich wollte ich:

Verschiedene Checkboxen anklicken -> danach auf Button klicken -> funktion $hlink+$aDATA01| (die ausgewählten Checkboxen lesen & mit einem Link+Datensatz auf der Homepage zu öffnen.)

& dann weiter.... nach einander nicht nur die letzte Checkbox ^^.

Ich hoffe Ihr könnt mir helfen, wäre sehr nett.

Ich habe einige Varianten die letzten paar Tage ausprobiert, ich bin kein experte, das ist klar aber ich habe es einfach nicht hinbekommen.

Leider habe ich grade einen Fehler mit eingebaut :

Code

"C:\Datensatz\2\bspppp.au3" (54) : ==> Subscript used on non-accessible variable.:
Global $acbl[][5] = [[ $aDATA02[1], $aDATA01[1], $aDATA03[1], $aDATA04[1] ] ]
Global $acbl[][5] = [[ $aDATA02[1], $aDATA01[1], $aDATA03^ ERROR

& kann diesen ebenfalls nicht finden, aber vielleicht seh ich einfach den Wald lauter Bäume nicht mehr.

Mit freundlichen Grüßen

Mojoe

die Test.bbdb :

Code

<data>TEST GERÄT 2327</data>=<SIM>4916093114052</SIM><TYP>testtyp</TYP><BS>HAMBURG</BS>
<data>TEST GERÄT 2421</data>=<SIM>4916093113907</SIM><TYP>(16)</TYP><BS>BISS</BS>
<data>TEST GERÄT 0999</data>=<SIM>4916092192082</SIM><TYP>(16)</TYP><BS>KAMERUN</BS>
<data>TEST GERÄT 0088</data>=<SIM>4916090506695</SIM><TYP>testtyp</TYP><BS>BERGHAUPTEN</BS>
<data>TEST GERÄT 2222</data>=<SIM>4915143124082</SIM><TYP>testtyp</TYP><BS>BERLIN</BS>
<data>TEST GERÄT 3230</data>=<SIM>4915117922365</SIM><TYP>testtyp</TYP><BS>MONHEIM</BS>
<data>TEST GERÄT 3632</data>=<SIM>4916092180511</SIM><TYP>testtyp</TYP><BS>IN DER ALL</BS>
<data>TEST GERÄT 3633</data>=<SIM>4916092180375</SIM><TYP>testtyp</TYP><BS>ZUSATZ</BS>
<data>TEST GERÄT 3634</data>=<SIM>4916092172661</SIM><TYP>testtyp</TYP><BS>COSMUS</BS>
<data>TEST GERÄT 3792</data>=<SIM>491622729776</SIM><TYP>testtyp</TYP><BS>ZWIEBLE</BS>
<data>TEST GERÄT 4754</data>=<SIM>4915119435278</SIM><TYP>Bahn</TYP><BS>TISCHER</BS>
<data>TEST GERÄT 7708</data>=<SIM>4915162722911</SIM><TYP>testtyp</TYP><BS>BERLIN</BS>
<data>TEST GERÄT 8833</data>=<SIM>4915117901056</SIM><TYP>testtyp</TYP><BS>MÜNCHEN</BS>
<data>TEST GERÄT 8836</data>=<SIM>491755502399</SIM><TYP>testtyp</TYP><BS>STUTTGART/BS>
<data>TEST GERÄT 8850</data>=<SIM>4915128347813</SIM><TYP>testtyp</TYP><BS>STASSHAUS</BS>
<data>TEST GERÄT 8885</data>=<SIM>491601672520</SIM><TYP>GWT/A</TYP><BS>BEISPIELSTADT</BS>
<data>TEST GERÄT 8887</data>=<SIM>491601657760</SIM><TYP>GWT/A</TYP><BS>HUGO</BS>
<data>TEST GERÄT 9880</data>=<SIM>4915172690936</SIM><TYP>testtyp(16)</TYP><BS>TELMIN</BS>
<data>TEST GERÄT 9922</data>=<SIM>4915172690934</SIM><TYP>testtyp(16)</TYP><BS>ZUKKER</BS>
<data>TEST GERÄT 9927</data>=<SIM>491718398763</SIM><TYP>testtyp(16)</TYP><BS>NIERNSTEH</BS>
<data>TEST GERÄT 9938</data>=<SIM>4916092170761</SIM><TYP>testtyp(16)</TYP><BS>BERLIN</BS>

Alles anzeigen

& das Script momentan für den Zweck den ich oben beschreibe :

C

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
;~ #include <funktion.au3>
#include <GUIListView.au3>
#include <ListViewConstants.au3>
#include <ButtonConstants.au3>
local $vdb
;~ $sections = IniReadSectionNames('hersteller.ini')
;~ For $a = 1 To UBound($sections) - 1
;~  $keys = IniReadSection('hersteller.ini', $sections[$a])
;~       For $b = 1 to  UBound($keys) - 1

;~           $h0=$keys[0][0];int
;~ ;
;~    Next
;~ Next



Global $Form1 = GUICreate("Form1", 1000, 800)
Global $Bt1 = GUICtrlCreateButton("Test", 16, 120, 50, 30, BitOR($BS_NOTIFY,$BS_FLAT))
$x = 16
$y = 16
$step = 120
$ListView = GUICtrlCreateListView("Daten01 | Daten02 | Daten03 | Daten04 |", 100, 100, 580, 280, $WS_BORDER, $LVS_EX_FULLROWSELECT + $LVS_EX_CHECKBOXES)

Dim $NumbStringSim, $hLink, $aDATA01, $aDATA02, $aDATA03, $aDATA04


                       $hLink = 'http://google.de'


Local $iCountLines = _FileCountLines('test.bbdb')
ConsoleWrite($iCountLines)
for $po = 1 to $iCountLines    _FileReadToArray('test.bbdb', $vdb, $iCountLines, '')

next


For $in = 1 to UBound($vdb)-1

Global $aDATA01 = StringRegExp($vdb[$in], '<SIM>(.*?)</SIM>', $STR_REGEXPARRAYFULLMATCH)
Global $aDATA02 = StringRegExp($vdb[$in], '<data>(.*?)</data>', $STR_REGEXPARRAYFULLMATCH)
Global $aDATA03 = StringRegExp($vdb[$in], '<BS>(.*?)</BS>', $STR_REGEXPARRAYFULLMATCH)
Global $aDATA04 = StringRegExp($vdb[$in], '<TYP>(.*?)</TYP>', $STR_REGEXPARRAYFULLMATCH)
;~

Global $acbl[][5] = [[ $aDATA02[1], $aDATA01[1], $aDATA03[1], $aDATA04[1] ] _
]
$name=$acbl[0][0]
$sim=$acbl[0][1]
$bsss=$acbl[0][2]
$herges=$acbl[0][3]
ConsoleWrite($name &'_____________________'&' '&$sim&' '&$bsss& '  '&$herges&@CRLF )

;~ ConsoleWrite($acb[0][1] &@CRLF)
;~ ConsoleWrite($acb[0][3] &@CRLF)



$item=GUICtrlCreateListViewItem($name &' | '& $sim &' | '& '$herges noch nicht definiert'  & ' | '& $bsss,$ListView ); ConsoleWrite($aDATA03[0])
;~ GUICtrlCreateListViewItem($aDATA02[1] &' | '& $aDATA01[1] &' | '&$aDATA03[1]& ' | '& $aDATA04[1] &' | ', $ListView );
Next

GUISetState(@SW_SHOW)


While 1  $nMsg = GUIGetMsg()  Switch $nMsg    Case $GUI_EVENT_CLOSE      Exit
      Case $Bt1

;~ For $i = 0 To UBound($item) - 1
;~ If _GUICtrlListView_GetItemChecked($item, $i) Then
;~             ConsoleWrite($item)

;~ EndIf
;~ Next
  EndSwitch
WEnd

Alles anzeigen

**Kanashius**

Hi

Ich denke, das hier dürfte etwa das sein, was du haben möchtest:

AutoIt

#include <array.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

Global $iWidth=800, $iHeight=600
Global $arCols=["Data","SIM","TYP","BS"]
$hGui=GUICreate("???",$iWidth,$iHeight)
$hDataListView=GUICtrlCreateListView(_arToString($arCols),5,5,$iWidth-10, $iHeight-40,BitOR($WS_BORDER,$LVS_SINGLESEL,$LVS_SHOWSELALWAYS), BitOr($LVS_EX_FULLROWSELECT,$LVS_EX_CHECKBOXES))
For $i=0 to UBound($arCols)-1 step 1
    _GUICtrlListView_SetColumnWidth($hDataListView,$i,($iWidth-10)/UBound($arCols))
Next
$hButtonOpenNext=GUICtrlCreateButton("Open Next (from current selection)",5,$iHeight-30,$iWidth-10,25)

GUISetState(@SW_SHOW, $hGui)

_loadFileIntoListview("Test.bbdb")

While 1
    $msg=GUIGetMsg()
    Switch $msg
        case -3
            exit
        case $hButtonOpenNext
            _openNext()
    EndSwitch
WEnd

Func _openNext()
    If NOT _selectNextChecked() Then return false
    local $sel=_GUICtrlListView_GetSelectedIndices($hDataListView,true)
    If UBound($sel)>1 Then
        If _GUICtrlListView_GetItemChecked($hDataListView,$sel[1]) Then
            ConsoleWrite("OPEN: "&_GUICtrlListView_GetItemTextArray($hDataListView,$sel[1])[1]&@crlf)
            ShellExecute("http://www.google.com?q="&_GUICtrlListView_GetItemTextArray($hDataListView,$sel[1])[1])
        EndIf
    EndIf
    return true
EndFunc

Func _selectNextChecked()
    local $iSize=_GUICtrlListView_GetItemCount($hDataListView)
    local $sel=_GUICtrlListView_GetSelectedIndices($hDataListView,true)
    local $iStart=UBound($sel)=1?-1:$sel[1]
    local $iDone=false
    for $i=$iStart+1 to $iSize-1 step 1
        If _GUICtrlListView_GetItemChecked($hDataListView,$i) Then
            _GUICtrlListView_SetItemSelected($hDataListView,$i,true,true)
            $iDone=true
            ExitLoop
        EndIf
    next
    If NOT $iDone Then
        _GUICtrlListView_SetItemSelected($hDataListView,0,true,true)
        return false
    EndIf
    return true
EndFunc

Func _loadFileIntoListview($sFile)
    local $arData=_getDataArrayFromFile($sFile), $sTmp
    For $i=0 to UBound($arData)-1 step 1
        GUICtrlCreateListViewItem(_arToString($arData, $i),$hDataListView)
    Next
EndFunc

Func _getDataArrayFromFile($sFile)
    local $arData=FileReadToArray($sFile)
    local $arResult[UBound($arData)][UBound($arCols)]
    local $count=0
    For $i=0 to UBound($arData)-1 step 1
        $arTmp=StringRegExp($arData[$i],"<data>(.*?)</data>=<SIM>(.*?)</SIM><TYP>(.*?)</TYP><BS>(.*?)</BS>",3)
        If @error Then
            ConsoleWrite("Error parsing line: """&$arData[$i]&""""&@crlf)
        Else
            For $j=0 to UBound($arResult,2)-1 step 1
                $arResult[$count][$j]=$arTmp[$j]
            Next
            $count+=1
        EndIf
    Next
    ReDim $arResult[$count][UBound($arCols)]
    return $arResult
EndFunc

Func _arToString(Byref $arData, $iIndex=-1)
    local $iDim=UBound($arData,0)
    local $sTmp=""
    For $i=0 to UBound($arData,$iDim)-1 step 1
        If UBound($arData,0)=1 Then
            $sTmp&=$arData[$i]
        ElseIf UBound($arData,0)=2 Then
            $sTmp&=$arData[$iIndex][$i]
        EndIf
        If $i<UBound($arData,$iDim)-1 Then $sTmp&="|"
    Next
    return $sTmp
EndFunc

Alles anzeigen

MfG Kanashius

**Bitnugger**

Zitat von MojoeB

<data>TEST GERÄT 8836</data>=<SIM>491755502399</SIM><TYP>testtyp</TYP><BS>STUTTGART/BS>

Hier fehlt das < vor /BS>

Schau mal hier:

AutoIt

;-- TIME_STAMP   2021-02-11 20:24:58   v 0.1

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;~ #include <Array.au3> ; _ArrayDisplay
#include <GUIListView.au3>

Global $hForm1, $idListView, $idBtnTest

Global $aFile = FileReadToArray('test.bbdb'), $aDATA[UBound($aFile)][4], $aRx

For $i = 0 To UBound($aFile) - 1 Step 1
    $aRx = StringRegExp($aFile[$i], "<data>(.*?)</data>=<SIM>(.*?)</SIM><TYP>(.*?)</TYP><BS>(.*?)</BS>", 3)
    If @error Then
        ConsoleWrite("! Error parsing line " & $i & ": '" & $aFile[$i] & "'" & @CRLF)
    Else
        For $j = 0 To UBound($aRx) -1 Step 1
            $aDATA[$i][$j] = $aRx[$j]
        Next
    EndIf
Next
;~ _ArrayDisplay($aDATA, '$aDATA', '', 0, Default, 'data|SIM|TYP|BS')

$hForm1 = GUICreate("Form1", 600, 400)
$idBtnTest = GUICtrlCreateButton("Test", 5, 360, 590, 30, BitOR($BS_NOTIFY, $BS_FLAT))
;~ $idListView = GUICtrlCreateListView("data|SIM|TYP|BS", 5, 5, 590, 350,  -1, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
$idListView = GUICtrlCreateListView("data|SIM|TYP|BS", 5, 5, 590, 350, BitOR($GUI_SS_DEFAULT_LISTVIEW, $WS_BORDER), BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
_GUICtrlListView_SetColumnWidth($idListView, 0, 150) ; data
_GUICtrlListView_SetColumnWidth($idListView, 1, 100) ; SIM
_GUICtrlListView_SetColumnWidth($idListView, 2, 150) ; TYP
_GUICtrlListView_SetColumnWidth($idListView, 3, 150) ; BS
_GUICtrlListView_AddArray($idListView, $aDATA)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $idBtnTest
            For $i = 0 To UBound($aDATA) - 1 Step 1
                If _GUICtrlListView_GetItemChecked($idListView, $i) Then
                    ConsoleWrite(StringFormat('> Item %i is checked! \t -->> data: %-26s SIM: %14s TYP: %-26s BS: %s\n', $i, $aDATA[$i][0], $aDATA[$i][1], $aDATA[$i][2], $aDATA[$i][3]))
                EndIf
            Next
    EndSwitch
WEnd

Alles anzeigen

MojoeB

@Kanashius : Danke :), für deine große mühe, aber ich meinte das so wie Bitnugger gepostet hat.

Ich werde mir deinen Code dennoch mal genauer anschauen, super Arbeit auch mit dem @error darauf hätte ich auch kommen können. Super Arbeit

@Bitnugger : '<' Danke :), ich dachte schon das es was blödes ist.^^ Genau so habe ich das gemeint ich danke dir ebenso werde nun damit weiter arbeiten.

Danke euch beiden.