_ReplaceStringInFile

ruby

Hallo ich brauch mal Eure Hilfe, ich komme nicht weiter.

Ich habe eine Datei "untitled.txt" in der möchte ich den String "version 9" in "version 7" ändern.

Wenn ich die Datei mit notepad++ öffne und es händisch ändere und wieder abspeiche funktioniert es.

In meiner GUI füge ich per Drag and Drop die Datei ein.

Aber mit _ReplaceStringInFile funktioniert es nicht.

Ich denke mir, es liegt an der Datei, weil weiter unten in der Datei stehen so komische Zeichen, siehe Anhang.

Hat jemand eine Idee, wie ich das lösen kann.

Danke im vorraus.

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <File.au3>


Global $gaDropFiles[1], $iDropItem = -1


#Region ###
Global $Form1 = GUICreate("", 200, 200, -1, -1, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_ACCEPTFILES, $WS_EX_CONTROLPARENT)) ;$WS_EX_CONTROLPARENT = verschiebt Fenster auch ohne Rahmen
GUISetBkColor(0x01A1F7)

$FILES_DROPPED = GUICtrlCreateDummy()

GUISetState(@SW_SHOW)

#EndRegion ###


GUIRegisterMsg($WM_DROPFILES, 'WM_DROPFILES_FUNC')


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $FILES_DROPPED
            $aFiles = $gaDropFiles

            _change_bip()

    EndSwitch
WEnd



Func _change_bip()
$file = FileOpen($aFiles[0], 512)
$read = FileRead($file)

        _ReplaceStringInFile($read, "version 9", "version 7") ;!!!!!!!!!!!!!!!!

EndFunc



Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    Local $nSize, $pFileName
    Local $nAmt = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', 0xFFFFFFFF, 'ptr', 0, 'int', 0)
    ReDim $gaDropFiles[$nAmt[0]]
       For $i = 0 To $nAmt[0] - 1
            $nSize = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', 0, 'int', 0)
            $nSize = $nSize[0] + 1
            $pFileName = DllStructCreate('wchar[' & $nSize & ']')
            DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', DllStructGetPtr($pFileName), 'int', $nSize)
            $gaDropFiles[$i] = DllStructGetData($pFileName, 1)
            $pFileName = 0
      Next
   GUICtrlSendToDummy($FILES_DROPPED, $nAmt[0])

EndFunc

Alles anzeigen

Micha_he

Ohne das ich mir das komplette Script und die genutzte Funktion _ReplaceStringInFile() angesehen habe, musst Du das Ergebnis der Funktion wieder einer Variablen zuweisen und diese auch wieder in die (oder eine neue) Datei zurückschreiben.

Meine Annahme war falsch: Die Funktion macht dies automatisch. Du must also den Dateinamen (im Beispiel $aFiles[0], bzw. $aFiles[x] per Schleife) an die Funktion übergeben und nicht den Inhalt.

Micha_he

vom Prinzip her möglicherweise so...

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <File.au3>


Global $gaDropFiles[1], $iDropItem = -1


#Region ###
Global $Form1 = GUICreate("", 200, 200, -1, -1, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_ACCEPTFILES, $WS_EX_CONTROLPARENT)) ;$WS_EX_CONTROLPARENT = verschiebt Fenster auch ohne Rahmen
GUISetBkColor(0x01A1F7)

$FILES_DROPPED = GUICtrlCreateDummy()

GUISetState(@SW_SHOW)

#EndRegion ###


GUIRegisterMsg($WM_DROPFILES, 'WM_DROPFILES_FUNC')


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $FILES_DROPPED
            For $i = 0 To UBound($gaDropFiles)-1
               _change_bip($gaDropFiles[$i])
            Next

    EndSwitch
WEnd



Func _change_bip($sFileName)
   _ReplaceStringInFile($sFileName, "version 9", "version 7")
EndFunc



Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    Local $nSize, $pFileName
    Local $nAmt = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', 0xFFFFFFFF, 'ptr', 0, 'int', 0)
    ReDim $gaDropFiles[$nAmt[0]]
       For $i = 0 To $nAmt[0] - 1
            $nSize = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', 0, 'int', 0)
            $nSize = $nSize[0] + 1
            $pFileName = DllStructCreate('wchar[' & $nSize & ']')
            DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', DllStructGetPtr($pFileName), 'int', $nSize)
            $gaDropFiles[$i] = DllStructGetData($pFileName, 1)
            $pFileName = 0
      Next
   GUICtrlSendToDummy($FILES_DROPPED, $nAmt[0])

EndFunc

Alles anzeigen

wobei ich noch nicht verstanden habe, warum der String nicht ersetzt wird !?

Edit: Mit einer anderen Testdatei geht es. liegt scheinbar am Dateiformat/Kodierung, mit der die Funktion nicht klar kommt....

ruby

Hallo Micha_he,

danke für die Info, aber wie Du auch festgestellt hast funktioniert das nicht.

Ich denke mir, das liegt an der Datei.

Die Extension ist eigentlich eine bip Datei (Keyshot), nur die konnte ich nicht als Anhang hochstellen, deswegen als txt.

Habe hier nur die Extension geändert, als Kodierung ist es eine ANSI.

Wenn mann sich die Datei im notepad++ anschaut stehen weiter unten so schwaze NUL Zeichen.

Wie gesagt händisch geht es nur nicht mit _ReplaceStringInFile

Ich hatte auch das mal probiert, geht auch nett:

Code

#include <File.au3>

Local $aFile, $sText, $sFile = @ScriptDir & "\untitled.bip"
    _FileReadToArray($sFile, $aFile)

_ArrayDisplay($aFile)

    For $a = 1 To $aFile[0]
        If StringInStr($aFile[$a], 'version 9') Then
            $sText = StringReplace(FileReadLine($sFile, $a), 'version 9', 'version 7')
            _FileWriteToLine($sFile, $a, $sText, 1)
        EndIf
    Next

Alles anzeigen

Im ArrayDisplay stehen dann so komische Zeichen.

Habe auch mal mit:

Code

$file = FileOpen($aFiles[0], 512)
$read = FileRead($file)

        _ReplaceStringInFile($read, "version 9", "version 7") ;!!!!!!!!!!!!!!!!

es versucht und den mode geändert, aber hat auch nichts gebracht.

Alles sehr seltsam

Micha_he

Die Konvertierung der binär eingelesenen Daten mit StringReplace() geht aber:

Code

$hInFile = FileOpen(@ScriptDir & "\untitled.txt", 16) ; Binary Read
$data = BinaryToString(FileRead($hInFile))
FileClose($hInFile)

$data = StringReplace($data, "version 9", "version 7")

$hOutFile = FileOpen(@ScriptDir & "\untitled_out.txt", 2 + 16) ;Binary Write
FileWrite($hOutFile, $data)
FileClose($hOutFile)

MojoeB

Bei mir funktioniert es auch ohne BinarytoString.

So in etwa oder?

Code

$file = 'kkk'
$rfile = _readfile($file)
$test = StringReplace($rfile, 'version 9', 'version 7')
ConsoleWrite($test)
FileDelete($file)
FileWrite($file, $test)

Func _readfile($file)
    Local $hFile, $rFile
    $hFile = FileOpen($file)
    $rFile = FileRead($hFile)
    FileClose($file)
    Return $rFile
EndFunc   ;==>_readfile

Alles anzeigen

Micha_he

Must Du mal Eingangs- und Ausgangsdatei vergleichen, ob dabei die restlichen Bytes nicht verändert werden.

ruby

Man seit Ihr schnell.

Dein Script funktioniert Micha_he.

Das von MojoeB funktioniert bei mir nicht.

Heute Nachmittag hatte ich auch die Idee mit Binary Read, nur habe ich Binary Write vergessen.

Super Arbeit und Danke für Eure Hilfe.