_DateDiff('s', ?, _NowCalc())

ConfluenceHunter

Hallo

ich brauche jetzt doch Hilfe, nachdem ich zwei Tage versucht habe eine Lösung zu finden.

Ich habe eine Eingabemaske und möchte die Anzahl der Sekunden zwischen der aktuellen Zeit und den Eingabewerten ($Date1 sowie $idTime ) und der aktuellen Zeit ermitteln.

_DateDiff('s', ?, _NowCalc()) durch welche Variable muß das ? ersetzt werden

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Date.au3>
#include <MsgBoxConstants.au3>


Example()

Func Example()

#Region ### START Koda GUI section ### Form=e:\autoit\scripte\eingabefeld.kxf
$Form1_1 = GUICreate("Wann soll die Ladung beginnen ? ", 345, 250, 800, 300)
$Input1 = GUICtrlCreateInput("10", 71, 25, 35, 27)
GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
$Button1 = GUICtrlCreateButton("OK", 200, 190, 49, 41)
GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
$Label1 = GUICtrlCreateLabel("KWh", 119, 29, 49, 23)
GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
$Date1 = GUICtrlCreateDate(_NowDate, 71,75, 197, 27)
GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
Global $idTime = GUICtrlCreateDate("", 71, 130, 197, 27, $DTS_TIMEFORMAT)
GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
global $sDate
Global $sTime
Global $iUebergabe
Global $date1
Global $iDateCalc
Global $iStartzeit
Global $iStartzeit2
Global $idDate
Global $iDate
global $iStart
Global $sStyle = "HH:mm:ss"

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
ExitLoop
Case $Button1
ExitLoop
EndSwitch
WEnd



Global $sDate = GUICtrlRead($idDate)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sDate = ' & $sDate & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
Global $sTime = GUICtrlRead($idTime)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sTime = ' & $sTime & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


Global $sDt = StringRegExpReplace($sDate, '(\d{2})\.(\d{2})\.(\d{4})', '$3$2$1')
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sDt = ' & $sDt & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
Global $sTm = StringReplace($sTime, ':', '')
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sTm = ' & $sTm & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

Local $sStyle = "yyyy/MM/dd"
GUICtrlSendMsg($Date1, $DTM_SETFORMATW, 0, $sStyle)

MsgBox(0,"Datum/Zeit","Datum " & GUICtrlRead($Date1) & " Std " & GUICtrlRead($idTime))

MsgBox (64,"Date ",GUICtrlRead($Date1))

MsgBox (64,"Time ",GUICtrlRead($idTime))

EndFunc

Alles anzeigen

Danke im voraus

**Schnuffel**

kleines Beispiel: (ich hab deinen Code mal in einen Codeblock gepackt, dann braucht man nicht so viel scrollen )

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Date.au3>
#include <MsgBoxConstants.au3>


Example()

Func Example()

	#Region ### START Koda GUI section ### Form=e:\autoit\scripte\eingabefeld.kxf
	$Form1_1 = GUICreate("Wann soll die Ladung beginnen ? ", 345, 250, 800, 300)
	$Input1 = GUICtrlCreateInput("10", 71, 25, 35, 27)
	GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
	$Button1 = GUICtrlCreateButton("OK", 200, 190, 49, 41)
	GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
	$Label1 = GUICtrlCreateLabel("KWh", 119, 29, 49, 23)
	GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
	$date1 = GUICtrlCreateDate(_NowDate, 71, 75, 197, 27, $DTS_SHORTDATEFORMAT)
	GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")
	Global $idTime = GUICtrlCreateDate("", 71, 130, 197, 27, $DTS_TIMEFORMAT)
	GUICtrlSetFont(-1, 12, 800, 0, "Times New Roman")

    ;GUICtrlSendMsg($date1, $DTM_SETFORMATW, 0, "yyyy/MM/dd HH:mm:ss")

	Global $sDate
	Global $sTime
	Global $iUebergabe
	Global $date1
	Global $iDateCalc
	Global $iStartzeit
	Global $iStartzeit2
	Global $idDate
	Global $iDate
	Global $iStart
	Global $sStyle = "HH:mm:ss"

	GUISetState(@SW_SHOW)
	#EndRegion ### END Koda GUI section ###

	While 1
		$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $Button1
				ExitLoop
		EndSwitch
	WEnd


	Global $aDate = StringSplit(GUICtrlRead($date1), '.')
	$sDate = $aDate[3] & "/" & $aDate[2] & "/" & $aDate[1]
	Global $sTime = GUICtrlRead($idTime)
	Global $Diff = _DateDIff('s', $sDate & " "  & $sTime, _NowCalc())
	MsgBox(0, "", "Zeitdifferenz in Sekunden:" & @CRLF & $Diff)


EndFunc   ;==>Example

Alles anzeigen

ConfluenceHunter

Super,

das klappt so wie es sein soll.

Vielen Dank

ConfluenceHunter

**AspirinJunkie**

Wenn dir dein altes, ausführliches Datumsformat so lieb ist, dann kannst du das auch behalten.
Der Trick hierbei wäre, das Format von dem Date-Element nur für den kurzen Zeitpunkt des Auslesens in ein anderes Format zu ändern und hinterher wieder zurück.
Das habe ich dir unten mal umgesetzt.
Daneben habe ich eine ganze Menge Zeug drumherum entfernt, welche für das Skript überhaupt nicht gebraucht wurde.
Ich gehe mal davon aus, dass das Teil eines größeres Skriptes ist, für welches der Teil hier benötigt wird.
Dennoch habe ich es zur besseren Übersichtlichkeit und Verständlichkeit entsprechend aufgeräumt:

AutoIt

#include <GUIConstantsEx.au3>
#include <Date.au3>

GUICreate("Wann soll die Ladung beginnen ? ", 345, 250, 800, 300)
; Schriftart für alle Elemente einmal setzen anstatt für jedes einzeln
GUISetFont(12, 800, 0, "Times New Roman")

Global $idButtonOk = GUICtrlCreateButton("OK", 200, 190, 49, 41)
Global $idDate = GUICtrlCreateDate(_NowDate, 71, 75, 197, 27)
Global $idTime = GUICtrlCreateDate("", 71, 130, 197, 27, $DTS_TIMEFORMAT)

; GUI sichtbar schalten
GUISetState(@SW_SHOW)

; Variablen, welche später mnoch verwendet werden
Global $sDate, $sTime, $nDiff

While 1
	Switch GUIGetMsg()
		
        Case $GUI_EVENT_CLOSE
			ExitLoop

        ; Wenn der OK-Button gedrückt wurde
		Case $idButtonOk

            ; Datum auslesen - hierzu erst einmal das Format vereinfachen
            GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, "yyyy/MM/dd")
            $sDate = GUICtrlRead($idDate)
            ; Format nach dem Auslesen wieder zurücksetzen
            GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, "")
 
            ; Zeit auslesen
            $sTime = GUICtrlRead($idTime)

            ; Datum und Zeit verknüpfen und Differenz zu jetzt berechnen
            $nDiff = _DateDIff('s', $sDate & " "  & $sTime, _NowCalc())

            ; Differenz ausgeben
            MsgBox(0, "", "Zeitdifferenz in Sekunden:" & @CRLF & $nDiff)
	EndSwitch
WEnd

Alles anzeigen

_DateDiff('s', ?, _NowCalc())

Ähnliche Themen

Ordner älter 24 h löschen

Outlook

VBA-UDF nach AutoIt