FFplay AutoitKonsole auslesen

ruby

Hallo,

ich habe folgendes Problem, vielleicht könnt Ihr mir helfen.
Ich habe diesen Code mit dem ich per ffprobe die Duration der mp4 ermittle und in das Imputfeld $sFilmlaenge schreibe.
Mit ffplay stelle ich das Video dar.

AutoIt

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>

Global $hGUI = GUICreate("Spieldauer anzeigen", 1000, 500, -1, -1)
Global $StartButton = GUICtrlCreateButton("Video Wählen", 10, 10, 100, 30)
Global $laufendeabspielzeit = GUICtrlCreateInput("", 120, 15, 100, 20, $ES_READONLY)
Local $Filmdauer = GUICtrlCreateInput("", 230, 15, 100, 20, $ES_READONLY)

Global $Edit1 = GUICtrlCreateEdit("", 10, 50, 980, 440)
GUICtrlSetData(-1, "")
_GUICtrlEdit_SetLimitText($Edit1, -1) ;kein Limit -1

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

        Case $StartButton
			_Filmlaenge()

		Case $laufendeabspielzeit

		Case $Filmdauer

		Case $Edit1

    EndSwitch
WEnd


Func _Filmlaenge()

	Global $sinput = @ScriptDir & "\film1.mp4" ; FileOpenDialog("Wähle ein Video aus", @ScriptDir, "Datei (*.mp4;*.*;*;)", 1)

	Local $iPID = Run(@ComSpec & ' /c ffplay -stats ' & """" & $sinput & """", @ScriptDir, @SW_HIDE, $STDOUT_CHILD)

	$filmlength = ""

	Local $cmd = 'ffprobe.exe ' & '"' & $sinput & '"' & ' 2>&1 | findstr Duration' ; ermittelt die Filmlänge des Filmes

	$handle = Run(@ComSpec & ' /c ' & $cmd, '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

	While True
		$line = StdoutRead($handle)
		If @error Then ExitLoop
		$filmlength &= StringStripWS($line, 8)

		$line &= StdoutRead($handle)
		GUICtrlSetData($Edit1, StdoutRead($line))

	WEnd

	ProcessWaitClose($handle)

	Global $sFilmlaenge = StringRegExpReplace($filmlength, ".*Duration:(\d+:\d+:\d+).*", "$1") ; Extrahiere die Filmlänge
	GUICtrlSetData($Filmdauer, $sFilmlaenge)

;~ 	GUICtrlSetData($Edit1, StdoutRead($iPID))

EndFunc

Alles anzeigen

Mein Problem ist, das ich die Daten in der Autoikonsole, die, während das Video läuft, nicht erfassen kann.
Als Test wollte ich dies in dem Editfeld darstellen, funktioniert aber nicht.

Mein Anliegen ist, dass ich nur Zahlen vor A-V: erfassen will und in das Imputfeld $laufendeabspielzeit einlese.
Sinn und Zweck ist, das man dann im Inputfeld laufendeabspielzeit die bereits abgelaufende Zeit des Videos sieht.
Wenn man die rechte/linke Pfeiltaste drückt springt das Video 10 Sekunden vor/zurück.
Man kann auch mit der rechten Maustaste sich durch das Video bewegen.

Ausschnitt aus der Autoitkonsole:

Code

0.88 A-V: -0.021 fd= 0 aq= 9KB vq= 11KB sq= 0B f=0/0 
0.93 A-V: -0.021 fd= 0 aq= 9KB vq= 10KB sq= 0B f=0/0 
0.97 A-V: -0.018 fd= 0 aq= 9KB vq= 8KB sq= 0B f=0/0 
1.02 A-V: -0.017 fd= 0 aq= 9KB vq= 8KB sq= 0B f=0/0 
1.07 A-V: -0.016 fd= 0 aq= 9KB vq= 7KB sq= 0B f=0/0 
1.11 A-V: -0.016 fd= 0 aq= 9KB vq= 7KB sq= 0B f=0/0 
16.72 A-V: -0.062 fd= 0 aq= 9KB vq= 35KB sq= 0B f=0/0 
16.75 A-V: -0.059 fd= 0 aq= 8KB vq= 35KB sq= 0B f=0/0 
16.80 A-V: -0.012 fd= 0 aq= 8KB vq= 35KB sq= 0B f=0/0 
16.84 A-V: -0.022 fd= 0 aq= 9KB vq= 53KB sq= 0B f=0/0 
16.87 A-V: -0.023 fd= 0 aq= 9KB vq= 53KB sq= 0B f=0/0 
16.90 A-V: -0.024 fd= 0 aq= 8KB vq= 50KB sq= 0B f=0/0 
16.95 A-V: -0.011 fd= 0 aq= 8KB vq= 49KB sq= 0B f=0/0 
usw...

Alles anzeigen

Vielen Dank schon einmal für Eure Hilfe

**Moombas**

Um aus deinem String nur die vorderen Zahlen zu bekommen, kannst du Stringsplit oder RegEx nutzen.

AutoIt

Opt('MustDeclareVars', 1)
Global Const $String = '0.88 A-V: -0.021 fd= 0 aq= 9KB vq= 11KB sq= 0B f=0/0'

Consolewrite(Stringsplit($String, ' ')[1] & @CRLF)

AutoIt

Opt('MustDeclareVars', 1)
#include <Array.au3>
Global Const $String = '0.88 A-V: -0.021 fd= 0 aq= 9KB vq= 11KB sq= 0B f=0/0'

Consolewrite(StringRegExp($String, '^\d*.\d{2}', $STR_REGEXPARRAYMATCH)[0] & @CRLF)

ruby

Hallo Moombas,

vielen Dank,

ja, aber ich muss doch erst einmal an die Daten von der Konsole rankommen.

Führe ich das zum testen aus: GUICtrlSetData($Edit1, StdoutRead($iPID)) werden kein Daten in das Editfeld übertragen.

Die Zahlen vor A-V: ändern sich auch ständig wie oben schon erwähnt.

**Moombas**

Musst du das nicht in deiner Schleife ändern/einbauen (Zeile 52)?

AutoIt

$Time = StringRegExp(StdoutRead($handle), '^\d*.\d{2}', $STR_REGEXPARRAYMATCH)[0]
GUICtrlSetData($Edit1, $Time)

ruby

Wenn ich das mache wird die GUI geschlossen und die Ausgabe an der Konsole brechen nach ca. 1 Sekunde ab, owohl der ffplay Player weiterläuft.

**Moombas**

Es ist so bekloppt wenn man nicht selber was zum Testen hat -.-

Aber auf jedenfall macht Zeile 52 für mich keinen Sinn, da $line kein handle oder pid ist auf die man mit stdoutread zugreifen könnte, sondern nur Text.

**Moombas**

Auch passen da einige Local/Global Zuweisungen nicht.

Vom Prinzip würde ich denken das es so funktionieren müsste, bin mir aber nicht sicher da ich wie gesagt nicht testen kann:

AutoIt

Opt('MustDeclareVars', 1)
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>

Global $PID_ff, $Time
Global $hGUI = GUICreate("Spieldauer anzeigen", 1000, 500, -1, -1)
Global $StartButton = GUICtrlCreateButton("Video wählen", 10, 10, 100, 30)
Global $laufendeabspielzeit = GUICtrlCreateInput("", 120, 15, 100, 20, $ES_READONLY)
Global $Filmdauer = GUICtrlCreateInput("", 230, 15, 100, 20, $ES_READONLY)

Global $Edit1 = GUICtrlCreateEdit("", 10, 50, 980, 440)
GUICtrlSetData(-1, "")
_GUICtrlEdit_SetLimitText($Edit1, -1) ;kein Limit -1

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
             Exit

        Case $StartButton
			 $PID_ff = _Filmlaenge()

		Case $laufendeabspielzeit

		Case $Filmdauer

		Case $Edit1

		Case Else ;Die Zeit aktualisieren - ggf. zu häufig (10* je Sek.), bitte prüfen
			 if not ProcessExists('ffprobe.exe') then Continueloop
			 $Time = StringRegExp(StdoutRead($PID_ff), '^\d*.\d{2}', $STR_REGEXPARRAYMATCH)[0]
			 If StringinStr($Time, 'A-V:') then GUICtrlSetData($laufendeabspielzeit, $Time)
    EndSwitch
    sleep(100); Offset für nicht zu häufiges Abfragen
WEnd


Func _Filmlaenge()
Local $sFilmlaenge, $line, $filmlength = ""
Local Const $sinput = @ScriptDir & "\film1.mp4" ; FileOpenDialog("Wähle ein Video aus", @ScriptDir, "Datei (*.mp4;*.*;*;)", 1)
Local Const $iPID   = Run(@ComSpec & ' /c ffplay -stats ' & """" & $sinput & """", @ScriptDir, @SW_HIDE, $STDOUT_CHILD)
Local Const $cmd    = 'ffprobe.exe ' & '"' & $sinput & '"' & ' 2>&1 | findstr Duration' ; ermittelt die Filmlänge des Filmes
Local Const $handle = Run(@ComSpec & ' /c ' & $cmd, '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

	While True
		$line = StdoutRead($handle)
		If @error Then ExitLoop
		$filmlength &= StringStripWS($line, 8)

		$line &= StdoutRead($handle)
	WEnd
	ProcessWaitClose($handle)

	$sFilmlaenge = StringRegExpReplace($filmlength, ".*Duration:(\d+:\d+:\d+).*", "$1") ; Extrahiere die Filmlänge
	GUICtrlSetData($Filmdauer, $sFilmlaenge)

	Return $iPID
EndFunc

Alles anzeigen

ruby

Ok danke, aber die GUI schliesst sich immer noch.

Habe festgestellt wenn man Opt('MustDeclareVars', 1) auskommentiert oder auf 0 bleibt die GUI sichtbar.

Vieleicht noch einmal zu Verständniss:
In dem Input $laufendeabspielzeit soll die laufende Abspielzeit dargestellt werden.
In dem Input $Filmdauer wird die gesamte Filmdauer dargestellt die ich ja schon mit ...

AutoIt

Global $sFilmlaenge = StringRegExpReplace($filmlength, ".*Duration:(\d+:\d+:\d+).*", "$1") ; Extrahiere die Filmlänge
GUICtrlSetData($Filmdauer, $sFilmlaenge)

... erfasse.

Dann steht im Inputfeld $Filmdauer: 01:47:31

Vielleicht sollten wir überprüfen ob überhaupt die Konsole im Editfeld ausgegeben wird, deswegen habe ich das Editfeld zur Kontrolle gemacht als Zwischenschritt, wird später wieder entfernt.
Aber da kommt nichts an.

Hier die Daten die in der Konsole geschrieben werden:

Code

ffplay version 2023-04-12-git-1179bb703e-full_build-http://www.gyan.dev Copyright (c) 2003-2023 the FFmpeg developers
built with gcc 12.2.0 (Rev10, Built by MSYS2 project)
configuration: --enable-gpl --enable-version3 --enable-static --disable-w32threads --disable-autodetect --enable-fontconfig --enable-iconv --enable-gnutls --enable-libxml2 --enable-gmp --enable-bzlib --enable-lzma --enable-libsnappy --enable-zlib --enable-librist --enable-libsrt --enable-libssh --enable-libzmq --enable-avisynth --enable-libbluray --enable-libcaca --enable-sdl2 --enable-libaribb24 --enable-libdav1d --enable-libdavs2 --enable-libuavs3d --enable-libzvbi --enable-librav1e --enable-libsvtav1 --enable-libwebp --enable-libx264 --enable-libx265 --enable-libxavs2 --enable-libxvid --enable-libaom --enable-libjxl --enable-libopenjpeg --enable-libvpx --enable-mediafoundation --enable-libass --enable-frei0r --enable-libfreetype --enable-libfribidi --enable-liblensfun --enable-libvidstab --enable-libvmaf --enable-libzimg --enable-amf --enable-cuda-llvm --enable-cuvid --enable-ffnvcodec --enable-nvdec --enable-nvenc --enable-d3d11va --enable-dxva2 --enable-libvpl --enable-libshaderc --enable-vulkan --enable-libplacebo --enable-opencl --enable-libcdio --enable-libgme --enable-libmodplug --enable-libopenmpt --enable-libopencore-amrwb --enable-libmp3lame --enable-libshine --enable-libtheora --enable-libtwolame --enable-libvo-amrwbenc --enable-libcodec2 --enable-libilbc --enable-libgsm --enable-libopencore-amrnb --enable-libopus --enable-libspeex --enable-libvorbis --enable-ladspa --enable-libbs2b --enable-libflite --enable-libmysofa --enable-librubberband --enable-libsoxr --enable-chromaprint
libavutil 58. 6.100 / 58. 6.100
libavcodec 60. 9.100 / 60. 9.100
libavformat 60. 4.101 / 60. 4.101
libavdevice 60. 2.100 / 60. 2.100
libavfilter 9. 5.100 / 9. 5.100
libswscale 7. 2.100 / 7. 2.100
libswresample 4. 11.100 / 4. 11.100
libpostproc 57. 2.100 / 57. 2.100
nan : 0.000 fd= 0 aq= 0KB vq= 0KB sq= 0B f=0/0 
Input #0, mov,mp4,m4a,3gp,3g2,mj2, from 'C:\Eigene-Programme\von-ulf\Filmarchiv-2024\autoit\film1.mp4':
Metadata:
major_brand : isom
minor_version : 1
compatible_brands: isomavc1
creation_time : 2020-12-01T10:10:09.000000Z
Duration: 01:47:31.39, start: 0.000000, bitrate: 427 kb/s
Stream #0:0[0x1](und): Video: h264 (High) (avc1 / 0x31637661), yuv420p(progressive), 480x256 [SAR 1:1 DAR 15:8], 360 kb/s, 29.95 fps, 29.95 tbr, 2396 tbn (default)
Metadata:
creation_time : 2020-12-01T10:10:09.000000Z
handler_name : ÃŒ?
vendor_id : [0][0][0][0]
Stream #0:1[0x2](und): Audio: aac (HE-AAC) (mp4a / 0x6134706D), 48000 Hz, stereo, fltp, 64 kb/s (default)
Metadata:
creation_time : 2020-12-01T10:11:09.000000Z
handler_name : ÃŒ?
vendor_id : [0][0][0][0]
-0.02 A-V: -0.100 fd= 0 aq= 9KB vq= 21KB sq= 0B f=0/0 
0.02 A-V: -0.096 fd= 0 aq= 9KB vq= 21KB sq= 0B f=0/0 
0.05 A-V: -0.049 fd= 0 aq= 9KB vq= 20KB sq= 0B f=0/0 
0.10 A-V: -0.046 fd= 0 aq= 9KB vq= 20KB sq= 0B f=0/0 
0.13 A-V: -0.025 fd= 0 aq= 8KB vq= 20KB sq= 0B f=0/0 
0.16 A-V: -0.027 fd= 0 aq= 9KB vq= 20KB sq= 0B f=0/0 
0.20 A-V: -0.028 fd= 0 aq= 9KB vq= 20KB sq= 0B f=0/0 
0.24 A-V: -0.015 fd= 0 aq= 9KB vq= 19KB sq= 0B f=0/0

Alles anzeigen

usw.

Das geht so lange wie der Film lang ist.
In der letzte Zeile steht = 6446.60 A-V: -5.189 fd= 0 aq= 0KB vq= 0KB sq= 0B f=0/0

Es sollen ja nur die Werte vor A-V: im Inputfeld $laufendeabspielzeit dann ausgegeben werden.

**Moombas**

Das Problem mit Opt('MustDeclareVars', 1) könnte daran liegen, das ich eine Variable vergessen hatte zu deklarieren, habe ich oben aber geändert (Änderung Zeile 42). Auch in Zeile 10 deine falsche Deklaration von Local auf Global noch geändert (das hatte ich auch noch übersehen).

Eine Abfrage ob wirklich die relevante Zeile schon ausgegeben wird habe ich auch mit eingebaut.

Wichtig wäre aber eine Prüfung z.B. via MsgBox was überhaupt ausgelesen wird mit dem StdoutRead in Zeile 34.

Wobei (aber da muss mich jetzt jemand korrigieren) ich glaube das deine Whileschleife bis zum Filende läuft richtig?
Wenn das stimmt, dann musst du Zeile 32 und 33 entfernen und Zeile 34 und 35 in die Schleife einbauen.

Nur ohne das hier wirklich testen zu können finde ich das immer ewtas schwer.

Folgendes funktioniert auf jeden fall für die Filmdauer:

AutoIt

Opt('MustDeclareVars', 1)
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>

Global $PID_ff, $Time
Global $hGUI = GUICreate("Spieldauer anzeigen", 1000, 500, -1, -1)
Global $StartButton = GUICtrlCreateButton("Video wählen", 10, 10, 100, 30)
Global $laufendeabspielzeit = GUICtrlCreateInput("", 120, 15, 100, 20, $ES_READONLY)
Global $Filmdauer = GUICtrlCreateInput("", 230, 15, 100, 20, $ES_READONLY)

Global $Edit1 = GUICtrlCreateEdit("", 10, 50, 980, 440)
GUICtrlSetData(-1, "")
_GUICtrlEdit_SetLimitText($Edit1, -1) ;kein Limit -1

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
             Exit

        Case $StartButton
			 $PID_ff = _Filmlaenge()

		Case $laufendeabspielzeit

		Case $Filmdauer

		Case $Edit1

		Case Else ;Die Zeit aktualisieren - ggf. zu häufig (10* je Sek.), bitte prüfen
			 if not ProcessExists('ffprobe.exe') then Continueloop

    EndSwitch
    sleep(100); Offset für nicht zu häufiges Abfragen
WEnd


Func _Filmlaenge()
Local $sFilmlaenge, $line
Local Const $sinput = @ScriptDir & "\film1.mp4" ; FileOpenDialog("Wähle ein Video aus", @ScriptDir, "Datei (*.mp4;*.*;*;)", 1)
Local Const $iPID   = Run(@ComSpec & ' /c ffplay.exe -stats ' & """" & $sinput & """", @ScriptDir, @SW_HIDE, $STDOUT_CHILD)
Local Const $cmd    = 'ffprobe.exe ' & '"' & $sinput & '"' & ' 2>&1 | findstr Duration' ; ermittelt die Filmlänge des Filmes
Local Const $handle = Run(@ComSpec & ' /c ' & $cmd, '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

	While True
		$line = StdoutRead($handle)
		If @error Then ExitLoop
		If StringInStr($line, 'Duration') then
			$sFilmlaenge = StringRegExp($line, '\d{2}:\d{2}:\d{2}', $STR_REGEXPARRAYMATCH)[0]
			GUICtrlSetData($Filmdauer, $sFilmlaenge)
		Endif
	WEnd
	ProcessWaitClose($handle)

	Return $iPID
EndFunc

Alles anzeigen

ruby

ja, die Whileschleife lauft bis zum Schluss.

Tja, bei der MsgBox kommt nichts an.

Schade das Du das anhand eine mp4 Datei nicht testen kannst.

**Kanashius**

Hi
Das Hauptproblem ist, dass ff* nicht auf StdOut schreibt, sondern aus irgendeinem Grund auf StdErr.

Ich hatte gerade lust zu programmieren, deshalb hab ich das ganze mal Umgesetzt:

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>

Local $sVideoPath = "test.mp4"

; START EXAMPLE WITH CONSOLE
Local $sLength = _getVideoLength($sVideoPath)
If @error Then ConsoleWrite("Error getting video length: "&@error& ">>" &@extended&@crlf)
ConsoleWrite($sLength&@crlf)

Local $iLength = _getVideoLength($sVideoPath, True)
If @error Then ConsoleWrite("Error getting video length: "&@error& ">>" &@extended&@crlf)
ConsoleWrite($iLength&@crlf)

_playVideo($sVideoPath, "_videoTimePlayed")
If @error Then ConsoleWrite("Error playing video: "&@error& ">>" &@extended&@crlf)

; START EXAMPLE WITH GUI
Local $iWidth = 800, $iHeight = 600, $iSpace = 5, $iCtrlHeight = 25
Local $hGui = GUICreate("Test", $iWidth, $iHeight)
Local $idButton = GUICtrlCreateButton("Play", $iSpace, $iSpace, 40, $iCtrlHeight)
Local $idLabelTime = GUICtrlCreateLabel("0",  $iSpace*2+40, $iSpace+5, $iWidth - ($iSpace*3+40), $iCtrlHeight)
Local $idProgress = GUICtrlCreateProgress($iSpace, $iSpace*2+$iCtrlHeight, $iWidth-2*$iSpace, $iCtrlHeight)
GUISetState(@SW_SHOW, $hGui)

While True
	_guiLoop()
WEnd

Func _guiLoop($iPid = 0)
	Local static $iOldPid = 0, $hPlayWindow
	If $iOldPid<>$iPid or ($hPlayWindow=0 And $iPid<>0) Then
		$iOldPid = $iPid
		If $iPid<>0 Then ; video starts playing in window
			$hPlayWindow = _processGetFirstWindow($iPid)
		Else ; video stops playing
			$hPlayWindow = 0
			GUICtrlSetState($idButton, $GUI_ENABLE)
			_videoTimePlayedGui(0, 0)
		EndIf
	EndIf
	Switch GUIGetMsg()
		Case -3
			If $iPid<>0 Then WinClose($hPlayWindow)
			Exit
		Case $idButton
			GUICtrlSetState($idButton, $GUI_DISABLE)
			_play()
	EndSwitch
EndFunc

Func _play()
	_playVideo($sVideoPath, "_videoTimePlayedGui", "_guiLoop")
	If @error Then ConsoleWrite("Error playing video: "&@error& ">>" &@extended&@crlf)
EndFunc

Func _videoTimePlayedGui($iSeconds, $iLength)
	GUICtrlSetData($idLabelTime, $iSeconds)
	GUICtrlSetData($idProgress, Int(100*($iSeconds/$iLength)))
EndFunc

Func _videoTimePlayed($iSeconds, $iLength)
	ConsoleWrite("Seconds: "&$iSeconds&@TAB&"Percent of video: "&($iSeconds/$iLength)&@crlf)
EndFunc

#cs
Errors:
	1: Error calling ffprobe => Check if ffprobe.exe is in the correct folder
	2: Timeout calling ffprobe (>60 seconds)
	3: Error parsing duration
#ce
Func _getVideoLength($sPath, $bAsSeconds = False)
	Local $iPid = Run(@ComSpec & ' /c ffprobe.exe "' & $sPath & '"', @ScriptDir, @SW_HIDE, BitOR($STDERR_CHILD, $STDOUT_CHILD))
	If @error Then return SetError(1, @error, -1)
	ProcessWait($iPid, 60)
	If @error Then return SetError(2, @error, -1)
	Local $sOut = StdoutRead($iPid) & @CRLF & StderrRead($iPid)
	Local $arTime = StringRegExp($sOut, ".*Duration:\s*(\d+):(\d{2}):(\d{2})\.(\d{2}).*", 1)  ; maybe use part of a second here ($arTime[3])
	If @error Then return SetError(3, @error, -1)
	If UBound($arTime)<>3 Then SetError(3, 0, 0)
	If Not $bAsSeconds Then return $arTime[0]&":"&$arTime[1]&":"&$arTime[2]
	return Int($arTime[0])*60*60 + Int($arTime[1])*60 + $arTime[2]
EndFunc

; Error 1: Could not read length (@extended contains the error from _getVideoLength)
; Error 2: Could not play (ffplay.exe failed)
Func _playVideo($sPath, $sCallbackTime = Default, $sCallbackLoop = Default)
	Local $iLength = 0
	If $sCallbackTime<>Default Then
		$iLength = _getVideoLength($sPath, True)
		If @error Then return SetError(1, @error, False)
	EndIf
	Local $iPid = Run(@ComSpec & ' /c ffplay.exe "' & $sPath & '"', @ScriptDir, @SW_HIDE, BitOR($STDERR_CHILD, $STDOUT_CHILD))
	If @error Then return SetError(2, @error, -1)
	Local $iSeconds = 0
	While ProcessExists($iPid)
		Local $sOut = StdoutRead($iPid) & StderrRead($iPid)
		If $sCallbackTime<>Default And Not @error And $sOut<>"" Then
			Local $arTime = StringRegExp($sOut, ".*?(\d+)\.(\d{2}) A-V:.*", 1) ; maybe use part of a second here ($arTime[1])
			If Not @error And UBound($arTime)=2 And $iSeconds<>Int($arTime[0]) Then
				$iSeconds = Int($arTime[0])
				Call($sCallbackTime, $iSeconds, $iLength)
				If @error Then ConsoleWrite("The function "&$sCallbackTime&" needs the two parameters ($iSecondsPlayed, $iSecondsVideoLength)")
			EndIf
		EndIf
		If $sCallbackLoop<>Default Then
			Call($sCallbackLoop, $iPid)
			If @error Then ConsoleWrite("The function "&$sCallbackLoop&" needs one parameter ($iProcessId)")
		EndIf
	WEnd
	return True
EndFunc

Func _processGetFirstWindow($iPid)
	Local $arWin = WinList()
	For $i=1 to UBound($arWin)-1 step 1
		If WinGetProcess($arWin[$i][1]) = $iPid Then return $arWin[$i][1]
	Next
	return 0
EndFunc

Alles anzeigen

Ich hab dabei mehrere Funktionen erstellt. Einmal zum Abrufen der Länge und einmal zum Abspielen, wobei beim Abspielen Callbacks genutzt werden.
Die übergebenen Funktionen werden aufgerufen und müssen die passende Anzahl an Parametern haben. Dadurch kann die aktuelle Laufzeit abgearbeitet werden und es gibt auch ein Callback in der PlayLoop, die für die Gui genutzt werden kann, damit die Gui weiterhin funktioniert, wenn die Schleife vom abspielen läuft.

Ich hab überall Local verwendet, falls das ganze mal in Funktionen ausgelagert werden soll... dann muss man nicht alles ändern und es macht eh keinen Unterschied.

Bei ffprobe.exe hat es übrigens auch nur funktioniert, weil du hier: Local $cmd = 'ffprobe.exe ' & '"' & $sinput & '"' & ' 2>&1 | findstr Duration' ; ermittelt die Filmlänge des Filmes mit dem 2>&1 den StdErr auf StdOut umgeleitet hast.

Ich hoffe das ist es, was du dir vorgestellt hast.
MfG, Kanashius

ruby

Hi Kanashius,

man bist Du gut.
Wahnsinn da werde ich mich ersteinmal durcharbeiten müssen.
Melde mich dann noch einmal.
Erst einmal vielen vielen Dank.

**Moombas**

Zitat von Kanashius

Hi
Das Hauptproblem ist, dass ff* nicht auf StdOut schreibt, sondern aus irgendeinem Grund auf StdErr.

Da wäre ich auch nie drauf gekommen -.-

Erklärt aber warum alle meine nachgelagerten Tests nix ausgeworfen haben

ruby

Hi Moombas,

auch Dir danke für Deine Mühe.

ruby 13. Mai 2024 um 10:52