Listbox wird immer mit letztem Eintrag angezeigt

hipfzwirgel

Hallo Gemeinde,

mit der folgenden Funktion erzeuge ich dynamisch beim Programmstart eine ListBox deren Einträge aus der ini-Datei ausgelesen werden.
Diese wiederum bestehen aus den Dateinamen des definierten Ordners. Alles funzt soweit prima.
Nur beim Programmstart wird die Listbox immer mit dem letzten Eintrag angezeigt, anstatt mit dem ersten.
Wie kann ich erreichen, das die Listbox immer mit dem ersten Eintrag angezeigt wird?

Code

Func CreateListBox()

	Local $sSection = "items"
	Local $sKeyPrefix = "item"
	Local $sINIFile = "PfadzurInidatei\listbox.ini"
	Local $aItems = IniReadSection($sINIFile, "items")

	$aFileList = _FileListToArray("Pfad zum Ordner für die Dateinamen", "QR_*")
	For $i = 1 To $aFileList[0] ; Array[0] enthält die Anzahl der Elemente im Array
		IniWrite($sINIFile, $sSection, $sKeyPrefix & $i, $aFileList[$i])
	Next
	If @error = 1 Then
		MsgBox($MB_SYSTEMMODAL, "", "Pfad ungültig.")
		Exit
	EndIf
	If @error = 4 Then
		MsgBox($MB_SYSTEMMODAL, "", "Keine Dateien gefunden.")
		Exit
	EndIf
	Sleep(200)

	If Not @error Then
		; Einträge durchlaufen und zur Listbox hinzufügen
		For $i = 1 To $aItems[0][0]
			GUICtrlSetData($QrCodeList, $aItems[$i][1])
		Next

	Else
		MsgBox(16, "Fehler", "Die INI-Datei konnte nicht gelesen werden.")
	EndIf

EndFunc   ;==>CreateListBox

Alles anzeigen

MojoeB

woher weißt du das es der letzte Eintrag ist, wie ermittelst du den welcher Eintrag zu erst da war ? an den Datei Zeiten ?!

Nutzt du die ini Datei, für ein weiteres Skript oder verarbeitest du alles in diesem Skript?
Falls du es alles in einem rutsch machst musst du dir keine ini Datei erstellen lassen ?!

es mag sein das es einer Datenbank ähnelt sie ist es aber nicht.
aber wenn eh alle Dateien auf dem System verfügbar hast kannst du auch gleich aus dem Explorer Datenlesen
und da kannst du dann auch filtern nach Datum/zeit Ersteller Datum Änderung Datum und was es sonst noch so gibt.

Leider habe ich entweder deine frage nicht verstanden oder es ist dem umstand geschuldet das ich nicht die selben Bedingungen habe wie du auf dem PC habe.
ich habe zum testen Dateien erstellt mit QR- vorne damit ich dein code ausführen kann. aber woher soll nun mein System wissen was zu erst kommen soll ?

C

#include <Array.au3>
#include <GuiListBox.au3>
#include <File.au3>

CreateListBox()
MsgBox(0, 'beendet', 'script beendet')

Func CreateListBox()

    Local $sSection = "items"
    Local $sKeyPrefix = "item"
    Local $sINIFile = @ScriptDir & "\listbox.ini"
    Local $aItems = IniReadSection($sINIFile, "items")
    Local $QrCodeList

    $hGUI = GUICreate("List Box Get ListBox Info", 400, 296)
    $QrCodeList = _GUICtrlListBox_Create($hGUI, "", 2, 2, 396, 296)

    GUISetState(@SW_SHOW)

    $aFileList = _FileListToArray("D:\Programming\Projects\temp68\test", "QR_*")
    For $i = 1 To $aFileList[0] ; Array[0] enthält die Anzahl der Elemente im Array
        IniWrite($sINIFile, $sSection, $sKeyPrefix & $i, $aFileList[$i])
    Next
   
   If @error = 1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Pfad ungültig.")
        Exit
    EndIf
    If @error = 4 Then
        MsgBox($MB_SYSTEMMODAL, "", "Keine Dateien gefunden.")
        Exit
    EndIf
    Sleep(200)

    If Not @error Then
     
        
        _GUICtrlListBox_BeginUpdate($QrCodeList)
        For $i = 1 To $aItems[0][0]
            _GUICtrlListBox_AddString($QrCodeList, $aItems[$i][1])
        Next
        _GUICtrlListBox_EndUpdate($QrCodeList)

        Sleep(1250)

    Else
        MsgBox(16, "Fehler", "Die INI-Datei konnte nicht gelesen werden.")
    EndIf

EndFunc   ;==>CreateListBox

Alles anzeigen

**Kanashius**

Ich hab das ganze mal so umgebaut, wie ich das Error-Handling eher gestalten würde: Die Funktion gibt True/False zurück, je nach Erfolg, und setzt die entsprechenden Error-Codes, die nach dem Aufruf der Funktion behandelt werden.

AutoIt

Global $sFolderData = "data\"


; ... Gui code

Local $sFilesFolder = @ScriptDir
_fillListBox($QrCodeList, $sFilesFolder)
If @error Then
	Local $sTitle = "Fehler beim befüllen der Liste"
	If @error = 1 Then MsgBox($MB_SYSTEMMODAL, $sTitle, 'Fehler beim auslesen des Ordners "'&$sFilesFolder&'": '&@extended&@crlf)
	If @error = 2 Then MsgBox($MB_SYSTEMMODAL, $sTitle, 'Fehler beim schreiben der Ini: '&@extended&@crlf)
	If @error = 4 Then MsgBox($MB_SYSTEMMODAL, $sTitle, '_fillListBox error, contact the developer with the following information: '&@error&">>"&@extended&@crlf)
	If @error = 3 Then
		If @extended = 1 Then
			MsgBox($MB_SYSTEMMODAL, $sTitle, 'Pfad ungültig.'&@crlf)
		ElseIf @extended = 4 Then
			MsgBox($MB_SYSTEMMODAL, $sTitle, 'Keine Dateien gefunden.'&@crlf)
		Else
			MsgBox(16, $sTitle, 'Die INI-Datei konnte nicht gelesen werden.'&@crlf)
		EndIf
		Exit
	EndIf
EndIf

; Errors:
;         1: _FileListToArray failed (@extended contains _FileListToArray error code)
;         2: IniWrite failed (@extended contains IniWrite error code)
;         3: IniReadSection failed (@extended contains IniReadSection error code)
;         4: GUICtrlSetData failed (@extended contains GUICtrlSetData error code) => probably not a control for $idListBox
Func _fillListBox($idListBox, $sFilePath, $sIniFile = $sFolderData & "listbox.ini")
	Local Static $sSection = "items", $sKeyPrefix = "item"

	; Update ini with files
	$aFileList = _FileListToArray($sFilePath, "QR_*")
	If @error Then Return SetError(1, @error, False)
	For $i = 1 To UBound($aFileList)-1
		IniWrite($sIniFile, $sSection, $sKeyPrefix & $i, $aFileList[$i])
		If @error Then Return SetError(2, @error, False)
	Next

	; Read ini and fill listbox
	Local $arItems = IniReadSection($sIniFile, "items")
	If @error Then Return SetError(3, @error, False)
	Sleep(200) ; Why?
	For $i = 1 To $arItems[0][0]
		GUICtrlSetData($idListBox, $arItems[$i][1])
		If @error Then Return SetError(4, @error, False)
	Next
	Return True
EndFunc   ;==>CreateListBox

Alles anzeigen

Das ganze behebt aber nicht dein eigentliches Problem. Dazu ein paar Anmerkungen/Fragen:

1. Wieso liest du erst die Ini-Datei, dann befüllst du sie mit den aktuellen Dateien (und überschreibst dabei die alten Daten) und schreibst dann die alten Daten in die ListBox? Von dem was ich vom Code/deiner Fragenstellung vermute ergibt das keinen Sinn.
2. MsgBox(16, "Fehler", "Die INI-Datei konnte nicht gelesen werden.") wird ausgegeben, wenn irgendein Fehler bei Sleep(200) aufgetreten ist??? Bedenke: @error wird bei jeglichem Funktionsaufruf auf 0 zurückgesetzt. Die Zeile kann also nie erreicht werden, da Sleep keine Fehlercode geben kann. Ich habe für meine Code-Änderung angenommen, dass sich die ganzen If @error Zeilen auf IniReadSection beziehen.
3. Brauchst du die Ini überhaupt? Wenn ja, wofür? Du kannst eigentlich die Daten mit _FileListToArray einlesen und direkt in die ListBox schreiben.
4. Was für eine Sortierung stellst du dir vor? Weder _FileListToArray noch IniReadSection garantieren, dass irgendeine Reihenfolge der Daten vorliegt. Normalerweise lesen sie von oben nach unten/alphabetisch, aber das kann sich auch aus irgendwelchen Gründen ändern. Vermutlich brauchst du also so oder so ein _ArraySort, oder etwas ähnliches.

MojoeB

Zitat von Kanashius

3. Brauchst du die Ini überhaupt? Wenn ja, wofür? Du kannst eigentlich die Daten mit _FileListToArray einlesen und direkt in die ListBox schreiben.
4. Was für eine Sortierung stellst du dir vor? Weder _FileListToArray noch IniReadSection garantieren, dass irgendeine Reihenfolge der Daten vorliegt. Normalerweise lesen sie von oben nach unten/alphabetisch, aber das kann sich auch aus irgendwelchen Gründen ändern. Vermutlich brauchst du also so oder so ein _ArraySort, oder etwas ähnliches.

genau, das meine ich auch, oder er geht einfach nach den Attributen der Dateien, die lassen sich ja auch einfacher sortieren, je nadem was er mit den daten macht.

hipfzwirgel

Hallo Mojoeb,
hallo Kanasius,

ich glaube meine Fragestellung war wohl genauso unperfekt wie der Code.

Es geht mir nicht ums Einlesen der Dateinamen als Einträge für eine ini-datei! Das funzt ja schon. Das eigentliche Problem:

Beim Erstellen der Listbox beim Programmstart ist diese dann ganz nach unten gescrollt und der letzte Eintrag ist blau hinterlegt.
Ich hätte gerne aber das die Listbox so angezeigt wird, dass der erste Eintrag da steht. also nicht herunter gescrollt.

hipfzwirgel

Jetzt bin ich total verwirrt. ich habe ein TestScript erstellt.
Wenn ich es starte, wird die Listbox richtig dargestellt.

C

#include <Array.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <File.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

#Region ### START Koda GUI section ### Form=
$Form1_1 = GUICreate("KVM-Auswahl", 767, 613, 205, 134)
$List1 = GUICtrlCreateList("", 10, 304, 308, 110, $LBS_USETABSTOPS)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
$Beenden4 = GUICtrlCreateButton("Beenden", 578, 544, 161, 41)
GUICtrlSetFont(-1, 12, 800, 0, "Arial")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
CreateListBox()

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Beenden4
			Exit

	EndSwitch
WEnd


	Func CreateListBox()

	Local $sINIFile = ".\Testini.ini"
    Local $aItems = IniReadSection($sINIFile, "items")

	If Not @error Then
        ; Einträge durchlaufen und zur Listbox hinzufügen
        For $i = 1 To $aItems[0][0]
            GUICtrlSetData($List1, $aItems[$i][1])
        Next

    Else
        MsgBox(16, "Fehler", "Die INI-Datei konnte nicht gelesen werden.")
    EndIf

EndFunc ;==> CreateListBox()

Alles anzeigen

**Kanashius**

Zum auswählen in der ListBox: _GUICtrlListBox_SetCurSel($idList, 0)
Dabei wird auch automatisch zu dem ausgewähltem Item gescrollt.

hipfzwirgel

Hallo Gemeinde,

bedingt durch die Denkanstöße habe ich die Sache mit der ini-Datei gelöscht (war eine Altlast aus dem aller ersten Entwurf).
Stattdessen habe ich die Funktion jetzt so erstellt:

Code

Func CreateListBox()
	
	GUICtrlSetData($QrCodeList, "||") ; eine LeerZeile am Anfang einblenden
	$aFileList = _FileListToArray("E:\Arbeit\Batchdateien\Scripte\QR-CodeGenerator\data", "QR_*")
	; Einträge durchlaufen und zur Listbox hinzufügen
	For $i = 1 To $aFileList[0]
		$sHelp = GUICtrlSetData($QrCodeList, $aFileList[$i])
	Next

EndFunc   ;==>CreateListBox

Was soll ich sagen. So wird die Listbox richtig angezeigt.

Vielen lieben aller herzlichsten Dank an Mojoeb und Kanashius. ihr habt mir mit den ideen geholfen