map fuer ein magisches quadrat und dessen aufloesung

bankesbusters

hallo zusammen,

bevor die familie gleich mein ganzes wochenende belagert, habe ich noch schnell fragen zu map coding und moeglichkeiten hierin.

ich poste ein voll funktionsfaehiges script. es laeuft und tut genau das was es soll, aber es ist viel zu lang und bislang sind alle versuche es irgendwie zu kuerzen gescheitert. ich habe viel zeit mit versuchen das irgendwie in einer 'map' zu verschachteln verbracht und dann damit regeln zu verfassen womit die map arbeiten soll. das ganze scheiterte daran, dass ich die map von Kanashius aus einem meiner letzten thema weiter getestet habe, aber irgendwie gar nicht verstehe wo ich was genau aendern muss damit ich es erweitern oder veraendern kann. damit ich aber nicht ungluecklich werde habe ich es dann manuell geschrieben, so das es genau das tut was es tun soll gemaess den regeln die ich dem ganzen mitgegeben habe.

es handelt sich um die verwendung eines sog. magischen quadrates (das einfachste was es gibt) ... zu finden in youtube unter dem suchbegriff:

"12 x 12 Magic Square! Easiest Method ! Don't miss !" ( youtube.com/watch?v=HBd8ZM6aEOw )

also das ist meine ini datei die ich mittels einer map verwenden moechte. ich habe also einen text geschrieben mit 144 woertern und habe ihn dann gemaess diesem magischen quadrat von den worten her angeordnet, damit ich dann durch das script den richtigen text wieder anzeigen lassen kann. (ja, es sind alles nur spielereien)

auf jeden fall habe ich versucht die felder abzurufen und an der entsprechenden stelle wieder einzufuegen. klappt alles prima, aber sind halt 144 zeilen in einer For-To-Next-Schleife und jegliche versuche irgendwo einen zaehler einzubauen sind gescheitert, weil es auch unregelmaessig ist, aber seht selbst:

ini datei:

Code

[DATA]
key01=1.2.3.141.140.139.138.137.136.10.11.12
key02=13.14.15.129.128.127.126.125.124.22.23.24
key03=25.26.27.117.116.115.114.113.112.34.35.36
key04=108.107.106.40.41.42.43.44.45.99.98.97
key05=96.95.94.52.53.54.55.56.57.87.86.85
key06=84.83.82.64.65.66.67.68.69.75.74.73
key07=72.71.70.76.77.78.79.80.81.63.62.61
key08=60.59.58.88.89.90.91.92.93.51.50.49
key09=48.47.46.100.101.102.103.104.105.39.38.37
key10=109.110.111.33.32.31.30.29.28.118.119.120
key11=121.122.123.21.20.19.18.17.16.130.131.132
key12=133.134.135.9.8.7.6.5.4.142.143.144

Alles anzeigen

AutoIT-script:

C

#include <MsgBoxConstants.au3>
#include <Array.au3>
#comments-start
als erstes holen wir uns die einzig _richtige_ loesung aus einer ini datei zum spaeteren vergleich:
#comments-end
Global $ini = @ScriptDir & "\magic.ini"
Global $iniOutput[1][1]
Global $sections = IniReadSectionNames($ini)
For $a = 1 To UBound($sections) - 1
   $keys = IniReadSection($ini, $sections[$a])
    Redim $iniOutput[UBound($keys)][12]
   For $b = 1 To UBound($keys) - 1
       $data = StringSplit($keys[$b][1], '.')
        $iniOutput[$b][0] = $data[1]
        $iniOutput[$b][1] = $data[2]
        $iniOutput[$b][2] = $data[3]
        $iniOutput[$b][3] = $data[4]
        $iniOutput[$b][4] = $data[5]
        $iniOutput[$b][5] = $data[6]
        $iniOutput[$b][6] = $data[7]
        $iniOutput[$b][7] = $data[8]
        $iniOutput[$b][8] = $data[9]
        $iniOutput[$b][9] = $data[10]
        $iniOutput[$b][10] = $data[11]
        $iniOutput[$b][11] = $data[12]
   Next
Next
_ArrayDisplay($iniOutput) ;  dies ist nur ein test zur kontrolle der daten!
_ArrayDelete($iniOutput, 0) ; wir loeschen die leere zeile am anfang des arrays
_ArrayDisplay($iniOutput) ; dies ist nur ein test zur kontrolle der daten!
Global $text
$text = "dieses kleine aber ihr und testen zu scripte kleine einen total konfus " & @CRLF & _
        "gewirbelten satz durch sortieren. zu woerter ganzen die dabei lesbaren string bzw. " & @CRLF & _
        "array verwandeln. es auch es damit muss stehen eigentlich mal zwoelf rasters "  & @CRLF & _
        "wort richtige das magisches quadrat dar. es ist das dann um muss " & @CRLF & _
        "stehen wort welches es im internet zu finden gibt. in vorher ganze " & @CRLF & _
        "das habe ich in jeweils zwoelf reihen und zwoelf somit spalten. zwoelf " & @CRLF & _
        "jeweils in worten sind es dann insgesamt 144 worte. worten zwoelf aus " & @CRLF & _
        "also besteht es libre office calc ausrechen lassen wo was quadrat magische " & @CRLF & _
        "simpelste bzw. einfachste eine ini datei zu schreiben wo ein stellt und " & @CRLF & _
        "aus dem text zwoelf eines prinzip dem auf basiert einen sinn ergibt. " & @CRLF & _
        "AutoIT hilft dann einen in wieder map ini eine ich finde das " & @CRLF & _
        "immer so toll soll script test AutoIT feine durchaus hoffentlich dann auch!" & @CRLF
;ConsoleWrite($text)
$arr_text = StringSplit($text, " ")
_ArrayDisplay($arr_text, "text jumble")
#comments-start
jetzt folgt der manuelle versuch die daten zu sortieren. ... soviel vorab, es klappt!
#comments-end

Local $result[UBound($arr_text)]
;ConsoleWrite("-----------"&"ini Array lookup"&"-----------"&@crlf)
For $i = 0 To UBound($iniOutput) - 1 Step 1
    For $j = 0 To UBound($iniOutput, 2) - 1 Step 1
        ;ConsoleWrite("Access $iniOutput["&$i&"]["&$j&"]: "&$iniOutput[$i][$j]&@crlf)
        ;>>>>>>>>>>>>>>>>> If $iniOutput[$i][$j] = "5" Then $result[2] = $arr_text[140] ; <<<<<<<<<<<<<<<< syntax zur manuellen funktion
        If $iniOutput[$i][$j] = "1" Then $result[1] = $arr_text[1]
        If $iniOutput[$i][$j] = "2" Then $result[2] = $arr_text[2]
        If $iniOutput[$i][$j] = "3" Then $result[3] = $arr_text[3]
        If $iniOutput[$i][$j] = "4" Then $result[4] = $arr_text[141]
        If $iniOutput[$i][$j] = "5" Then $result[5] = $arr_text[140]
        If $iniOutput[$i][$j] = "6" Then $result[6] = $arr_text[139]
        If $iniOutput[$i][$j] = "7" Then $result[7] = $arr_text[138]
        If $iniOutput[$i][$j] = "8" Then $result[8] = $arr_text[137]
        If $iniOutput[$i][$j] = "9" Then $result[9] = $arr_text[136]
        If $iniOutput[$i][$j] = "10" Then $result[10] = $arr_text[10]
        If $iniOutput[$i][$j] = "11" Then $result[11] = $arr_text[11]
        If $iniOutput[$i][$j] = "12" Then $result[12] = $arr_text[12]
        If $iniOutput[$i][$j] = "13" Then $result[13] = $arr_text[13]
        If $iniOutput[$i][$j] = "14" Then $result[14] = $arr_text[14]
        If $iniOutput[$i][$j] = "15" Then $result[15] = $arr_text[15]
        If $iniOutput[$i][$j] = "16" Then $result[16] = $arr_text[129]
        If $iniOutput[$i][$j] = "17" Then $result[17] = $arr_text[128]
        If $iniOutput[$i][$j] = "18" Then $result[18] = $arr_text[127]
        If $iniOutput[$i][$j] = "19" Then $result[19] = $arr_text[126]
        If $iniOutput[$i][$j] = "20" Then $result[20] = $arr_text[125]
        If $iniOutput[$i][$j] = "21" Then $result[21] = $arr_text[124]
        If $iniOutput[$i][$j] = "22" Then $result[22] = $arr_text[22]
        If $iniOutput[$i][$j] = "23" Then $result[23] = $arr_text[23]
        If $iniOutput[$i][$j] = "24" Then $result[24] = $arr_text[24]
        If $iniOutput[$i][$j] = "25" Then $result[25] = $arr_text[25]
        If $iniOutput[$i][$j] = "26" Then $result[26] = $arr_text[26]
        If $iniOutput[$i][$j] = "27" Then $result[27] = $arr_text[27]
        If $iniOutput[$i][$j] = "28" Then $result[28] = $arr_text[117]
        If $iniOutput[$i][$j] = "29" Then $result[29] = $arr_text[116]
        If $iniOutput[$i][$j] = "30" Then $result[30] = $arr_text[115]
        If $iniOutput[$i][$j] = "31" Then $result[31] = $arr_text[114]
        If $iniOutput[$i][$j] = "32" Then $result[32] = $arr_text[113]
        If $iniOutput[$i][$j] = "33" Then $result[33] = $arr_text[112]
        If $iniOutput[$i][$j] = "34" Then $result[34] = $arr_text[34]
        If $iniOutput[$i][$j] = "35" Then $result[35] = $arr_text[35]
        If $iniOutput[$i][$j] = "36" Then $result[36] = $arr_text[36]
        If $iniOutput[$i][$j] = "37" Then $result[37] = $arr_text[108]
        If $iniOutput[$i][$j] = "38" Then $result[38] = $arr_text[107]
        If $iniOutput[$i][$j] = "39" Then $result[39] = $arr_text[106]
        If $iniOutput[$i][$j] = "40" Then $result[40] = $arr_text[40]
        If $iniOutput[$i][$j] = "41" Then $result[41] = $arr_text[41]
        If $iniOutput[$i][$j] = "42" Then $result[42] = $arr_text[42]
        If $iniOutput[$i][$j] = "43" Then $result[43] = $arr_text[43]
        If $iniOutput[$i][$j] = "44" Then $result[44] = $arr_text[44]
        If $iniOutput[$i][$j] = "45" Then $result[45] = $arr_text[45]
        If $iniOutput[$i][$j] = "46" Then $result[46] = $arr_text[99]
        If $iniOutput[$i][$j] = "47" Then $result[47] = $arr_text[98]
        If $iniOutput[$i][$j] = "48" Then $result[48] = $arr_text[97]
        If $iniOutput[$i][$j] = "49" Then $result[49] = $arr_text[96]
        If $iniOutput[$i][$j] = "50" Then $result[50] = $arr_text[95]
        If $iniOutput[$i][$j] = "51" Then $result[51] = $arr_text[94]
        If $iniOutput[$i][$j] = "52" Then $result[52] = $arr_text[52]
        If $iniOutput[$i][$j] = "53" Then $result[53] = $arr_text[53]
        If $iniOutput[$i][$j] = "54" Then $result[54] = $arr_text[54]
        If $iniOutput[$i][$j] = "55" Then $result[55] = $arr_text[55]
        If $iniOutput[$i][$j] = "56" Then $result[56] = $arr_text[56]
        If $iniOutput[$i][$j] = "57" Then $result[57] = $arr_text[57]
        If $iniOutput[$i][$j] = "58" Then $result[58] = $arr_text[87]
        If $iniOutput[$i][$j] = "59" Then $result[59] = $arr_text[86]
        If $iniOutput[$i][$j] = "60" Then $result[60] = $arr_text[85]
        If $iniOutput[$i][$j] = "61" Then $result[61] = $arr_text[84]
        If $iniOutput[$i][$j] = "62" Then $result[62] = $arr_text[83]
        If $iniOutput[$i][$j] = "63" Then $result[63] = $arr_text[82]
        If $iniOutput[$i][$j] = "64" Then $result[64] = $arr_text[64]
        If $iniOutput[$i][$j] = "65" Then $result[65] = $arr_text[65]
        If $iniOutput[$i][$j] = "66" Then $result[66] = $arr_text[66]
        If $iniOutput[$i][$j] = "67" Then $result[67] = $arr_text[67]
        If $iniOutput[$i][$j] = "68" Then $result[68] = $arr_text[68]
        If $iniOutput[$i][$j] = "69" Then $result[69] = $arr_text[69]
        If $iniOutput[$i][$j] = "70" Then $result[70] = $arr_text[75]
        If $iniOutput[$i][$j] = "71" Then $result[71] = $arr_text[74]
        If $iniOutput[$i][$j] = "72" Then $result[72] = $arr_text[73]
        If $iniOutput[$i][$j] = "73" Then $result[73] = $arr_text[72]
        If $iniOutput[$i][$j] = "74" Then $result[74] = $arr_text[71]
        If $iniOutput[$i][$j] = "75" Then $result[75] = $arr_text[70]
        If $iniOutput[$i][$j] = "76" Then $result[76] = $arr_text[76]
        If $iniOutput[$i][$j] = "77" Then $result[77] = $arr_text[77]
        If $iniOutput[$i][$j] = "78" Then $result[78] = $arr_text[78]
        If $iniOutput[$i][$j] = "79" Then $result[79] = $arr_text[79]
        If $iniOutput[$i][$j] = "80" Then $result[80] = $arr_text[80]
        If $iniOutput[$i][$j] = "81" Then $result[81] = $arr_text[81]
        If $iniOutput[$i][$j] = "82" Then $result[82] = $arr_text[63]
        If $iniOutput[$i][$j] = "83" Then $result[83] = $arr_text[62]
        If $iniOutput[$i][$j] = "84" Then $result[84] = $arr_text[61]
        If $iniOutput[$i][$j] = "85" Then $result[85] = $arr_text[60]
        If $iniOutput[$i][$j] = "86" Then $result[86] = $arr_text[59]
        If $iniOutput[$i][$j] = "87" Then $result[87] = $arr_text[58]
        If $iniOutput[$i][$j] = "88" Then $result[88] = $arr_text[88]
        If $iniOutput[$i][$j] = "89" Then $result[89] = $arr_text[89]
        If $iniOutput[$i][$j] = "90" Then $result[90] = $arr_text[90]
        If $iniOutput[$i][$j] = "91" Then $result[91] = $arr_text[91]
        If $iniOutput[$i][$j] = "92" Then $result[92] = $arr_text[92]
        If $iniOutput[$i][$j] = "93" Then $result[93] = $arr_text[93]
        If $iniOutput[$i][$j] = "94" Then $result[94] = $arr_text[51]
        If $iniOutput[$i][$j] = "95" Then $result[95] = $arr_text[50]
        If $iniOutput[$i][$j] = "96" Then $result[96] = $arr_text[49]
        If $iniOutput[$i][$j] = "97" Then $result[97] = $arr_text[48]
        If $iniOutput[$i][$j] = "98" Then $result[98] = $arr_text[47]
        If $iniOutput[$i][$j] = "99" Then $result[99] = $arr_text[46]
        If $iniOutput[$i][$j] = "100" Then $result[100] = $arr_text[100]
        If $iniOutput[$i][$j] = "101" Then $result[101] = $arr_text[101]
        If $iniOutput[$i][$j] = "102" Then $result[102] = $arr_text[102]
        If $iniOutput[$i][$j] = "103" Then $result[103] = $arr_text[103]
        If $iniOutput[$i][$j] = "104" Then $result[104] = $arr_text[104]
        If $iniOutput[$i][$j] = "105" Then $result[105] = $arr_text[105]
        If $iniOutput[$i][$j] = "106" Then $result[106] = $arr_text[39]
        If $iniOutput[$i][$j] = "107" Then $result[107] = $arr_text[38]
        If $iniOutput[$i][$j] = "108" Then $result[108] = $arr_text[37]
        If $iniOutput[$i][$j] = "109" Then $result[109] = $arr_text[109]
        If $iniOutput[$i][$j] = "110" Then $result[110] = $arr_text[110]
        If $iniOutput[$i][$j] = "111" Then $result[111] = $arr_text[111]
        If $iniOutput[$i][$j] = "112" Then $result[112] = $arr_text[33]
        If $iniOutput[$i][$j] = "113" Then $result[113] = $arr_text[32]
        If $iniOutput[$i][$j] = "114" Then $result[114] = $arr_text[31]
        If $iniOutput[$i][$j] = "115" Then $result[115] = $arr_text[30]
        If $iniOutput[$i][$j] = "116" Then $result[116] = $arr_text[29]
        If $iniOutput[$i][$j] = "117" Then $result[117] = $arr_text[28]
        If $iniOutput[$i][$j] = "118" Then $result[118] = $arr_text[118]
        If $iniOutput[$i][$j] = "119" Then $result[119] = $arr_text[119]
        If $iniOutput[$i][$j] = "120" Then $result[120] = $arr_text[120]
        If $iniOutput[$i][$j] = "121" Then $result[121] = $arr_text[121]
        If $iniOutput[$i][$j] = "122" Then $result[122] = $arr_text[122]
        If $iniOutput[$i][$j] = "123" Then $result[123] = $arr_text[123]
        If $iniOutput[$i][$j] = "124" Then $result[124] = $arr_text[21]
        If $iniOutput[$i][$j] = "125" Then $result[125] = $arr_text[20]
        If $iniOutput[$i][$j] = "126" Then $result[126] = $arr_text[19]
        If $iniOutput[$i][$j] = "127" Then $result[127] = $arr_text[18]
        If $iniOutput[$i][$j] = "128" Then $result[128] = $arr_text[17]
        If $iniOutput[$i][$j] = "129" Then $result[129] = $arr_text[16]
        If $iniOutput[$i][$j] = "130" Then $result[130] = $arr_text[130]
        If $iniOutput[$i][$j] = "131" Then $result[131] = $arr_text[131]
        If $iniOutput[$i][$j] = "132" Then $result[132] = $arr_text[132]
        If $iniOutput[$i][$j] = "133" Then $result[133] = $arr_text[133]
        If $iniOutput[$i][$j] = "134" Then $result[134] = $arr_text[134]
        If $iniOutput[$i][$j] = "135" Then $result[135] = $arr_text[135]
        If $iniOutput[$i][$j] = "136" Then $result[136] = $arr_text[9]
        If $iniOutput[$i][$j] = "137" Then $result[137] = $arr_text[8]
        If $iniOutput[$i][$j] = "138" Then $result[138] = $arr_text[7]
        If $iniOutput[$i][$j] = "139" Then $result[139] = $arr_text[6]
        If $iniOutput[$i][$j] = "140" Then $result[140] = $arr_text[5]
        If $iniOutput[$i][$j] = "141" Then $result[141] = $arr_text[4]
        If $iniOutput[$i][$j] = "142" Then $result[142] = $arr_text[142]
        If $iniOutput[$i][$j] = "143" Then $result[143] = $arr_text[143]
        If $iniOutput[$i][$j] = "144" Then $result[144] = $arr_text[144]
    Next
Next
_ArrayDisplay($result)
_ArrayDelete($result, 0) ; wir loeschen die leere zeile am anfang des arrays
_ArrayDisplay($result) ; dies ist nur ein test zur kontrolle der daten!
$corrected_text = _ArrayToString($result, " ")
MsgBox(0, "output", $corrected_text)

Alles anzeigen

also, ich hatte ein wert $k versucht als zaehler, aber es aenderte nicht wirklich etwas an der laenge, denn der auszugebene text springt ja wirklich durch die zeilen wie ein osterhase auf drogen. also ist zunaechst die erste frage:

1. kann der code durch clevere zaehler verkuerzt werden? wenn ja, wie und wo?

die zweite frage ist dann die nutzung einer map. also das ist fuer mich so undurchsichtig, dass ich nocht nicht mal weiss wie wo was ich genau brauche um eine verbindung der zeilennummern zur ini herzustellen um dann eine korrekte ausgabe zu erhalten. also zweite frage:

2. map? - ja gerne, aber wie? mit lerneffekt gerne gewuenscht.

leider muss ich nun das restliche wochenende aufs internet verzichten, denn wir bekommen gleich familien besuch und die bleiben das ganze osterfest. aber was macht man nicht alles fuer die familie.

das thema hier hat also keine eile, ich kann eh nicht vor montag/dienstag checken ob jemand geantwortet hat.

geniesst alle das osterfest.

bis bald.

bankesbusters

PS: eines meiner sachen habe ich selbst geregelt bekommen von meiner to-do-liste: zahlen mit ini einlesen, werte veraendern je spalte und dann weiterverwenden. hat erstaunlich einfach mehr oder weniger auf anhieb geklappt. also stueck fuer stueck lerne ich fleissig weiter.

**Schnuffel**

my short one.

Mal bewusst ohne jegliche Erklärung.

Alles was im Moment "hard-gecoded" ist (z.B. die 12) kann natürlich für dynamisches Verhalten auch durch eine Variable ersetzt werden.

Sollte ich an deiner Aufgabenstellung etwas falsch verstanden haben, dann sry

AutoIt

#include <MsgBoxConstants.au3>
#include <Array.au3>

Global $ini = @ScriptDir & "\magic.ini"
Global $iniOutput[12][12]
Global $keys = IniReadSection($ini, 'Data')
Global $text = "dieses kleine aber ihr und testen zu scripte kleine einen total konfus " & _
        "gewirbelten satz durch sortieren. zu woerter ganzen die dabei lesbaren string bzw. " & _
        "array verwandeln. es auch es damit muss stehen eigentlich mal zwoelf rasters "  & _
        "wort richtige das magisches quadrat dar. es ist das dann um muss " & _
        "stehen wort welches es im internet zu finden gibt. in vorher ganze " & _
        "das habe ich in jeweils zwoelf reihen und zwoelf somit spalten. zwoelf " & _
        "jeweils in worten sind es dann insgesamt 144 worte. worten zwoelf aus " & _
        "also besteht es libre office calc ausrechen lassen wo was quadrat magische "  & _
        "simpelste bzw. einfachste eine ini datei zu schreiben wo ein stellt und "  & _
        "aus dem text zwoelf eines prinzip dem auf basiert einen sinn ergibt. "  & _
        "AutoIT hilft dann einen in wieder map ini eine ich finde das "  & _
        "immer so toll soll script test AutoIT feine durchaus hoffentlich dann auch!"
Global $aText = StringSplit($text, ' ')
Global $Ausgabe
For $i = 1 To 12
	$a = StringSplit($keys[$i][1], '.')
	For $j = 1 To 12
		$iniOutput[$i-1][$j-1] = $a[$j]
	Next
Next
Global $Ausgabe

For $i = 1 To 12
	For $j = 1 To 12
		$Ausgabe &= $aText[$iniOutput[$i-1][$j-1]] & " "
	Next
	$Ausgabe = StringTrimRight($ausgabe,1)
	$Ausgabe &= @CRLF
Next
ConsoleWrite($Ausgabe & @CRLF)
MsgBox(0, "dein Text:", $Ausgabe)

Alles anzeigen

**Kanashius**

Ich fand Magic Squares ganz interessant, wollte die aber nicht in einer Ini abspeichern, sondern selbst generieren.
Bis ich das fertig hatte, hat in der Zwischenzeit Schnuffel schon gepostet, deshalb geh ich auf dein Script mal nicht weiter ein.
Stattdessen hab ich noch eine Gui dazugebastelt, in der man einen Text eingeben kann und sowohl mit Magic Square verschlüsseln als auch entschlüsseln kann.
Das ganze arbeitet dabei mit einem Füll-Zeichen, wenn die Anzahl an Text nicht ein ganzes Magic Square füllt.
Das Trenn-Zeichen kann dabei auch geändert werden. (Wenn es leer gelassen wird, wird jeder Buchstabe einzeln vertauscht, was für ein richtiges durcheinander sorgt :D)

Vielleicht hat ja noch jemand Spaß daran

AutoIt

Global $sExampleText = "dieses kleine aber durchaus feine AutoIT test script soll einen total konfus"&@crlf& _
						"gewirbelten satz durch eine ini map wieder in einen lesbaren string bzw."&@crlf& _
						"array verwandeln. es basiert auf dem prinzip eines zwoelf mal zwoelf rasters"&@crlf& _
						"und stellt ein magisches quadrat dar. es ist das einfachste bzw. simpelste"&@crlf& _
						"magische quadrat was es im internet zu finden gibt. es besteht also"&@crlf& _
						"aus zwoelf worten in jeweils zwoelf reihen und zwoelf worten in jeweils"&@crlf& _
						"zwoelf spalten. somit sind es dann insgesamt 144 worte. ich habe das"&@crlf& _
						"ganze vorher in libre office calc ausrechen lassen wo welches wort stehen"&@crlf& _
						"muss um dann eine ini datei zu schreiben wo das richtige wort"&@crlf& _
						"aus dem text eigentlich stehen muss damit es auch einen sinn ergibt."&@crlf& _
						"AutoIT hilft dann dabei die ganzen woerter zu sortieren. ich finde das"&@crlf& _
						"immer so toll kleine scripte zu testen und ihr hoffentlich dann auch!"

; Print a square to console
; Local $arSquare = _calcMagicSquare(12)
; _printMagicSquare($arSquare)

; checking if the square generation works:
; For $i=0 To 100 Step 1
;	 Local $arSquare = _calcMagicSquare($i)
;	 If (Not _checkAllOneValue(_getArrayLineSums($arSquare))) Or (Not _checkAllOneValue(_getArrayLineSums($arSquare, True))) Then ConsoleWrite("Magic Square for "&$i&" was wrong."&@crlf)
; Next

; open encrypt/decrypt gui
_openGui()

Func _openGui()
	Local $iWidth = 1200, $iHeight=800, $iSpace = 10, $iCtrlHeight=25
	Local $hGui = GUICreate("Text scrambler", $iWidth, $iHeight)
	Local $iEditWidth = ($iWidth-($iSpace*3))/2, $iEditHeight = $iHeight-$iSpace*4-$iCtrlHeight*2
	Local $iWidth4th = ($iWidth-$iSpace*5)/4
	GUICtrlCreateLabel("Delimeter: ", $iSpace, $iSpace, $iWidth4th, $iCtrlHeight)
	Local $idInputDelimeter = GUICtrlCreateInput(" ", $iSpace*2+$iWidth4th, $iSpace, $iWidth4th, $iCtrlHeight)
	GUICtrlCreateLabel("Filler: ", $iSpace*3+$iWidth4th*2, $iSpace, $iWidth4th, $iCtrlHeight)
	Local $idInputFiller = GUICtrlCreateInput(".", $iSpace*4+$iWidth4th*3, $iSpace, $iWidth4th, $iCtrlHeight)
	Local $idEditClearText = GUICtrlCreateEdit($sExampleText, $iSpace, $iSpace*2+$iCtrlHeight, $iEditWidth, $iEditHeight)
	Local $idButtonEncrypt = GUICtrlCreateButton("Encrypt >>", $iSpace, $iHeight-$iSpace-$iCtrlHeight, $iEditWidth, $iCtrlHeight)
	Local $idEditEncrypted = GUICtrlCreateEdit("", $iSpace*2+$iEditWidth, $iSpace*2+$iCtrlHeight, $iEditWidth, $iEditHeight)
	Local $idButtonDecrypt = GUICtrlCreateButton("<< Decrypt", $iSpace*2+$iEditWidth, $iHeight-$iSpace-$iCtrlHeight, $iEditWidth, $iCtrlHeight)
	GUISetState(@SW_SHOW, $hGui)
	Local $iMsg
	While 1
		$iMsg = GUIGetMsg()
		Switch $iMsg
			Case -3
				Exit
			Case $idButtonEncrypt
				Local $sDelimeter = GUICtrlRead($idInputDelimeter)
				Local $sFiller = GUICtrlRead($idInputFiller)
				Local $sEncrypted = _cryptSquare(GUICtrlRead($idEditClearText), True, $sDelimeter, $sFiller)
				GUICtrlSetData($idEditEncrypted, $sEncrypted)
			Case $idButtonDecrypt
				Local $sDelimeter = GUICtrlRead($idInputDelimeter)
				Local $sFiller = GUICtrlRead($idInputFiller)
				Local $sEncrypted = _cryptSquare(GUICtrlRead($idEditEncrypted), False, $sDelimeter, $sFiller)
				If @error Then MsgBox(16, "Error", "Input length does not match any magic square size.")
				GUICtrlSetData($idEditClearText, $sEncrypted)
		EndSwitch
	WEnd
EndFunc

Func _cryptSquare($sText, $bEncrypt = True, $sDelimeter=" ", $sFiller = ".")
	Local $arParts = StringSplit($sText, $sDelimeter, BitOR(1,2))
	Local $iSize = Sqrt(UBound($arParts))
	If Mod($iSize, 1)<>0 Then $iSize = Int($iSize+1)
	If $iSize=2 Then $iSize+=1
	Local $arSquare = _calcMagicSquare($iSize)
	If $bEncrypt Then
		Local $sResult = ""
		For $i=0 To UBound($arSquare)-1 Step 1
			For $j=0 To UBound($arSquare)-1 Step 1
				Local $iVal = $arSquare[$i][$j]
				If $iVal>UBound($arParts) Then
					$sResult &= $sFiller
				Else
					$sResult &= $arParts[$arSquare[$i][$j]-1]
				EndIf
				If $i<UBound($arSquare)-1 Or $j<UBound($arSquare)-1 Then $sResult &= $sDelimeter
			Next
		Next
		Return $sResult
	Else
		Local $arResult[UBound($arParts)], $iCount = 0
		For $i=0 To UBound($arSquare)-1 Step 1
			For $j=0 To UBound($arSquare)-1 Step 1
				Local $iIndex = $arSquare[$i][$j]-1
				If $iCount>UBound($arParts)-1 Then Return SetError(1, 0, -1)
				If $iIndex<UBound($arResult) Then $arResult[$iIndex] = $arParts[$iCount]
				$iCount+=1
			Next
		Next
		Local $sResult = ""
		For $i=0 To UBound($arResult)-1 Step 1
			$sResult &= $arResult[$i]
			If $i<UBound($arResult)-1 Then $sResult&=$sDelimeter
		Next
		Return $sResult
	EndIf
EndFunc

Func _checkAllOneValue(ByRef $arArray)
	Local $iVal = $arArray[0]
	For $i=0 To UBound($arArray)-1 Step 1
		If $arArray[$i]<>$iVal Then Return False
	Next
	Return True
EndFunc

Func _printMagicSquare(ByRef $arSquare, $bShowInfo = True)
	Local $arSumRight, $arSumBottom
	If $bShowInfo Then
		$arSumRight = _getArrayLineSums($arSquare)
		$arSumBottom = _getArrayLineSums($arSquare, True)
	EndIf
	Local $iSize = UBound($arSquare)
	Local $iMaxLength = StringLen(String($iSize*$iSize))
	If $bShowInfo Then
		If StringLen($arSumBottom[UBound($arSumBottom)-1])+1>$iMaxLength Then $iMaxLength=StringLen($arSumBottom[UBound($arSumBottom)-1])+1
	EndIf
	Local $sNumberFormat = "%"&$iMaxLength&"d|"
	For $x=0 To $iSize-1 Step 1
		_printLine($iSize, $iMaxLength)
		ConsoleWrite("|")
		For $y=0 To $iSize-1 Step 1
			ConsoleWrite(StringFormat($sNumberFormat, $arSquare[$x][$y]))
		Next
		If $bShowInfo Then ConsoleWrite(" ="&$arSumRight[$x])
		ConsoleWrite(@crlf)
	Next
	If $bShowInfo Then
		_printLine($iSize, $iMaxLength)
		For $x=0 To $iSize-1 Step 1
			ConsoleWrite(StringFormat("%"&$iMaxLength+1&"s", "="&$arSumBottom[$x]))
		Next
		ConsoleWrite(@crlf)
	EndIf
EndFunc

; Last item contains the max sum
Func _getArrayLineSums(ByRef $arSquare, $bRow=False)
	Local $iSize = UBound($arSquare)
	Local $arSum[$iSize+1]
	For $i=0 To $iSize-1 Step 1
		Local $iSum = 0
		For $j=0 To $iSize-1 Step 1
			If $bRow Then
				$iSum += $arSquare[$j][$i]
			Else
				$iSum += $arSquare[$i][$j]
			EndIf
		Next
		$arSum[$i] = $iSum
		If $iSum>$arSum[$iSize] Then $arSum[$iSize] = $iSum
	Next
	Return $arSum
EndFunc

Func _printLine($iSegmentCount, $iSegmentLength)
	Local $sSep = ""
	For $x=0 To $iSegmentLength-1 Step 1
		$sSep&="-"
	Next
	ConsoleWrite("+")
	For $y=0 To $iSegmentCount-1 Step 1
		ConsoleWrite($sSep&"+")
	Next
	ConsoleWrite(@crlf)
EndFunc

; https://www.iupindia.in/910/IJCM_Magic_Square_Construction_Algorithms34.pdf
Func _calcMagicSquare($iSize)
	If $iSize=2 Then Return SetError(1, -1, -1) ; not possible for $iSize=2
	Local $arSquare[$iSize][$iSize]
	If $iSize=4 Then
		Local $arTmp = [[1, 15, 14, 4], [12, 6, 7, 9], [8, 10, 11, 5], [13, 3, 2, 16]] ; algorithm used only once, so why implement it
		Return $arTmp
	ElseIf Mod($iSize, 2)=0 Then ; size is even
		If Mod($iSize, 4)=2 Then
			Local $iMatMax = ($iSize*$iSize)/4, $iMatSize = $iSize/2
			Local $arM1 = _calcMagicSquare($iSize/2)
			; initial square
			For $i=0 To 1 Step 1
				For $j=0 To 1 Step 1
					Local $iAdd = 0
					If $i=1 And $j=0 Then $iAdd = $iMatMax*3
					If $i=0 And $j=1 Then $iAdd = $iMatMax*2
					If $i=1 And $j=1 Then $iAdd = $iMatMax
					For $x=0 To $iMatSize-1 Step 1
						For $y=0 To $iMatSize-1 Step 1
							$arSquare[$x+($i*$iMatSize)][$y+($j*$iMatSize)] = $arM1[$x][$y] + $iAdd
						Next
					Next
				Next
			Next
			; swapping around
			Local $iMatSizeHalf = Int($iMatSize/2)
			For $x=0 To $iMatSizeHalf-1
				For $y=0 To $iMatSizeHalf-1
					_swap($arSquare, $x, $y, $x+$iMatSize, $y)
				Next
			Next
			For $x=$iMatSizeHalf+1 To $iMatSize-1 Step 1
				For $y=0 To $iMatSizeHalf-1 Step 1
					_swap($arSquare, $x, $y, $x+$iMatSize, $y)
				Next
			Next
			Local $x=$iMatSizeHalf
			For $y=1 To $iMatSizeHalf Step 1
				_swap($arSquare, $x, $y, $x+$iMatSize, $y)
			Next
			For $x=0 To $iMatSize-1 Step 1
				For $y=($iMatSize-$iMatSizeHalf)+1 To $iMatSize-1 Step 1
					_swap($arSquare, $x, $y+$iMatSize, $x+$iMatSize, $y+$iMatSize)
				Next
			Next
		Else
			Local $iMatMax = ($iSize*$iSize)/4, $iMatSize = $iSize/2
			Local $arM1 = _calcMagicSquare($iSize/2)
			; initial square
			For $i=0 To 1 Step 1
				For $j=0 To 1 Step 1
					Local $iAdd = 0
					If $i=1 And $j=0 Then $iAdd = $iMatMax*2
					If $i=0 And $j=1 Then $iAdd = $iMatMax*3
					If $i=1 And $j=1 Then $iAdd = $iMatMax
					For $x=0 To $iMatSize-1 Step 1
						For $y=0 To $iMatSize-1 Step 1
							$arSquare[$x+($i*$iMatSize)][$y+($j*$iMatSize)] = $arM1[$x][$y] + $iAdd
						Next
					Next
				Next
			Next
			If Mod($iMatSize, 4) = 2 Then
				Local $iMiddleRows = Int($iMatSize/2)+1
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x, $y, $x, $y+$iMatSize)
					Next
				Next
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x+$iMatSize, $y, $x+$iMatSize, $y+$iMatSize)
					Next
				Next
			Else
				Local $iMiddleRows = $iMatSize/2
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2-1 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x, $y, $x, $y+$iMatSize)
					Next
				Next
				For $x=$iMiddleRows/2 To $iMatSize-$iMiddleRows/2-1 Step 1
					For $y=0 To $iMatSize-1 Step 1
						_swap($arSquare, $x+$iMatSize, $y, $x+$iMatSize, $y+$iMatSize)
					Next
				Next
			EndIf
		EndIf
	Else ; size is odd
		Local $iN = 1, $x=0, $y=Int($iSize/2), $iLimit = $iSize*$iSize
		While $iN<=$iLimit
			If $arSquare[$x][$y]=0 Then
				$arSquare[$x][$y] = $iN
				$iN+=1
				$x -= 1
				If $x<0 Then $x=$iSize-1
				$y -= 1
				If $y<0 Then $y=$iSize-1
			Else
				$x = Mod($x+2, $iSize)
				$y = Mod($y+1, $iSize)
			EndIf
		WEnd
	EndIf
	Return $arSquare
EndFunc

Func _swap(ByRef $arSquare, $x1, $y1, $x2, $y2)
	Local $iTmp = $arSquare[$x1][$y1]
	$arSquare[$x1][$y1] = $arSquare[$x2][$y2]
	$arSquare[$x2][$y2] = $iTmp
EndFunc

Alles anzeigen

Referenz:
Paper mit dem Algorithmus für die Berechnung der Magic Squares: https://www.iupindia.in/910/IJCM_Magic…lgorithms34.pdf

bankesbusters

hi,

als der rest der familie ein wenig spazieren war und ich mit den vorbereitungen vom essen durch war, habe ich noch eine kurze weile hinsetzen koennen und experimentieren koennen und habe es dann hiermit versucht (nur die eingentliche For-To-Next-Schleife):

Code

For $i = 0 To UBound($iniOutput) - 1
For $j = 0 To UBound($iniOutput, 2) - 1
Local $index = Int($iniOutput[$i][$j]) ; Um den Wert als Ganzzahl zu verwenden
If $index >= 1 And $index <= UBound($arr_text) Then
$result[$index] = $arr_text[$index]
EndIf
Next
Next

das hat aber nicht geklappt gehabt, weil ich keinen weg gefunden hatte dort den $arr_text von der nummer her anders zu gestalten. sprich das script griff immer nur die exakt gleichen nummern ab, aber der code war auf das absolute minimum verkuerzt worden. nur eben die funktion nicht wirklich.

ich werde heute mir mal die anderen obigen ideen anschauen und mal sehen ob ich mich dadurch kaempfen kann. ... aber wie immer: auf jeden fall bereits ein dickes danke an dieser stelle an Schnuffel und Kanashius

Kanashius hat ja bald mehr geschrieben wie mein original. ich bin so gespannt.

gruss

PS: hoffe schoene ostern gehabt zu haben an alle.

*grund fuer edit: vergessen code in codedarstellung zu packen

bankesbusters

hi,

also ... nach etlichen (langen) tests und vielen vielen fehlversuchen, (ich habe alles richtig abgeschrieben, alles kontrolliert und trotzdem schlichen sich fehler immer wieder ein!), kann ich sagen, dass die Version von Schnuffel fuer meine zwecke zu 100% perfekt ist und alles so tut wie es tun soll. das ist sowas von genial! Danke vielmals!

natuerlich moechte ich die arbeit von Kanashius nicht schmaelern, denn sie ist auf eine andere art auch total genial und spannend zugleich, denn sie geht noch einige extra schritte weiter, die zwar nicht notwendig waren, aber total klasse sind. auf jeden fall ein script, welches ich ggf. auch noch mal verwenden werde. tolle sache.

also, beides wirklich toll und auch verschieden in der herangehensweise.

euch beiden einen ganz dicken dank an dieser stelle. ich weiss eure hilfe stets zu schaetzen. danke sehr.

gruss

bankesbusters