ColorChangeIconButton - BugWorkaround?

UPIA

Es ist mir nicht gelungen einen farbigen Button mit OnmouseOver-Effekt UND transparentem .ico zu erstellen.
Wahrscheinlich wegen des GUI-Bugs werden die transparenten Teile eines .ico Files immer in der Farbe der GUI-BG-Color dargestellt.
Ein möglicher Weg dies (mit einfachen Mitteln) zu umgehen ist es die ButtonFarbe unter dem Icon gleichzeitig mit der GUI-BG-Color zu wechseln.
Das klappt prima, solange ich nur einen Button habe. Habe ich mehrere Buttons brauche ich für jeden Button eine subGUI ...

Das habe ich hier mal umgesetzt. Macht dies Methode wirklich Sinn?
Oder gibt es da inzwischen leichtere Workarounds?
(ich habe stundenlang gesucht, aber just diese Problemlösung des Icons nicht gefunden)

Im Beispiel habe ich 24 Buttons, weil ich die Kapazität von GUIGetMsg() testen wollte, scheint aber zu gehen.
Beim Clicken wird nur in die Console geloggt (keine Action).
Außerdem wäre mein nächstes Ziel dass die GUI beim Aufbau nicht so sehr flackert (habe bisher - offensichtlich - nicht viel mit GUIs gearbeitet).
Programmierstil und Ordentlichkeit sind furchtbar sorry ist work in prgoress!

Vorschau:

IconButtonHoverEffect.au3:

AutoIt

#include <GUIConstants.au3>
#include <Array.au3>

; This script creates colored button-like-control-set with states with proper icon
; ------------------------------------------------------------------------------------------------------------------- BG + Text/ButtonStyle Setup
Global $_Buttons[1][21]
$_Buttons[0][0] = 0
Global $_ButtonGuiOverlay 	= 0x999999		; use this overlay to hide the true bg-color as it changes
Global $_ButtonStyle[1][10] = [ _ ;FontCol,Size,Weight,Attribute,Fontname,winhandle,quality,LableStyle,LabelStyleX
							  [ 0xfffffff, 12, 400, Default, "Tahoma", Default, Default, Default, Default]]

; ------------------------------------------------------------------------------------------------------------------- Create GUI & Buttons
Local $hGUI = GUICreate("ColorChangeIconButton Test", 800, 870, -1, -1)									; global $hGUI (Main)
;~ GUISetState(@SW_HIDE, $hGUI)
GUISetBkColor($_ButtonGuiOverlay, $hGUI)
GUISetState(@SW_SHOW)
Local $plate = GUICtrlCreateLabel("", 0,0, 800, 870)								; main Surface of GUI (used to get onmouseover for hover-out
GUICtrlSetBkColor($plate, $_ButtonGuiOverlay)
GUISetState(@SW_SHOW, $hGUI) ; no idea how to make this not flicker on startup!

Local $butt1 = _ButtonCreate($hGUI, $plate, "", "Test", 100, 100, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn") ; add userfunction???
Local $butt2 = _ButtonCreate($hGUI, $plate, "", "", 200, 100, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt3 = _ButtonCreate($hGUI, $plate, "", "", 300, 100, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt4 = _ButtonCreate($hGUI, $plate, "", "", 400, 100, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt5 = _ButtonCreate($hGUI, $plate, "", "", 100, 200, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt6 = _ButtonCreate($hGUI, $plate, "", "", 300, 200, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt7 = _ButtonCreate($hGUI, $plate, "", "", 400, 200, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt8 = _ButtonCreate($hGUI, $plate, "", "Test", 200, 200, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt9 = _ButtonCreate($hGUI, $plate, "", "", 100, 300, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt10 = _ButtonCreate($hGUI, $plate, "", "", 400, 300, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt11 = _ButtonCreate($hGUI, $plate, "", "", 200, 300, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt12 = _ButtonCreate($hGUI, $plate, "", "", 300, 300, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt13 = _ButtonCreate($hGUI, $plate, "", "", 100, 400, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt14 = _ButtonCreate($hGUI, $plate, "", "Test", 200, 400, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt15 = _ButtonCreate($hGUI, $plate, "", "", 300, 400, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt16 = _ButtonCreate($hGUI, $plate, "", "", 400, 400, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt17 = _ButtonCreate($hGUI, $plate, "", "", 100, 500, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt18 = _ButtonCreate($hGUI, $plate, "", "", 300, 500, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt19 = _ButtonCreate($hGUI, $plate, "", "", 400, 500, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt20 = _ButtonCreate($hGUI, $plate, "", "", 200, 500, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt21 = _ButtonCreate($hGUI, $plate, "", "", 100, 600, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt22 = _ButtonCreate($hGUI, $plate, "", "", 400, 600, 50, 50, 0x777777, 0x007777, 0xffff00, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt23 = _ButtonCreate($hGUI, $plate, "", "", 200, 600, 50, 50, 0xcccccc, 0x00cccc, 0x00ffff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
Local $butt24 = _ButtonCreate($hGUI, $plate, "", "", 300, 600, 50, 50, 0x2277ff, 0x114477, 0xff00ff, "C:\Windows\System32\shell32.dll", 4, 32, 32, 9, 9, 0, "UserFn")
;_ButtonSetState(@SW_SHOW)
GUISetState(@SW_SHOW, $hGUI)

; ------------------------------------------------------------------------------------------------------------------- GUIGetMsg Handler
GUISwitch($hGUI)
While 1
	;Local $state = -1
	Local $gm = GUIGetMsg()
	Switch $gm
		Case $GUI_EVENT_CLOSE ; add custom stuff on hGUI here!
			CloseProgram()
;~ 		Case $GUI_EVENT_PRIMARYUP ; not reliable, play for some ms only
;~ 			$state = 0
;~ 		Case $GUI_EVENT_PRIMARYDOWN
;~ 			Local $state = 1
		Case Else
			_ButtonGetEvent($gm)
	EndSwitch
	Sleep(10)
WEnd

CloseProgram()

; use sth this to add actions to the button states
Func UserFn($id, $bID, $_Event, $userA)
	_log("UserFn --------------------------------------------")
	Switch $_Event
		Case "Static"
			;
		Case "Hover"
			;
		Case "Press"
			If IsArray($userA) Then
				;
			Else
				;MsgBox(0, "$_Buttons", "$_Buttons[" & $id & "][0] = " & $bID & " .. was pressed!") ; dont use msgbox when button is down!
				_log("do something...")
			EndIf
	EndSwitch
EndFunc

; ------------------------------------------------------------------------------------------------------------------- Functions --->

;	Catch GuiGetMsg() And GuiGetCursorInfo() to create events
Func _ButtonGetEvent($gm)
	For $i = 1 To $_Buttons[0][0]
		Local $bL = $_Buttons[$i][0]
		Local $bI = $_Buttons[$i][1]
		If $gm > 0 Then
			If $gm = $bL Or $gm = $bI Then															; check if buttons(label or icon) are Presssed
				_ButtonHandle($_Buttons[$i][0], "Press")
				;ExitLoop ;only 1 event?
			EndIf
		Else
			Local $gui = $_Buttons[$i][19]
			Local $info = GUIGetCursorInfo($gui)													; check cursor for hover
			If ($info[4] = $bL Or $info[4] = $bI) Then ;And $state <> 1 Then
				_ButtonHandle($_Buttons[$i][0], "Hover")
				ExitLoop
			ElseIf ($info[4] <> $bL And $info[4] <> $bI) And $_Buttons[$i][20] = "Hover" Then
				_ButtonHandle($_Buttons[$i][0], "Static")
				ExitLoop
			EndIf
		EndIf
	Next
EndFunc

;	Destroy a Button
Func _ButtonDestroy($i, $index=False) ;?
	If Not $index Then
		$i = _ArraySearch($_Buttons, $i, 1, 0, 0, 0, 1, 0)
		If $i < 0 Then
			MsgBox(64, "Error", "No Index")
			Return False
		EndIf
	EndIf
	_ArrayDelete($_Buttons, String($i))
	$_Buttons[0][0] -= 1 ;UBound($_Buttons+1)
	;_ArrayDisplay($_Buttons)
EndFunc

; 	Create "Button" as a LabelControl and save data for handling
; 	MainGUI, SurroundingSurfaceHnd, optButtonText, optTooltipText, x, y, w,           h, RegularColor, HoverColor, PressColor, IconFile, IconIndex, IconWidth,    IconHight, xOffIcon, yOffIcon,  ButtonSyle, userfn, userdata
Func _ButtonCreate($hGUI, $hSurface, $strText, $strTooltip, $xPos, $yPos, $bWidth, $bHight, $colStatic, $colHover, $colPress, $iconFile, $iconIndex, $iconSizeX, $iconSizeY, $iconXoff, $iconYoff, $bStyle, $UserFn, $UserData=-1)
	Local $ctrlID = -1, $icon[3]
	Local $hChild = GUICreate("", $bWidth, $bHight, $xPos, $yPos, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
	GUISwitch($hChild)
	GUISetState(@SW_DISABLE, $hChild)
	GUISetState(@SW_HIDE, $hChild)
	; FontSetup
	GUISetFont($_ButtonStyle[$bStyle][1], $_ButtonStyle[$bStyle][2], $_ButtonStyle[$bStyle][3], $_ButtonStyle[$bStyle][4], $hChild, $_ButtonStyle[$bStyle][6])
	$ctrlID = GUICtrlCreateLabel($strText, 0, 0, $bWidth, $bHight)
	GUICtrlSetColor($ctrlID, $_ButtonStyle[$bStyle][0])
	If $strTooltip <> "" Then GUICtrlSetTip ( $ctrlID, $strTooltip, "", $TIP_NOICON, $TIP_CENTER)
	;
	GUISetBkColor($colStatic, $hChild)												;set state static
	GUICtrlSetBkColor($ctrlID, $colStatic)
	$icon[0] = GUICtrlCreateIcon($iconFile, $iconIndex, 0+$iconXoff, 0+$iconYoff, $iconSizeX, $iconSizeY, Default)

	GUISetState(@SW_ENABLE, $hChild)
	GUISetState(@SW_SHOW, $hChild)

	$_Buttons[0][0] += 1														; store data for handling
	ReDim $_Buttons[ $_Buttons[0][0]+1 ][25]
	$_Buttons[ $_Buttons[0][0] ][0] = $ctrlID
	$_Buttons[ $_Buttons[0][0] ][1] = $icon[0]
;~ 	$_Buttons[ $_Buttons[0][0] ][2] = $icon[1]
;~ 	$_Buttons[ $_Buttons[0][0] ][3] = $icon[2]
	$_Buttons[ $_Buttons[0][0] ][4] = $hGUI
	$_Buttons[ $_Buttons[0][0] ][5] = $hSurface
	$_Buttons[ $_Buttons[0][0] ][6] = $strText
	$_Buttons[ $_Buttons[0][0] ][7] = $strTooltip
	$_Buttons[ $_Buttons[0][0] ][8] = $xPos
	$_Buttons[ $_Buttons[0][0] ][9] = $yPos
	$_Buttons[ $_Buttons[0][0] ][10] = $bWidth
	$_Buttons[ $_Buttons[0][0] ][11] = $bHight
	$_Buttons[ $_Buttons[0][0] ][12] = $colStatic
	$_Buttons[ $_Buttons[0][0] ][13] = $colHover
	$_Buttons[ $_Buttons[0][0] ][14] = $colPress
	$_Buttons[ $_Buttons[0][0] ][15] = $iconIndex
	$_Buttons[ $_Buttons[0][0] ][16] = $iconSizeX
	$_Buttons[ $_Buttons[0][0] ][17] = $iconXoff
	$_Buttons[ $_Buttons[0][0] ][18] = $iconYoff
	$_Buttons[ $_Buttons[0][0] ][19] = $hChild
	$_Buttons[ $_Buttons[0][0] ][20] = $bStyle
	$_Buttons[ $_Buttons[0][0] ][21] = $iconSizeY
	$_Buttons[ $_Buttons[0][0] ][22] = $UserFn
	$_Buttons[ $_Buttons[0][0] ][23] = $UserData
	;MsgBox(0,"done","")
	Return $ctrlID
EndFunc

;	Handle Button States
Func _ButtonSetState($Flag) ;?
	_log("Set " & $_Buttons[0][0] & " Flags")
	GUISetState(@SW_HIDE, $hGUI)
	For $i = 1 To $_Buttons[0][0]
		Local $gui = $_Buttons[ $i ][19]
		GUISetState($Flag, $gui)
	Next
	GUISetState(@SW_SHOW, $hGUI)
EndFunc

;	Handle Button Colors due to events
Func _ButtonHandle($bID, $_Event)
	Local $id = _ArraySearch($_Buttons, $bID, 1, 0, 0, 0, 1, 0)
	If $id > 0 And $_Buttons[$id][20] <> $_Event Then
		_log("_ButtonHandle( " & $bID & " , " & $_Event & ") -  Button found: " & $id)
		Switch $_Event
			Case "Hover"
				GUISetBkColor($_Buttons[$id][13], $_Buttons[$id][19])
				GUICtrlSetBkColor($_Buttons[$id][0], $_Buttons[$id][13])
				GUISetState(@SW_SHOW, $_Buttons[$id][19])
			Case "Press"
				GUISetBkColor($_Buttons[$id][14], $_Buttons[$id][19])
				GUICtrlSetBkColor($_Buttons[$id][0], $_Buttons[$id][14])
				GUISetState(@SW_SHOW, $_Buttons[$id][19])
				Local $fn = $_Buttons[$id][22]
				Local $data = $_Buttons[$id][23]
				_log("Calling: " & $fn & ", " & $id & ", " & $bID)
				Call($fn, $id, $bID, $_Event, $data)
			Case "Static"
				GUISetBkColor($_Buttons[$id][12], $_Buttons[$id][19])
				GUICtrlSetBkColor($_Buttons[$id][0], $_Buttons[$id][12])
				GUISetState(@SW_SHOW, $_Buttons[$id][19])
		EndSwitch
	EndIf
	$_Buttons[$id][20] = $_Event
EndFunc

Func CloseProgram()
	GUISetState(@SW_HIDE, $hGUI)
	For $i = 1 To $_Buttons[0][0]
		GUISetState(@SW_HIDE, $_Buttons[$i][20])
		GUIDelete($_Buttons[$i][20])
	Next
	GUIDelete($hGUI)
	Exit 0
EndFunc

Func _log($str)
	ConsoleWrite($str & @CRLF)
EndFunc

Alles anzeigen

Freu mich über Feedback!

UPIA

Hier nochmal ein ganz einfaches Beispiel um das Problem darzustellen:
1. Button (nicht eingefärbt) mit .ico funtz perfekt, aber eben nur mit dem default-weiß
2. Button (eingefärbt) jetzt ist das .ico weg
3. Button (ein gefärbtes Label mit Icon) ist immer nur transparent,
wenn der Hintergrund des Bildes mit der des GuiBG identisch ist. ("See this bug!")

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>

Example()

Func Example()
	Local $bg_color = 0xf0f0f0
    Global $hGUI = GUICreate("GuiTest", 300, 200)

    ; Create a button control. - from examples working perfectly with trans icon on Default Color (No GUISetBkColor!) but has no color!
    Local $idButton_1 = GUICtrlCreateButton("", 30, 30, 48, 48, $BS_ICON)
	GUICtrlSetTip ( $idButton_1, "DefBtn", "")
	Local $idIcon_1 = GUICtrlSetImage($idButton_1, "C:\Windows\System32\imageres.dll", -82, 1)

	; The same but with color => not showing .ico file
    Local $idButton_2 = GUICtrlCreateButton("ColBtn", 100, 30, 48, 48, $BS_ICON)
	GUICtrlSetTip ( $idButton_2, "no ico!", "")
	GUICtrlSetBkColor($idButton_2, 0x666666)
	Local $idIcon_2 = GUICtrlSetImage($idButton_2, "C:\Windows\System32\imageres.dll", -82, 1)

	; Createing a color label with the icon as pseudo-button works ONLY if GUI-BG-color is  same as the icons background
    Local $idButton_3 = GUICtrlCreateLabel("", 170, 30, 48, 48)
	GUICtrlSetTip ( $idButton_3, "bad ico", "")
	GUICtrlSetBkColor($idButton_3, 0x666666)
	Local $idIcon_3 = GUICtrlCreateIcon("C:\Windows\System32\imageres.dll", -82, 178,38, 32,32)

	; Press this button to "solve" the problem
    Local $idButton_Switch = GUICtrlCreateButton("See the bug!", 210, 170, 85, 25)

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $idButton_Switch
				If $bg_color = 0xf0f0f0 Then
					$bg_color = 0x666666
					GUISetBkColor($bg_color, $hGUI)
					$msg = "nice ico"
				ElseIf $bg_color = 0x666666 Then
					$bg_color = 0xf0f0f0
					GUISetBkColor($bg_color, $hGUI)
					$msg = "bad ico"
				EndIf
            Case $idButton_1
                ; Run Notepad with the window maximized.
                MsgBox(0,"Default Button", "ico is transparent, but surface has fix color!")
            Case $idButton_2
                ; Run Notepad with the window maximized.
                MsgBox(0,"Default Button with Color", "Color set with GUICtrlSetBkColor() prevents ico")
            Case $idButton_3
                ; Run Notepad with the window maximized.
                MsgBox(0,"Label-Button", "Color will only work with transparency if gui-bg-bol matches the Label!")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example

Alles anzeigen

Als Lösungsweg ohne WinApi/GDI+ .. hab ich nichts anderes gefunden. So lässt sich auch ein Button mit States Static/Hover/Press gestalten.
Das ist aber auch das Limit der Methode für Buttons mit State-orientierten Farben, denn ab 2 Buttons in unterschiedlichen States funktioniert das natürlich nicht mehr. Also Workaround 2 eine (sub)GUI pro Button setzen. (siehe erster Post).

**Kanashius**

Hi, ja, ohne WinAPi/GDI+ wird es schwierig. Ich denke, dein Workaround im ersten Beispiel funktionierte schon recht gut. Da hatte ich auf die schnelle auch keine bessere Lösung gesehen.

Da du dir die Mühe mit dem weiteren Bespiel gemacht hast gehe ich mal davon aus, dass du eine andere/bessere Lösung möchtest.
Ich hab also mal gebastelt und eine recht elegante Lösung gefunden, denke ich. Ich verpacke das ganze in eine eigene GuiCtrlCreateIconEx -Funktion. Intern wird dabei ein GuiCtrlCreateGraphic verwendet, bei dem die Pixel entsprechend gesetzt werden.
Ich denke die Performance könnte noch verbessert werden (z.B. GDIPlus global laden/entladen (_GDIPlus_StartUp/Shutdown) oder eine ganz andere Methode zu verwenden mit z.B. GuiCtrlCreatePic).
Die Verwendung ist aber mit einem Funktionsaufruf recht elegant und es kann danach wie ein normales AutoIt-Ctrl verwendet werden (Es ist halt nur ein GraphicCtrl).

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <GDIPlus.au3>
#include <WinAPIShellEx.au3>
#include <WinAPISysWin.au3>

Example()

Func Example()
	Local $bg_color = 0xf0f0f0
    Global $hGUI = GUICreate("GuiTest", 300, 200)

    ; Create a button control. - from examples working perfectly with trans icon on Default Color (No GUISetBkColor!) but has no color!
    Local $idButton_1 = GUICtrlCreateButton("", 30, 30, 48, 48, $BS_ICON)
	GUICtrlSetTip ( $idButton_1, "DefBtn", "")
	Local $idIcon_1 = GUICtrlSetImage($idButton_1, "C:\Windows\System32\imageres.dll", -82, 1)

	; The same but with color => not showing .ico file
    Local $idButton_2 = GUICtrlCreateButton("ColBtn", 100, 30, 48, 48, $BS_ICON)
	GUICtrlSetTip ( $idButton_2, "no ico!", "")
	GUICtrlSetBkColor($idButton_2, 0x666666)
	Local $idIcon_2 = GUICtrlSetImage($idButton_2, "C:\Windows\System32\imageres.dll", -82, 1)

	; Createing a color label with the icon as pseudo-button works ONLY if GUI-BG-color is  same as the icons background
    Local $idButton_3 = GUICtrlCreateLabel("", 170, 30, 48, 48)
	GUICtrlSetTip ( $idButton_3, "bad ico", "")
	GUICtrlSetBkColor($idButton_3, 0x666666)
	Local $idIcon_3 = GUICtrlCreateIcon("C:\Windows\System32\imageres.dll", -82, 178,38, 32,32)

	Local $idIcon = GuiCtrlCreateIconEx("C:\Windows\System32\imageres.dll", -82, 30, 80, 48, 48, 32,32)
	GUICtrlSetBkColor(-1, 0x666666)

	; Press this button to "solve" the problem
    Local $idButton_Switch = GUICtrlCreateButton("See the bug!", 210, 170, 85, 25)

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $idButton_Switch
				If $bg_color = 0xf0f0f0 Then
					$bg_color = 0x666666
					GUISetBkColor($bg_color, $hGUI)
					$msg = "nice ico"
				ElseIf $bg_color = 0x666666 Then
					$bg_color = 0xf0f0f0
					GUISetBkColor($bg_color, $hGUI)
					$msg = "bad ico"
				EndIf
            Case $idButton_1
                ; Run Notepad with the window maximized.
                MsgBox(0,"Default Button", "ico is transparent, but surface has fix color!")
            Case $idButton_2
                ; Run Notepad with the window maximized.
                MsgBox(0,"Default Button with Color", "Color set with GUICtrlSetBkColor() prevents ico")
            Case $idButton_3
                ; Run Notepad with the window maximized.
                MsgBox(0,"Label-Button", "Color will only work with transparency if gui-bg-bol matches the Label!")
            Case $idIcon
                ; Run Notepad with the window maximized.
                MsgBox(0,"IconEx-Button", "Works!")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example

Func GuiCtrlCreateIconEx($sFilename, $iIconIndex, $iLeft, $iTop, $iWidth = Default, $iHeight = Default, $iIconWidth = Default, $iIconHeight = Default, $iStyle = Default)
	If $iIconWidth = Default Then $iIconWidth = $iWidth
	If $iIconHeight = Default Then $iIconHeight = $iHeight
	Local $idGraphic = GUICtrlCreateGraphic($iLeft, $iTop, $iWidth, $iHeight, $iStyle)
	_GDIPlus_Startup()
	Local $hIcon = _WinAPI_ShellExtractIcon($sFilename, $iIconIndex, $iIconWidth, $iIconHeight)
    Local $hBitmap = _GDIPlus_BitmapCreateFromHICON($hIcon)
	Local $iColorPrev = -1, $iImgWidth=_GDIPlus_ImageGetWidth($hBitmap), $iImgHeight = _GDIPlus_ImageGetHeight($hBitmap)
	Local $iLeftSpace = (_WinAPI_GetClientWidth(GUICtrlGetHandle($idGraphic))-$iImgWidth)/2, $iTopSpace = (_WinAPI_GetClientHeight(GUICtrlGetHandle($idGraphic))-$iImgHeight)/2
	For $x=0 To $iImgWidth
		For $y=0 To $iImgHeight
			Local $iColor = _GDIPlus_BitmapGetPixel($hBitmap, $x, $y)
			If BitAND($iColor, 0xFF000000)<>0 Then
				$iColor = BitAND($iColor, 0xFFFFFF)
				If $iColor<>$iColorPrev Then
					GUICtrlSetGraphic($idGraphic, $GUI_GR_COLOR, $iColor, $iColor)
					$iColorPrev = $iColor
				EndIf
				GUICtrlSetGraphic($idGraphic, $GUI_GR_PIXEL, $iLeftSpace+$x, $iTopSpace+$y, 40, 30, 270)
			EndIf
		Next
	Next
	_GDIPlus_BitmapDispose($hBitmap)
	_GDIPlus_Shutdown()
	return $idGraphic
EndFunc

Alles anzeigen

Ich hoffe das hilft dir weiter

UPIA

Hi Kanashius,
danke für deine antwort & Lösung. diese behebt das Problem, wie es sein soll und GUICtrlSetBkColor() funktioniert!
das icon on-the-fly umzumalen hatte ich auch schon in Betracht gezogen. Allerdings würde ich die Icons bei solch einem Aufwand dann auch gerne für den nächsten Start speichern*. (und an diesem Punkt bekam ich aus GDI+ nur jpg's und keine .ico).
"bei dem die Pixel entsprechend gesetzt werden" was passiert da? wieso funzt das ico danach auf allen farben? ich dachte zunächst das icon wird repariert und ich könnte es dann in diesem Zustand speichern, und beim nächsten Start aus dem .ico ohne Umwandlung laden.
(ginge das??? - das wäre genau das was ich suche!)
Aber da siegt wohl nur mein Wunschdenken über die Realität

Dann werde ich mal ein kleines Farb-Button Menü mit deiner Methode basteln und vorstellen.

Merci!!

*Kurz zum Hintergrund:
mein quicklauncher öffnet kleine GUI-Menüs mit Icons per Geste und Hotkeys. Diese erstelle ich beim ersten Einlesen und speicher die Icons (weil ich einige auch tauschen möchte).

Die meisten Menüs haben weniger als 8 Icons, da wäre die Performance theoretisch nicht so wichtig.
diese wollte ich nun in einer Art Windows-Start-Menü als Hauptmenü zusammenführen. Daher war ich mal nach einer brauchbaren Lösung für viele Buttons.

Velted

Moin,

wenn Du ein Label als Buttonersatz nehmen willst, könnte das auch so funktionieren:

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <StaticConstants.au3>
#include <WinAPIShellEx.au3>

Global Const $SS_REALSIZEIMAGE = 0x0800 ; fehlt in StaticConstants.au3

Example()

Func Example()
	Local $sIconFileName = "C:\Windows\System32\imageres.dll"
	Local $iIconIndex = 4
	Local $bg_color = 0x008000
    Global $hGUI = GUICreate("GuiTest", 300, 200)

	; Createing a color label with the icon as pseudo-button
	Local $iBtnStyle = BitOR($SS_CENTERIMAGE, $SS_ICON, $SS_NOTIFY, $SS_REALSIZEIMAGE)
    Local $idButton_3 = GUICtrlCreateLabel("", 170, 30, 48, 48, $iBtnStyle)
	GUICtrlSetTip(-1, "nice ico", "")
	GUICtrlSetBkColor(-1, $bg_color)
	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 4, 32, 32)
	GUICtrlSendMsg(-1, $STM_SETICON, $hIcon, 0)

	; Press this button to "solve" the problem
    Local $idButton_Switch = GUICtrlCreateButton("See the bug!", 210, 170, 85, 25)

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $idButton_Switch
				If $bg_color = 0x008000 Then
					$bg_color = 0x000080
					GUICtrlSetBkColor($idButton_3, $bg_color)
					$msg = "nice ico"
				ElseIf $bg_color = 0x000080 Then
					$bg_color = 0x008000
					GUICtrlSetBkColor($idButton_3, $bg_color)
					$msg = "Nice ico"
				EndIf
            Case $idButton_3
                ; Run Notepad with the window maximized.
                MsgBox(0,"Label-Button", "Does what you want it to do!")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example

Alles anzeigen

UPIA

Velted wow, dass ergebnis sieht gleich aus wie bei Kanashius nur mit weniger code.

~~Kann mir jemand das bitte noch final bestätigen:~~
"~~Man kann einen .ico file nicht so manipulieren, dass er in AutoIt per GUICtrlCreateIcon() geladen wird und nicht den Transparenz-Bug aufweist!"~~

EDIT: hab das erst jetzt kapiert!
Velted zeichnet das Icon einfach richtig (ohne bug mit WinAPI) auf ein Label.
Kanashius Weg "repariert" die transparenten Pixel auf einem GraphicHandle.
Und mein "Workaround" zeichnet eine neue sub-gui die ihren wahren BG nie zeigt und der Button ist auch nur ein Label.
Das funktioniert zwar, ohne Einsatz von extra-Bibliotheken aber auf Kosten von Programmierkomfort.

Tendentiell ist für mich die Methode von Velted am geeignetsten. Ich werde mal die Tage einen Performance-Test für alle 3 Methoden machen und berichten!

ich hab hier mal alle 3 Versionen hinzugefügt und mit OnMouseOver Effekten belegt. Funzen alle super!
Besonders beim Button-Handling zeigt sich aber der Mehraufwand meiner Methode (da wäre eine Handler-Funktion sinnvoll - im nächsten Post verbessert.)

GUI-Button-Test: (Originale, Kanashius, Velted, UPIA)

Der Code:

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <GDIPlus.au3>
#include <WinAPIShellEx.au3>
#include <WinAPISysWin.au3>

#include <StaticConstants.au3> ;velted
Global Const $SS_REALSIZEIMAGE = 0x0800 ; fehlt in StaticConstants.au3


Example() ; compare multiple buttons fixing the icon-gui-bug

Func Example()
	Local $winbg = 0x666666
    Global $hGUI = GUICreate("GuiTest", 300, 400)
	GUISetBkColor($winbg, $hGUI) ;$winbg

    ; Create a button control. - from examples working perfectly with trans icon on Default Color (No GUISetBkColor!) but has no color!
    Local $idButton_1 = GUICtrlCreateButton("", 30, 30, 48, 48, $BS_ICON)
	GUICtrlSetTip ( $idButton_1, "DefBtn", "")
	Local $idIcon_1 = GUICtrlSetImage($idButton_1, "C:\Windows\System32\imageres.dll", -82, 1)

	; The same but with color => not showing .ico file
    Local $idButton_2 = GUICtrlCreateButton("ColBtn", 100, 30, 48, 48, $BS_ICON)
	GUICtrlSetTip ( $idButton_2, "no ico!", "")
	GUICtrlSetBkColor($idButton_2, 0x666666)
	Local $idIcon_2 = GUICtrlSetImage($idButton_2, "C:\Windows\System32\imageres.dll", -82, 1)

	; Createing a color label with the icon as pseudo-button works ONLY if GUI-BG-color is  same as the icons background
    Local $idButton_3 = GUICtrlCreateLabel("", 170, 30, 48, 48)
	GUICtrlSetTip ( $idButton_3, "bad ico", "")
	GUICtrlSetBkColor($idButton_3, 0x666666)
	Local $idIcon_3 = GUICtrlCreateIcon("C:\Windows\System32\imageres.dll", -82, 178,38, 32,32)


	; Press this button to "solve" the problem
    Local $idButton_bg = GUICtrlCreateButton("Change BG!", 210, 370, 85, 25)

	;kanashius
	Local $idIcon1 = GuiCtrlCreateIconEx("C:\Windows\System32\imageres.dll", -82, 30, 110, 48, 48, 32,32)
	GUICtrlSetBkColor(-1, 0x8888ff)
	GUICtrlSetTip ( $idIcon1, "Kanashius", "")
	Local $idIcon2 = GuiCtrlCreateIconEx("C:\Windows\System32\imageres.dll", -82, 100, 110, 48, 48, 32,32)
	GUICtrlSetBkColor(-1, 0xff8888)
	GUICtrlSetTip ( $idIcon2, "Kanashius", "")
	Local $idIcon3 = GuiCtrlCreateIconEx("C:\Windows\System32\imageres.dll", -82, 170, 110, 48, 48, 32,32)
	GUICtrlSetBkColor(-1, 0x88ff88)
	GUICtrlSetTip ( $idIcon3, "Kanashius", "")

	;velted
	Local $idIcon4 = GuiCtrlCreateIcon2("", 30, 180, 48, 48, "C:\Windows\System32\imageres.dll", 4)
	GUICtrlSetBkColor(-1, 0x8888ff)
	GUICtrlSetTip ( $idIcon4, "Velted", "")
	Local $idIcon5 = GuiCtrlCreateIcon2("", 100, 180, 48, 48, "C:\Windows\System32\imageres.dll", 4)
	GUICtrlSetBkColor(-1, 0xff8888)
	GUICtrlSetTip ( $idIcon5, "Velted", "")
	Local $idIcon6 = GuiCtrlCreateIcon2("", 170, 180, 48, 48, "C:\Windows\System32\imageres.dll", 4)
	GUICtrlSetBkColor(-1, 0x88ff88)
	GUICtrlSetTip ( $idIcon6, "Velted", "")

	;upia
	Local $idIcon7 = GuiSubButtonCreate($hGUI, "", 30, 250, 48, 48, "C:\Windows\System32\imageres.dll", -132, 32, 32, 8, 8)
	GuiSubButtonSet($idIcon7, 0x8888ff)
	GUICtrlSetTip ( $idIcon7[1], "UPIA", "")
	Local $idIcon8 = GuiSubButtonCreate($hGUI, "", 100, 250, 48, 48, "C:\Windows\System32\imageres.dll", -132, 32, 32, 8, 8)
	GuiSubButtonSet($idIcon8, 0xff8888)
	GUICtrlSetTip ( $idIcon8[1], "UPIA", "")
	Local $idIcon9 = GuiSubButtonCreate($hGUI, "", 170, 250, 48, 48, "C:\Windows\System32\imageres.dll", -132, 32, 32, 8, 8)
	GuiSubButtonSet($idIcon9, 0x88ff88)
	GUICtrlSetTip ( $idIcon9[1], "UPIA", "")

	;_WinAPI_SetLayeredWindowAttributes($hGUI, $winbg, 255)

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

	Local  $lastH[2] = [-1,-1] ; for button control (regular)
	Local  $lastB[2] = [-1,-1] ; for gui-buttons

    ; Loop until the user exits.
    While 1
		Local $gmb = GUIGetMsg(1)
		Local $gm = $gmb[0]
		Local $h = $gmb[1]
		Local $c = $gmb[2]
		;If $gm <> 0 Then ConsoleWrite($gm & " - Handle: " & $h & " - Control: " & $c & " -------> lH: " & $lastH[0] & @CRLF)
        Switch $gm
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $idButton_bg
				If $winbg = 0xcccccc Then
					$winbg = 0x666666
					GUISetBkColor($winbg, $hGUI)
					GUISetState()
				ElseIf $winbg = 0x666666 Then
					$winbg = 0xcccccc
					GUISetBkColor($winbg, $hGUI)
					GUISetState()
				EndIf
           Case $idButton_1
                MsgBox(0,"Default Button", "ico is transparent, but surface has fix color!")
            Case $idButton_2
                MsgBox(0,"Default Button with Color", "Color set with GUICtrlSetBkColor() prevents ico")
            Case $idButton_3
				If $winbg = 0xcccccc Then
					$winbg = 0x666666
					GUISetBkColor($winbg, $hGUI)
					GUISetState()
				ElseIf $winbg = 0x666666 Then
					$winbg = 0xcccccc
					GUISetBkColor($winbg, $hGUI)
					GUISetState()
				EndIf
            Case $idIcon1
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon2
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon3
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon4
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon5
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon6
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon7[1]								; check subgui-buttons
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon8[1]
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon9[1]
				ConsoleWrite("Works!" & @CRLF)
			Case $GUI_EVENT_NONE
				; Button handling of the SubGui's with cursorinfo
				Local $CHECK = $idIcon7
				Local $ci = GUIGetCursorInfo($CHECK[0])
				If $ci[4] = $CHECK[1] Or $ci[4] = $CHECK[1]+1 Then
					If $lastB[0] <> $CHECK[1] Then
						GuiSubButtonSet($CHECK, 0xbbbbff)
						$lastB[0] = $CHECK[1]
						$lastB[1] = $CHECK[0]
					EndIf
				Else
					If $lastB[0]  = $CHECK[1] Then
						GuiSubButtonSet($CHECK, 0x8888ff)
						$lastB[0] = 0
						$lastB[1] = 0
					EndIf
				EndIf
				Local $CHECK = $idIcon8
				Local $ci = GUIGetCursorInfo($CHECK[0])
				If $ci[4] = $CHECK[1] Or $ci[4] = $CHECK[1]+1 Then
					If $lastB[0] <> $CHECK[1] Then
						GuiSubButtonSet($CHECK, 0xffbbbb)
						$lastB[0] = $CHECK[1]
						$lastB[1] = $CHECK[0]
					EndIf
				Else
					If $lastB[0]  = $CHECK[1] Then
						GuiSubButtonSet($CHECK, 0xff8888)
						$lastB[0] = 0
						$lastB[1] = 0
					EndIf
				EndIf
				Local $CHECK = $idIcon9
				Local $ci = GUIGetCursorInfo($CHECK[0])
				If $ci[4] = $CHECK[1] Or $ci[4] = $CHECK[1]+1 Then
					If $lastB[0] <> $CHECK[1] Then
						GuiSubButtonSet($CHECK, 0xbbffbb)
						$lastB[0] = $CHECK[1]
						$lastB[1] = $CHECK[0]
					EndIf
				Else
					If $lastB[0]  = $CHECK[1] Then
						GuiSubButtonSet($CHECK, 0x88ff88)
						$lastB[0] = 0
						$lastB[1] = 0
					EndIf
				EndIf

				Local $nfo = GUIGetCursorInfo($hGUI)						; use this to check hover and out - regular buttons/ctrlid's
				Local $hover = $nfo[4]
				;If $hover <> 0 Then ConsoleWrite("............ " & $hover)
				Switch $hover
					Case $idIcon1
						If Not $lastH[0] = $idIcon1 Then
							GUICtrlSetBkColor($idIcon1,0xbbbbff)
							$lastH[0] = $idIcon1
							$lastH[1] = 1
						EndIf
					Case $idIcon2
						If Not $lastH[0] = $idIcon2 Then
							GUICtrlSetBkColor($idIcon2,0xffbbbb)
							$lastH[0] = $idIcon2
							$lastH[1] = 1
						EndIf
					Case $idIcon3
						If Not $lastH[0] = $idIcon3 Then
							GUICtrlSetBkColor($idIcon3,0xbbffbb)
							$lastH[0] = $idIcon3
							$lastH[1] = 1
						EndIf
					Case $idIcon4
						If Not $lastH[0] = $idIcon4 Then
							GUICtrlSetBkColor($idIcon4,0xbbbbff)
							$lastH[0] = $idIcon4
							$lastH[1] = 1
						EndIf
					Case $idIcon5
						If Not $lastH[0] = $idIcon5 Then
							GUICtrlSetBkColor($idIcon5,0xffbbbb)
							$lastH[0] = $idIcon5
							$lastH[1] = 1
						EndIf
					Case $idIcon6
						If Not $lastH[0] = $idIcon6 Then
							GUICtrlSetBkColor($idIcon6,0xbbffbb)
							$lastH[0] = $idIcon6
							$lastH[1] = 1
						EndIf
					Case 0														; regular buttons/ctrlid's check - no hover => release any
						If Not $lastH[0]  = 0 Then
							Local $cid = $lastH[0]
							Switch $cid
								Case $idIcon1
									GUICtrlSetBkColor($idIcon1,0x8888ff)
								Case $idIcon2
									GUICtrlSetBkColor($idIcon2,0xff8888)
								Case $idIcon3
									GUICtrlSetBkColor($idIcon3,0x88ff88)
								Case $idIcon4
									GUICtrlSetBkColor($idIcon4,0x8888ff)
								Case $idIcon5
									GUICtrlSetBkColor($idIcon5,0xff8888)
								Case $idIcon6
									GUICtrlSetBkColor($idIcon6,0x88ff88)
							EndSwitch
							$lastH[0] = 0
							$lastH[1] = 0
						EndIf
				EndSwitch
        EndSwitch
    WEnd
    GUIDelete($hGUI)
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example

Func GuiCtrlCreateIconEx($sFilename, $iIconIndex, $iLeft, $iTop, $iWidth = Default, $iHeight = Default, $iIconWidth = Default, $iIconHeight = Default, $iStyle = Default) ;kanashius
	If $iIconWidth = Default Then $iIconWidth = $iWidth
	If $iIconHeight = Default Then $iIconHeight = $iHeight
	Local $idGraphic = GUICtrlCreateGraphic($iLeft, $iTop, $iWidth, $iHeight, $iStyle)
	_GDIPlus_Startup()
	Local $hIcon = _WinAPI_ShellExtractIcon($sFilename, $iIconIndex, $iIconWidth, $iIconHeight)
    Local $hBitmap = _GDIPlus_BitmapCreateFromHICON($hIcon)
	Local $iColorPrev = -1, $iImgWidth=_GDIPlus_ImageGetWidth($hBitmap), $iImgHeight = _GDIPlus_ImageGetHeight($hBitmap)
	Local $iLeftSpace = (_WinAPI_GetClientWidth(GUICtrlGetHandle($idGraphic))-$iImgWidth)/2, $iTopSpace = (_WinAPI_GetClientHeight(GUICtrlGetHandle($idGraphic))-$iImgHeight)/2
	For $x=0 To $iImgWidth
		For $y=0 To $iImgHeight
			Local $iColor = _GDIPlus_BitmapGetPixel($hBitmap, $x, $y)
			If BitAND($iColor, 0xFF000000)<>0 Then
				$iColor = BitAND($iColor, 0xFFFFFF)
				If $iColor<>$iColorPrev Then
					GUICtrlSetGraphic($idGraphic, $GUI_GR_COLOR, $iColor, $iColor)
					$iColorPrev = $iColor
				EndIf
				GUICtrlSetGraphic($idGraphic, $GUI_GR_PIXEL, $iLeftSpace+$x, $iTopSpace+$y, 40, 30, 270)
			EndIf
		Next
	Next
	; export here once to _ffccff
	_GDIPlus_BitmapDispose($hBitmap)
	_GDIPlus_Shutdown()
	return $idGraphic
EndFunc

Func GuiCtrlCreateIcon2($tx, $pX, $pY, $iW, $iH, $sIconFileName, $IconIndex, $iBtnStyle=BitOR($SS_CENTERIMAGE, $SS_ICON, $SS_NOTIFY, $SS_REALSIZEIMAGE) ) ;velted
	; Createing a color label with the icon as pseudo-button
    Local $idButton = GUICtrlCreateLabel($tx, $pX, $pY, $iW, $iH, $iBtnStyle)
	GUICtrlSetTip(-1, "nice ico", "")
	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, $IconIndex, 32, 32)
	GUICtrlSendMsg(-1, $STM_SETICON, $hIcon, 0)
	Return $idButton
EndFunc

Func GuiSubButtonCreate($hGUI, $strText, $xPos, $yPos, $bWidth, $bHight, $iconFile, $iconIndex, $iconSizeX, $iconSizeY, $iconXoff, $iconYoff, $initCol=0xf0f0f0)
	Local $ctrlID = -1, $icon
	Local $hChild = GUICreate("", $bWidth, $bHight, $xPos, $yPos, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
	GUISwitch($hChild)
	GUISetState(@SW_DISABLE, $hChild)
	GUISetState(@SW_HIDE, $hChild)
	$ctrlID = GUICtrlCreateLabel($strText, 0, 0, $bWidth, $bHight)
	GUISetBkColor($initCol, $hChild)												;set state static
	GUICtrlSetBkColor($ctrlID, $initCol)
	$icon = GUICtrlCreateIcon($iconFile, $iconIndex, 0+$iconXoff, 0+$iconYoff, $iconSizeX, $iconSizeY, Default)
	GUISetState(@SW_ENABLE, $hChild)
	GUISetState(@SW_SHOW, $hChild)
	Local $ret[2] = [$hChild, $ctrlID]
	Return $ret
EndFunc
Func GuiSubButtonSet($aID, $col)
	GUISetBkColor($col, $aID[0])
	GUICtrlSetBkColor($aID[1], $col)
	GUISetState(@SW_SHOW)
EndFunc

Alles anzeigen

UPIA

wenn ich für meine "methode" einfach ein label auf der hGUI unter die subGUI platzieren kann ich den hover-status mit GUIGetCursorInfo($hGUI) auslesen. damit reduziert sich der button-handling code auch wesentlich. letztenendes wird sich aber doch jeder der mehrere OnMouseOver Buttons kontrollieren will einen button-händler basteln.

das noch zur ergänzung, meine Buttons etwas schlanker mit einem zusätzlichen Label:

AutoIt

#include <GUIConstants.au3>

Example() ; compare multiple buttons fixing the icon-gui-bug

Func Example()
	Local $winbg = 0x666666
    Global $hGUI = GUICreate("GuiTest", 300, 400)
	GUISetBkColor($winbg, $hGUI)

	; Press this button to "solve" the problem
    Local $idButton_bg = GUICtrlCreateButton("Change BG!", 210, 370, 85, 25)

	;upia
	Local $idIcon7 = GuiSubButtonCreate($hGUI, "", 30, 250, 48, 48, "C:\Windows\System32\imageres.dll", -132, 32, 32, 8, 8, 0xff8888, 0xffbbbb, 0xffcccc)
	Local $idIcon8 = GuiSubButtonCreate($hGUI, "", 100, 250, 48, 48, "C:\Windows\System32\imageres.dll", -132, 32, 32, 8, 8, 0x8888ff, 0xbbbbff, 0xccccff)
	Local $idIcon9 = GuiSubButtonCreate($hGUI, "", 170, 250, 48, 48, "C:\Windows\System32\imageres.dll", -132, 32, 32, 8, 8, 0x88ff88, 0xbbffbb, 0xccffcc)

    GUISetState(@SW_SHOW, $hGUI)

    ; Loop until the user exits.
    While 1
		Local $gmb = GUIGetMsg(1)
		Local $gm = $gmb[0]
		Local $h = $gmb[1]
		Local $c = $gmb[2]
        Switch $gm
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $idButton_bg
				If $winbg = 0xcccccc Then
					$winbg = 0x666666
					GUISetBkColor($winbg, $hGUI)
					GUISetState()
				ElseIf $winbg = 0x666666 Then
					$winbg = 0xcccccc
					GUISetBkColor($winbg, $hGUI)
					GUISetState()
				EndIf
            Case $idIcon7[1]								; check subgui-buttons on [1] hSUB Label
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon8[1]
				ConsoleWrite("Works!" & @CRLF)
            Case $idIcon9[1]
				ConsoleWrite("Works!" & @CRLF)
			Case $GUI_EVENT_NONE
				; Button handling of the SubGui's with cursorinfo
				Local $nfo = GUIGetCursorInfo($hGUI)						; use this to check hover and out on [3] (hGUI-Label)
				Local $hover = $nfo[4]
				Switch $hover
					Case $idIcon7[3]
						$idIcon7 = GuiSubButtonSet($idIcon7, 1)
					Case $idIcon8[3]
						$idIcon8 = GuiSubButtonSet($idIcon8, 1)
					Case $idIcon9[3]
						$idIcon9 = GuiSubButtonSet($idIcon9, 1)
					Case 0														; check - no hover => release any if state is hover
						If $idIcon7[7] = 1 Then $idIcon7 = GuiSubButtonSet($idIcon7, 0)
						If $idIcon8[7] = 1 Then $idIcon8 = GuiSubButtonSet($idIcon8, 0)
						If $idIcon9[7] = 1 Then $idIcon9 = GuiSubButtonSet($idIcon9, 0)
				EndSwitch
        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func GuiSubButtonCreate($hGUI, $strText, $xPos, $yPos, $bWidth, $bHight, $iconFile, $iconIndex, $iconSizeX, $iconSizeY, $iconXoff, $iconYoff, $staticCol, $overCol, $pressCol)
	Local $ctrlID = -1, $icon
	GUISwitch($hGUI)
	Local $xLayer = GUICtrlCreateLabel("", $xPos, $yPos, $bWidth, $bHight) ; <<--------------------------- Trick? this triggers GUIGetCursorInfo($hGUI) - no sub-check
	Local $hChild = GUICreate("", $bWidth, $bHight, $xPos, $yPos, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
	GUISwitch($hChild)
	GUISetState(@SW_DISABLE, $hChild)
	GUISetState(@SW_HIDE, $hChild)
	$ctrlID = GUICtrlCreateLabel($strText, 0, 0, $bWidth, $bHight)
	GUISetBkColor($staticCol, $hChild)												;set state static
	GUICtrlSetBkColor($ctrlID, $staticCol)
	$icon = GUICtrlCreateIcon($iconFile, $iconIndex, 0+$iconXoff, 0+$iconYoff, $iconSizeX, $iconSizeY, Default)
	GUISetState(@SW_ENABLE, $hChild)
	GUISetState(@SW_SHOW, $hChild)
	Local $ret[8] = [$hChild, $ctrlID, $icon, $xLayer, $staticCol, $overCol, $pressCol, 0]
	GUISwitch($hGUI)
	Return $ret
EndFunc
Func GuiSubButtonSet($aID, $state)
	Local $stateL = $aID[7]
	If $stateL <> $state Then
		Local $i = $state + 4
		Local $c = $aID[$i]
		GUISetBkColor($c, $aID[0])
		GUICtrlSetBkColor($aID[1], $c)
		GUISetState(@SW_SHOW)
		$aID[7] = $state;?!
	EndIf
	Return $aID
EndFunc

Alles anzeigen

Velted

Moin,

hier kommt die Methode "Velted2". Die sollte das Leben deutlich einfacher machen:

AutoIt

#include <GUIConstants.au3>
#include <StaticConstants.au3>
#include <StructureConstants.au3>
#include <ButtonConstants.au3>
#Include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPIShellEx.au3>

Global Const $tagNMCUSTOMDRAW = "struct;" & $tagNMHDR & ";dword dwDrawStage;handle hdc;" & $tagRECT & _
								";dword_ptr dwItemSpec;uint uItemState;lparam lItemlParam;endstruct"

Example()

Func Example()
	Local $sIconFileName = "C:\Windows\System32\imageres.dll"
    Global $hGUI = GUICreate("GuiTest", 300, 200)

	; Create 'icon buttons'
	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 4, 48, 48)
	Local $idBtn1 = _GUICtrlCreateIconButton(20, 20, 50, 50, $hIcon, 48, 48, 0xCCCCCC, 0x00CCCC, 0x00FFFF)
	GUICtrlSetTip($idBtn1, "IconButton 1", "")

	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 16, 32, 32)
	Local $idBtn2 = _GUICtrlCreateIconButton(20, 80, 50, 50, $hIcon, 32, 32, 0x0000CC, 0x00CC00, 0xFF0000)
	GUICtrlSetTip($idBtn2, "IconButton 2", "")

	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 82, 16, 16)
	Local $idBtn3 = _GUICtrlCreateIconButton(20, 140, 50, 50, $hIcon, 16, 16, 0x808080, 0xE0E0E0, 0x404040)
	GUICtrlSetTip($idBtn3, "IconButton 3", "")

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idBtn1
                ; Run Notepad with the window maximized.
                MsgBox(0, "Button 1", "You clicked me!")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example
; ----------------------------------------------------------------------------------------------------------------------
Func _GuiCtrlCreateIconButton($iX, $iY, $iW, $iH, $hIcon, $iIconW, $iIconH, $iColorN, $iColorH, $iColorP)
	Static $bOnmessage = False
	Local $idBtn = GUICtrlCreateButton("", $ix, $iY, $iw, $iH, $BS_ICON)
	GUICtrlSendMsg(-1, $BM_SETIMAGE, 1, $hIcon)
	Local $aSettings = [$iW, $iH, $hIcon, $iIconW, $iIconH, $iColorN, $iColorH, $iColorP]
	_GuiIconButtonsSettings($idBtn, $aSettings)
	If Not $bOnmessage Then
		GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
		$bOnmessage = True
	EndIf
	Return $idBtn
EndFunc
; ----------------------------------------------------------------------------------------------------------------------
Func _GuiIconButtonsSettings($idBtn, $aSettings = Default)
	Static $mBtns[]
	Select
		Case IsArray($aSettings) And UBound($aSettings) = 8
			$mBtns[$idBtn] = $aSettings
			Return True
		Case MapExists($mBtns, $idBtn)
			Return $mBtns[$idBtn]
	EndSelect
	Return False
EndFunc
; ----------------------------------------------------------------------------------------------------------------------
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
	Local $tNMCD = DllStructCreate($tagNMCUSTOMDRAW, $lParam)
	Local $idFrom = $tNMCD.IDFrom, $iCode = $tNMCD.Code
	Local $aSettings = _GuiIconButtonsSettings($idFrom)
	If IsArray($aSettings) And ($iCode = $NM_CUSTOMDRAW) Then
		Local $iDS = $tNMCD.dwDrawStage
		Local $hDC = $tNMCD.hdc
		Local $tRC = DllStructCreate($tagRECT, DllStructGetPtr($tNMCD, 6))
		Local $iST = $tNMCD.uItemState
		Local $iColor = 5
		Select
			Case BitAnd($iST, $CDIS_SELECTED)
				$iColor = 7
			Case BitAND($iST, $CDIS_HOT)
				$iColor = 6
		EndSelect
		Local $hBR = _WinAPI_CreateSolidBrush($aSettings[$iColor])
		_WinAPI_FillRect( $hDC, $tRC, $hBR)
		Local $hIcon = $aSettings[2]
		Local $iW = $aSettings[3]
		Local $iH = $aSettings[4]
		Local $iX = Round(($aSettings[0] - $IW) / 2)
		Local $iY = Round(($aSettings[1] - $IH) / 2)
		_WinAPI_DrawIconEX($hDC, $iX, $iY, $hIcon, $iW, $iH)
		_WinAPI_DeleteObject($hBR)
		If BitAND($iST, $CDIS_FOCUS) Then
			$hBR = _WinAPI_GetSysColorBrush($COLOR_HIGHLIGHT )
			_WinAPI_FrameRect($hDC, $tRC, $hBR)
		EndIf
		Return $CDRF_SKIPDEFAULT
	EndIf

	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Bei den Includes kann wahrscheinlich noch 'entschlackt' werden. Und das Zeichnen des Buttons könnte man noch verfeinern bzw. an Win 11 anpassen. Für den Start sollte es aber reichen.

Viel Spaß!

Edit 05.12.25 13:13: _WinAPI_DrawIconEX() korrigiert

UPIA

jetzt weiß ich wofür diese wm_notify geschichte gut ist große erkenntnis für das button-handling, sehr geil!
mir ist ab diesem punkt nicht klar, welchen nachteil es hat ob mein button ein label, grafikhandle oder ein echter button ist!
"Das Zeichnen des Buttons könnte man noch verfeinern bzw. an Win 11 anpassen"
das würde mich auch interessieren (habe die gui-stlyes probiert aber die sind nicht wirklich der bringer.
hat der echte button hier vorteile, weil er besser dargestellt werden kann?

Velted

Moin UPIA,

der 'echte' Button liefert bei NM_CUSTOMDRAW den 'Hover' Status automatisch.

Zitat von UPIA

"Das Zeichnen des Buttons könnte man noch verfeinern bzw. an Win 11 anpassen"

Die Styles bringen Dir hier nichts, weil der Button komplett selbst gezeichnet wird.

Velted

Moin UPIA,

vielleicht gefällt Dir diese Version von Func WM_NOTIFY() besser:

AutoIt

; ----------------------------------------------------------------------------------------------------------------------
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
	Local $tNMCD = DllStructCreate($tagNMCUSTOMDRAW, $lParam)
	Local $idFrom = $tNMCD.IDFrom, $iCode = $tNMCD.Code
	Local $aSettings = _GuiIconButtonsSettings($idFrom)
	If IsArray($aSettings) And ($iCode = $NM_CUSTOMDRAW) Then
		Local $hBN = $tNMCD.hWndFrom
		Local $iDS = $tNMCD.dwDrawStage
		Local $hDC = $tNMCD.hdc
		Local $tRC = DllStructCreate($tagRECT, DllStructGetPtr($tNMCD, 6))
		Local $iST = $tNMCD.uItemState
		If Not $iST = $CDDS_PREPAINT Then Return $GUI_RUNDEFMSG
		Local $iColor = 5
		Select
			Case BitAnd($iST, $CDIS_SELECTED)
				$iColor = 7
			Case BitAND($iST, $CDIS_HOT)
				$iColor = 6
		EndSelect
		_WinAPI_DrawThemeParentBackground($hBN, $hDC)
		Local $hBR = _WinAPI_CreateSolidBrush($aSettings[$iColor])
		Local $hRgn = 0
		If @OSVersion = "WIN_11" Then
			$hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aSettings[0], $aSettings[1], 9, 9)
		Else
			$hRgn = _WinAPI_CreateRectRgn(0, 0, $aSettings[0], $aSettings[1])
		EndIf
		_WinAPI_FillRgn($hDC, $hRgn, $hBR)
		_WinAPI_DeleteObject($hBR)
		Local $hIcon = $aSettings[2]
		Local $iW = $aSettings[3]
		Local $iH = $aSettings[4]
		Local $iX = Round(($aSettings[0] - $IW) / 2)
		Local $iY = Round(($aSettings[1] - $IH) / 2)
		_WinAPI_DrawIconEX($hDC, $iX, $iY, $hIcon, $iW, $iH)
		If BitAND($iST, $CDIS_FOCUS) Or BitAnd($iST, $CDIS_HOT) Then
			$hBR = _WinAPI_GetSysColorBrush($COLOR_HIGHLIGHT)
			_WinAPI_FrameRgn($hDC, $hRgn, $hBR, 1, 1)
		EndIf
		_WinAPI_DeleteObject($hRgn)
		Return $CDRF_SKIPDEFAULT
	EndIf
	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

UPIA

Zitat von Velted

der 'echte' Button liefert bei NM_CUSTOMDRAW den 'Hover' Status automatisch.

okay, mächtig! das wm_notify zu lesen ist wirklich schick. letztenendes muss halt doch der Farbeimer ran und das Icon wieder draufgeballert werden - dafür aber vollends kompatibel!

Ich hab die Buttons auf die Schnelle nicht abrunden können wie den Default. Das sollte aber doch mit den Styles gehen?!

Velted

AutoIt

		If @OSVersion = "WIN_11" Then
			$hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aSettings[0], $aSettings[1], 9, 9)
		Else
			$hRgn = _WinAPI_CreateRectRgn(0, 0, $aSettings[0], $aSettings[1])
		EndIf

Moin, was zeigt bei Dir MsgBox(0, "OSVersion", @OSVersion) an?

UPIA

hi.
Sehe jetzt erst, deine überarbeitete wm_notify. Funzt einwandfrei bei mir!
ich bin auf win11. danke für die info! Jetzt kapier ich auch wie dieses Script funktioniert, dass ich eine zeitlang her gefunden habe:

Code

Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
   Dim $pos, $ret, $ret2
   $pos = WinGetPos($h_win)
    $ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long",  $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3,  "long", $i_y3)
   If $ret[0] Then
      $ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
      If $ret2[0] Then
         Return 1
      Else
         Return 0
      EndIf
   Else
      Return 0
   EndIf
EndFunc;==>_GuiRoundCorners

Alles anzeigen

Schönen Sonntag!