Beiträge von fee

_ChristmasTree(8)

Func _ChristmasTree($n)
  Local Const $c = $n * 2 - 1
  Local $t = ''
  If $n > 0 Then
    $t &= StringFormat('%' & $c & 's%' & $c - 1 & 's\r\n', '*', '')
    For $i = 1 To $c - 4 Step 2
      $t &= StringFormat('%' & $c - $i + 1 & 's%0' & $i - 1 & 's' & _
                         '%' & $c - $i & 's\r\n', '0', '', '')
    Next
    If $n > 1 Then $t &= StringFormat('%' & $c & 's%' & $c - 3 & 's\r\n', '| |', '')
    $t = StringReplace(StringReplace($t, '  ', ' '), '0', 'X')
  EndIf
  ConsoleWrite(@CRLF & $t & @CRLF)
EndFunc   ;==>_ChristmasTree

_ChristmasTree(8)

Func _ChristmasTree($n)
  Local Const $c = StringReplace(StringFormat('%' & $n * 2 - 5 & 's', ''), ' ', 'X')
  Local $s = StringFormat('%' & $n - 1 & 's', '')
  Local $t = ''
  If $n > 0 Then
    $t = $s & '*' & $s & @CRLF
    For $i = 1 To $n - 2
      $t &= StringMid($s & $c, $i, $i + $n - 1) & StringMid($s, $i) & @CRLF
    Next
    $s = StringTrimRight($s, 1)
    If $n > 1 Then $t &= $s & '| |' & $s & @CRLF
  EndIf
  ConsoleWrite(@CRLF & $t & @CRLF)
EndFunc   ;==>_ChristmasTree

AutoItSetOption('MustDeclareVars', 1)

; Letzten freien Laufwerksbuchstaben ermitteln
Global $sDrive = ''
For $i = Asc('Z') To Asc('A') Step -1
  $sDrive = Chr($i) & ':'
  If FileExists($sDrive) = 0 Then ExitLoop
  $sDrive = ''
Next

; Bei Fehlschlag Meldung anzeigen und abbrechen
If $sDrive = '' Then
  MsgBox(16, 'Fehler', 'Kein Laufwerksbuchstabe frei!')
  Exit 1
EndIf

; Aktuelles Skriptverzeichnis ermitteln
Global Const $sScript = @ScriptDir

; Zielverzeichnispfad festlegen
Global Const $sPath = '\Ungültiger Pfad mit Leerzeichen'

; Zieldateiname mit Erweiterung festlegen
Global Const $sName = '\Sehr langer Dateiname.erweitert'

; Verknüpfung erstellen
If FileCreateShortcut($sDrive & $sPath & $sName, $sScript & '\Test.lnk', $sDrive & $sPath) = 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verknüpfung nicht erstellt!')
  Exit 2
EndIf

; Skriptende
Exit 0

AutoItSetOption('MustDeclareVars', 1)

; Letzten freien Laufwerksbuchstaben ermitteln
Global $sDrive = ''
For $i = Asc('Z') To Asc('A') Step -1
  $sDrive = Chr($i) & ':'
  If FileExists($sDrive) = 0 Then ExitLoop
  $sDrive = ''
Next

; Bei Fehlschlag Meldung anzeigen und abbrechen
If $sDrive = '' Then
  MsgBox(16, 'Fehler', 'Kein Laufwerksbuchstabe frei!')
  Exit 1
EndIf

; Aktuelles Skriptverzeichnis ermitteln
Global Const $sScript = @ScriptDir

; Zielverzeichnispfad festlegen
Global Const $sPath = '\Ungültiger Pfad mit Leerzeichen'

; Zieldateiname mit Erweiterung festlegen
Global Const $sName = '\Sehr langer Dateiname.erweitert'

; Verzeichnisstruktur abfragen
If FileExists($sScript & $sPath & $sName) = 1 Then
  ; Bei Erfolg Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verzeichnisstruktur bereits vorhanden!')
  Exit 2
EndIf

; Verzeichnisstruktur anlegen
Global Const $hFile = FileOpen($sScript & $sPath & $sName, 9)
If $hFile = -1 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verzeichnisstrukturerstellung fehlgeschlagen!')
  Exit 3
EndIf
; Geöffnete Datei schließen
FileClose($hFile)

; Freien Laufwerksbuchstaben mit Verzeichnis verbinden
If _Substitute($sDrive, $sScript & $sPath) <> 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Laufwerk nicht mit Verzeichnis verbunden!')
  Exit 4
EndIf

; Verknüpfung erstellen
If FileCreateShortcut($sDrive & $sPath & $sName, $sScript & '\Test.lnk', $sDrive & $sPath) = 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verknüpfung nicht erstellt!')
  Exit 5
EndIf

; Verzeichnisverbindung trennen
If _Substitute($sDrive, '/d') <> 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Laufwerkstrennung fehlgeschlagen!')
  Exit 6
EndIf

; Verzeichnisstruktur löschen
If DirRemove($sScript & $sPath, 1) = 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verzeichnisstrukturlöschung fehlgeschlagen!')
  Exit 7
EndIf

; Skriptende
Exit 0


Func _Substitute($sDrive, $sArgs = '')
  ; Übergebene Argumente verarbeiten
  If $sArgs <> '' Then
    ; Mögliche Gegenschrägstriche am Pfadende entfernen
    $sArgs = StringRegExpReplace($sArgs, '\\+$', '')
    ; Pfad mit Sonderzeichen zwischen zwei doppelte Anführungszeichen setzen
    StringRegExpReplace($sArgs, "[][{}()!`'^=~+;, ]+", '')
    If @Extended > 0 Then $sArgs = '"' & $sArgs & '"'
    ; Leerzeichentrenner vors Argument setzen
    $sArgs = ' ' & $sArgs
  EndIf

  ; Konsolenbefehl 'subst' mit Parametern ausführen
  Local Const $iSubst = Run('subst ' & $sDrive & $sArgs, $sScript, @SW_Show, 6)

  ; Zeitgeber einrichten und Variablen festlegen
  Local $hTimer = TimerInit()
  Local $sInfo  = ''
  Local $sError = ''

  ; Standard-Ausgabe- und Fehler-Datenströme der Konsole auslesen
  While 1
    $sInfo &= StdOutRead($iSubst)
    If @Error <> 0 Then ExitLoop                ; Bei Fehler Schleife verlassen
    If TimerDiff($hTimer) >= 3800 Then ExitLoop ; Bei Zeitüberschreitung Schleife verlassen
  WEnd
  $hTimer = TimerInit()
  While 1
    $sError &= StdErrRead($iSubst)
    If @Error <> 0 Then ExitLoop                ; Bei Fehler Schleife verlassen
    If TimerDiff($hTimer) >= 3800 Then ExitLoop ; Bei Zeitüberschreitung Schleife verlassen
  WEnd

  ; Möglichen noch vorhandenen Konsolenprozess schließen
  If ProcessExists($iSubst) <> 0 Then ProcessClose($iSubst)

  ; Fehler oder Erfolg zurückgeben
  If $sInfo <> '' Or $sError <> '' Then Return 1
  Return 0
EndFunc   ;==>_Substitute

#Include <WinAPIShPath.au3>

AutoItSetOption('MustDeclareVars', 1)

; Letzten freien Laufwerksbuchstaben ermitteln
Global $sDrive = ''
For $i = Asc('Z') To Asc('A') Step -1
  $sDrive = Chr($i) & ':'
  If FileExists($sDrive) = 0 Then ExitLoop
  $sDrive = ''
Next

; Bei Fehlschlag Meldung anzeigen und abbrechen
If $sDrive = '' Then
  MsgBox(16, 'Fehler', 'Kein Laufwerksbuchstabe frei!')
  Exit 1
EndIf

; Aktuelles Skriptverzeichnis ermitteln
Global Const $sScript = @ScriptDir

; Zielverzeichnispfad festlegen
Global Const $sPath = '\Ungültiger Pfad mit Leerzeichen'

; Zieldateiname mit Erweiterung festlegen
Global Const $sName = '\Sehr langer Dateiname.erweitert'

; Verknüpfungsziel in vorschriftsmäßige URL umwandeln
Global Const $sScheme = _WinAPI_URLCreateFromPath($sDrive & $sPath & $sName)

; Verknüpfung erstellen
If FileCreateShortcut($sScheme, $sScript & '\Test.lnk', $sDrive & $sPath) = 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verknüpfung nicht erstellt!')
  Exit 2
EndIf

; Skriptende
Exit 0

AutoItSetOption('MustDeclareVars', 1)

; Letzten freien Laufwerksbuchstaben ermitteln
Global $sDrive = ''
For $i = Asc('Z') To Asc('A') Step -1
  $sDrive = Chr($i) & ':'
  If FileExists($sDrive) = 0 Then ExitLoop
  $sDrive = ''
Next

; Bei Fehlschlag Meldung anzeigen und abbrechen
If $sDrive = '' Then
  MsgBox(16, 'Fehler', 'Kein Laufwerksbuchstabe frei!')
  Exit 1
EndIf

; Aktuelles Skriptverzeichnis ermitteln
Global Const $sScript = @ScriptDir

; Zielverzeichnispfad festlegen
Global Const $sPath = '\Ungültiger Pfad mit Leerzeichen'

; Zieldateiname mit Erweiterung festlegen
Global Const $sName = '\Sehr langer Dateiname.erweitert'

; Verknüpfungsziel in vorschriftsmäßige URL umwandeln
Global Const $sScheme = _WinAPI_URLCreateFromPath($sDrive & $sPath & $sName)

; Verknüpfung erstellen
If FileCreateShortcut($sScheme, $sScript & '\Test.lnk', $sDrive & $sPath) = 0 Then
  ; Bei Fehlschlag Meldung anzeigen und abbrechen
  MsgBox(16, 'Fehler', 'Verknüpfung nicht erstellt!')
  Exit 2
EndIf

; Skriptende
Exit 0


; #FUNCTION# =======================================================================================
; Author ..: Yashied
; Modified : jpm
; ==================================================================================================
Func _WinAPI_UrlCreateFromPath($sFilePath)
  Local $aRet = DLLCall('shlwapi.dll', _
                        'long'  , 'UrlCreateFromPathA', _
                        'wstr'  , $sFilePath          , _
                        'wstr'  , ''                  , _
                        'dword*', 4096                , _
                        'dword' , 0)
  If @Error Then Return SetError(@Error, @Extended, '')
  If $aRet[0] < 0 Or $aRet[0] > 1 Then ; S_OK, S_FALSE
    Return SetError(10, $aRet[0], '')
  EndIf
  Return $aRet[2]
EndFunc   ;==>_WinAPI_UrlCreateFromPath

Func _CreateShortcut($sLocation, $sTarget, $iWindowStyle = 1, $sHotkey = '', $iIcon = 0, _
                     $sDescription = '', $sWorkingDirectory = '')
  ; Source: https://www.autoitscript.com/forum/topic/32252-creating-a-shortcut/
  Local Const $oShell = ObjCreate('WScript.Shell')
  If @Error = 0 Then
    Local $oLink = $oShell.CreateShortcut($sLocation)
    If IsObj($oLink) = 1 Then
      $oLink.TargetPath       = $sTarget
      $oLink.WindowStyle      = $iWindowStyle
      $oLink.Hotkey           = $sHotkey
      $oLink.IconLocation     = $iIcon
      $oLink.Description      = $sDescription
      $oLink.WorkingDirectory = $sWorkingDirectory
      $oLink.Save
      If FileExists($sLocation) = 1 Then
        Return True
      EndIf
    EndIf
  EndIf
  Return False
EndFunc   ;==>_CreateShortcut

AutoItSetOption('MustDeclareVars', 1)

Global $s = ''

; Letzten freien Laufwerksbuchstaben ermitteln
For $i = Asc('Z') To Asc('A') Step -1
  $s = Chr($i) & ':\'
  If FileExists($s) = 0 Then ExitLoop
  $s = ''
Next

; Bei Fehlschlag Meldung anzeigen und abbrechen
If $s = '' Then
  MsgBox(16, 'Fehler', 'Kein Laufwerksbuchstabe frei!')
  Exit 1
EndIf

; Pfade festlegen und Verknüpfung erstellen
$s &= 'Ungültiger Pfad mit Leerzeichen'
FileCreateShortcut($s & '\nul.ext', @ScriptDir & '\Test.lnk', $s)

; Skriptende
Exit 0

#NoTrayIcon
;===================================================================================================
; AutoIt-Version .: 3.3.16.1
; VorausSetzungen : Siehe #Include
; Dateiname ......: AusweisNummerPruefer.au3
; Autoren ........: Unbekannt, fee
; Begonnen am ....: 2023-07-22
; Geändert am ....: 2023-07-24
; Dateiversion ...: 1.0.0.0
; Webseiten ......: Unbekannt
; Beschreibung ...: AusweisNummer auf Gültigkeit prüfen.
; Anmerkungen ....: Keine
;===================================================================================================

; Skriptanfang.
#Include <APIGDIConstants.au3>
#Include <ButtonConstants.au3>
#Include <Date.au3>
#Include <GUIConstantsEx.au3>
#Include <MsgBoxConstants.au3>
#Include <SendMessage.au3>
#Include <StringConstants.au3>
#Include <WinAPIGDI.au3>
#Include <WinAPIGDIDC.au3>
#Include <WinAPIGDIInternals.au3>
#Include <WinAPIHObj.au3>
#Include <WinAPISysInternals.au3>
#Include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global Enum _
    $Geburtstag  , _
    $Geburtsmonat, _
    $Geburtsjahr , _
    $Alter       , _
    $Volljaehrig , _
    $Ablauftag   , _
    $Ablaufmonat , _
    $Ablaufjahr  , _
    $Herkunft    , _
    $Deutscher   , _
    $Erstwohnsitz, _
    $Ende

;--- Anwendungsbeispiel ---

Global Const $Window = GUICreate('AusweisNummerPrüfer', 200, 100)
Local $Sizes = WinGetPos($Window)
$Sizes[2] -= 200
$Sizes[3] -= 100

GUICtrlCreateLabel('Personalnummer:', 10, 8, -1, 17)

GUISetFont(9, 400, 0, 'Consolas')
Opt('GUICoordMode', 0)
Local Const $InputA = GUICtrlCreateInput('', 0, 17, _TextWidth('00000000000') + 1, 21)

Opt('GUICoordMode', 2)
GUICtrlCreateLabel('<<', 0, -18, _TextWidth('<<') - 2, 17)
Local Const $InputB = GUICtrlCreateInput('', 0, -20, _TextWidth('0000000') + 5, 21)

GUICtrlCreateLabel('<', 0, -18, _TextWidth('<') - 1, 17)
Local Const $InputC = GUICtrlCreateInput('', 0, -20, _TextWidth('0000000') + 5, 21)

GUICtrlCreateLabel('<<<<<', 0, -18, _TextWidth('<<<<<') - 5, 17)
Local Const $InputD = GUICtrlCreateInput('', 0, -20, _TextWidth('0') + 5, 21)

Local $Width = ControlGetPos($Window, '', $InputD)
$Width = $Width[0] + $Width[2]

GUISetFont(8.5)
Opt('GUICoordMode', 1)
Local Const $Button = GUICtrlCreateButton('Ü&berprüfen', $Width - 79, 50, 80, 23, $BS_DEFPUSHBUTTON)

Local $Hight = $Sizes[3] + 50 + 23 + 9
$Width += $Sizes[2] + 10
_CenterWindow($Width, $Hight)

GUICtrlSetLimit($InputA, 11)
GUICtrlSetLimit($InputB, 7)
GUICtrlSetLimit($InputC, 7)
GUICtrlSetLimit($InputD, 1)

GUISetState(@SW_Show, $Window)

Local $Perso_ID
Local $Data[]
While 1
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      ExitLoop
    Case $Button
      $Perso_ID = GUICtrlRead($InputA) & ' ' & _
                  GUICtrlRead($InputB) & ' ' & _
                  GUICtrlRead($InputC) & ' ' & _
                  GUICtrlRead($InputD)
      If _Perso_Check($Perso_ID) Then
        $Data = _Perso_Info($Perso_ID)
        MsgBox($MB_ICONINFORMATION, 'Information', _
               'Personalnummer korrekt.' & @CRLF & @CRLF & _
               'Daten der AusweisNummer:' & @CRLF & _
               'Geburtstag:'   & @Tab        & $Data[$Geburtstag  ] & @CRLF & _
               'GeburtsMonat:' & @Tab        & $Data[$Geburtsmonat] & @CRLF & _
               'Geburtsjahr:'  & @Tab        & $Data[$Geburtsjahr ] & @CRLF & _
               'Alter:'        & @Tab & @Tab & $Data[$Alter       ] & @CRLF & _
               'Volljährig:'   & @Tab & @Tab & $Data[$Volljaehrig ] & @CRLF & _
               'Ablauftag:'    & @Tab & @Tab & $Data[$Ablauftag   ] & @CRLF & _
               'Ablaufmonat:'  & @Tab        & $Data[$Ablaufmonat ] & @CRLF & _
               'Ablaufjahr:'   & @Tab        & $Data[$Ablaufjahr  ] & @CRLF & _
               'Herkunft:'     & @Tab & @Tab & $Data[$Herkunft    ] & @CRLF & _
               'Deutscher:'    & @Tab        & $Data[$Deutscher   ] & @CRLF & _
               'ErstwohnSitz:' & @Tab        & $Data[$Erstwohnsitz], 0, $Window)
      Else
        MsgBox($MB_ICONERROR, 'Fehler', 'Personalnummer falsch!', 0, $Window)
      EndIf
  EndSwitch
WEnd

; Skriptende:
Exit 0


#Region ==============================::[ Hauptfunktionen ]::=======================================
  ; Prüfnummer überprüfen
  Func _Check_Number($Number = 0)
    Local $p = 7
    Local $Return = 0
    For $i = 1 To StringLen($Number)
      $Return += StringRight(StringMid($Number, $i, 1) * $p, 1)
      Switch $p
        Case 1
          $p = 7
        Case 3
          $p = 1
        Case 7
          $p = 3
      EndSwitch
    Next
    Return StringRight($Return, 1)
  EndFunc   ;==>_Check_Number

  ; Zweistellige JahresZahl verlängern
  Func _JahresZahl($Year)
    If StringLen($Year) = 2 Then
      If $Year < 70 Then
        $Year = '20' & $Year
      Else
        $Year = '19' & $Year
      EndIf
    EndIf
    Return $Year
  EndFunc   ;==>_JahresZahl

  ; Ist der Personalausweis gültig?
  Func _Perso_Check($ID)
    Local Const $Array = StringSplit($ID, ' ', $STR_ENTIRESPLIT + $STR_NOCOUNT)

    ; Erste Checknummer: Zählnummer und Erstwohnsitz
    If _Check_Number(StringLeft($Array[0], 9)) <> StringMid($Array[0], 10, 1) Then _
        Return False

    ; Zweite Checknummer: Geburtstag
    If _Check_Number(StringLeft($Array[1], 6)) <> StringMid($Array[1], 7, 1) Then _
        Return False

    ; Dritte Checknummer: Gültig bis
    If _Check_Number(StringLeft($Array[2], 6)) <> StringMid($Array[2], 7, 1) Then _
        Return False

    ; Ausweis abgelaufen? Wenn gewünscht, deaktivieren
    If _DateDiff('s', _JahresZahl(StringLeft($Array[2], 2   )) & '/' & _
                                  StringMid ($Array[2], 2, 2)  & '/' & _
                                  StringMid ($Array[2], 4, 2)  & ' ' & _
                                  '00:00:00', _NowCalc()) > 0 Then _
        Return False

    ; Vierte Checknummer: Die gesamte Personalausweis-ID
    If _Check_Number(StringLeft($Array[0], 10) & _
                     StringLeft($Array[1],  7) & _
                     StringLeft($Array[2],  7)) <> $Array[3] Then _
        Return False

    Return True
  EndFunc   ;==>_Perso_Check

  ; Informationen aus dem Personalausweis beziehen
  Func _Perso_Info($ID)
    Local Const $Array = StringSplit($ID, ' ', $STR_ENTIRESPLIT + $STR_NOCOUNT)

    Local $Return[$Ende] ; Array mit Daten aus AusweisNummer

    $Return[$Geburtstag  ] =             StringMid ($Array[1], 5, 2)  ; Geburtstag
    $Return[$Geburtsmonat] =             StringMid ($Array[1], 3, 2)  ; Geburtsmonat
    $Return[$Geburtsjahr ] = _JahresZahl(StringLeft($Array[1], 2   )) ; Geburtsjahr

    $Return[$Alter] = @Year - $Return[$Geburtsjahr]

    ; Hatte er schon Geburtstag?
    If (Number(@Mon )  < $Return[$Geburtsmonat]) Or _
       (Number(@Mon ) == $Return[$Geburtsmonat]  And _
        Number(@MDay)  < $Return[$Geburtstag  ]) Then _
        $Return[$Alter] -= 1

    If $Return[$Alter] < 18 Then
      $Return[$Volljaehrig] = False
    Else
      $Return[$Volljaehrig] = True
    EndIf

    $Return[$Ablauftag  ] =             StringMid ($Array[2], 5, 2)  ; Ausweis-Ablauftag
    $Return[$Ablaufmonat] =             StringMid ($Array[2], 3, 2)  ; Ausweis-Ablaufmonat
    $Return[$Ablaufjahr ] = _JahresZahl(StringLeft($Array[2], 2   )) ; Ausweis-Ablaufjahr

    $Return[$Herkunft] = StringRight($Array[0], 1)

    ; Ein Deutscher?
    If StringUpper($Return[$Herkunft]) == 'D' Then
      $Return[$Deutscher] = True
    Else
      $Return[$Deutscher] = False
    EndIf

    ; ErstwohnSitz als Nummer
    $Return[$Erstwohnsitz] = StringLeft($Array[0], 4)

    Return $Return
  EndFunc   ;==>_Perso_Info
#EndRegion ===========================::[ Hauptfunktionen ]::=======================================


#Region ==============================::[ Nebenfunktionen ]::=======================================
  Func _TextWidth($String)
    Local Const $Device = _WinAPI_GetDC($Window)
    Local Const $Script = _SendMessage($Window, $WM_GETFONT)
    Local Const $Object = _WinAPI_SelectObject($Device, $Script)
    Local Const $Dimens = _WinAPI_GetTextExtentPoint32($Device, $String)
    _WinAPI_SelectObject($Device, $Object)
    _WinAPI_ReleaseDC($Window, $Device)
    Return DllStructGetData($Dimens, 1)
  EndFunc   ;==>_TextWidth

  Func _CenterWindow($Width = -1, $Hight = -1)
    Local Const $Monitor = _WinAPI_MonitorFromWindow($Window, $MONITOR_DEFAULTTONEAREST)
    If $Width = -1 Or $Hight = -1 Then
      Local Const $Size = WinGetPos($Window)
      If $Width = -1 Then $Width = $Size[2]
      If $Hight = -1 Then $Hight = $Size[3]
    EndIf
    Local Const $Desktop = _WinAPI_GetMonitorInfo($Monitor)
    If @Error Then Return False
    Return _WinAPI_MoveWindow($Window, _
                              (DllStructGetData($Desktop[1], 3) + _
                               DllStructGetData($Desktop[1], 1) - $Width) / 2, _
                              (DllStructGetData($Desktop[1], 4) + _
                               DllStructGetData($Desktop[1], 2) - $Hight) / 2, _
                              $Width, $Hight, True)
  EndFunc   ;==>_CenterWindow
#EndRegion ===========================::[ Nebenfunktionen ]::=======================================

#NoTrayIcon

Opt('MustDeclareVars', 1)

ConsoleWrite(@CRLF & '       Zurück Fehler')
ConsoleWrite(@CRLF & '_Eins:   ' & _Eins() & '     ' & @Error)
ConsoleWrite(@CRLF & '_Zwei:   ' & _Zwei() & '     ' & @Error)
ConsoleWrite(@CRLF & @CRLF)

Exit


Func _Eins()
  Return _Drei()
EndFunc

Func _Zwei()
  Local $Return = _Drei()
  If @Error Then SetError(@Error)
  Return $Return
EndFunc

Func _Drei()
  Return SetError(1, 0, -1)
EndFunc