1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Oscar

Beiträge von Oscar

  • Passwort-Generator

    • Oscar
    • 25. Januar 2008 um 00:55

    Da wir ja grad das Thema hatten, habe ich das Script gleich noch ausgebaut zu einem voll funktionierenden Passwort-Generator.

    Damit kann man Passwörter mit einer Länge zwischen 3 und 36 Zeichen generieren lassen. Außerdem gibt es 5 verschiedene Passwort-Stärken (siehe Script).

    Spoiler anzeigen
    [autoit]


    #NoTrayIcon
    #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_icon=PassGen.ico
    #AutoIt3Wrapper_outfile=PassGen.exe
    #AutoIt3Wrapper_Allow_Decompile=n
    #AutoIt3Wrapper_Res_Description=Passwort-Generator
    #AutoIt3Wrapper_Res_Fileversion=1.0.0.2
    #AutoIt3Wrapper_Res_LegalCopyright=Thomas Stephan (oscar at elektronik-kurs dot de)
    #AutoIt3Wrapper_Res_Language=1031
    #AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
    #include<GuiSlider.au3>
    #include<Misc.au3>
    #include<String.au3>
    #include<ButtonConstants.au3>
    #include<ComboConstants.au3>
    #include<EditConstants.au3>
    #include<GUIConstantsEx.au3>
    #include<SliderConstants.au3>
    #include<StaticConstants.au3>
    Global $title = 'Passwort-Generator' ; Fenstertitel
    If _Singleton($title, 1) = 0 Then ; testen, ob das Programm bereits läuft
    MsgBox(48, $title, 'Das Programm läuft bereits!') ; Benutzer informieren
    Exit ; zweite Instanz beenden
    EndIf
    Opt('TrayMenuMode', 1) ; Tray-Standardmenü ausschalten
    Opt('TrayAutoPause', 0) ; AutoPause ausschalten

    [/autoit] [autoit][/autoit] [autoit]

    Global $key[5] ; Array deklarieren (5 = 0...4)
    $key[0] = '1234567890' ; Level 1 = nur Zahlen
    $key[1] = _StringRepeat($key[0], 4) & 'abcdefghijklmnopqrstuvwxyz' ; Level 2 = Zahlen (4fach um den prozentualen Anteil zu erhöhen) und Buchstaben (nur Kleinschreibung)
    $key[2] = $key[1] & 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' ; Level 3 = Zahlen und Buchstaben (gemischte Groß-/Kleinschreibung)
    $key[3] = $key[2] & 'öäüÖÄÜß' ; Level 4 = zusätzlich Umlaute
    $key[4] = $key[3] & '@€µ²³°!§$%&/()=<>|,.-;:_#+*~?\' & Chr(34) & Chr(39) ; Level 5 = zusätzlich alle übrigen Sonderzeichen einer deutschen Tastatur

    [/autoit] [autoit][/autoit] [autoit]

    Global $GUI = GUICreate($title, 640, 180, -1, -1) ; Fenster erstellen
    GUISetBKColor(0xAAAAAA) ; Hintergrundfarbe des Fensters
    GUISetIcon(@SystemDir & '\shell32.dll', -212) ; Icon in der Titelleiste setzen
    Global $TrayShow = TrayCreateItem('Passwort-Generator anzeigen') ; Tray-Menü erstellen
    Global $TrayExit = TrayCreateItem('Beenden') ; Tray-Menü erstellen

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateGroup('Stärke', 10, 8, 130, 55) ; Gruppe 'Stärke' erstellen
    Global $Combo = GUICtrlCreateCombo ('', 20, 30, 110, 20, $CBS_DROPDOWNLIST) ; Auswahlbox für die Passwort-Stärke
    GUICtrlSetData(-1, '1 = Sehr Leicht|2 = Leicht|3 = Mittel|4 = Hoch|5 = Sehr Hoch', '3 = Mittel') ; Werte der Auswahlbox
    GUICtrlCreateGroup ('', -99, -99, 1, 1) ; Ende der Grupppe

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateGroup('Passwortlänge', 150, 8, 480, 55) ; Gruppe 'Passwortlänge' erstellen
    Global $Slider = GUICtrlCreateSlider(160, 30, 400, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS)) ; Slider für Passwortlänge
    GUICtrlSetLimit(-1, 36, 3) ; Slider auf Werte zwischen 3 und 36 limitieren
    _GUICtrlSlider_SetTicFreq($Slider, 3) ; alle 3 Stellen ein Strich setzen
    _GUICtrlSlider_SetPageSize($Slider, 3) ; bei Klick vor oder hinter dem aktuellen Wert, um 3 Stellen weiterspringen
    _GUICtrlSlider_SetPos($Slider, 18) ; Slider auf den Wert 18 setzen
    Global $Range = GUICtrlCreateLabel('18', 580, 30, 40, 20, $SS_CENTER) ; Die Anzeige für die Passwortlänge (Startwert=18)
    GUICtrlSetFont(-1, 12, 400, 0, 'Courier New Bold') ; Schriftart und -größe der Anzeige
    GUICtrlSetBKColor(-1, 0x000000) ; Hintergrundfarbe der Anzeige
    GUICtrlSetColor(-1, 0xFFFF00) ; Vordergrundfarbe der Anzeige
    GUICtrlCreateGroup ('', -99, -99, 1, 1) ; Ende der Grupppe

    [/autoit] [autoit][/autoit] [autoit]

    Global $Button = GUICtrlCreateButton('Start', 120, 70, 90, 25, $BS_DEFPUSHBUTTON) ; Startbutton erstellen
    GUICtrlSetFont(-1, 10, 400, 0, 'Arial') ; Schriftart und -größe des Buttons

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateGroup('Passwort', 10, 102, 620, 65) ; Gruppe 'Passwort' erstellen
    Global $Code = GUICtrlCreateInput('', 20, 120, 600, 40, $ES_READONLY) ; Ausgabefeld für das Passwort
    GUICtrlSetFont(-1, 20, 400, 0, 'Courier New Bold') ; Schriftart und -größe des Ausgabefeldes
    GUICtrlCreateGroup ('', -99, -99, 1, 1) ; Ende der Grupppe

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlSetState($Code, $GUI_FOCUS) ; den Focus auf das Ausgabefeld, damit man das Passwort einfach per Kontextmenü ('Kopieren') in die Zwischenablage packen kann
    Passwort() ; Funktion aufrufen, damit beim Programmstart bereits ein Passwort angezeigt wird
    GUISetState() ; GUI-Fenster anzeigen

    [/autoit] [autoit][/autoit] [autoit]

    While 1 ; MessageLoop-Schleife
    Switch GUIGetMsg() ; Anhand des eingetretenen GUI-Ereignisses die entsprechenden Befehle ausführen
    Case $Combo ; Benutzer hat die Passwort-Stärke geändert
    Passwort() ; Funktion Passwort() aufrufen
    Case $Slider ; Benutzer hat den Slider bewegt
    GUICtrlSetData($Range, GUICtrlRead($Slider)) ; Sliderwert auslesen und in das Anzeigefeld schreiben
    Passwort() ; Funktion Passwort() aufrufen
    Case $Button ; Benutzer hat auf den 'Start'-Button geklickt
    Passwort() ; Funktion Passwort() aufrufen
    Case $GUI_EVENT_MINIMIZE ; Benutzer hat auf Minimieren geklickt
    Opt('TrayIconHide', 0) ; Tray-Menü anzeigen
    TraySetIcon(@SystemDir & '\shell32.dll', -212) ; Icon für Tray-Menü setzen
    GUISetState(@SW_HIDE, $GUI) ; Fenster verstecken
    While 2 ; Tray-Menü-Schleife
    Switch TrayGetMsg() ; Anhand des eingetretenen Tray-Ereignisses die entsprechenden Befehle ausführen
    Case $TrayShow ; wurde 'Anzeigen' aufgerufen, dann...
    Opt('TrayIconHide', 1) ; Tray-Menü wieder verstecken
    GUISetState(@SW_SHOW, $GUI) ; Fenster anzeigen
    GUISetState(@SW_RESTORE, $GUI) ; und wiederherstellen (minimieren rückgängig machen)
    ExitLoop ; Tray-Menü-Schleife verlassen
    Case $TrayExit ; Benutzer hat 'Beenden' ausgewählt
    Exit ; Programm beenden
    EndSwitch
    WEnd
    Case $GUI_EVENT_CLOSE ; Benutzer hat auf 'X' geklickt oder 'ESC' gedrückt
    Exit ; Programm beenden
    EndSwitch
    Wend

    [/autoit] [autoit][/autoit] [autoit]

    Func Passwort()
    Local $choice = Number(StringLeft(GUICtrlRead($Combo), 1)) ; den 1. Buchstaben von links (Zahl) der Combobox (Passwort-Stärke) auslesen und als $key-Auswahl speichern
    Local $i, $pass = '' ; Passwort = Leerstring
    For $i = 1 To Number(GUICtrlRead($Range)) ; Schleife von 1 bis eingestellter Passwortlänge
    $pass &= StringMid($key[$choice-1], Random(1, StringLen($key[$choice-1]), 1), 1) ; dem Passwort ein zufälliges Zeichen aus dem ausgewählten Stärkestring hinzufügen
    Next ; Schleife fortsetzen
    GUICtrlSetData($Code, $pass) ; das generierte Passwort in das Ausgabefeld schreiben
    GUICtrlSetState($Code, $GUI_FOCUS) ; den Focus auf das Ausgabefeld, damit man das Passwort einfach per Kontextmenü ('Kopieren') in die Zwischenablage packen kann
    EndFunc

    [/autoit]

    Edit ( 29.10.08 :( Script angepasst, sodass es auch mit der aktuellen AutoIt-Version funktioniert.

  • wahrlos Zeichen aus String lesen

    • Oscar
    • 24. Januar 2008 um 23:28

    Mir war grad langweilig und so habe ich das Script mal erstellt:

    Spoiler anzeigen
    [autoit]


    #include <String.au3>
    #include <array.au3>
    #include <File.au3>
    #include <GUIConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $key[4]
    $key[0] = "1234567890abcdefghijklmnopqrstuvwxyz"
    $key[1] = "1234567890abcdefghijklmnopqrSTUVWXYZ"
    $key[2] = "1234567890abcdefghijklmnOPQRSTUVWXYZ#?&%$§!{[]})"
    $key[3] = "1234567890abcdefghijklmNOPQRSTUVWXYZ#?&%$§!{[]})çãáÿÍõÇÔÊÂâÕ<>|)"

    [/autoit] [autoit][/autoit] [autoit]

    GUICreate("Passwort-Generator", 420, 120, -1, -1)
    $Combo = GUICtrlCreateCombo ("", 10, 10, 120, 20, $CBS_DROPDOWNLIST)
    GUICtrlSetData(-1,"1 = Leicht|2 = Mittel|3 = Hoch|4 = Sehr Hoch","1 = Leicht")
    $Edit2 = GUICtrlCreateInput("12", 10, 40, 80, 20)
    $Button = GUICtrlCreateButton("Start", 120, 40, 60, 20, $BS_DEFPUSHBUTTON)
    GUICtrlSetState($Edit2, $GUI_FOCUS)
    $Code = GUICtrlCreateInput("", 10, 70, 400, 20, $ES_READONLY)
    GUISetState ()

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $msg = GUIGetMsg()
    If $msg = $Button Then Passwort()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    Wend

    [/autoit] [autoit][/autoit] [autoit]

    Func Passwort()
    Local $auswahl = Number(StringLeft(GUICtrlRead($Combo), 1))
    Local $anzahl = Number(GUICtrlRead($Edit2))
    Local $pass = ""
    For $i = 1 To $anzahl
    $pass &= StringMid($key[$auswahl-1], Random(1, StringLen($key[$auswahl-1]), 1), 1)
    Next
    GUICtrlSetData($Code, $pass)
    EndFunc

    [/autoit]

    Combo zur Auswahl, Eingabefeld für die Anzahl der Zeichen und auf 'Start' klicken. Jeder weitere Klick auf 'Start' generiert ein neues Passwort.

  • _arryamax

    • Oscar
    • 24. Januar 2008 um 22:48

    Eine andere Variante:

    [autoit]


    #include <String.au3>
    #include <array.au3>
    #include <File.au3>

    [/autoit][autoit][/autoit][autoit]

    Global $string = _FileListToArray(@ScriptDir, "*.txt")
    Global $aTmp[1], $i
    _ArrayDisplay($string, "Array", 10)
    For $i = 1 To $string[0]
    $aTmp = _StringBetween($string[$i], 'bk', '.txt')
    If IsArray($aTmp) Then $string[$i] = $aTmp[0]
    Next
    MsgBox(64,"Min",_ArrayMin($string, 1, 1))
    MsgBox(64,"Max",_Arraymax($string, 1, 1))

    [/autoit]
  • Zwei parallele Schleifen

    • Oscar
    • 24. Januar 2008 um 14:43

    Ich dachte schon, Du strebst eine sekundengenaue Verarbeitung an. ;)

    Wenn Du nur willst, dass eine Funktion um 7:00 Uhr gestartet wird, dann teste doch zusätzlich, ob sie bereits gestartet wurde.
    Wenn es also bereits z.B. 7:00:05 ist und Deine Funktion noch nicht gestartet wurde, dann starte sie. Das läßt sich doch einfach mit einer Prüfvariablen erledigen.

  • Zwei parallele Schleifen

    • Oscar
    • 24. Januar 2008 um 09:12
    Zitat von Davor

    Micha_he: Sowas habe ich mir auch gedacht, aber was wenn die Schleife um 07:00 Uhr nicht durchlaufen wird, sondern bspw. eine Sekunde später/früher? Da war mir das Risiko zu hoch.

    'Eine Sekunde später/früher?'
    Da fehlt jetzt aber der Ironie-Smily, oder?
    Deine Programme laufen unter Windows!

  • Zwei parallele Schleifen

    • Oscar
    • 23. Januar 2008 um 22:25

    Diese Möglichkeit besteht auch, wenn das mit dem parallelen Abarbeiten nicht so genau genommen wird. Wenn also die 1. Funktion so lange ruhen kann, wie die 2. Funktion für die Abarbeitung der Daten braucht, dann kann man das so vereinfachen. Aber vielleicht beschreibt Davor mal genauer, was er vorhat, dann kann man besser helfen.

  • nach eingabe in einer GUICtrlCreateInput () , nach Enter drücken soll ein button fokusiert und ausgeführt werden

    • Oscar
    • 23. Januar 2008 um 19:13
    Zitat von TOMTOM25m

    Ich will das Passwort eingeben und auf ENTER drücken damit das Programm startet.

    Dann solltest Du die GUI-Elemente mal in die richtige Reihenfolge bringen, dann klappt das auch mit $BS_DEFPUSHBUTTON.

    [autoit]


    #include <GUIConstants.au3>

    [/autoit][autoit][/autoit][autoit]

    $AWS_START = GUICreate("V93130AWS Starter", 240, 187, 1181, 512, BitOR($WS_CAPTION, $WS_POPUP, $WS_BORDER, $WS_CLIPSIBLINGS))
    GUISetBkColor(0x0000FF)
    $AWSUSR = GUICtrlCreateLabel("Username Eingeben", 15, 5, 100, 17)
    $AWS_USER = GUICtrlCreateInput(@LogonDomain & "\" & @UserName, 15, 29, 200, 21)
    $AWSP = GUICtrlCreateLabel("Passwort Eingeben", 17, 64, 95, 17)
    $AWS_PW = GUICtrlCreateInput("", 15, 89, 200, 21, BitOR($ES_PASSWORD, $ES_AUTOHSCROLL))
    $Start = GUICtrlCreateButton("Start", 65, 125, 101, 26, $BS_DEFPUSHBUTTON)
    GUICtrlSetState($AWS_PW, $GUI_FOCUS)
    GUISetState()

    [/autoit][autoit][/autoit][autoit]

    While 1
    $msg = GUIGetMsg()
    Select
    Case $msg = $Start
    MsgBox(0, 'Testing', 'Button was pressed')
    exit
    EndSelect
    Wend

    [/autoit]
  • Textfeld

    • Oscar
    • 23. Januar 2008 um 15:21

    Zum debuggen kann man auch eine MsgBox() zweckentfremden.

  • nach eingabe in einer GUICtrlCreateInput () , nach Enter drücken soll ein button fokusiert und ausgeführt werden

    • Oscar
    • 23. Januar 2008 um 15:19

    Äh...wozu?

    Der Fokus ist da, wo etwas eingegeben wird. Das ist doch richtig. :rolleyes:

  • Button ist nicht transparent

    • Oscar
    • 23. Januar 2008 um 13:50

    Was ich mit 'Spaghetti-Code' meine:

    1. Du springst wahllos von einer Function in die nächste, ohne das die vorherige jemals beendet würde.
    2. Der Programmcode von If...Then, For...Next, While...WEnd, Func...EndFunc, usw. ist nicht eingerückt.
    3. Die GUI-Elemente werden ebenfalls erst erstellt, kurz bevor Du sie benutzt.
    4. In jeder Function gibt es eine MessageLoop-Schleife.
    5. Die #include-Anweisungen sind fehlerhaft (liegt hier am Forum. Musst beim einfügen von AutoIt-Programmcode in den Quellcode-Modus wechseln)
    6. Einige Programmteile werden nie ausgeführt, weil das Script dort nie hinkommt.
    usw...

    Gerade Punkt 1 ist dabei das 'Todesurteil', weil eine Function nicht als GOTO missbraucht werden soll.
    Funktionen sind Unterprogramm-Aufrufe. Bei jedem Funktionsaufruf wird die Rücksprungadresse intern abgespeichert. Wird in dem Script irgendwann EndFunc oder Return erreicht, so holt sich der Interpreter diese Rücksprungadresse und kehrt ins Hauptprogramm zurück. Wird aber EndFunc bzw. Return niemals erreicht, weil man (wie Du das machst) ständig von einer Funktion in die nächste springt, so läuft irgendwann der interne Speicher über und Du erhälst eine Fehlermeldung (das Script beendet sich).
    Das heißt: Dein gesamtes Script wird, wenn überhaupt, nur sehr unzuverlässig laufen.
    Lerne erstmal strukturiert zu programmieren. Überlege Dir genau, was soll in der und der Funktion ausgeführt werden, rufe die einzelnen Funktionen vom Hauptprogramm aus auf und (vor allem) kehre dorthin wieder zurück.
    Es ist außerdem ein guter Stil, alle GUI-Fenster am Anfang des Scripts zu erstellen und diese erst bei Bedarf mit GUISetState(@SW_SHOW, $GUI) sichtbar zu machen.

    Entschuldige diese harte Kritik, aber solch ein Script wird Dir vermutlich niemand debuggen, weil es einem neuschreiben gleichkommt.

  • nach eingabe in einer GUICtrlCreateInput () , nach Enter drücken soll ein button fokusiert und ausgeführt werden

    • Oscar
    • 23. Januar 2008 um 11:41

    Beim Start-Button musst Du folgendes einfügen:

    [autoit]


    $Start = GUICtrlCreateButton("Start", 65, 125, 101, 26, $BS_DEFPUSHBUTTON)

    [/autoit]
  • Zwei parallele Schleifen

    • Oscar
    • 23. Januar 2008 um 11:36

    Das kannst Du entweder per AdlibEnable() oder per TimerInit() und TimerDiff() lösen.

  • Button ist nicht transparent

    • Oscar
    • 23. Januar 2008 um 10:13

    Sorry, dass ich das sagen muss, aber solch einen 'Spaghetti-Code' kann man nur sehr schwer verstehen. Es fehlt einfach die Motivation diese (fast 500) Zeilen durchzugehen. Reduzier Dein Problem auf ein kurzes Beispiel, dann wird Dir sicher schneller geholfen werden. :)

  • Dos Programm mit drei Parametern automatisieren

    • Oscar
    • 23. Januar 2008 um 09:51

    Oder so:

    [autoit]


    #Include <File.au3>
    #Include <Array.au3>
    $FileList = _FileListToArray('c:\inv_Dateien', '*.out', 1)
    If @Error Then
    MsgBox (0,'','No Files/Folders Found.')
    Exit
    EndIf
    _ArrayDisplay($FileList, '$FileList')

    [/autoit]
  • dyndns & Buffalo-Linkstation

    • Oscar
    • 23. Januar 2008 um 09:43

    Das uploaden der Bilder etc. auf den FTP-Server kannst Du am besten mit einem FTP-Programm machen oder, wie ich, mit dem TotalCommander. :)

    Das Script zum downloaden könnte so aussehen:

    [autoit]


    $user = 'autoit' ; Benutzername
    $pass = 'autoit1' ; Passwort

    [/autoit][autoit][/autoit][autoit]

    $datei = 'test.jpg' ; die Datei, die gedownloadet werden soll

    [/autoit][autoit][/autoit][autoit]

    $ziel = 'bla.jpg' ; wie die Datei dann auf dem lokalen Rechner heißen soll

    [/autoit][autoit][/autoit][autoit]

    $size = InetGetSize('ftp://' & $user & ':' & $pass & '@e2m2.dyndns.org/' & $datei) ; Dateigröße holen

    [/autoit][autoit][/autoit][autoit]

    $r = InetGet('ftp://' & $user & ':' & $pass & '@e2m2.dyndns.org/' & $datei, $ziel, 1, 1) ; Datei downloaden (Script nicht anhalten)
    SplashTextOn('Download', 'test', 320, 80)
    While @InetGetActive
    ControlSetText('Download', '', 'Static1', 'Download = ' & @InetGetBytesRead & ' von ' & $size & ' Bytes')
    Sleep(20)
    Wend
    SplashOff()
    MsgBox(0, 'Download', 'Download erfolgreich')

    [/autoit]
  • SB v X.0

    • Oscar
    • 20. Januar 2008 um 09:33

    Version: 3.4.2.5

    - Dialog für 'Netzlaufwerk verbinden' erweitert. Man kann jetzt mehrere Profile anlegen, in
    denen Pfad, Benutzername und Passwort gespeichert werden.

    Screenshot:
    bild2.gif

    P.S.: Der Eintrag ist nur zum testen. Den gibt es nicht wirklich. :P

    Dateien

    SpaceBar_3.4.2.5_2008-01-20.zip 578,66 kB – 636 Downloads screen2.png 19,68 kB – 0 Downloads
  • SB v X.0

    • Oscar
    • 19. Januar 2008 um 08:58

    Änderungen:

    - 'Netzlaufwerk verbinden' jetzt mit eigenem GUI-Fenster

    Version: 3.4.2.3

    Dateien

    SpaceBar_3.4.2.3_2008-01-19.zip 576,21 kB – 501 Downloads
  • a hug for huggy

    • Oscar
    • 18. Januar 2008 um 22:27

    Auch von mir: Alles Gute zum Geburtstag! Scite.bmp

    Wir haben ja am gleichen Tag Geburtstag. Auch wenn ich mehr als zweieinhalb mal so alt bin. :D

  • Happy Birthday Oscar

    • Oscar
    • 18. Januar 2008 um 22:20

    Huch!
    Da wäre mir doch beinahe beim programmieren dieser Thread entgangen. :rolleyes:

    Vielen Dank für die vielen guten Wünsche.

    @xeno: Ja, wenn man erstmal die 4 vorne stehen hat...

    Geburtstagsfeier findet dann erst morgen statt, wenn alle Freunde und Bekannte Zeit haben. :D

  • SB v X.0

    • Oscar
    • 18. Januar 2008 um 21:53

    Neue Version!

    Änderungen:

    - Netzlaufwerk trennen

    - Netzlaufwerk verbinden

    Version: 3.4.2.2

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™