Beiträge von Bitnugger

;-- TIME_STAMP   2020-05-01 20:50:32

#AutoIt3Wrapper_UseX64=y ; <<<=== Change it to y/n and press <Alt + F5> to start the patched Beta!

;~ https://autoit.de/thread/86867-msgbox-verlangsamt-den-skriptablauf-unter-win-10/?postID=699015#post699015
;~ https://www.autoitscript.com/forum/topic/202270-script-becomes-way-slower-after-a-msgbox-moved/
;~ https://www.autoitscript.com/autoit3/files/beta/autoit/win10slow/

ConsoleWrite(StringFormat(';~ %-55s %-10s\n', @AutoItExe, @AutoItVersion))

_Test(False, 0)
_Test(False, 1)
_Test(True, 0)
_Test(True, 1)

Func _Test($bMsgBox = False, $iGUIOnEventMode = 0)
    Local Static $iMsgBox = False
    Local $x = 0, $hTimer = TimerInit()
    AutoItSetOption('GUIOnEventMode', $iGUIOnEventMode)
    If $bMsgBox And $iMsgBox = False Then
        $iMsgBox = True
        MsgBox(0, "", TimerDiff($hTimer), 1, WinGetHandle('[ACTIVE]'))
    EndIf
    For $i = 1 To 500000
        $x += 1
    Next
    ConsoleWrite(StringFormat(';~ Diff = %15s, GUIOnEventMode = %i, $iMsgBox = %i\n', TimerDiff($hTimer), $iGUIOnEventMode, $iMsgBox))
    If $iGUIOnEventMode Then AutoItSetOption('GUIOnEventMode', 0)
EndFunc

;~ C:\Program Files (x86)\AutoIt3\autoit3.exe              3.3.14.5
;~ Diff =        121.6931, GUIOnEventMode = 0, $iMsgBox = 0
;~ Diff =         277.118, GUIOnEventMode = 1, $iMsgBox = 0
;~ Diff =       1839.2242, GUIOnEventMode = 0, $iMsgBox = 1
;~ Diff =        953.5653, GUIOnEventMode = 1, $iMsgBox = 1

;~ C:\Program Files (x86)\AutoIt3\autoit3_x64.exe          3.3.14.5
;~ Diff =        113.2212, GUIOnEventMode = 0, $iMsgBox = 0
;~ Diff =        264.4404, GUIOnEventMode = 1, $iMsgBox = 0
;~ Diff =       1760.7921, GUIOnEventMode = 0, $iMsgBox = 1
;~ Diff =        843.8279, GUIOnEventMode = 1, $iMsgBox = 1

;;~ C:\Program Files (x86)\AutoIt3\Beta\autoit3.exe         3.3.15.1
;~ Diff =         99.0429, GUIOnEventMode = 0, $iMsgBox = 0
;~ Diff =        262.1309, GUIOnEventMode = 1, $iMsgBox = 0
;~ Diff =       1170.7505, GUIOnEventMode = 0, $iMsgBox = 1
;~ Diff =        256.9184, GUIOnEventMode = 1, $iMsgBox = 1

;~ C:\Program Files (x86)\AutoIt3\Beta\autoit3_x64.exe     3.3.15.1
;~ Diff =         94.2364, GUIOnEventMode = 0, $iMsgBox = 0
;~ Diff =         251.337, GUIOnEventMode = 1, $iMsgBox = 0
;~ Diff =       1172.7595, GUIOnEventMode = 0, $iMsgBox = 1
;~ Diff =        246.0969, GUIOnEventMode = 1, $iMsgBox = 1

import os, nimbass/bass # https://github.com/genotrance/nimbass

discard BASS_Init(cint(-1), cast[DWORD](44100), cast[DWORD](0), cast[DWORD](0), nil)
discard BASS_SetVolume(0.1)

var 
    iActive: DWORD
    iLen: QWORD
    iSeconds, iSecondsNow: cdouble
    sMp3File = ""

if paramCount() > 0:
    echo paramCount(), " ", paramStr(1)
    sMp3File = paramStr(1)
else:
    sMp3File = "F:/Audio/MP3/CD/Top 3000-4ever/Top 3000-4ever 0401-0500/0458. Albert Hammond - The Free Electric Band (1973).mp3"

#[
    So funktioniert es nicht!
    let sMp3File = "F:\Audio\MP3\CD\Top 3000-4ever\Top 3000-4ever 0401-0500\0458. Albert Hammond - The Free Electric Band (1973).mp3"

    So aber...
    let sMp3File = "F:/Audio/MP3/CD/Top 3000-4ever/Top 3000-4ever 0401-0500/0458. Albert Hammond - The Free Electric Band (1973).mp3"
    
    let sMp3File = "0458. Albert Hammond - The Free Electric Band (1973).mp3"
]#

let cMp3File: cstring = sMp3File
let hChannel = BASS_StreamCreateFile(false, cMp3File, 0, 0, BASS_STREAM_PRESCAN or BASS_STREAM_AUTOFREE)
discard BASS_ChannelPlay(hChannel, false)
iLen = BASS_ChannelGetLength(hChannel, BASS_POS_BYTE)
iSeconds = BASS_ChannelBytes2Seconds(hChannel, iLen)

while true:
    iActive = BASS_ChannelIsActive(hChannel)
    if iActive != BASS_ACTIVE_PLAYING: break
    iLen = BASS_ChannelGetPosition(hChannel, BASS_POS_BYTE)
    iSecondsNow = BASS_ChannelBytes2Seconds(hChannel, iLen)
    echo "Play: " & $int(iSecondsNow) & " / " & $int(iSeconds)
    sleep(1000)
discard BASS_ChannelStop(hChannel)
discard BASS_Free()

;-- TIME_STAMP   2020-04-28 23:21:10   v 0.1

Opt('MustDeclareVars', 1)

#include <MsgBoxConstants.au3>
#include <APIRegConstants.au3>
#include <Array.au3>
#include <Word.au3>
#include <WinAPIShPath.au3>
#include <WinAPIReg.au3>

Global $g_aPicExt = ['.ani', '.awd', '.bmp', '.dib', '.cam', '.cdr', '.cur', '.clp', '.dcm', '.acr', '.dcx', '.djvu', '.iw44', '.emf', '.eps', '.fpx', '.g3', '.gif', '.icl', '.ico', '.iff', '.lbm', '.img', '.jpg', '.jpeg', '.kdc', '.ldf', '.lwf', '.pbm', '.pcd', '.pcx', '.pgm', '.png', '.ppm', '.psd', '.psp', '.ras', '.sun', '.rle', '.sff', '.sfw', '.sgi', '.rgb', '.tga', '.svg', '.tbn', '.tif', '.thm']

_Main()

Func _Main()
    ; PIC_To_PDF [/F:FileName.jpg | /L:ListName.txt] [/S[:SaveAs.pdf]]
    ; Examples:
    ; PIC_To_PDF /F:FileName.bmp
    ; PIC_To_PDF /F:FileName.jpg /S
    ; PIC_To_PDF /F:FileName.png /S:SaveAs.pdf
    ; PIC_To_PDF /L:ListName.txt /S
    ; PIC_To_PDF /L:ListName.txt /S:SaveAs.pdf
    Local $aList[0], $aBadFiles[0], $sListName, $sFileName, $sSaveAs, $sExtension
    If $CMDLINE[0] Then
        For $i = 1 To $CMDLINE[0]
            Select
                Case $CMDLINE[$i] = '/?'
                    Exit MsgBox(0x40000, @ScriptName & ' Help', _
                            'Switches are:' & @CRLF _
                             & @CRLF & 'PIC_To_PDF [/F:FileName.jpg | /L:ListName.txt] [/S[:SaveAs.pdf]]' _
                             & @CRLF & @TAB & 'Convert any PIC/s to PDF')
                Case StringLeft($CMDLINE[$i], 3) = '/F:'
                    $sFileName = StringMid($CMDLINE[$i], 4)
                    If Not FileExists($sFileName) Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                            "Error : " & $sFileName & " not found!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
                    ReDim $aList[1]
                    $aList[0] = $sFileName
                Case StringLeft($CMDLINE[$i], 3) = '/L:'
                    $sListName = StringMid($CMDLINE[$i], 4)
                    If Not FileExists($sListName) Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                            "Error : " & $sListName & " not found!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
                    $aList = FileReadToArray($sListName)
                    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                            "Error : " & $sListName & " is empty!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
                    For $j = @extended - 1 To 0 Step -1
                        _ArraySearch($g_aPicExt, _WinAPI_PathFindExtension($aList[$j]))
                        If @error Then
                            _ArrayAdd($aBadFiles, $aList[$j])
                            _ArrayDelete($aList, $j)
                        EndIf
                    Next
                Case StringLeft($CMDLINE[$i], 2) = '/S'
                    $sSaveAs = (StringMid($CMDLINE[$i], 3, 1) = ':' ? StringMid($CMDLINE[$i], 4) : InputBox('PIC_To_PDF', 'Save as: ', _WinAPI_PathRenameExtension($aList[0], '.pdf')))
                    If $sSaveAs = '' Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                            "Error : InputBox for SaveAs name canceled!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
                    $sExtension = _WinAPI_PathFindExtension($sSaveAs)
                    $sSaveAs = $sExtension = '.pdf' ? $sSaveAs : $sExtension ? _WinAPI_PathRenameExtension($sSaveAs, '.pdf') : $sSaveAs & '.pdf'
                    If FileExists($sSaveAs) Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                            "Error : " & $sSaveAs & " already exists!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
                Case Else
                    MsgBox(0x40000, 'PIC_To_PDF', _
                            'Incorrect switch used' & @CRLF & _
                            'Command used:' & @CRLF & $CMDLINERAW & @CRLF & _
                            @CRLF & 'Use /? for the switches available.')
                    Exit
            EndSelect
        Next
        If $sSaveAs = '' Then $sSaveAs = InputBox('PIC_To_PDF', 'Save as: ', _WinAPI_PathRenameExtension($aList[0], '.pdf'))
        If $sSaveAs = '' Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                            "Error : InputBox for SaveAs name canceled!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
        If UBound($aList) Then _PIC_To_PDF($aList, $sSaveAs)
        If UBound($aBadFiles) Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                "Error : This files are ignored - no PICs!" & @CRLF & _ArrayToString($aBadFiles, ', ') & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    EndIf
EndFunc   ;==>_Main

Func _PIC_To_PDF(ByRef $_aList, $_sSaveAs)
    ConsoleWrite('$_sSaveAs = ' & $_sSaveAs & @CRLF)
    Local $aProcessList = ProcessList('winword.exe')
    If @error Or $aProcessList[0][0] = 0 Then
        Local $sWord = _WinAPI_AssocQueryString('.docx', $ASSOCSTR_EXECUTABLE)
        If @error Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                "Error : WINWORD.EXE not found!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
        ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $sWord --> " & $sWord & @LF)
        Local $iPID = Run(StringFormat('"%s" /Automation -Embedding', $sWord))
        ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $iPID --> " & $iPID & @LF)
        If Not $iPID Or Not WinWait('[TITLE:Word; CLASS:OpusApp]', '', 5) Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF", _
                "Error : Can't start WINWORD.EXE!" & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    EndIf

    ; Create application object
    Local $oWord = _Word_Create(False) ; window will not be visible
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF: _Word_DocAdd", _
            "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

    ; Add a new empty document
    Local $oDoc = _Word_DocAdd($oWord)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF: _Word_DocAdd", "Error creating a new Word document." _
             & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    ; https://docs.microsoft.com/de-de/office/vba/api/overview/word
    ; https://docs.microsoft.com/en-us/office/vba/api/word.wdpapersize
    ; https://docs.microsoft.com/de-de/office/vba/api/word.pagesetup.papersize
    Local Const $wdPaperA4 = 7 ; A4 dimensions.

    With $oDoc.PageSetup
        .TopMargin    = 0 ;CentimetersToPoints(1)
        .BottomMargin = 0 ;CentimetersToPoints(1)
        .LeftMargin   = 0 ;CentimetersToPoints(1)
        .RightMargin  = 0 ;CentimetersToPoints(1)
        .PaperSize    = $wdPaperA4
;~         .orientation  = $wdOrientLandscape ; Hochformat
        .orientation  = $wdOrientPortrait ; Querformat
    EndWith

    ; Insert a picture in the document
    Local $oShape
    For $i = UBound($_aList) - 1 To 0 Step -1
        $oShape = _Word_DocPictureAdd($oDoc, $_aList[$i])
        If @error Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF: _Word_DocPictureAdd", _
                "Error adding the picture " & $_aList[$i] & " to the document" & @CRLF & " @error = " & @error & ", @extended = " & @extended)
        $oShape.Height = CentimetersToPoints(29.7) ; DIN A4
        $oShape.Width = CentimetersToPoints(21.0)
    Next

    ; Export the complete document as PDF
    _Word_DocExport($oDoc, $_sSaveAs, $WdExportFormatPDF)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "PIC_To_PDF: _Word_DocExport", "Error exporting the document." & _
            @CRLF & "@error = " & @error & ", @extended = " & @extended)

    ; Close a Word document
;~     _Word_DocClose($oDoc)

    ; Closes all documents, the Word application and removes the object reference to it
    _Word_Quit($oWord)
EndFunc   ;==>_PIC_To_PDF

Func CentimetersToPoints($iValue)
    Return ($iValue * 28.35)
EndFunc   ;==>CentimetersToPoints

;-- TIME_STAMP   2020-04-28 20:41:42   v 0.1

#include <MsgBoxConstants.au3>
#include <Word.au3>

Opt('MustDeclareVars', 1)

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Add a new empty document
Local $oDoc = _Word_DocAdd($oWord)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; https://docs.microsoft.com/en-us/office/vba/api/word.wdpapersize
Local Const $wdPaperA4 = 7 ; A4 dimensions.

With $oDoc.PageSetup
    .TopMargin    = 0 ;CentimetersToPoints(1)
    .BottomMargin = 0 ;CentimetersToPoints(1)
    .LeftMargin   = 0 ;CentimetersToPoints(1)
    .RightMargin  = 0 ;CentimetersToPoints(1)
    .PaperSize    = $wdPaperA4
;~     .orientation  = $wdOrientLandscape ; Hochformat
    .orientation  = $wdOrientPortrait ; Querformat
EndWith

; Insert a picture
;~ Local $oShape = _Word_DocPictureAdd($oDoc, 'm:\_Word_DocPictureAdd\Lohnabrechnung_RS_02.2020.jpg')
Local $oShape = _Word_DocPictureAdd($oDoc, @ScriptDir & '\Feb_2020_OK.jpg')
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error adding the picture to the document" & @CRLF & " @error = " & @error & ", @extended = " & @extended)
$oShape.Height = CentimetersToPoints(29.7) ; DIN A4
$oShape.Width = CentimetersToPoints(21.0)

MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Picture has successfully been added after word 4 in the document.", 2)

; Export the complete document as PDF
;~ _Word_DocExport($oDoc, 'm:\_Word_DocPictureAdd\Lohnabrechnung_RS_02.2020.pdf', $WdExportFormatPDF)
_Word_DocExport($oDoc, @ScriptDir & '\Feb_2020_OK.pdf', $WdExportFormatPDF)
_Word_DocClose($oDoc)

Func CentimetersToPoints($iValue)
    Return ($iValue * 28.35)
EndFunc   ;==>CentimetersToPoints

;-- TIME_STAMP   2020-04-28 18:31:03   v 0.1

#include <MsgBoxConstants.au3>
#include <Word.au3>

Opt('MustDeclareVars', 1)

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Add a new empty document
Local $oDoc = _Word_DocAdd($oWord)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Insert a picture after the fourth word of the document
Local $oShape = _Word_DocPictureAdd($oDoc, @ScriptDir & '\Feb_2020_OK.jpg')
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error adding the picture to the document" & @CRLF & " @error = " & @error & ", @extended = " & @extended)
$oShape.ScaleWidth = 100
$oShape.ScaleHeight = 100
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Picture has successfully been added after word 4 in the document.")

; Export the complete document as PDF
_Word_DocExport($oDoc, @ScriptDir & '\Feb_2020_OK.pdf', $WdExportFormatPDF)
_Word_DocClose($oDoc)