Beiträge von Bitnugger

;-- TIME_STAMP   2019-10-24 16:14:38   v 0.1

#RequireAdmin
#include <Array.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPISys.au3>

Global $g_hGUI = GUICreate("", 483, 165, 192, 114, -1, BitOR($WS_EX_ACCEPTFILES, $WS_EX_WINDOWEDGE))
Global $g_idPathIn = GUICtrlCreateInput("", 16, 32, 441, 21)
Global $g_aDragQueryFiles
GUICtrlSetState(-1, $GUI_ACCEPTFILES)
Global $g_idFileMenu = GUICtrlCreateMenu('Datei')
Global $g_idFileMenuItem_LoadDatabase = GUICtrlCreateMenuItem('Datenbank laden', $g_idFileMenu)

Global $g_idMainGUI_ESC_Dummy   = GUICtrlCreateDummy()
Global $g_aAccelKeys[1][2] = [['{ESC}', $g_idMainGUI_ESC_Dummy]]
GUISetState(@SW_SHOW)

_WinAPI_ChangeWindowMessageFilterEx($g_hGUI, $WM_DROPFILES, $MSGFLT_ALLOW)
_WinAPI_ChangeWindowMessageFilterEx($g_hGUI, $WM_COPYDATA, $MSGFLT_ALLOW)
_WinAPI_ChangeWindowMessageFilterEx($g_hGUI, $WM_COPYGLOBALDATA, $MSGFLT_ALLOW)
GUIRegisterMsg($WM_DROPFILES, "WM_DROPFILES")

; Sent when the user selects a command item from a menu, when a control sends a notification message to its parent window, or when an accelerator keystroke is translated.
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func WM_DROPFILES($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $ilParam
    Switch $iMsg
        Case $WM_DROPFILES
            $g_aDragQueryFiles = _WinAPI_DragQueryFileEx($iwParam)
            If Not @error Then
                ConsoleWrite('> WM_DROPFILES $g_aDragQueryFiles:' & @CRLF & _ArrayToString($g_aDragQueryFiles, @CRLF) & @CRLF)
            Else
                ConsoleWrite('! WM_DROPFILES $g_aDragQueryFiles:'& @LF & "!@ " & @TAB & "#Error: " & @error & @LF)
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_DROPFILES

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $lParam
    $iIDFrom = _WinAPI_LoWord($wParam)
    $iCode = _WinAPI_HiWord($wParam)
    
    Switch $hWndFrom
        Case 0 ; Menu or Accelerator key/s has been pressed
            Switch $iCode
                Case 0 ; Menu
                    Switch $iIDFrom ; Menu identifier (IDM_*)
                        Case $g_idFileMenuItem_LoadDatabase
                            ConsoleWrite('- WM_COMMAND Case $g_idFileMenuItem_LoadDatabase' & @CRLF)
                        Case Else
;~                             ...
                    EndSwitch
                Case 1 ; Accelerator key/s has been pressed
                    Switch $iIDFrom ; Control identifier
                        Case $g_idMainGUI_ESC_Dummy
                            Exit
                        Case Else
;~                             ...
                    EndSwitch
            EndSwitch
        Case Else ; Control identifier
            Switch $iCode
                Case $EN_CHANGE ; $EN_CHANGE message from one of the input / edit controls to its parent window.
                    Switch $iIDFrom
                        ; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
                        ; Inputs Main-GUI
                        ; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
                        Case $g_idPathIn
                            ConsoleWrite('- WM_COMMAND $g_idPathIn: ' & GUICtrlRead($g_idPathIn) & @CRLF)
                    EndSwitch
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG ; Anweisung an Windows, dass es mit der normalen Abarbeitung fortfahren kann
EndFunc  ;==>WM_COMMAND

;-- TIME_STAMP   2019-10-19 17:51:43   v 0.1

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>

Local $aResult, $iRows, $iColumns, $iRval

_SQLite_Startup()
If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Error", "SQLite.dll Can't be Loaded!")
    Exit -1
EndIf
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Open() ; Open a :memory: database
If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Error", "Can't Load Database!")
    Exit -1
EndIf

; Example Table
;     Name        | Age
;     -----------------------
;     Alice       | 43
;     Bob         | 28
;     Cindy       | 21

If Not _SQLite_Exec(-1, "CREATE TEMP TABLE persons (Name, Age);") = $SQLITE_OK Then _
        MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Alice','43');") = $SQLITE_OK Then _
        MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Bob','28');") = $SQLITE_OK Then _
        MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Cindy','21');") = $SQLITE_OK Then _
        MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())

; Query
;~    $iRval = _SQLite_GetTable(-1, "SELECT * FROM persons;", $aResult, $iRows, $iColumns) ; kopiert die komplette Tabelle in ein Array
$iRval = _SQLite_GetTable(-1, "SELECT Name FROM persons;", $aResult, $iRows, $iColumns) ; kopiert nur die Spalte Name in ein Array
If $iRval = $SQLITE_OK Then
    ; $aResult Looks Like this:
    ; [0]    = 4
    ; [1]    = Name
    ; [3]    = Alice
    ; [5]    = Bob
    ; [7]    = Cindy
    _ArrayDisplay($aResult, "Query Result")
Else
    MsgBox($MB_SYSTEMMODAL, "SQLite Error: " & $iRval, _SQLite_ErrMsg())
EndIf

_SQLite_Close()
_SQLite_Shutdown()

#RequireAdmin
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_hGUI = GUICreate("test", 317, 38, 192, 114, -1, BitOR($WS_EX_ACCEPTFILES, $WS_EX_WINDOWEDGE))
Global $g_idInput = GUICtrlCreateInput("", 8, 8, 297, 21)
Global $g_hInput = GUICtrlGetHandle($g_idInput)
GUICtrlSetState(-1, $GUI_ACCEPTFILES)
GUISetState(@SW_SHOW)

; Allow WM_DROPFILES to be received from lower privileged processes (Windows Vista or later)
If IsAdmin() Then
    _WinAPI_ChangeWindowMessageFilterEx($g_hInput, $WM_COPYGLOBALDATA, $MSGFLT_ALLOW)
    _WinAPI_ChangeWindowMessageFilterEx($g_hInput, $WM_DROPFILES, $MSGFLT_ALLOW)
EndIf

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

; == Example 2 for writing in SciTe output pane

ConsoleWrite('! = Red' & @CRLF) ; ! = red text color
ConsoleWrite('> = Blue' & @CRLF) ; > = blue text color
ConsoleWrite('- = Orange' & @CRLF) ; - = orange text color
ConsoleWrite('+ = Green' & @CRLF) ; + = green text color
ConsoleWrite('@@(5) : = Red (jump to line 5 when double-clicked)' & @CRLF) ; '(5) :' red text color and double click jumps to (line number)
ConsoleWrite('Start_with_String_or_Integer_WithOut_Space' & @TAB & @TAB & '6' & ' = Pink (jump to line 6 when double-clicked)' & @CRLF)
; pink text color, any sign (without space) and then @TAB & @TAB & 'line number'

; Example 1
ConsoleWrite('@@ (' & @ScriptLineNumber & ') : = Red (jump to line ' & @ScriptLineNumber & ' when double-clicked)' & @CRLF)

; Clear console output pane of SciTE after 5000 ms - funktioniert nicht mehr!
;~ Sleep(5000)
;~ ControlSend("[CLASS:SciTEWindow]", "", "Scintilla2", "+{F5}") ; war früher "Clean", ist jetzt aber "Test Run"
;~ ControlSend("[CLASS:SciTEWindow]", "", "Scintilla2", "+{F7}") ; "Clean" | "Test Compile" --> doppelt belegt, letzteres wird verwendet, ergo "Test Compile"

--[[    OHK.ConvertFileToUTF8()
]]
-------------------------------------------------------------------------
OHK.ConvertFileToUTF8 = function()
    local UserTools   = props['user.tools.path']
    local FilePath    = props['FilePath']
--~     local FileDir     = props['FileDir']
--~     local FileName    = props['FileName']
--~     local FileExt     = props['FileExt']
--~     local FileNameExt = props['FileNameExt']

--~     print('UserTools   = '..UserTools)
--~     print('FilePath    = '..FilePath)
--~     print('FileDir     = '..FileDir)
--~     print('FileName    = '..FileName)
--~     print('FileExt     = '..FileExt)
--~     print('FileNameExt = '..FileNameExt)

    editor:BeginUndoAction()
    OHK.ExecuteAU3(UserTools..'\\_ConvertFileToUTF8.au3', FilePath)
    editor:EndUndoAction()
end
-------------------------------------------------------------------------

;-- TIME_STAMP   2018-06-23 07:32:01   v 0.1

#Region    ;************ Includes ************
#Include <File.au3>
;~ #Include <WinAPI.au3>
#EndRegion ;************ Includes ************

Switch $CMDLINE[0]
    Case 0
        Exit 1
    Case 1
        _ToUTF8($CMDLINE[1])
    Case 2
        _ToUTF8($CMDLINE[1], $CMDLINE[2])
    Case Else
        Exit 2
EndSwitch

Func _ToUTF8($sFilePath, $sSaveAs = '')
    If $sSaveAs = '' Then $sSaveAs = $sFilePath

;~     MsgBox(0, '_ToUTF8', '$sFilePath = ' & $sFilePath & @CRLF & '$sSaveAs = ' & $sSaveAs)
;~     Return

    Local $sFile, $hFile, $iSize, $iEncoding, $iWrite, $FO, $sExt

    $hFile = FileOpen($sFilePath, $FO_READ) ; $FO_READ (0), $FO_BINARY (16), $FO_UTF8 (128), $FO_UTF8_NOBOM (256), $FO_ANSI (512)
    $iEncoding = FileGetEncoding($hFile)
    $sFile = FileRead($hFile)
    $iSize = @extended
    FileClose($hFile)
    If $iSize = 0 Then
        ConsoleWrite('! Error $hFile = ' & $hFile & ' $iSize = ' & $iSize & ' FileRead('&$sFilePath&')' & @CRLF)
        Return 0
    EndIf

    $sExt = StringRegExpReplace($sFilePath, '.+(\..+)', '\1')

;~     Leere Datei.txt = $FO_UTF8_NOBOM
    Switch $iEncoding
        Case $FO_UTF8_NOBOM
            If $sExt = '.lua' Then
                Return SetExtended($iSize, $iEncoding) ; Lua mag kein BOM!!!
                ConsoleWrite(StringFormat('+ %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage ist bereits $FO_UTF8_NOBOM'))
            Else
                ConsoleWrite(StringFormat('- %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage $FO_UTF8_NOBOM wird zu $FO_UTF8 konvertiert'))
            EndIf
        Case $FO_UTF8
            ConsoleWrite(StringFormat('+ %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage ist bereits $FO_UTF8'))
            Return SetExtended($iSize, $iEncoding)
        Case $FO_ANSI
            If $sExt = '.lua' Then
                ConsoleWrite(StringFormat('- %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage $FO_ANSI wird zu $FO_UTF8_NOBOM konvertiert'))
            Else
                ConsoleWrite(StringFormat('- %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage $FO_ANSI wird zu $FO_UTF8 konvertiert'))
            EndIf
        Case Else
            Return 0
    EndSwitch

    $hFile = FileOpen($sSaveAs, $FO_OVERWRITE + $FO_CREATEPATH + ($sExt = '.lua' ? $FO_UTF8_NOBOM : $FO_UTF8)) ; $FO_APPEND (1), $FO_OVERWRITE (2), $FO_CREATEPATH (8), $FO_BINARY (16), $FO_UTF8 (128), $FO_UTF8_NOBOM (256), $FO_ANSI (512)
    $iWrite = FileWrite($hFile, $sFile) + FileClose($hFile) ? FileGetSize($sSaveAs) : -1
    If $iWrite < 1 Then
        ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Error $hFile = ' & $hFile & ' $iWrite = ' & $iWrite & ' FileWrite('&$sSaveAs&')' & @CRLF)
        Exit 999
    EndIf
    Send('^r')
    Return SetExtended($iSize, $iEncoding)
EndFunc

Func _StrRepeat($sStr, $iRepeat)
    Local $sString
    For $i = 1 To $iRepeat Step 1
        $sString &= $sStr
    Next
    Return $sString
EndFunc