Beiträge von Bitnugger

;-- TIME_STAMP   2019-07-24 14:12:24


; setzt Status des Toolbar-Button <SAVE> abhängig von Erfordernis zu speichern oder nicht auf ENABLE/DISABLE
; Skript kompilieren

#NoTrayIcon

#include <Misc.au3>
#include <WinAPISys.au3>
#include <GuiToolbar.au3>

Opt('MustDeclareVars', 1)

If Not @Compiled Then Exit 1

Global $g_hUSER32 = DllOpen('user32.dll')

; Index des gewünschten Button ermitteln
; Die Trennstriche zählen mit! Gezählt wird bei 0 beginnend.
; Bsp. Button "Save": Davor liegt "Trenner", "NEW", "OPEN" --> "SAVE" ist das 4.te Element - somit Index "3"
Global Const $g_iIndexSave = 3

If $CMDLINE[0] And $CMDLINE[1] = '/Exit' Then _SciTE_EnDisable_SaveBtn_Exit()

_Singleton('SciTE_EnDisable_SaveBtn') ; Enforce a design paradigm where only one instance of the script may be running

While Sleep(500)
    _CheckAndSetState()
WEnd
Exit


Func _CheckAndSetState()
    Local $hScite, $sTitle, $iBtnState, $iNewState, $hWndToolbar, $idCmd, $aResult

    $hScite = WinGetHandle('[ACTIVE]')
    $aResult = DllCall($g_hUSER32, "int", "GetClassNameW", "hwnd", $hScite, "wstr", "", "int", 4096)
    If Not @error And $aResult[2] = 'SciTEWindow' Then
        $hWndToolbar = ControlGetHandle($hScite, '', '[CLASS:ToolbarWindow32; INSTANCE:1]')
        $aResult = DllCall($g_hUSER32, "bool", "IsWindowVisible", "hwnd", $hWndToolbar)
        If Not @error And $aResult[0] Then
            $idCmd = _GUICtrlToolbar_IndexToCommand($hWndToolbar, $g_iIndexSave)

            $sTitle = WinGetTitle($hScite)
            If StringRegExp($sTitle, 'SciTE( \[\d+ (of|von) \d+\])?$') Then
                $iBtnState = _GUICtrlToolbar_GetButtonState($hWndToolbar, $idCmd)
                If Not StringInStr($sTitle, '*') And BitAND($iBtnState, $TBSTATE_ENABLED) Then
                    $iNewState = BitXOR($iBtnState, $TBSTATE_ENABLED)
                ElseIf StringInStr($sTitle, '*') And Not BitAND($iBtnState, $TBSTATE_ENABLED) Then
                    $iNewState = BitOR($iBtnState, $TBSTATE_ENABLED)
                Else
                    Return
                EndIf
                _GUICtrlToolbar_SetButtonState($hWndToolbar, $idCmd, $iNewState)
            EndIf
        EndIf
    EndIf
EndFunc

Func _SciTE_EnDisable_SaveBtn_Exit()
    Local $aWinList = WinList('[CLASS:SciTEWindow]'), $hWndToolbar, $idCmd, $iBtnState, $iNewState, $aProcessList = ProcessList(@ScriptName)
    For $i = 1 To $aProcessList[0][0] Step 1
        If $aProcessList[$i][1] <> @AutoItPID Then ProcessClose($aProcessList[$i][1])
    Next
    DllClose($g_hUSER32)
    For $i = 1 To $aWinList[0][0] Step 1
        $hWndToolbar = ControlGetHandle($aWinList[$i][1], '', '[CLASS:ToolbarWindow32; INSTANCE:1]')
        $idCmd = _GUICtrlToolbar_IndexToCommand($hWndToolbar, $g_iIndexSave)
        $iBtnState = _GUICtrlToolbar_GetButtonState($hWndToolbar, $idCmd)
        $iNewState = BitOR($iBtnState, $TBSTATE_ENABLED)
        If $iNewState <> $iBtnState Then _GUICtrlToolbar_SetButtonState($hWndToolbar, $idCmd, $iNewState)
    Next
    Exit
EndFunc

;-- TIME_STAMP   2016-06-07 02:22:11   v 1.0

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global Const $SS_EDITCONTROL = 0x00002000

Global $FontName = "Courier New" ; Font mit fester Laufweite
Global $FontSize = 9, $MinFontSize = 5
Global $FontWeight = -1
Global $FontAttr = -1
Global $iMaxZeichenInZeile = 72 ; 140
Global $iMaxLines = 3
Global $sZeile = ""

; Wir bauen uns einen String mit der gewünschten Zeichenanzahl
 For $I = 1 To $iMaxZeichenInZeile
     If Mod($I, 10) Then
         $sZeile &= Mod($I, 10)
     Else
         $sZeile &= " "
     EndIf
 Next

;~ Global $sPlot = ClipGet()
Global $sPlot = 'Setzt ein Flag, das festlegt, ob ein mehrzeiliges Bearbeitungssteuerelement weiche Zeilenumbruchzeichen enthält. Ein weicher Zeilenumbruch besteht aus zwei Zeilenumbrüchen und einem Zeilenvorschub und wird am Ende einer Zeile eingefügt, die aufgrund von Zeilenumbrüchen unterbrochen wurde.'

; Wir erstellen ein DUMMY GUI
GUICreate("DUMMY")
; Wir setzen den gewünschten Font (mit fester Laufweite)
GUISetFont($FontSize, $FontWeight, $FontAttr, $FontName)
; Wir schauen mal, wie breit ein Label sein muss, um den String aufzunehmen
GUICtrlCreateLabel($sZeile, 0, 0, -1, -1, $SS_EDITCONTROL)
Global $aLabel = WinGetClientSize(GUICtrlGetHandle(-1))
; Wir erzeugen ein Edit gleicher Breite und holen uns die realen Abmessungen der Clientarea
GUICtrlCreateEdit($sZeile, 0, 0, $aLabel[0], 40, $ES_WANTRETURN + $WS_VSCROLL)
Global $aEdit = WinGetClientSize(GUICtrlGetHandle(-1))
; Das DUMMY GUI hat seine Schuldigkeit getan
GUIDelete()

; Die benötigte Breite des Edits entspricht der Breite des Labels
; zuzüglich der Differenz Labelbreite - Editbreite
Global $iEditW = $aLabel[0] + $aLabel[0] - $aEdit[0]

; Jetzt erstellen wir das echte GUI
Global $hGUI = GUICreate("Edit GUI", $iEditW, 330)
; Das Edit wird in der korrekten Breite für $iMaxZeichenInZeile erstellt
Global $idEdit = GUICtrlCreateEdit($sPlot, 0, 0, $iEditW, 280, $ES_WANTRETURN + $WS_VSCROLL)
ControlMove($hGUI, '', $idEdit, 0, 0, $iEditW, 280)
; Dem Edit wird der Font zugewiesen
GUICtrlSetFont(-1, $FontSize, $FontWeight, $FontAttr, $FontName)
; ... und ein Button, der den Inhalt übernimmt
Global $idBtn = GUICtrlCreateButton("Text holen", 110, 300, 300, 25)
GUISetState()

Global $aText
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $idBtn
            Do
                ; Das Edit soll die "weichen" Zeilenumbrüche mit CRCRLF markieren
                GUICtrlSendMsg($idEdit, $EM_FMTLINES, True, 0)
                ; Wir holen uns den Inhalt
                Local $sText = GUICtrlRead($idEdit)
                ; Das Edit kann den Text jetzt wieder normal formatieren
                GUICtrlSendMsg($idEdit, $EM_FMTLINES, False, 0)
                ; Die "weichen" Zeilenumbrüche werden durch echte ersetzt
                $sText = StringReplace($sText, @CR & @CRLF, @CRLF)
                ConsoleWrite('> $FontSize = ' & $FontSize & @CRLF)
                ConsoleWrite($sText & @CRLF & @CRLF)
                $aText = StringSplit($sText, @CRLF, 3)
                _ArrayDisplay($aText, '$aText')
                If UBound($aText) <= $iMaxLines Then ExitLoop
                $FontSize -= 0.5
                GUICtrlSetFont($idEdit, $FontSize, $FontWeight, $FontAttr, $FontName)

            Until $FontSize <= $MinFontSize
    EndSwitch
WEnd

If UBound($aText) > $iMaxLines Then ConsoleWrite('! Text ist zu lang!' & @CRLF)

#include <Array.au3>
#include <WinAPIShPath.au3>

Local $aData = _WinAPI_CommandLineToArgv('C:\Program Files\Intel\bin\iWrap.exe /CMD:7 %1')
;~ _ArrayDisplay($aData, '_WinAPI_CommandLineToArgv')

For $i = 1 To $aData[0] Step 1
    If _WinAPI_PathFindExtension($aData[$i]) = '' Then ContinueLoop
    $aData[0] = _ArrayToString($aData, ' ', 1, $i)
    _ArrayDelete($aData, '1-' & $i)
    ExitLoop
Next
_ArrayDisplay($aData, '$aData')

Local $sCmd = 'C:\Program Files\Intel\bin\iWrap.exe /CMD:7 %1'
ConsoleWrite('$sCmd: ' & $sCmd & @CRLF)    ; RICHTIG --> C:\Program Files\Intel\bin\iWrap.exe /CMD:7 %1
$sCmd = _PathAddQuote($sCmd)
ConsoleWrite('$sCmd: ' & $sCmd & @CRLF)    ; RICHTIG --> "C:\Program Files\Intel\bin\iWrap.exe" /CMD:7 %1

Local $sPath = _WinAPI_PathRemoveArgs($sCmd)
ConsoleWrite("$sPath: " & $sPath & @LF)    ; RICHTIG  --> "C:\Program Files\Intel\bin\iWrap.exe"
$sPath = _WinAPI_PathUnquoteSpaces($sPath)
ConsoleWrite("$sPath: " & $sPath & @LF)    ; RICHTIG  --> C:\Program Files\Intel\bin\iWrap.exe

Local $sArgs = _WinAPI_PathGetArgs($sCmd)
ConsoleWrite("$sArgs: " & $sArgs & @LF)    ; RICHTIG  --> /CMD:7 %1

Func _PathAddQuote($sPath)
    Return StringLeft($sPath, 1) = '"' ? $sPath : StringRegExpReplace($sPath, '(?U)(.+\..+) (.+)', '"\1" \2')
EndFunc

;-- TIME_STAMP   2019-06-25 23:15:03   v 1.0

#include <Array.au3>

Opt('MustDeclareVars', 1)

Global $g_sShare

$g_sShare = _Test1(@ComputerName)
ConsoleWrite('> _Test1: $g_sShare = "' & $g_sShare & '"' & @CRLF)
$g_sShare = _Test2(@ComputerName)
ConsoleWrite('- _Test2: $g_sShare = "' & $g_sShare & '"' & @CRLF)

Func _Test1($_sServername) ; Parameter beginnen immer mit "$_"
    Local $iIndex, $aOutput, $iPID = Run('net view', '', @SW_HIDE, $STDOUT_CHILD)
    ProcessWaitClose($iPID)
    $aOutput = StringRegExp(StdoutRead($iPID), '(.+)\R?', 3) ; @CR|@LF|@CRLF als Trennzeichen verwenden.
    ; ( ... )  ; Capturing group. Das was in den Klammer ist, wollen wir haben.
    ; .+       ; . steht für ein beliebiges Zeichen, + für 1 oder mehr.
    ; \R?      ; \R matcht "(?>\r\n|\n|\r)" eg. @CRLF|@LF|@CR, ? macht \R optional, es kann ein Trennzeichen vorhanden sein, muss es aber nicht - dann wird der komplette String genommen.
    ; , 3      ; $STR_REGEXPARRAYGLOBALMATCH (3) Return array of global matches.
    $iIndex = _ArraySearch($aOutput, '\\' & $_sServername, 0, 0, 0, 1)
    Return @error ? False : StringStripWS(_ArrayToString(_ArrayExtract($aOutput, $iIndex, $iIndex)), $STR_STRIPTRAILING)
EndFunc  ;==>_Test1

Func _Test2($_sServername) ; Parameter beginnen immer mit "$_"
    ; NET VIEW zeigt eine Liste der Computer oder der von einem Computer freigegebenen Ressourcen an.
    Local $sTrennzeichen, $iIndex, $sOutput, $aOutput[1], $iPID = Run('net view', '', @SW_HIDE, $STDOUT_CHILD)
    ProcessWaitClose($iPID)
    $sOutput = StdoutRead($iPID)
    ; Problematisch wird es mit StringSplit aber, wenn $sOutput gemischte Trennzeichen für die Zeilenumbrüche enthält, was mit StringRegExp aber kein Problem ist!
    Switch True
        Case StringInStr($sOutput, @CRLF)
            $sTrennzeichen = @CRLF ; @CRLF als Trennzeichen verwenden
        Case StringInStr($sOutput, @CR)
            $sTrennzeichen = @CR ; @CR als Trennzeichen verwenden
        Case StringInStr($sOutput, @LF)
            $sTrennzeichen = @LF ; @LF als Trennzeichen verwenden
        Case Else
            $aOutput[0] = $sOutput ; $sOutput enthält nur eine Zeile
    EndSwitch
    If $sTrennzeichen Then $aOutput = StringSplit($sOutput, $sTrennzeichen, BitOR($STR_ENTIRESPLIT, $STR_NOCOUNT)) ; @CR|@LF|@CRLF als Trennzeichen verwenden
    $iIndex = _ArraySearch($aOutput, '\\' & $_sServername, 0, 0, 0, 1) ; $_sServername im Array suchen
    If @error Then Return False ; $_sServername nicht in gefunden!
    Return StringStripWS(_ArrayToString(_ArrayExtract($aOutput, $iIndex, $iIndex)), $STR_STRIPTRAILING) ; Zeile aus dem Array extrahieren, als String konvertieren und alle Leerzeichen am Ende eliminieren.
EndFunc  ;==>_Test2

;-- TIME_STAMP   2019-06-25 23:15:03   v 1.0

#include <Array.au3>

Opt('MustDeclareVars', 1)

Global $g_sShare = _Test(@ComputerName)
ConsoleWrite('$g_sShare = "' & $g_sShare & '"' & @CRLF)

Func _Test($_sServername) ; Parameter beginnen immer mit "$_"
    Local $iIndex, $aOutput, $iPID = Run('net view', '', @SW_HIDE, $STDOUT_CHILD)
    ProcessWaitClose($iPID)
    $aOutput = StringRegExp(StdoutRead($iPID), '(.+)\R?', 3) ; @CR|@LF|@CRLF als Trennzeichen verwenden
    $iIndex = _ArraySearch($aOutput, '\\' & $_sServername, 0, 0, 0, 1)
    Return @error ? False : StringStripWS(_ArrayToString(_ArrayExtract($aOutput, $iIndex, $iIndex)), $STR_STRIPTRAILING)
EndFunc