Beiträge von Bitnugger

**Bitnugger**

Wie die gelieferte xml-Datei aussieht, hängt ganz davon ab, welche Parameter du bei der Suchanfrage übergibst.

Hier mal eine einfache Anfrage...

AutoIt

;-- TIME_STAMP   2018-10-23 22:09:44   v 0.1

#include <Array.au3>

;~ https://tel.search.ch/api/help

; API-Key, wird benötigt, wenn mehr als eine Anfrage pro Tag gesendet wird.
Global $key = "xxxxxx"

; Allgemeiner Suchstring. Suche nach Namen, Rubriken oder Telefonnummern
Global $sSuche = "john+meier" ; "0442777777"


Global $aErgebnis = _Abfragen($sSuche)
_ArrayDisplay($aErgebnis, '$aErgebnis')

Func _Abfragen($was)
;~     Local $sURL = StringFormat("https://tel.search.ch/api/?maxnum=1&was=%s&key=%s", $was, $key) ; mit API-Key suchen
    Local $sURL = StringFormat("https://tel.search.ch/api/?maxnum=1&was=%s", $was) ; ohne API-Key suchen

    If FileExists('api-response.xml') Then
        ConsoleWrite('! api-response.xml war bereits vorhanden' & @CRLF)
    Else
        If Not InetGet($sURL, 'api-response.xml', 1) Then Return False
        ConsoleWrite('! api-response.xml wurde soeben gespeichert' & @CRLF)
    EndIf

    Local $sXML = FileRead('api-response.xml')
    Local $sContent = StringRegExpReplace($sXML, '(?s).+<content type="text">(.+)</content>.+', '\1')

    Local $aContent = StringRegExp($sContent & @CRLF, '(.+)(?:\R)', 3)
    For $i = 0 To UBound($aContent) -1 Step 1
        $aContent[$i] = StringStripWS($aContent[$i], 1)
        ConsoleWrite('> ' & $acontent[$i] & @CRLF)
    Next

    Return $aContent
EndFunc   ;==>_Abfragen

Alles anzeigen

und hier die gelieferte xml-Datei...

XML: api-response.xml

<?xml version="1.0" encoding="utf-8" ?>
<feed xml:lang="de" xmlns="http://www.w3.org/2005/Atom" xmlns:openSearch="http://a9.com/-/spec/opensearchrss/1.0/" xmlns:tel="http://tel.search.ch/api/spec/result/1.0/">
  <id>https://tel.search.ch/api/fb10afc3a3e24bfa6da1b80fb59869e6</id>
  <title type="text">tel.search.ch API Search Results</title>
  <generator version="1.0" uri="https://tel.search.ch">tel.search.ch</generator>
  <updated>2018-10-23T02:00:00Z</updated>
  <link href="https://tel.search.ch/result.html?was=john+meier" rel="alternate" type="text/html" />
  <link href="http://tel.search.ch/api/?was=john+meier" type="application/atom+xml" rel="self" />
  <link href="http://tel.search.ch/api/?was=john+meier&amp;pos=2" rel="next" type="application/atom+xml" />
  <openSearch:totalResults>9</openSearch:totalResults>
  <openSearch:startIndex>1</openSearch:startIndex>
  <openSearch:itemsPerPage>1</openSearch:itemsPerPage>
  <openSearch:Query role="request" searchTerms="john meier " startPage="2"></openSearch:Query>
  <openSearch:Image height="1" width="1" type="image/gif">https://www.search.ch/audit/CP/tel/de/api</openSearch:Image>
  <entry>
    <id>urn:uuid:b15768ab56be5411</id>
    <updated>2018-10-23T02:00:00Z</updated>
    <published>2018-10-23T02:00:00Z</published>
    <title type="text">Meier, John</title>
    <content type="text">Meier, John
    Via General Guisan 11
    6828 Balerna/TI
    *091 682 12 17</content>
    <tel:nopromo>*</tel:nopromo>
    <author>
      <name>tel.search.ch</name>
    </author>
    <link href="https://tel.search.ch/balerna/via-general-guisan-11/john-meier" title="Details" rel="alternate" type="text/html" />
    <link href="https://tel.search.ch/vcard/Meier.vcf?key=b15768ab56be5411" type="text/x-vcard" title="VCard Download" rel="alternate" />
    <link href="https://tel.search.ch/edit/?id=b15768ab56be5411" rel="edit" type="text/html" />
  </entry>
</feed>

Alles anzeigen

**Bitnugger**

Zitat von autoiter

wenn es dir wirklich nur darum geht eine Nummer vor jeden String einzufügen.

Hehe... und ich habe ihn so verstanden, dass er nur bei den Zeilen mit den Pfaden eine Nummer einfügen will und nicht bei allen Zeilen.

Egal, hier noch ein kleines Script mit dem genau dies geht - nur bei den Zeilen mit den Pfaden eine Nummer einfügen.

AutoIt

;-- TIME_STAMP   2018-10-14 23:50:07   v 0.1

#include <File.au3>

Local $sFileName = "KeePass.config.txt"

;~ If Not FileExists($sFileName) Then
    FileDelete($sFileName)
    FileWrite($sFileName, _
            "<Path>D:\Documents\KeePass\Test.kdbx</Path>" & @CRLF & _
            "<Test>Test</Test>" & @CRLF & _
            "<Path>E:\Documents\KeePass\Test.kdbx</Path>" & @CRLF & _
            "<Path>F:\Documents\KeePass\Test.kdbx</Path>" & @CRLF & _
            "<Ende>Ende</Ende>" & @CRLF)
;~ EndIf

Local $iIndex, $iStart = 0, $iEnd = 0, $iCase = 0, $iCompare = 3, $iReplaceCount = 0, $aFileRead = FileReadToArray($sFileName)

While 1
    $iIndex = _ArraySearch($aFileRead, '(?i)<Path>([a-z].+)</Path>', $iStart, $iEnd, $iCase, $iCompare)
    If @error Then ExitLoop
    $iReplaceCount += 1
    $iStart = $iIndex + 1
    $aFileRead[$iIndex] = '<Path>' & $iReplaceCount & '=' & StringMid($aFileRead[$iIndex], 7)
WEnd

_ArrayDisplay($aFileRead, '$aFileRead')
Local $sFileRead = _ArrayToString($aFileRead, @CRLF)
MsgBox(64, @ScriptName, $sFileRead & @CRLF & @CRLF & 'ReplaceCount = ' & $iReplaceCount)

;~ Local $hFile = FileOpen($sFileName, $FO_OVERWRITE)
;~ FileWrite($hFile, $sFileRead)
;~ FileClose($hFile)

Alles anzeigen

und hier noch eins...

AutoIt

;-- TIME_STAMP   2018-10-15 03:28:06   v 0.1

#include <File.au3>

Local $sFileName = "KeePass.config.txt"

;~ If Not FileExists($sFileName) Then
    FileDelete($sFileName)
    FileWrite($sFileName, _
            "<Path>D:\Documents\KeePass\Test.kdbx</Path>" & @CRLF & _
            "<Test>Test</Test>" & @CRLF & _
            "<Path>E:\Documents\KeePass\Test.kdbx</Path>" & @CRLF & _
            "<Path>F:\Documents\KeePass\Test.kdbx</Path>" & @CRLF & _
            "<Ende>Ende</Ende>" & @CRLF)
;~ EndIf

Local $sFileRead = FileRead($sFileName)

_AddCounter($sFileRead, '(?i)<Path>([a-z].+)</Path>')
MsgBox(64, @ScriptName, $sFileRead & @CRLF & @CRLF & 'ReplaceCount = ' & @extended)

;~ Local $hFile = FileOpen($sFileName, $FO_OVERWRITE)
;~ FileWrite($hFile, $sFileRead)
;~ FileClose($hFile)

Func _AddCounter(ByRef $sString, $sPattern, $iCount = 1)
    While True
        $sString = StringRegExpReplace($sString, $sPattern, $iCount & '=\1', 1)
        If Not @extended Then Return SetExtended($iCount, $sString)
        $iCount += 1
    WEnd
EndFunc   ;==>_AddCounter

Alles anzeigen

**Bitnugger**

AutoIt

;-- TIME_STAMP   2018-10-14 13:57:09   v 0.1

#include <Array.au3>

Example()

Func Example()
    Local $aResult, $aFile = ['# 2 ', 'a', '# 2 ', 'b', '# 2 ', 'c', '# 2 ', 'd']

    $aResult = Example_While($aFile)
    _ArrayDisplay($aResult, '$aResult - While')

    $aResult = Example_For($aFile)
    _ArrayDisplay($aResult, '$aResult - For')

    ; Aber Achtung...
    ; denn steht der gesuchte String in der letzten Zeile des Arrays, wird kein '# 2a' eingefügt, weil _ArrayInsert hier versagt...
    Local $aFile2 = ['# 2 ', 'a', '# 2 ', 'b', '# 2 ', 'c', '# 2 ', 'd', '# 2 ']

    ; Fehler!
    $aResult = Example_While($aFile2)
    _ArrayDisplay($aResult, '$aResult - While')

    ; Fehler!
    $aResult = Example_For($aFile2)
    _ArrayDisplay($aResult, '$aResult - For')

    ; so geht es...
    $aResult = Example_For2($aFile2)
    _ArrayDisplay($aResult, '$aResult - For2')

;~     _ArrayToClip ($aResult, @CRLF)
EndFunc

Func Example_While($aArray)
    Local $i = 0
    While $i < UBound($aArray)
        If StringLeft($aArray[$i], 3) = '# 2' Then
            $i += 1
            _ArrayInsert($aArray, $i, '# 2a')
        EndIf
        $i += 1
    WEnd
    Return $aArray
EndFunc

Func Example_For($aArray)
    For $i = UBound($aArray) -1 To 0 Step -1
        If StringLeft($aArray[$i], 3) = '# 2' Then
            _ArrayInsert($aArray, $i + 1, '# 2a')
        EndIf
    Next
    Return $aArray
EndFunc

Func Example_For2($aArray)
    For $i = UBound($aArray) -1 To 0 Step -1
        If StringLeft($aArray[$i], 3) = '# 2' Then
            If $i = UBound($aArray) -1 Then
                _ArrayAdd($aArray, '# 2a')
            Else
                _ArrayInsert($aArray, $i + 1, '# 2a')
            EndIf
        EndIf
    Next
    Return $aArray
EndFunc

Alles anzeigen

**Bitnugger**

Ich blicke da nicht so ganz durch... du hast zwar die Datei KeePass.config.xml in den Spoiler gelegt, aber die Datei myBackup.ini fehlt und insgesamt ist dein Script eine einzige Katastrophe.

Erkläre doch einfach mal mit Worten, was genau du machen willst... dann helfe ich dir auch gerne dabei.

**Bitnugger** · The MATRIX build 2018-10-16 **Bitnugger** 10. Oktober 2018 um 19:14

Hehe, auch nicht übel @bazii, allerdings frage ich mich, was der Befehl mode 1000 bewirken soll, denn so wie ich das verstehe, ist die Syntax für diesen Befehl in keiner Betriebssystem-Version korrekt.

https://docs.microsoft.com/en-us/windows-…s-commands/mode

https://www.computerhope.com/modehlp.htm

**Bitnugger**

Zitat von autoiter

Hat denn jemand dies hier überhaupt verstanden?

Was gibt es da groß zu verstehen? Ohne das Programm und den Quellcode des AutoIt Info Tools kann man nur vermuten... z.B. dass es eine Message an das Fenster schickt, wodurch das Programm dann abstürzt. Das habe ich mit einer anderen Anwendung aber auch schon mal gehabt, kann mich aber nicht mehr erinnern, welche es war.

**Bitnugger**

Zeige uns mal die Ausgabe von WinGetControls und was du bis jetzt versucht hast (Script) und ein Bild des Fensters mit dem Button/Textzeile, den du noch anklicken willst.

**Bitnugger**

$SD_POWERDOWN macht nur Sinn, wenn du es in Kombination mit $SD_SHUTDOWN verwendest. $SD_SHUTDOWN fährt Windows runter und es gelten die Einstellungen, die im Energiesparplan aktiviert sind, mit $SD_POWERDOWN werden diese jedoch ignoriert und der PC wird nach dem Herunterfahren ausgeschaltet.

**Bitnugger**

Wenn nur Zeilen gefunden werden sollen, die mit TCP beginnen und mit HERGESTELLT enden, dann reicht das hier:

AutoIt

#include <Array.au3>

If Not FileExists('test.txt') Then
    Local $sFile = _
        'TCP 0.0.0.0:1234    0.0.0.0:0 ABHOEHREN' & @CRLF & _
        'TCP 172.0.0.1:56789 172.0.0.2:56789 HERGESTELLT' & @CRLF & _
        'TCP 172.0.0.1:12345 172.0.0.2:1234 WARTEND' & @CRLF & _
        'TCP 172.0.0.1:12345 172.0.0.2:1234 WARTEND' & @CRLF & _
        'TCP 172.0.0.1:12345 172.0.0.2:1234 HERGESTELLT' & @CRLF
    FileWrite('test.txt', $sFile)
EndIf

Local $sFile = FileRead("test.txt")

Local $aRegEx = StringRegExp($sFile, 'TCP.+HERGESTELLT', 3)

MsgBox(64, @ScriptName, _ArrayToString($aRegEx, @CRLF))
_ArrayDisplay($aRegEx, '$aRegEx')

Alles anzeigen

**Bitnugger**

Zitat von Baden2016

Wenn ich mit dem AutoIt InfoTool über das Objekt ziehe, dann stürzt das Programm mit schwerwiegendem Fehler ab.

Autsch... das ist aber nicht schön... versuche es mal mit _WinGetControls (s. Anhang), ob es damit geht.

**Bitnugger**

Zitat von Baden2016

Ich möchte keine neuen Dialog Fenster erzeugen, sondern aus einem Programm entsprechende Werte auslesen.

Kann es sein, dass du nicht weißt, wie du das anstellen sollst?

Im AutoIt-Programmverzeichnis findest du das AutoIt Info Tool (Au3Info.exe, Au3Info_x64.exe). Damit kannst du die benötigten Infos auslesen.

**Bitnugger**

Zitat von Tuxedo

Dann irgendwohin nach Wunsch entpacken und danach die 3 Dateien aus meinem Archiv "DoodleJump8.1_Source.zip"

auch in diesen Ordner entpacken und Game Starten.

ja klar, man kann sich von hinten durch den Ellenbogen vorne durchs Knie schießen, wenn man die Ferse treffen will... oder man zielt direkt auf die Ferse... sprich, man macht es so, wie alpines es bereits gezeigt hat und braucht dann auch deine Source-Files nicht.

Zitat von Tuxedo

den 64-bit Download könnt ihr euch schenken

Ja, denn die Files sind alle identisch mit den 32-Bit.

**Bitnugger**

Zitat von Tuxedo

Es läuft jetzt mit der neuen Autoitversion und zwei alten GDIPlus Files ohne grosse sonstige Änderungen.

Die beiden Files (*.dll) brauchst du nicht mehr, weil du die Funktion _GDIPlus_Startupdll() (in dieser wurden sie geladen) gelöscht und durch _GDIPlus_Startup() ersetzt hast.

Zitat von Tuxedo

Wenn ichs jetzt noch hinkriege das Game-Fenster doppelt so groß zu kriegen(bei diesem Script evtl utopisch) dann wäre ich zufrieden.

Hehe... ja, viel Spaß dabei... utopisch ist wohl schon das richtige Wort.

**Bitnugger**

Zitat von Tuxedo

Wie schafft ihr das eigentlich so schnell solche Fehler in einem so riesigen unübersichtlichen Script zu finden, habt ihr Euch einen Bot

dafür gebastelt oder wie macht ihr das?

Wenn du SciTE4AutoIt3 als Editor für deine Scripte benutzt, kannst du mit Strg + F5 das Tool "Au3Check" ausführen lassen, welches dir diese Arbeit abnimmt. Mit F4 springst du zum nächsten Fehler, mit Shift + F4 zum vorherigen. Mit einem Doppelklick im Output-Pannel von SciTE (der untere Bereich) auf eine (rote) Fehlerzeile, springt der Editor an diese Stelle im Script. Damit hast du dann schon die halbe Miete...

SciTE4AutoIt3.png

**Bitnugger**

Schau mal, ob das hier was für dich ist... denn wenn ich es richtig verstehe, kannst du mit dem Printer das erzeugte PDF mit dem Original-Namen speichern und auch nach dem "Drucken" ein beliebiges Programm starten.

https://www.pc-magazin.de/download/virtu…ee-1011749.html

**Bitnugger**

Hier noch ein wenig erweitert, da du ja auch die Werte haben willst.

AutoIt

#Region ;************ Includes ************
#include <Array.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <GuiComboBox.au3>
#include <WindowsConstants.au3>
#EndRegion ;************ Includes ************

Global $hForm1, $idList1, $idCombo1, $idButton1

_Main()

Func _Main()
    $hForm1 = GUICreate("Form1", 210, 220, 192, 124)
    $List1 = GUICtrlCreateList("", 40, 16, 121, 97)
    GUICtrlSetData(-1, "1|2|3|4|5")
    $idCombo1 = GUICtrlCreateCombo("", 32, 136, 145, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
    GUICtrlSetData(-1, "a|b|c|d|e")
    $idButton1 = GUICtrlCreateButton("Button1", 32, 176, 145, 33)
    GUISetState(@SW_SHOW)

    Local $nMsg, $aListData, $iListLines, $aComboData, $iComboLines
    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit

            Case $idButton1
                $aListData = _GUICtrlListBox_GetListArray(ControlGetHandle("Form1", "", "[CLASS:ListBox; INSTANCE:1]")) ; $aListData[0] = 1, $aListData[4] = 5
                $iListLines = @extended

                $aComboData = _GUICtrlComboBox_GetListArray(ControlGetHandle("Form1", "", "[CLASS:ComboBox; INSTANCE:1]")) ; $aComboData[0] = 'a', $aComboData[4] = 'e'
                $iComboLines = $aComboData[0]
                _ArrayDelete($aComboData, 0)

                MsgBox(0, 0, "List:" & $iListLines & @CRLF & _ArrayToString($aListData, @CRLF) & @CRLF & @CRLF & "Combo:" & $iComboLines & @CRLF & _ArrayToString($aComboData, @CRLF))

        EndSwitch
    WEnd
EndFunc

Func _GUICtrlListBox_GetListArray($hWnd)
    Local $iLines = _GUICtrlListBox_GetCount($hWnd), $aData[$iLines]
    For $i = 0 To $iLines - 1 Step 1
        $aData[$i] = _GUICtrlListBox_GetText($hWnd, $i)
    Next

    Return SetExtended($iLines, $aData)
EndFunc   ;==>_GUICtrlListBox_GetListArray

Alles anzeigen

**Bitnugger**

Zitat von entsel

Es geht nicht um die Installation mit Autoit (FileCreateShortcut) - es soll nur ein Link (ev. mit Icon ? - heißt wohl unter win10 "Kachel" ? - sowas: https://www.google.at/url?sa=i…stUl&ust=1538488601871780 ) erzeugt werden, über den man das (fertige) Programm (*.exe) per Doppelklick startet.

Genau das machst du doch mit FileCreateShortcut... eine symbolische Verknüpfung an beliebiger Stelle (Desktop/Startmenü/...) zu dem Programm erzeugen, damit man es nicht erst suchen muss.

**Bitnugger**

Zitat von vcopsmtl

Code
1. Methode
$hFile = FileOpen($file,1)
_ReplaceStringInFile($file,'(?i)time.{45}',"ersetzender Text");

Dir ein Handle mit FileOpen zu besorgen, macht nur Sinn, wenn du es dann auch benutzt! Die Funktion _ReplaceStringInFile erwartet allerdings kein Handle, sondern einen Dateipfad. Das FileOpen kannst du dir in dem Fall also sparen. Zu jedem FileOpen gehört übrigens ein FileClose.

Wie in 2. Methode zu sehen ist, willst du das am Anfang jeder Zeile stehende "time" durch "Zeit" ersetzen... in Methode 1 und 3 willst du jedes Auftreten von "time" gefolgt von 45 beliebigen Zeichen ersetzen... das sind zwei völlig verschiedene Dinge. Methode 1 und 3 können nicht funktionieren, weil _ReplaceStringInFile kein RegExp unterstützt.

Was genau willst du also nun finden und durch was willst du es ersetzen?

**Bitnugger**

Das Script aus Post #2 mit ein paar Änderungen, so dass auch remote der Status der Lizenz abgefragt werden kann - damit geht es auch ohne erhöhte Rechte.

AutoIt: _Get_Lizenzstatus.au3

;-- TIME_STAMP   2018-09-27 16:56:09   v 0.1

#include <Array.au3>

Global $g_aLizenzstatus = _Get_Lizenzstatus(@ComputerName)
_ArrayDisplay($g_aLizenzstatus, '$g_aLizenzstatus - ' & @ComputerName)

Global $g_sComputerName = 'Server', $g_sUserName = @UserName, $g_sPassword = 'Geheim0815!'
Global $g_aLizenzstatus = _Get_Lizenzstatus($g_sComputerName, $g_sUserName, $g_sPassword)
_ArrayDisplay($g_aLizenzstatus, '$g_aLizenzstatus - ' & $g_sComputerName)

;~ Name: Windows(R), Professional edition
;~ Beschreibung: Windows(R) Operating System, RETAIL channel
;~ Teil-Product Key: XXXXX
;~ Lizenzstatus: Lizenziert
Func _Get_Lizenzstatus($sComputerName = @ComputerName, $sUser = @UserName, $sPassword = '')
    Local $sCMD, $iPID, $sText, $aText, $aSplit
    If $sComputerName = @ComputerName Then
        $sCMD = 'cscript.exe //nologo C:\Windows\System32\slmgr.vbs /dli'
    Else
        $sCMD = StringFormat('psexec.exe \\\%s -u %s -p %s cscript.exe //nologo C:\Windows\System32\slmgr.vbs /dli', $sComputerName, $sUser, $sPassword)
    EndIf
;~     ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sCMD --> " & $sCMD & @CRLF)
    $iPID = Run($sCMD, '', @SW_HIDE, $STDOUT_CHILD)
    If Not $iPID Then Return SetError(1, 0, False)
    ProcessWaitClose($iPID)

    $sText = StdoutRead($iPID)
    If $sText Then
        $aText = StringSplit($sText, @CRLF, 3)
        _ArrayColInsert($aText, 1)
        For $i = UBound($aText) -1 To 0 Step -1
            $aSplit = StringSplit($aText[$i][0], ': ', 3)
            If UBound($aSplit) <> 2 Then
                _ArrayDelete($aText, $i)
                ContinueLoop
            EndIf
            $aText[$i][0] = $aSplit[0]
            $aText[$i][1] = $aSplit[1]
        Next
        Return $aText
    EndIf

    Return SetError(2, 0, False)
EndFunc

Alles anzeigen

**Bitnugger**

Zitat von AquaBall

Dann bleibt nur noch die Fragen, warum Intellisense noch falscher Meinung ist, und dass es jetzt zu _DebugArrayDisplay GARNICHTS anzeigt.

Diese Frage hat dir alpines bereits beantwortet...

Zitat von alpines

Ich schätz mal das VSCode Plugin wurde auf die neue Definition nicht angepasst.

Beiträge von Bitnugger

COM error 80020009

_StringBetween, Zeilen durchnummerieren

Array - _ArrayInsert - Bitnugger

_StringBetween, Zeilen durchnummerieren

The MATRIX build 2018-10-16

Werte aus ListBox und ComboBox

Werte aus ListBox und ComboBox

Shutdown vs Powerdown

Eine von mehreren Zeilen mit bestimmten Wort in in MsgBox ausgeben

Werte aus ListBox und ComboBox

Werte aus ListBox und ComboBox

Doodle Jump gesucht

Doodle Jump gesucht

Doodle Jump gesucht

Dummy-Drucker

Werte aus ListBox und ComboBox

[gelöst] "Desktop-Link" unter Win10

kann _ReplaceStringInFile komplexe Suchen durchführen ala StringRegExp(Replace) ?

Windows 10 Lizenz vorhanden?

Au3Check, Hilfe und Intellisense sind sich uneinig