Beiträge von water

;===============================================================================
; Function Name.....: _FileGetProperty
; Description.......: Returns a property or all properties for a file.
; Version...........: 1.0.2
; Change Date.......: 05-16-2012
; AutoIt Version....: 3.2.12.1+
; Parameter(s)......: $FGP_Path - String containing the file path to return the property from.
;                     $FGP_PROPERTY - [optional] String containing the name of the property to return. (default = "")
;                     $iPropertyCount - [optional] The number of properties to search through for $FGP_PROPERTY, or the number of items
;                                       returned in the array if $FGP_PROPERTY is blank. (default = 300)
; Requirements(s)...: None
; Return Value(s)...: Success: Returns a string containing the property value.
;                     If $FGP_PROPERTY is blank, a two-dimensional array is returned:
;                         $av_array[0][0] = Number of properties.
;                         $av_array[1][0] = 1st property name.
;                         $as_array[1][1] = 1st property value.
;                         $av_array[n][0] = nth property name.
;                         $as_array[n][1] = nth property value.
;                     Failure: Returns an empty string and sets @error to:
;                       1 = The folder $FGP_Path does not exist.
;                       2 = The property $FGP_PROPERTY does not exist or the array could not be created.
;                       3 = Unable to create the "Shell.Application" object $objShell.
; Author(s).........: - Simucal <Simucal@gmail.com>
;                     - Modified by: Sean Hart <autoit@hartmail.ca>
;                     - Modified by: teh_hahn <sPiTsHiT@gmx.de>
;                     - Modified by: BrewManNH:
;                       https://www.autoitscript.com/forum/topic/148232-_filegetproperty-retrieves-the-properties-of-a-file
; URL...............: http://www.autoitscript.com/forum/topic/34732-udf-getfileproperty/page__view__findpost__p__557571
; Note(s)...........: Modified the script that teh_hahn posted at the above link to include the properties that
;                     Vista and Win 7 include that Windows XP doesn't. Also removed the ReDims for the $av_ret array and
;                     replaced it with a single ReDim after it has found all the properties, this should speed things up.
;                     I further updated the code so there's a single point of return except for any errors encountered.
;                     $iPropertyCount is now a function parameter instead of being hardcoded in the function itself.
;===============================================================================
Func _FileGetProperty($FGP_Path, $FGP_PROPERTY = "", $iPropertyCount = 500)
    If $FGP_PROPERTY = Default Then $FGP_PROPERTY = ""
    $FGP_Path = StringRegExpReplace($FGP_Path, '["'']', "") ; strip the quotes, if any from the incoming string
    If Not FileExists($FGP_Path) Then Return SetError(1, 0, "") ; path not found
    Local Const $objShell = ObjCreate("Shell.Application")
    If @error Then Return SetError(3, 0, "")
    Local Const $FGP_File = StringTrimLeft($FGP_Path, StringInStr($FGP_Path, "\", 0, -1))
    Local Const $FGP_Dir = StringTrimRight($FGP_Path, StringLen($FGP_File) + 1)
    Local Const $objFolder = $objShell.NameSpace($FGP_Dir)
    Local Const $objFolderItem = $objFolder.Parsename($FGP_File)
    Local $Return = "", $iError = 0
    If $FGP_PROPERTY Then
        For $I = 0 To $iPropertyCount
            If $objFolder.GetDetailsOf($objFolder.Items, $I) = $FGP_PROPERTY Then
                $Return = $objFolder.GetDetailsOf($objFolderItem, $I)
            EndIf
        Next
        If $Return = "" Then
            $iError = 2
        EndIf
    Else
        Local $av_ret[$iPropertyCount + 1][2] = [[0]]
        For $I = 1 To $iPropertyCount
            If $objFolder.GetDetailsOf($objFolder.Items, $I) Then
                $av_ret[$I][0] = $objFolder.GetDetailsOf($objFolder.Items, $I - 1)
                $av_ret[$I][1] = $objFolder.GetDetailsOf($objFolderItem, $I - 1)
;~              $av_ret[0][0] += 1
                $av_ret[0][0] = $I
            EndIf
        Next
        ReDim $av_ret[$av_ret[0][0] + 1][2]
        If Not $av_ret[1][0] Then
            $iError = 2
            $av_ret = $Return
        Else
            $Return = $av_ret
        EndIf
    EndIf
    Return SetError($iError, 0, $Return)
EndFunc   ;==>_FileGetProperty

#include <Constants.au3>
#include <Debug.au3>

_ADO_OLEDBProvidersList()

Func _ADO_OLEDBProvidersList()
	Local $sKey = "HKCR\CLSID"
	Local $iIndexReg = 1, $iIndexResult = 0
	Local $iMax = 100000, $iMin = 1, $iPrevious = $iMin, $iCurrent = $iMax / 2
	Local $aResult[200][6]

	ProgressOn("OLE DB Providers", "Processing the Registry", "", Default, Default, $DLG_MOVEABLE)
	AutoItSetOption("ExpandEnvStrings", 1)

	; Count the number of keys
	While 1
		RegEnumKey($sKey, $iCurrent)
		If @error = -1 Then ; Requested subkey (key instance) out of range
			$iMax = $iCurrent
			$iCurrent = Int(($iMin + $iMax) / 2)
			$iPrevious = $iMax
		Else
			If $iPrevious <= ($iCurrent + 1) And $iPrevious >= ($iCurrent - 1) Then ExitLoop
			$iMin = $iCurrent
			$iCurrent = Int(($iMin + $iMax) / 2)
			$iPrevious = $iMin
		EndIf
	WEnd

	Local $iPercent = 0
	Local $sKeyValue = ''
	; Process registry
	While 1
		If Mod($iIndexReg, 10) = 0 Then
			$iPercent = Int($iIndexReg * 100 / $iCurrent)
			ProgressSet($iPercent, $iIndexReg & " keys of " & $iCurrent & " processed (" & $iPercent & "%)")
		EndIf
		$sSubKey = RegEnumKey($sKey, $iIndexReg)
		If @error Then ExitLoop

		$sKeyValue = RegRead($sKey & "\" & $sSubKey, "OLEDB_SERVICES")
		If @error = 0 Then
			$aResult[$iIndexResult][0] = $sKey & "\" & $sSubKey                                   ; Registry Key
			$aResult[$iIndexResult][1] = RegRead($sKey & "\" & $sSubKey, "")                      ; OLE DB Provider
			$aResult[$iIndexResult][2] = RegRead($sKey & "\" & $sSubKey & "\OLE DB Provider", "") ; Description
			$aResult[$iIndexResult][3] = RegRead($sKey & "\" & $sSubKey & "\InprocServer32", "")  ; DLL file
			If $aResult[$iIndexResult][3] <> "" Then
				$aResult[$iIndexResult][4] = _FileGetProperty($aResult[$iIndexResult][3], "Dateiversion")
				$aResult[$iIndexResult][5] = _FileGetProperty($aResult[$iIndexResult][3], "Änderungsdatum")
			EndIf
			$iIndexResult += 1
		EndIf

		$iIndexReg += 1
	WEnd

	ProgressOff()
	ReDim $aResult[$iIndexResult][UBound($aResult, 2)]

	_DebugArrayDisplay($aResult, "OLE DB Providers", "", 0, Default, "Registry key|OLE DB Provider|Description|DLL|DLL Version|DLL last modified")

EndFunc   ;==>_ADO_OLEDBProvidersList

Global $mDDRType[]
$mDDRType[0] = "Unknown"
$mDDRType[1] = "Other"
$mDDRType[2] = "DRAM"
$mDDRType[3] = "Synchronous DRAM"
$mDDRType[4] = "Cache-DRAM"
$mDDRType[5] = "EDO"
$mDDRType[6] = "EDRAM"
$mDDRType[7] = "VRAM"
$mDDRType[8] = "SRAM"
$mDDRType[9] = "RAM"
$mDDRType[10] = "ROM"
$mDDRType[11] = "Flash"
$mDDRType[12] = "EEPROM"
$mDDRType[13] = "FEPROM"
$mDDRType[14] = "EPROM"
$mDDRType[15] = "CDRAM"
$mDDRType[16] = "3DRAM"
$mDDRType[17] = "SDRAM"
$mDDRType[18] = "SGRAM"
$mDDRType[19] = "RDRAM"
$mDDRType[20] = "DDR"
$mDDRType[21] = "DDR2"
$mDDRType[22] = "BRAM"
$mDDRType[23] = "FB-DIMM"
$mDDRType[24] = "DDR3"
$mDDRType[25] = "FBD2"
$mDDRType[26] = "DDR4"
$mDDRType[27] = "LPDDR"
$mDDRType[28] = "LPDDR2"
$mDDRType[29] = "LPDDR3"
$mDDRType[30] = "LPDDR4"
$mDDRType[31] = "Logical non-volatile device"
$mDDRType[32] = "HBM (High Bandwidth Memory)"
$mDDRType[33] = "HBM2 (High Bandwidth Memory Generation 2)"
$mDDRType[34] = "DDR5"
$mDDRType[35] = "LPDDR5"
$mDDRType[36] = "HBM3 (High Bandwidth Memory Generation 3)"
$mDDRType[37] = "DMTF Reserved" ; 37 – 32567
$mDDRType[32568] = "Vendor Reserved" ; 32568 – 65535

; Beispielaufruf
ConsoleWrite(_GetDDRTypeText($mDDRType, 28) & @CRLF)

Func _GetDDRTypeText(ByRef $mDDRType, $iDDRType)
    ; Set ranges of numbers to the first number in the range. This number has to be defined in the $mDDRType map.
    If $iDDRType >= 37 And $iDDRType <= 32567 Then $iDDRType = 37
    If $iDDRType >= 32568 And $iDDRType <= 65535 Then $iDDRType = 32568
    If Not MapExists($mDDRType, $iDDRType) Then
        Return "Unbekannter Wert in Win32_PhysicalMemory: SMBIOSMemoryType"
    Else
        Return $mDDRType[$iDDRType]
    EndIf
EndFunc ;==>_GetDDRTypeText