1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. autoiter

Beiträge von autoiter

  • Fehler in der deutschen Hilfe bitte hier melden (Hilfedatei 3.3.14.2 2017.11.12)

    • autoiter
    • 24. November 2017 um 17:55

    Oscar ,

    das meint, dass du automatisch eine neue lokale Variable deklarierst, wenn du die Parameter-Variable nicht als Konstante deklarierst/weiter gibst..

    Ähm, ja. Genau was Bitnugger gerade geschrieben hat.. :D

  • Process über Basic Control Info finden

    • autoiter
    • 24. November 2017 um 16:21

    Hallo Paul01

    https://www.autoitscript.com/autoit3/docs/f…nGetProcess.htm

  • Verständnisfrage - RAMVerbrauch

    • autoiter
    • 20. November 2017 um 11:08
    Zitat von Sonderbaar

    Wenn ich das Script poste, wird der Thread geschlossen werden

  • braucht man eigentlich Excel um excel.au3 zu benutzen? oder läuft das auch ohne?

    • autoiter
    • 15. November 2017 um 18:31

    Hey Leute,

    seit dem Update vom 14.11. funktioniert der Jet Treiber (bei mir) wieder! 8)

    https://support.microsoft.com/en-us/help/4048953

    Vielen Dank an ahe für den Hinweis auf meiner Pinnwand. :thumbup::thumbup:

  • FileInstall Funktion funktioniert nicht (immer) auf Windows 7 32 Bit?

    • autoiter
    • 15. November 2017 um 17:47

    Hallo ahe

    zu deinem Problem kann ich direkt gar keine Aussage treffen. Ich hätte nur eine alternative Vorgehensweise vorzuschlagen. Statt per FileInstall bindest du die Datei(en) per Base64 String ein. UEZ hat hier einen Generator bereitgestellt. File to Base64 String Code Generator v1.20 Build 2015-01-20

    (Du musst im Code die maximale Dateigröße ändern/deaktivieren).

    Ich nutze das sehr gerne. Ich kann dir zwar nicht garantieren, dass es nun immer die Datei schreibt, weil ich das Problem ja nicht kenne (vllt. mangelnde Schreibrechte im gewünschten Verzeichnis oder was auch immer). Allerdings machst du dann selbst den Aufruf zum Erstellen der Datei. Das gibt dir die Möglichkeit Vorbereitungen zu treffen (bspw. Verzeichnis erstellen/Schreibrechte prüfen) und eigene Fehlerprüfungen/-meldungen zu implementieren.

    EDIT: Nach etwas überlegen, weiß ich gar nicht, ob das wirklich bei so großen Paketen praktikabel ist. So groß waren meine integrierten Pakete noch nie.

  • Intel RST, Raid Status Abfrage

    • autoiter
    • 15. November 2017 um 11:01

    Gut. Das Skript ist auch noch aus Zeiten, in denen nicht auf jedem Rechner das Snipping Tool installiert war. Damit hat man es heute noch etwas komfortabler.

  • Forenupdate - September 2017 - Probleme / Anregungen / Feedback - Sammelthread

    • autoiter
    • 15. November 2017 um 09:22

    BugFix

    Google hat seinen Job glaube ich erledigt. Da komme ich mittlerweile auf die Beiträge unter der neuen URL.

    Wenn die Verlinkungen hier im Forum aber angepasst werden könnten, wäre das auf jeden Fall toll!

  • GetUniqueColors

    • autoiter
    • 14. November 2017 um 19:03

    Hm, stimmt. Das ist mir eben nicht aufgefallen, weil die Hexfunktion doch den größten Teil ausmachte (von 6674ms zu 2765ms).

    Wieso ist hier die Zuweisung in ein Array schneller, alpines? Das widerspricht total meinen bisherigen (geringen) Erfahrungen. Ich war schon so weit, dass ich versuchen wollte alle einfachen Arrays durch Dictionaries zu ersetzen.

  • GetUniqueColors

    • autoiter
    • 14. November 2017 um 18:43

    Bei meinen Tests entsteht der Zeitgewinn nicht durch das Array sondern durch den Verzicht auf die Hex Funktion.

  • Parameterauswertung für Konsolenprogramme

    • autoiter
    • 14. November 2017 um 08:15

    Ähm. Das man nicht an vllt. hundert Stellen & @CRLF schreiben muss. Ist doch wohl klar. Ich sehe da wirklich keinen Diskussionsbedarf.

  • Parameterauswertung für Konsolenprogramme

    • autoiter
    • 14. November 2017 um 07:33
    Zitat von Musashi

    Gute Idee

    Finde ich nicht. Das wurde völlig zu hoch gehängt von den Leuten, die hier geschrieben haben. Aus meiner Sicht, ist es auch falsch.

    Gerade die kleine Hilfsfunktion Print. So eine kleine Optimierung findet sich in ganz vielen Beispielen in der Hilfe. Und man möge sich bitte mal ein beliebiges Skript von Bitnugger anschauen. Wenn man darin so etwas nicht findet, hat man den falschen User gesucht.. ;)

    Ich halte es jedenfalls oft für sinnvoll und verstehe auch nicht, warum das ein Problem sein soll.

  • Merkwürdiges Verhalten auch bei DirCopy ?

    • autoiter
    • 12. November 2017 um 19:53

    Hallo @Musashi

    ich kann das bestätigen. Wenn ich nicht $FC_OVERWRITE setze erhalte ich einen Fehler. Mit $FC_OVERWRITE klappt es. Allerdings werden hier aber wirklich vorhandene Dateien überschrieben.

    Die Funktionen sind Murks. Besser eine eigene Funktion nutzen.

    Achso. Habs jetzt erst gepeilt. DirCopy meint eben DirCopy.. X/

    Wenn beim zweiten Versuch das Verzeichnis bereits existiert und nicht $FC_OVERWRITE gesetzt ist, bricht die Funktion eben wie versprochen mit Fehler ab. Das ganze funktioniert einfach ohne Ansehen der Inhalte. Es geht nur um die Verzeichnisse.. Also alles gut.

  • StringFormat -- und kein bisschen weise?

    • autoiter
    • 5. November 2017 um 21:15

    Ehrlich gesagt verstehe ich das immer noch nicht ganz. Auch wenn du Leerzeichen vor den String bringst, ist das doch nicht richtig rechtsbündig.

    Ich würde da vllt. eine kleine Funktion basteln, die mir je nach String-Länge Leerzeichen davor knallt, damit ich es fertig habe und hier wie du auf eine bessere Antwort warten ^^

  • StringFormat -- und kein bisschen weise?

    • autoiter
    • 5. November 2017 um 20:16

    Hallo Peter S. Taler

    Ich denke du gehst das falsch an. Normalerweise würde ich einen Style für das jeweilige Control suchen, der mir so etwas ermöglicht.

    Bei einer Message Box:

    AutoIt
    #include <MsgBoxConstants.au3>
    
    MsgBox($MB_RIGHT, "Test", 5554564.488)
  • Aus ini und txt Excel erzeugen aus mehreren Verzeichnissen

    • autoiter
    • 4. November 2017 um 08:33

    Hallo subzero007

    Zitat von subzero007

    Habe leider kein Ansatz oder weiss nicht wie ich anfangen soll kann mir jemand helfen stehe unter Druck muss dringend mein Chef was liefern und bin verzweifelt

    Es fällt mir wirklich schwer zu glauben, dass jemand mit über siebenhundert Beiträgen hier im Forum nicht einmal einen Ansatz hat, diese Aufgabe zu lösen. Ich glaube nicht, dass ich dir wirklich die Befehle DriveMapAdd, FileRead, FileWrite oder _Excel_RangeWrite nennen muss.

    Gibt es vielleicht ein Problem, dass du noch nicht genannt hast?

  • Rekursiv Dateien per Explorer Kontextmenü drucken

    • autoiter
    • 3. November 2017 um 18:44

    Hey Zeitriss,

    Toll, das du drüber geschaut hast. Wieder einmal vielen Dank für deine Hinweise. :)

    (Fühl dich bitte beklatscht. Den entsprechenden Emoji, finde ich nur zu aufgeregt, um ihn zu benutzen ;) )

    Der Hinweis auf den Fehler in _FileListToDict ist für mich Gold wert, weil ich die Funktion tatsächlich noch häufiger benutzen will. Du hast recht. Hier in diesem "Tool" sind die Dictionaries nicht wirklich ausgenutzt, da es wohl nie genug Dateien werden, dass man einen Geschwindigkeitsvorteil merkt. (Außerdem war ich wohl in einem unüberlegten Dictionary Rausch beim Schreiben. Das Objekt für nicht gedruckte Dateien ist völlig sinnlos ^^ ). Ansonsten würde ich das jetzt nicht wieder umschreiben zu Arrays, weil es ja keinen Nachteil gibt. Ich brauche die Daten ja nicht indexiert.

    Ja, GUICtrlCreateUpdown ist eigentlich sinniger als die Combobox. Ich hatte mich dafür wegen dem $CBS_DROPDOWNLIST-Style entschieden. Finde ich hübscher, als mit Inputfeld (war aber natürlich aus praktischer Sicht völliger Quatsch, weil man dabei die Auswahlmöglichkeiten vorher festlegen musste..). Das sollte ich sicher auch für mich ändern.

  • DNS-Server IP auslesen

    • autoiter
    • 2. November 2017 um 18:42

    Hallo alpines

    ich habe mit @IPAddress1 schon häufiger Probleme gehabt. Aktuell etwa belegt eine VPN Software diesen Platz..

    Hier gibt es auch noch ein paar schöne Methoden dazu von UEZ und Micha_he: Zuverlässig eigene IP auslesen?

  • Endungen ändern / Ausnahme

    • autoiter
    • 2. November 2017 um 14:11

    Hehe,

    gestern hat sich der TE bereits im englischen Forum für eine Lösung bedankt. Weder hier noch dort ein Hinweis. Das zum Thema:

    Zitat von bobmarley

    Im gegenteil, ich finde es normal so, selbst wenn das Problem dort gelöst wurde, werde ich auch die Lösung hier posten.

    und das Thema wird als gelöst markiert.

    .. und das nachdem hier so ein Fass aufgemacht wurde. :D

  • Rekursiv Dateien per Explorer Kontextmenü drucken

    • autoiter
    • 1. November 2017 um 19:34

    Hier habe ich ein kleines Skript, mit dem man - wie der Threadtitel bereits verrät - Dateien über das Kontextmenü des Explorers drucken kann.

    Es macht eigentlich nichts anderes als das bereits vorhandene Drucken/Print. Einziger Gewinn ist, dass man auch bei Ordnern in der Auswahl per Rechtsklick drucken kann. Wenn mindestens ein Ordner unter den markierten Dateien ist, erscheint eine kleine GUI, in der man einstellen kann, wie viele weitere Unterverzeichnisse auch nach druckbaren Dateien durchsucht werden sollen. Null meint keine - also nur die druckbaren Dateien in dem Ordner, eins meint auch die druckbaren Dateien in Verzeichnissen, die in diesem Ordner liegen usw.

    Hinweis: Es können nur Dateien gedruckt werden, bei denen auch der normale Windows-Eintrag "Drucken" oder "Print" im Kontextmenü vorhanden ist. Das unterscheidet sich mit der Software, die installiert ist. Ich habe mir nicht die Mühe gemacht, zu schauen wie man das am besten ausliest, sondern meine Konfiguration fest eingetragen. Bei mir ist Office installiert. Daher habe ich in die Liste der druckbaren Dateien etwa doc und xls eingetragen. Je nachdem, was man braucht, gilt es die Zeilen 106 und 110 anzupassen (oder es gleich ordentlich zu machen ;) )

    Siehe hierzu vllt. auch einen Diskussions-Thread dazu: Dateien drucken per Explorer Kontextmenü


    Das Skript kann solo ohne Installation getestet werden. Einfach Dateien im Explorer markieren und das Skript ausführen.

    Das Skript
    AutoIt
    #AutoIt3Wrapper_UseX64=Y
    #AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_stripped.au3"
    #AutoIt3Wrapper_Run_Au3Stripper=Y
    #Au3Stripper_Parameters=/PE /SF=1 /SV=1 /RM /SCI=1
    ;~ #pragma compile(Icon, '.\Avosoft-Warm-Toolbar-Print.ico') ; Dieses Icon ist nicht für kommerz. Nutzung frei.
    
    Opt("MustDeclareVars", 1)
    
    #include <WindowsConstants.au3>
    #include <Misc.au3>
    #include <GUIConstantsEx.au3>
    #include <FileConstants.au3> ; Für die Konstanten in _FileListToDict
    
    
    Global $sName = "Benutzerdefiniertes Drucken"
    
    
    _Main()
    
    Func _Main()
        If _Singleton($sName, 1) = 0 Then Exit ; Bei meheren markierten Dateien, wird das Skript duch das Kontextmenü mehrfach gestartet. Daher Abbruch.
    
        ; Zum Auslesen der markierten Dateien aus dem Explorer:
        ; ; LarsJ - https://www.autoitscript.com/forum/topic/162905-automating-windows-explorer/
        Local $hExplorer = WinGetHandle("[REGEXPCLASS:^(Cabinet|Explore)WClass$]")
        If Not $hExplorer Then Exit
    
        Local $oShell = ObjCreate("Shell.Application")
    
        For $oWindow In $oShell.Windows()
            If $oWindow.HWND() = $hExplorer Then ExitLoop
        Next
    
        Local $oPrintItems = ObjCreate("Scripting.Dictionary")
        Local $iFolder = 0
    
        For $oItem In $oWindow.Document.SelectedItems() ; Hier ein erster Schleifendurchlauf und Übertrag, um zu checken, ob Ordner markiert sind.
            $oPrintItems($oItem.Path()) = True ; Speicherung in ein neues Objekt, damit nicht eventuell während die GUI angezeigt wird, andere Dateien markiert werden können..
            If StringInStr(FileGetAttrib($oItem.Path()), "D") Then $iFolder += 1
        Next
    
        If $iFolder Then ; Wenn Ordner in Auswahl, dann Frage nach Rekursionstiefe.
                Local $iAnswer = _Gui($iFolder)
                If $iAnswer = -1 Then Exit MsgBox(64, $sName, "Drucken abgebrochen", 1)
        EndIf
    
        Local $iIsPrinted, $sNotPrinted = ""
    
        For $oItem In $oPrintItems.Keys ; Dateien werden in Schleife abgearbeitet.
            If StringInStr(FileGetAttrib($oItem), "D") Then
                Local $oFiles = _FileListToDict($oItem, True, -1, False, $iAnswer + 1, 1) ; Bei Ordnern wird in angegebener Rekursionstiefe nach weiteren Dateien gesucht und gedruckt.
                For $vFiles In $oFiles.Keys
                    $iIsPrinted = _PrintFile($vFiles)
                    If Not $iIsPrinted Then $sNotPrinted &= $vFiles & @CRLF ; Falls nicht gedruckt, werden Dateien zur späteren Ausgabe in $sNotPrinted gespeichert.
                Next
            Else
                $iIsPrinted = _PrintFile($oItem)
                If Not $iIsPrinted Then $sNotPrinted &= $oItem & @CRLF ; Falls nicht gedruckt, werden Dateien zur späteren Ausgabe in $sNotPrinted gespeichert.
            EndIf
        Next
        If $sNotPrinted <> "" Then ; Falls es Druckfehler gab, werden diese Dateien in MsgBox angezeigt.
            $sNotPrinted = "Folgende Dateien wurden nicht gedruckt: " & @CRLF & @CRLF & $sNotPrinted
            MsgBox(16, $sName, $sNotPrinted)
        EndIf
    EndFunc   ;==>_Main
    
    
    Func _Gui($iFolder)
        Local $sString = $iFolder & " Verzeichnis"
        If $iFolder > 1 Then $sString &= "se"
    
        Local $hGUI = GUICreate($sName, 400, 125, -1, -1, -1, $WS_EX_TOPMOST)
        GUISetFont(10, 600, "", "Segoe UI", $hGUI, 5)
        Local $idInputBox = GUICtrlCreateInput("0", 72, 48, 55, 25)
        GUICtrlCreateUpdown(-1)
        GUICtrlSetLimit(-1, 100)
        GUICtrlCreateLabel($sString & " ausgewählt. Wie viele weitere evtl.", 5, 5, 390, 20)
        GUICtrlCreateLabel("vorhandene Unterverzeichnisse sollen auch gedruckt", 5, 28, 390, 18)
        GUICtrlCreateLabel("werden?", 5, 51, 390, 18)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        Local $idOK = GUICtrlCreateButton("OK", 100, 95, 100, 25)
        Local $idAbort = GUICtrlCreateButton("Abbrechen", 215, 95, 100, 25)
    
        GUISetState()
    
        While 1
            Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE, $idAbort
                    GUIDelete($hGUI)
                    Return -1
                Case $idOK
                    Local $iAnswer = GUICtrlRead($idInputBox)
                    GUIDelete($hGUI)
                    Return $iAnswer
            EndSwitch
        WEnd
    EndFunc   ;==>_Gui
    
    
    Func _PrintFile($sFilePath)
        Local $sExtension = StringTrimLeft($sFilePath, StringInStr($sFilePath, '.', 0, -1))
        Switch $sExtension
            Case "xls", "xlsx", "doc", "docx", "odt", "rtf", "csv" ; Auswahl von Dateien, die in meinem Fall gedruckt werden sollen.
                ShellExecuteWait($sFilePath, "", @WorkingDir, "print", @SW_HIDE)
                If Not @error Then Return 1
                Sleep(50) ; Pause notwendig, weil sonst Fehlermeldungen, wegen gesperrten Dokumenten auftauchen (bei Office-Nutzung). Falls notwendig Pause verlängern.
            Case "pdf", "txt"
                Return ShellExecute($sFilePath, "", @WorkingDir, "print", @SW_HIDE) ; ShellExecute haut die Druckaufträge einfach raus. Bei ShellExecuteWait bleibt die Reihenfolge erhalten.
            Case Else
                Return 0
        EndSwitch
    EndFunc   ;==>_PrintFile
    
    
    ;===============================================================================
    ;
    ; Function Name:   _FileListToDict($vFolder[, $bRec[, $iFileInformation[, $bRelative[, $iMaxDepth[, $iFilesAndOrFolders]]]]])
    ; Description:     Speichert Dateien, optional mit einer gewählten Eigenschaft, in einerm Dictionary-Objekt.
    ; Parameter(s):    $vFolder = Ein Startverzeichnis oder ein eindimensionales Array von Startverzeichnissen für die Dateisuche.
    ;                  $bRec = Rekursive Dateisuche bei $bRec = True (Standardwert)
    ;                  $iFileInformation = In $oFiles.Items kann eine gewählte Datei-Information gespeichert werden.
    ;                   |-1 = Keine Information. $oFiles.Items = True. (Standardwert).
    ;                   |0 = Bearbeitungszeitpunkt
    ;                   |1 = Erstellzeitpunkt
    ;                   |2 = Letzte Zugriffszeit
    ;                   |-2 = Dateigröße in bytes
    ;                   |-3 = Dateigröße in größter erreichter Einheit.
    ;                  $bRelative = $oFiles.Keys haben relativem Dateipfad bei $bRelative = True (Standardwert = False).
    ;                  $iMaxDepth = Anzahl der ausgelesenen Unterverzeichnisse unterhalb der/des Startverzeichniss(es) (Standardwert = 100).
    ;                  $iFilesAndOrFolders = $oFiles.Keys haben relativem Dateipfad bei $bRelative = True (Standardwert = False).
    ;                   |0 = Dateien und Ordner
    ;                   |1 = Nur Dateien
    ;                   |2 = Nur Ordner
    ; Return Value(s): Zurückgegeben wird ein Objekt mit den kompletten oder relativen Dateipfaden als Key (abhängig von $bRelative)
    ;                  und in Abhängigkeit von $iFileInformation mit True oder Datei-Information als Item.
    ;
    ;                  @error kann folgende Werte annehmen (Kombinationen möglich, BitOr):
    ;                         0 = kein Fehler aufgetreten, alle Dateien wurden korrekt kopiert
    ;                         1 = Der übergebene Pfad ist kein existierendes Verzeichnis
    ;                         2 = Startverzeichnis-Array ist nicht eindimensional
    ; Author(s):       autoiter
    ; Modified:
    ; Remarks:
    ;===============================================================================
    Func _FileListToDict($vFolder, $bRec = True, $iFileInformation = -1, $bRelative = False, $iMaxDepth = 100, $iFilesOrFolders = 0)
    
        If $iFileInformation <> -1 Then
            Switch $iFileInformation
                Case 0
                    $iFileInformation = $FT_MODIFIED
                Case 1
                    $iFileInformation = $FT_CREATED
                Case 2
                    $iFileInformation = $FT_ACCESSED
                Case -2, -3 ; FileGetSize
                Case Else
                    $iFileInformation = -1
            EndSwitch
        EndIf
    
        If $bRec Then
            If $iMaxDepth < 1 Or Int($iMaxDepth) = 0 Then $iMaxDepth = 1
        EndIf
    
        If IsArray($vFolder) Then
            If UBound($vFolder, 2) > 1 Then Return SetError(2)
            Local $iMaxIndex = UBound($vFolder)
            Local $aFolder[$iMaxIndex], $iCount = 0
            For $i = 0 To $iMaxIndex - 1
                If Not StringInStr(FileGetAttrib($vFolder[$i]), "D") Then ContinueLoop
                $aFolder[$iCount] = $vFolder[$i]
                $iCount += 1
            Next
            If $iCount = 0 Then Return SetError(1)
            $iMaxIndex = $iCount
            ReDim $aFolder[$iMaxIndex]
        Else
            Local $iMaxIndex = 1
            Local $aFolder[$iMaxIndex]
            If Not StringInStr(FileGetAttrib($vFolder), "D") Then Return SetError(1)
            $aFolder[0] = $vFolder
        EndIf
    
        Local $oFiles = ObjCreate("Scripting.Dictionary")
    
        Local $aSearchFile[256], $sFile, $iDepth, $iInfo, $sFolder, $sStartFolder
    
        For $i = 0 To $iMaxIndex - 1
            $iDepth = 1
    
            $sFolder = StringRegExpReplace($aFolder[$i], "\\$", "")
    
            $sStartFolder = $sFolder ; Startfolder wird zur Bildung des vollen Dateipfades gespeichert.
    
            $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*")
            While $iDepth >= 0 ; In dieser Schleife werden alle Dateien/Ordner abgehandelt
                $sFile = FileFindNextFile($aSearchFile[$iDepth])
                If @extended And $bRec And $iDepth < $iMaxDepth Then ; Wenn es sich um ein Ordner handelt wird in diesem weiter gesucht - solange max. Rekursionstiefe nicht erreicht.
                    $iDepth += 1
                    $sFolder &= "\" & $sFile
                    If $iFilesOrFolders <> 1 Then $oFiles($sFolder) = $iInfo
                    $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*")
                ElseIf @error Then ; Wenn keine Dateien mehr im Ordner vorhanden sind wird das "Handle" Freigegeben
                    FileClose($aSearchFile[$iDepth])
                    $iDepth -= 1
                    $sFolder = StringRegExpReplace($sFolder, "\\[^\\]*$", "")
                Else
                    If $iFilesOrFolders <> 0 Then
                        If $iFilesOrFolders = 1 And StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then ContinueLoop
                        If $iFilesOrFolders = 2 And Not StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then ContinueLoop
                    EndIf
    
                    If $iFileInformation <> -1 Then
                        $iInfo = ""
                        Switch $iFileInformation
                            Case 0, 1, 2
                                $iInfo = FileGetTime($sFolder & "\" & $sFile, $iFileInformation, $FT_STRING)
                            Case -2
                                If Not StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then $iInfo = FileGetSize($sFolder & "\" & $sFile)
                            Case -3
                                If Not StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then $iInfo = __FileListToDict_ByteSuffix(FileGetSize($sFolder & "\" & $sFile))
                        EndSwitch
                        If @error Then ContinueLoop
                        If Not $bRelative Then
                            $oFiles($sFolder & "\" & $sFile) = $iInfo
                        Else
                            $oFiles(StringReplace($sFolder, $sStartFolder, "") & "\" & $sFile) = $iInfo
                        EndIf
                    Else
                        If Not $bRelative Then
                            $oFiles($sFolder & "\" & $sFile) = True
                        Else
                            $oFiles(StringReplace($sFolder, $sStartFolder, "") & "\" & $sFile) = True
                        EndIf
                    EndIf
                EndIf
            WEnd
        Next
        Return SetError(0, $oFiles.Count, $oFiles)
    EndFunc   ;==>_FileListToDict
    
    Func __FileListToDict_ByteSuffix($iBytes) ; Aus der Hilfe zu FileGetSize.
        Local $iIndex = 0, $aArray = [' bytes', ' KB', ' MB', ' GB', ' TB', ' PB', ' EB', ' ZB', ' YB']
        While $iBytes > 1023
            $iIndex += 1
            $iBytes /= 1024
        WEnd
        Return Round($iBytes) & $aArray[$iIndex]
    EndFunc   ;==>__FileListToDict_ByteSuffix
    Alles anzeigen
    Installation in Kontextmenü


    Hier ein Skript zum Installieren in das Kontextmenü (muss im Skriptverzeichnis liegen. Skript muss kompiliert im Verzeichnis vorhanden sein - kann man natürlich auch alles ändern..)

    AutoIt
    #RequireAdmin
    
    Global $sName = "Benutzerdefiniertes Drucken"
    Global $bError = False
    
    RegWrite("HKEY_CLASSES_ROOT\*\shell\" & $sName)
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\*\shell\" & $sName, "", "REG_SZ", $sName)
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\*\shell\" & $sName, "Icon", "REG_SZ", '"' & @ScriptDir & '\' & $sName & '.exe"')
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\*\shell\" & $sName & "\command")
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\*\shell\" & $sName & "\command", "", "REG_SZ", '"' & @ScriptDir & '\' & $sName & '.exe"')
    If @error Then $bError = True
    
    
    RegWrite("HKEY_CLASSES_ROOT\Folder\shell\" & $sName)
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\Folder\shell\" & $sName, "", "REG_SZ", $sName)
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\Folder\shell\" & $sName, "Icon", "REG_SZ", '"' & @ScriptDir & '\' & $sName & '.exe"')
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\Folder\shell\" & $sName & "\command")
    If @error Then $bError = True
    RegWrite("HKEY_CLASSES_ROOT\Folder\shell\" & $sName & "\command", "", "REG_SZ", '"' & @ScriptDir & '\' & $sName & '.exe"')
    If @error Then $bError = True
    
    
    If $bError Then
    RegDelete("HKEY_CLASSES_ROOT\*\shell\" & $sName)
    RegDelete("HKEY_CLASSES_ROOT\Folder\shell\" & $sName)
    Exit MsgBox(16, $sName, "Fehler beim Installieren. Keine Änderungen vorgenommen.")
    EndIf
    MsgBox(64, $sName, "Installation abgeschlossen.")
    Alles anzeigen
    Deinstallation aus dem Kontextmenü
    AutoIt
    #RequireAdmin
    Global $sName = "Benutzerdefiniertes Drucken"
    Global $bNothing = False
    Global $iError = 0
    $iTest = RegDelete("HKEY_CLASSES_ROOT\*\shell\" & $sName)
    $iError = @error
    If $iTest = 0 And $iError = 1 Then $bNothing = True
    RegDelete("HKEY_CLASSES_ROOT\Folder\shell\" & $sName)
    $iError = @error
    If $iTest = 0 And $iError = 1 Then
        If $bNothing Then Exit MsgBox(64, $sName, "Ein Fehler ist aufgetreten. Programm ist nicht installiert.")
    EndIf
    If $iError <> 0 Then
        MsgBox(16, $sName, "Ein Fehler ist aufgetreten. Deinstallation nicht möglich.")
    Else
        MsgBox(64, $sName, "Deinstallation erfolgreich.")
    EndIf
    Alles anzeigen

    Im Anhang nochmal die Skripte zusammen mit einem Icon.

    EDIT: Das Skript wurde nach Beitrag 2 nochmal leicht bearbeitet. Zwar ohne sichtbaren Effekt, aber nun ohne Fehler.

    Dateien

    Drucken aus Kontextmenü.zip 32,66 kB – 658 Downloads
  • Daten in Array strukturieren

    • autoiter
    • 1. November 2017 um 17:24

    Hallo tubsids

    du benutzt einfach den falschen Befehl aus der UDF.

    Aus der Hilfe zu _Excel_RangeInsert: Inserts one or multiple empty cells, rows or columns into the specified worksheet

    Du kannst damit also leere Zellen, Zeilen oder Spalten einfügen..

    Du musst den Befehl _Excel_RangeWrite benutzen.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™