Moin Oscar ,
gute Sache, danke!
Nur eine Anmerkung, auch wenn es in diesem Fall keine Rolle spielen sollte:
<?xml version="1.0" encoding="UTF-8"?>
Moin Oscar ,
gute Sache, danke!
Nur eine Anmerkung, auch wenn es in diesem Fall keine Rolle spielen sollte:
<?xml version="1.0" encoding="UTF-8"?>
Moin,
um noch einmal auf das ß zurückzukommen:
Der Standard-Zeichensatz für englische und deutsche Windows-Versionen ist CP1252. Dieser Zeichensatz enthält das ß auf Position DF. Wenn die Konvertierung nicht gelingt, scheint mir das Prolem eher hier zu liegen:
é,ü,ö,Ã,ä,è
é,ü,ö,ß,ä,è
Hammersbacher StraÃe
Die UTF-8 Codierung für das Zeichen ß ist kein einzelnes Ã, sondern die Folge ß. Das Zeichen à leitet immer eine zwei byte lange Folge ein, die zusammen ein Zeichen ergeben.
In Deinem Fall ist also entweder schon beim Erstellen des Seiteninhalts bei der UTF-8 Kodierung etwas vermasselt worden oder das fehlende Ÿ wird in Deinem Skript entfernt.
Bspw. + statt X zu verwenden geht nicht - bei uns hier schon 😅 .
Das + ist ein Kopierschutz. Man kann damit eindeutig erkennen, ob jemand abgeschrieben hat. ![]()
Es gibt keinen maximalen Zeilenparameter. Nur das Minimum existiert, ist m.M.n. aber 3:
Da hast Du aber eine Spitze auf einen frischen Austrieb eines jüngst gefällten Tannenbaums gesteckt. ![]()
Die 32 habe ich willkürlich gesetzt, weil das Ganze irgendwann sinnlos wird. Die Funktion verkraftet auch 1024.
Moin,
in der Hoffnung, dass als viertes Zeichen auch das Leerzeichen erlaubt ist:
Weihnachtsbaum(20)
Func Weihnachtsbaum($iZeilen)
If Not IsInt($iZeilen) Or $iZeilen < 5 Or $iZeilen > 32 Then
MsgBox(16, "Fehler", "Der Parameter $iZeilen ist ungültig: " & $iZeilen)
Return False
EndIf
Local $iLinks = $iZeilen - 1 ; bei zwei Leerzeichen am linken Rand
Local $sLeer = ""
For $I = 1 To $iLinks
$sLeer &= " "
Next
ConsoleWrite(StringLeft($sLeer, $iLinks) & "*" & @CRLF)
Local $sBaum = "+"
For $I = 1 To $iZeilen - 2
ConsoleWrite(StringLeft($sLeer, $iLinks) & $sBaum & @CRLF)
$iLinks -= 1
$sBaum &= "++"
Next
ConsoleWrite(StringLeft($sLeer, $iZeilen - 2) & "| |" & @CRLF)
Return True
EndFunc
Alles anzeigen
Ich wünsche Allen ein frohes Weihnachtsfest und einen guten neues Jahr.
Mein Script öffnet und aktualisiert in definierten Intervallen eine HTML Seite, die aus Excel erzeugt wird.
Moin,
läuft das Scannen in einem eigenen Skript oder hast Du alles in ein Skript gesteckt?
Wenn die vom System aufgerufenen Hookprozeduren nicht in angemessener Zeit beendet werden, entfernen die 'moderneren' Windows Versionen den Hook gnadenlos und endgültig. Das könnte erklären, warum das Skript nicht mehr auf den Scanner reagiert. Andererseits ist nicht ersichtlich, weshalb die Hookprozedur die maximale Zeit überschreiten sollte. Der Code tut ja nichts Aufregendes.
Moin,
au3 und txt Dateien kannst Du locker mit einem Skript durchsuchen. Außerdem hat SciTE eine FindInFiles Option. Ich habe nicht probiert, ob das auch rekursiv geht. Bei PSPad klappt es.
Moin,
bei der Anzahl der Sätze in den Dateien ist das kein Muss, es liefert aber trotzdem ein schönes Beispiel für den Einsatz von Maps:
; ----------------------------------
; INFO : Aufbau der Fernsehliste.sdx
; ----------------------------------
; Beispielzeile (Zeilenumbruch @LF) :
; SATCODX103Astra 1 (19.2E) TMPG20113030001ServusTV0192___ ______220002____________049140000101007_____________ HD Deutschl
; Die Sendernamen sind gesplittet, aber immer an festen Positionen.
; ==> max 8 Zeichen an Position 44..52 und (falls länger) max 12 Zeichen an Position 116..128
; Der Sendername aus der .SDX-Datei ist max. 20 Zeichen lang, z.B. :
; ServusTV HD Deutschl
; Zu beachten : Die Senderliste aus dem Netz enthält die vollständigen Namen, also z.B. :
; ServusTV HD Deutschland -> wird auf 20 Zeichen gekürzt
; $sNETSource = BinaryToString(InetRead("https://www.satindex.de/tv/1/1/0/"), 4) ; UTF8
; $sPattern = '<div class="col freqx_1" >.*?">(.*?)</a></div>'
; $sNETSource = FileRead(@ScriptDir & "\Satindex.txt") ; UTF8
Dim $sSatURL = "https://www.satindex.de/tv/1/1/0/"
Dim $sSatFile = @ScriptDir & "\Satindex.txt"
Dim $sSDXLst = @ScriptDir & "\Fernsehliste.sdx"
Dim $sSDXNeu = @ScriptDir & "\Fernsehliste_neu.sdx"
Dim $sPattern = '<div class="col freqx_1" ><a[^>]+>\K[^<]{1,20}' ; unter col freqx_1 sind die Sendernamen gelistet
; Einlesen der Satindex.txt in ein Map-Objekt :
Dim $mSatNames[] ; Map
; For $sName In StringRegExp(FileRead($sSatFile), $sPattern, 3)
For $sName In StringRegExp(BinaryToString(InetRead($sSatURL), 4), $sPattern, 3)
$mSatNames[$sName] = 1
Next
; Einlesen der Fernsehliste.sdx in ein Array :
Dim $sSDXName
Dim $aSDXList = FileReadToArray($sSDXLst)
; Daten vergleichen und neues Array mit Treffern erstellen :
Dim $aNewList[UBound($aSDXList)]
Dim $iNew = 0
For $sLine In $aSDXList
$sSDXName = StringStripWS(StringMid($sLine, 44, 8) & StringMid($sLine, 116, 12), 3)
If MapExists($mSatNames, $sSDXName) Then
$aNewList[$iNew] = $sLine
$iNew += 1
EndIf
Next
ReDim $aNewList[$iNew]
; Neues Array anzeigen :
Dim $hGui = GUICreate("Bereinigte Senderliste", 1000, 600)
Dim $idFile = GUICtrlCreateMenu("&Datei")
Dim $idSave = GUICtrlCreateMenuItem("&Speichern", $idFile)
Dim $idExit = GUICtrlCreateMenuItem("&Beenden", $idFile)
GUISetFont(9, Default, Default, "Consolas")
Dim $idLV = GUICtrlCreateListView("Index|Senderdaten", 0, 0, 1000, 600)
For $iLV = 0 To UBound($aNewList) - 1
GUICtrlCreateListViewItem($iLV & "|" & $aNewList[$iLV], $idLV)
Next
GUICtrlSendMsg($idLV, 0x101E, 1, -2) ; LVM_SETCOLUMNWIDTH
GUISetState()
While True
Switch GuiGetMsg()
Case -3
Exit
Case $idExit
Exit
; Case $idSave
; _Save()
EndSwitch
WEnd
; ==> Array in eine neue Datei schreiben (nicht getestet):
Func _Save()
Local $hFile = FileOpen($sSDXNeu, 514) ; $FO_OVERWRITE + $FO_ANSI
If $hFile = -1 Then
MsgBox(16, "", "Die Datei " & $sSDXNeu & " konnte nicht neu erstellt werden!")
Return
EndIf
For $Line In $aNewList
FileWrite($hFile, $Line & @LF)
Next
FileClose($hFile)
EndFunc
Alles anzeigen
Ich erwarte grundsätzlich von einem "Programmierer" , dass der mit seinem Handwerkszeug Programmiersprache umgehen kann. Und ja, warum auch nicht Copypasten? Wo ist das Problem aus bspw. _FileWriteFromArray() ein _FileWriteFromArrayCR() oder _FileWriteFromArrayLF() oder _FileWriteFromArrayANSI() zu erstellen oder die Funktion, wie von dir vorgeschlagen, mit entsprechend erweiterten Parametern auszustatten?!
Mein höchstpersönlicher Senf zu diesem Thema:
Wenn der "Programmierer" das locker meistert, hat er oft keinen Grund, die UDF zu benutzen. Wenn es z.B. darum geht, ein eindimensionales Array in eine Datei zu schreiben, sind das Einbinden der <Array.au3> und der Aufruf von _FileWriteFromArray() ziemlich unnötig. Es ist auch gut möglich, dass die Lernkurve von Einsteigern durch die vielen vorhandenen UDFs eher abgeflacht wird.
Moin,
beim Regex fehlt ein Leerzeichen: <div class="col freqx_1" >
Wenn Du nur die Namen haben willst, kannst Du das mal probieren:
#include <Array.au3>
#include <Inet.au3>
$sHTML = BinaryToString(_INetGetSource("https://www.satindex.de/tv/1/1/0/", 0), 4) ; UTF8
$oHtmlDoc = ObjCreate("HTMLFILE")
$oHtmlDoc.open()
$oHtmlDoc.write($sHTML)
$oHtmlDoc.close()
While $oHtmlDoc.readyState <> "complete"
Sleep(10)
WEnd
$oNodeList = $oHtmlDoc.querySelectorAll('a[title^="Senderdaten"]')
Dim $aSender[$oNodeList.length]
Dim $I = 0
For $Node In $oNodeList
$aSender[$I] = $Node.innerText
$I += 1
Next
_ArrayDisplay($aSender)
Exit
Alles anzeigen
Moin,
das mit meiner Map kannst Du vergessen. Ich habe die Aufgabenstellung falsch verstanden. Ich habe jetzt aber noch eine Array-basierte Lösung, die - so sie denn macht was Du willst - das Array in der ursprünglichen Reihenfolge belässt.
Du kannst ja mal probieren. Bei sehr großen Eingabedateien mag es allerdings etwas dauern. Die Ergebnisausgabe per MsgBox ist auch suboptimal. ![]()
#include <Date.au3>
; ======================================================================================================================
; $aCSV = FileReadToArray("CSV.csv")
Dim $aCSV = ["1-G;10/10/2022 00:10:55", _
"2-G;10/10/2022 00:12", _
"3-G;10/10/2022 00:13", _
"1-G;10/10/2022 00:13:12", _
"4-G;10/10/2022 00:14", _
"1-G;10/10/2022 00:14:00", _
"2-G;10/10/2022 00:14", _
"6-G;10/10/2022 00:14", _
"7-G;10/10/2022 00:14", _
"1-G;10/10/2022 00:20:00"]
Dim $aLine1, $aLine2, $iCount, $sDate1, $sDate2, $sName
For $I = 0 To UBound($aCSV) - 1
If $aCSV[$I] <> "" Then
$aLine1 = StringSplit($aCSV[$I], ";")
$iCount = 1
$sName = $aLine1[1]
$sDate1 = ToDate($aLine1[2])
For $J = $I + 1 To UBound($aCSV) - 1
If $aCSV[$J] <> "" Then
$aLine2 = StringSplit($aCSV[$J], ";")
$sDate2 = ToDate($aLine2[2])
If _DateDiff("s", $sDate1, $sDate2) > 300 Then ExitLoop
If $aLine2[1] = $sName Then
$iCount += 1
$aCSV[$J] = ""
EndIf
EndIf
Next
$aCSV[$I] &= ";" & $iCount
EndIf
Next
Dim $sOut = ""
For $Line In $aCSV
If $Line <> "" Then $sOut &= $Line & @CRLF
Next
MsgBox(0, "Ergebnis", $sOut)
; ======================================================================================================================
Func ToDate($Str)
Local $aDT = StringSplit($Str, "/ ")
Return $aDT[3] & "/" & $aDT[2] & "/" & $aDT[1] & " " & $aDT[4]
EndFunc
Alles anzeigen
Moin,
ich habe versucht, das mit einer Map zu lösen (braucht 3.3.16+). Das Ausgabeformat des Datums entspricht noch nicht Deiner Vorgabe, das lässt sich aber einfach anpassen.
#include <Date.au3>
; $aCSV = FileReadToArray("CSV.csv")
Dim $aCSV = ["1-G;10/10/2022 00:10:55", _
"2-G;10/10/2022 00:12", _
"3-G;10/10/2022 00:13", _
"1-G;10/10/2022 00:13:12", _
"4-G;10/10/2022 00:14", _
"1-G;10/10/2022 00:14:00", _
"2-G;10/10/2022 00:14", _
"6-G;10/10/2022 00:14", _
"7-G;10/10/2022 00:14", _
"1-G;10/10/2022 00:20:00"]
Dim $mTmp[]
Dim $aTmp[2]
Dim $sOut = ""
Dim $aDT, $aLN, $sDate, $sName
For $LN In $aCSV
$aLN = StringSplit($LN, ";")
$sName = $aLN[1]
$aDT = StringSplit($aLN[2], "/ ")
$sDate = $aDT[3] & "/" & $aDT[2] & "/" & $aDT[1] & " " & $aDT[4]
If MapExists($mTmp, $sName) Then
$aTmp = $mTmp[$sName]
If _DateDiff("s", $aTmp[0], $sDate) <= 300 Then
$aTmp[1] += 1
$mTmp[$sName] = $aTmp
ContinueLoop
EndIf
If $aTmp[1] > 1 Then
$sOut &= $sName & ";" & $aTmp[0] & ";Anzahl innerhalb 5 Min;" & $aTmp[1] & @CRLF
EndIf
EndIf
$aTmp[0] = $sDate
$aTmp[1] = 1
$mTmp[$sName] = $aTmp
Next
For $K In MapKeys($mTmp)
$aTmp = $mTmp[$K]
If $aTmp[1] > 1 Then
$sOut &= $K & ";" & $aTmp[0] & ";Anzahl innerhalb 5 Min;" & $aTmp[1] & @CRLF
EndIf
Next
MsgBox(0, "Ergebnis", $sOut)
Alles anzeigen
Gibt es übrigens wirklich unterschiedliche Zeitangaben (mit/ohne Sekunden) in der CSV-Datei?
Moin!
ZitatA Map is a variable containing a series of data elements, each consisting of a key/value pairing. An element can only be accessed by a key, which can be either a string or an integer
Floats werden offenbar auf den Integerteil zusammengekürzt, die anderen Datentypen werden als Key 0 abgebildet.
Moin,
nach dem GUISetState() braucht es noch etwas Zeit, bis das Fenster im Vordergrund angezeigt wird. Bei mir reicht es, wenn ich dahinter ein WinWaitActive($hGUI) einfüge.
MfG, Velted
Moin,
wenn die Anzahl der Zeilen in der Datei nicht begrenzt ist, solltest Du ein Edit Control verwenden. Darin kannst Du bei Bedarf scrollen. Wenn nichts verändert werden darf, musst Du den Stil $ES_READONLY ergänzen.
Zitat... und mit FileMove bekomme ich es so nicht hin.
Moin Alina
was bekommst Du wie nicht hin? Und warum hast Du die Option MULTISELECT aktiviert?
SWbemServices.ExecQuery() gibt eine SWbemObjectSet Collection zurück, wenn man nicht das Flag wbemFlagForwardOnly setzt. Mit dem Flag soll es nach MS schneller gehen und weniger Speicher verbrauchen, andererseits verfügt die 'normale' Collection über eine Count Eigenschaft, die die Anzahl der Einträge liefert. Damit sollte sich das 'Array-Dim-Gehampel' erübrigen, weil die maximale Anzahl der Einträge feststeht. Wenn Leereinträge übersprungen werden sollen, kann man mitzählen und das Array zum Schluss passend eindampfen.
Moin,
wenn Du nichts Anderes bestimmst, werden Label-Controls mit der Hintergrundfarbe des Fensters gezeichnet.
Global $GUIBKCOLOR = 0x738599
Das ist zwar kein Schwarz, erweckt aber beim kurzen Flackern einen recht dunklen Eindruck.
Wenn Du den Fensterhintergrund auf Weiß setzt, siehst Du den Unterschied.
Für GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT) muss AutoIt in den Zeichenprozess eingreifen. Wie das geschieht, bleibt bei "Closed Source" ein Geheimnis.
Das Folgende funktioniert hier recht gut bei 10 Hz (100 ms);
#include <ColorConstants.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Dim $sPic = "C:\Windows\Web\Wallpaper\Theme1\img1.jpg" ; <<<<< ggf. ändern
Dim $sTxt = "Das ist der Text in Version "
Dim $iCount = 1
Dim $hGui = GUICreate("Test", 800, 600, -1, -1, -1, $WS_EX_COMPOSITED)
Dim $idLab = GUICtrlCreateLabel($sTxt & $iCount & ".", 0, 290, 800, 20, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetFont(-1, 10, $FW_BOLD)
GUICtrlSetColor(-1, $CLR_WHITE)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
Dim $idPic = GUICtrlCreatePic($sPic, 0, 0, 800, 600) ; <<<<< Das Hintergrundbild muss nachträglich eingefügt werden!!!
GUISetState(@SW_SHOW)
Dim $hStart = TimerInit()
While True
If GUIGetMsg() = -3 Then Exit
If TimerDiff($hStart) > 100 Then
$iCount += 1
GUICtrlSetData($idLab, $sTxt & $iCount & ".")
$hStart = TimerInit()
EndIf
WEnd
Exit
Alles anzeigen
Aber ich gehe halt mal davon aus dass das noch ein Bug von Autoit ist und hoffe mal darauf dass es in der nächsten Version behoben sein wird.
Moin,
da irrst Du gewaltig. AutoIt verändert zwar den Inhalt der Controls durch das Senden entsprechender Nachrichten, um die Darstellung auf dem Bildschirm kümmert sich aber das System, in diesem Fall höchstwahrscheinlich der Desktop Window Manager (DWM), zusammen mit den vom System bereitgestellten Fensterprozeduren für die Windows Standardcontrols. Man kann das nur durch das setzen von Styles bzw. Exstyles beeinflussen.
Moin,
ich habe das mal eingearbeitet. Die IDs der zu behandelnden Inputs werden in der globalen Variablen $sInputs gesammelt. Mit AutoIt 3.3.16 böte sich eine Lösung per Map an.
Solche 'Komfortfunktionen' machen für mich allerdings nur Sinn, wenn auch bereits bei derEingabe geprüft wird, ob die Daten 'sinnvoll' sind (z.B. Pause-Beginn nach Arbeit-Beginn oder Pause-Ende nach Pause- Beginn oder Pause nicht länger als 10 Stunden oder ...).
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
;~ #include <Array.au3>
;~ #include <Debug.au3>
#include <Date.au3>
Opt('MustDeclareVars', 1)
Global $ankunftzeit, $pause_bgn_zeit, $pause_end_zeit, $datum
$datum = _DateDayOfWeekDeutsch(@WDAY) & ", " & _NowDate()
Global $sInputs = "|"
#Region ### START Koda GUI section ### Form=c:\users\wkivag15\documents\zeitrechner_neu_hgui.kxf
Global $g_hGUI = GUICreate("Zeitrechner", 520, 353, 617, 296)
GUISetFont(12, 400, 0, "Calibri")
Global $idLbl_datum = GUICtrlCreateLabel($datum, 16, 22, 250, 29)
GUICtrlSetFont(-1, 14, 400, 0)
Global $idBtn_ankunft = GUICtrlCreateButton("Ankunft", 16, 80, 107, 29)
Global $idInp_ankunft = GUICtrlCreateInput("08:00", 128, 80, 80, 29, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlCreateLabel ("Uhr", 210, 80, 30, 29)
$sInputs &= $idInp_ankunft & "|"
Global $idBtn_pause_bgn = GUICtrlCreateButton("Pause Begin", 16, 120, 107, 29)
Global $idInp_pause_bgn = GUICtrlCreateInput("12:00", 128, 119, 80, 29, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlCreateLabel ("Uhr", 210, 119, 30, 29)
$sInputs &= $idInp_pause_bgn & "|"
Global $idBtn_pause_end = GUICtrlCreateButton("Pause Ende", 16, 160, 107, 29)
Global $idInp_pause_end = GUICtrlCreateInput("12:30", 128, 159, 80, 29, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlCreateLabel ("Uhr", 210, 159, 30, 29)
$sInputs &= $idInp_pause_end & "|"
Global $idLbl_feierabend = GUICtrlCreateLabel("Feierabend", 270, 80, 110, 29)
Global $idInp_feierabend = GUICtrlCreateInput("18:00", 371, 80, 95, 29, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlCreateLabel ("Uhr", 470, 80, 30, 29)
$sInputs &= $idInp_feierabend & "|"
Global $idLbl_Label6 = GUICtrlCreateLabel("Soll-Arbeitzeit", 270, 119, 116, 29)
Global $idInp_soll_zeit = GUICtrlCreateInput("07:48", 371, 119, 95, 29, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlCreateLabel ("Std.", 470, 119, 30, 29)
Global $idLbl_laenge_pause = GUICtrlCreateLabel("Länge der Pause", 16, 224, 125, 25)
Global $idInp_laenge_der_pause = GUICtrlCreateLabel("", 170, 224, 80, 29)
Global $idLbl_Label8 = GUICtrlCreateLabel("Frühester Feierabend", 14, 260, 175, 25)
Global $idInp_frue_zeit = GUICtrlCreateLabel("", 170, 260, 80, 29)
Global $idLbl_Label9 = GUICtrlCreateLabel("Spätester Feierabend", 14, 298, 168, 25)
Global $idInp_spaet_zeit = GUICtrlCreateLabel("", 170, 298, 80, 29)
Global $idLbl_Label7 = GUICtrlCreateLabel("Tatsächliche Arbeitzeit", 270, 224, 186, 25)
Global $idInp_tats_zeit = GUICtrlCreateLabel("", 430, 224, 80, 29)
Global $idLbl_Label4 = GUICtrlCreateLabel("Überstunden heute", 270, 260, 183, 25)
Global $idInp_ueberstunden_heute = GUICtrlCreateLabel("", 430, 260, 80, 29)
Global $idLbl_Label10 = GUICtrlCreateLabel("Pause nach 6 Stunden", 270, 298, 187, 25)
Global $idInp_pause_6std = GUICtrlCreateLabel("", 430, 298, 80, 29)
Global $idBtn_calculate = GUICtrlCreateButton("Berechnen", 270, 159, 222, 29)
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')
#EndRegion ### END Koda GUI section ###
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $idBtn_ankunft
$ankunftzeit = (_NowTime(4))
GUICtrlSetData($idInp_ankunft, $ankunftzeit)
Case $idBtn_pause_bgn
$pause_bgn_zeit = (_NowTime(4))
GUICtrlSetData($idInp_pause_bgn, $pause_bgn_zeit)
Case $idBtn_pause_end
$pause_end_zeit = (_NowTime(4))
GUICtrlSetData($idInp_pause_end, $pause_end_zeit)
;~ _ComputeAll()
Case $idBtn_calculate
GUICtrlSetColor($idLbl_Label9, 0xFF0000)
GUICtrlSetColor ($idInp_spaet_zeit, 0xFF0000)
_Std_Uhr()
_ComputeAll()
EndSwitch
WEnd
Func _WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
Local $id = BitAND($wParam, 0x0000FFFF)
Local $code = BitShift($wParam, 16)
If StringInStr($sInputs, "|" & $id & "|") AND $code = $EN_UPDATE Then
GUICtrlSetData($id, _FormatInputNumber(GUICtrlRead($id)))
EndIf
Return $GUI_RUNDEFMSG
EndFunc
Func _FormatInputNumber($iNumber)
If StringRegExp($iNumber, '^:|[^:\d]|:.*:') Then Return StringTrimRight($iNumber, 1)
Local $tmp = StringSplit($iNumber, ":")
Switch $tmp[0]
Case 1
; If first digit is > 2, lets say 8 then write 08:
If StringLeft($tmp[1], 1) > 2 Then $tmp[1] = "0" & $tmp[1] & ":"
; values from 00:00 to 23:59 are possible
If $tmp[1] > 23 Then Return StringTrimRight($iNumber, 1)
; user types in only the digits, the : is inserted automatically
If StringLen($tmp[1]) = 2 Then $tmp[1] &= ":"
If StringLen($tmp[1]) > 3 Then Return "don't fool me !"
Return $tmp[1]
Case 2
If StringLen($tmp[1]) < 2 Then $iNumber = "0" & $tmp[1] & ":"
; If the users types in 12:7 then the input should just show 12:
If StringLeft($tmp[2], 1) > 5 Then Return StringTrimRight($iNumber, 1)
Return $iNumber
EndSwitch
EndFunc
Func _Std_Uhr ()
GUICtrlCreateLabel ("Std.", 210, 224, 30, 29)
GUICtrlCreateLabel ("Uhr", 210, 260, 30, 29)
GUICtrlCreateLabel ("Uhr", 210, 298, 30, 29)
GUICtrlSetColor (-1, 0xFF0000)
GUICtrlCreateLabel ("Std.", 470, 224, 30, 25)
GUICtrlCreateLabel ("Std.", 470, 260, 30, 25)
GUICtrlCreateLabel ("Uhr", 470, 298, 30, 25 )
EndFunc
Func _DateDayOfWeekDeutsch($iDayNum, $iShort = 0)
; The first element (0) is intentionally empty. The valid range is 1 - 7. It is important
; this empty element is preserved or the days will be off by one.
Local Const $aDayOfWeek[8] = ["", "Sonntag", "Montag", "Dienstag", "Mittwoch", "Donnerstag", "Freitag", "Samstag"]
Select
Case Not StringIsInt($iDayNum) Or Not StringIsInt($iShort)
Return SetError(1, 0, "")
Case $iDayNum < 1 Or $iDayNum > 7
Return SetError(1, 0, "")
Case Else
Select
Case $iShort = 0
Return $aDayOfWeek[$iDayNum]
Case $iShort = 1
Return StringLeft($aDayOfWeek[$iDayNum], 3)
Case Else
Return SetError(1, 0, "")
EndSelect
EndSelect
EndFunc ;==>_DateDayOfWeekDeutsch
Func _ComputeAll()
ConsoleWrite('_ComputeAll(' & _NowTime() & ')' & @CRLF)
Local $sTime, $iTime, $iTime1, $iTime2, $iTime3, $iPause
;~ länge Pause
$iTime1 = _GetMins($idInp_pause_bgn) ; Minuten
$iTime2 = _GetMins($idInp_pause_end) ; Minuten
$sTime = _SubTime($iTime2, $iTime1) ; hh:nn
$iPause = @extended
GUICtrlSetData($idInp_laenge_der_pause, $sTime)
;~ tats arbeitszeit
$iTime1 = _GetMins($idInp_ankunft)
$iTime2 = _GetMins($idInp_feierabend)
$sTime = _SubTime($iTime2 - $iPause, $iTime1)
GUICtrlSetData($idInp_tats_zeit, $sTime)
;~ überstd heute
$iTime1 = _GetMins($idInp_tats_zeit)
$iTime2 = _GetMins($idInp_soll_zeit)
$sTime = _SubTime($iTime1, $iTime2)
$iTime = @extended
If $iTime < 1 Then $sTime = '00:00' ; "00:00"
;~ If $iTime < 1 Then $sTime = '' & $sTime ; "-02:15"
GUICtrlSetData($idInp_ueberstunden_heute, $sTime)
;~ früh feierabend
$iTime1 = _GetMins($idInp_ankunft)
$iTime2 = _GetMins($idInp_soll_zeit)
$iTime3 = _GetMins($idInp_laenge_der_pause)
$sTime = _SubTime($iTime3, $iTime1 + $iTime2)
GUICtrlSetData($idInp_frue_zeit, $sTime)
;~ spä Feierabend
;~ Local $max_arbeit_zeit = "10:00"
$iTime1 = _GetMins($idInp_ankunft)
$iTime2 = _GetMins('10:00')
$iTime3 = _GetMins($idInp_laenge_der_pause)
$iTime = $iTime1 + $iTime2 + $iTime3
$sTime = StringRight('0' & Int($iTime / 60), 2) & ':' & StringRight('0' & Mod($iTime, 60), 2)
GUICtrlSetData($idInp_spaet_zeit, $sTime)
;~ pause nach 6 std
$iTime1 = _GetMins($idInp_ankunft)
$iTime2 = _GetMins('06:00')
$iTime = $iTime1 + $iTime2
$sTime = StringRight('0' & Int($iTime / 60), 2) & ':' & StringRight('0' & Mod($iTime, 60), 2)
GUICtrlSetData($idInp_pause_6std, $sTime)
EndFunc ;==>_ComputeAll
Func _GetMins($idCtrl) ; idCtrl or string eg. "08:15"
Local $aSplit = StringSplit(IsString($idCtrl) ? $idCtrl : GUICtrlRead($idCtrl), ':', 2)
If UBound($aSplit) < 2 Then Exit 999
Return $aSplit[0] * 60 + $aSplit[1] ; Minuten
EndFunc
; $iTime1 - $iTime2 (in Minuten)
Func _SubTime($iTime1, $iTime2)
Local $_iTime = $iTime1 - $iTime2
Local $_sTime = StringRight('0' & Int($_iTime / 60), 2) & ':' & StringRight('0' & Mod($_iTime, 60), 2)
Return SetExtended($_iTime, $_sTime) ; hh:nn and @extended = Minuten
EndFunc
Alles anzeigen
Die Berechnung des 'frühesten Feierabends' ist übrigens nicht korrekt.
Viel Spaß, Velted
Moin,
mal ein Beispiel für das Aufteilen der eingelesenen Daten:
; Eingelesene Daten
Global $sData = "T6FUS0127;8806092585201;20;IMEI1;IMEI2;IMEI3;IMEI4;IMEI5;IMEI6;IMEI7;IMEI8;IMEI9;IMEI10;IMEI11;IMEI12;IMEI13;IMEI14;IMEI15;IMEI16;IMEI17;IMEI18;IMEI19;IMEI20"
ProcessScan($sData)
Exit
Func ProcessScan($sScan)
; Daten in ein Array aufsplitten, Feldbegrenzer ist ";"
Local $aScan = StringSplit($sScan, ";")
; Wenn der Feldbegrenzer gefunden wurde und die Zahl im Feld 3 der Anzahl der folgengenden Felder entspricht ...
If Not @error And ($aScan[3] = ($aScan[0] - 3)) Then
; relevante Datenfelder ausgeben
For $I = 4 To $aScan[0]
MsgBox(0, "IMEI " & $I - 3, $aScan[$I])
Next
; sonst ...
Else
; Fehlernachricht ausgeben
MsgBox(16, "Fehlerhafte Daten", $sScan)
EndIf
EndFunc
Alles anzeigen