TV Senderliste bearbeiten

Also, du kannst natürlich die Webseite herunterladen (rechtsklick, speichern), dort hast du alle Informationen in der html, die du auch im Browser angezeigt bekommst.

Die müsstest du dann natürlich durch ackern.

Das ist jedoch der unschöne und teil-manuelle Weg.

Es gibt jedoch auch UDF's für Chrome um die Webseiten-Daten auszulesen. Damit habe ich mich persönlich jedoch nicht beschäftigt, müsste aber dir die Möglichkeit geben darüber die Daten evtl. zu holen.

Sicher das die Liste korrekt ist? Das sieht etwas durcheinander aus

SATCODX103Astra 1 (19.2E)   TMPG20111120001Eurospor0192___     ______220002____________125020000101043_____________t 1 HD      
SATCODX103Astra 1 (19.2E)   TMPG20113030001ServusTV0192___     ______220002____________049140000101007_____________ HD Deutschl
SATCODX103Astra 1 (19.2E)   TMPG20110530001tagessch0192___     ______220002____________103750000101039_____________au24 HD     
SATCODX103Astra 1 (19.2E)   TMPG20119730000Comedy C0192___     ______275003____________286520000101078_____________entral HD   
SATCODX103Astra 1 (19.2E)   TMPG20108030001Deluxe M0192___     ______220003____________055030000101055_____________usic HD     
SATCODX103Astra 1 (19.2E)   TMPG20119730000Nick/Com0192___     ______275003____________286800000101078_____________edy Central+

Vielleicht eher so?
SATCODX103Astra 1 (19.2E)   TMPG20111120001___0192______220002____________125020000101043_____________Eurosport 1 HD            
SATCODX103Astra 1 (19.2E)   TMPG20113030001___0192______220002____________049140000101007_____________ServusTVHD Deutschl  
SATCODX103Astra 1 (19.2E)   TMPG20110530001___0192______220002____________103750000101039_____________tagesschau24 HD          
SATCODX103Astra 1 (19.2E)   TMPG20119730000___0192______275003____________286520000101078_____________Comedy Central HD      
SATCODX103Astra 1 (19.2E)   TMPG20108030001___0192______220003____________055030000101055_____________Deluxe Music HD          
SATCODX103Astra 1 (19.2E)   TMPG20119730000___0192______275003____________286800000101078_____________Nick/Comedy Central+

Bin nicht besonders gut in regex aber probier es mal so: \<div class\=\"col freqx_1\"\>(.{0,})\<\/div\> bzw. wenn du auch die anderen haben willst: \<div class\=\"col\d? freqx_\d\"\>(.{0,})\<\/div\>

Testen kannst du gut hier: https://regex101.com/

Moin,

beim Regex fehlt ein Leerzeichen: <div class="col freqx_1" >

Wenn Du nur die Namen haben willst, kannst Du das mal probieren:

#include <Array.au3>
#include <Inet.au3>
$sHTML = BinaryToString(_INetGetSource("https://www.satindex.de/tv/1/1/0/", 0), 4) ; UTF8
$oHtmlDoc = ObjCreate("HTMLFILE")
$oHtmlDoc.open()
$oHtmlDoc.write($sHTML)
$oHtmlDoc.close()
While $oHtmlDoc.readyState <> "complete"
    Sleep(10)
WEnd
$oNodeList = $oHtmlDoc.querySelectorAll('a[title^="Senderdaten"]')
Dim $aSender[$oNodeList.length]
Dim $I = 0
For $Node In $oNodeList
    $aSender[$I] = $Node.innerText
    $I += 1
Next
 _ArrayDisplay($aSender)
Exit

Zitat von Velted

Moin,

beim Regex fehlt ein Leerzeichen: <div class="col freqx_1" >

Wie kommst du darauf? Bei mir ist dort kein Leerzeichen.

Zitat von dieselwiesel

Denke am StringRegExp passt etwas noch nicht, ...

Zitat von Velted

beim Regex fehlt ein Leerzeichen: <div class="col freqx_1" >

Zitat von Moombas

Wie kommst du darauf? Bei mir ist dort kein Leerzeichen.

Moombas :

Velted hat recht - es fehlt bei freqx_1"> das Leerzeichen, also freqx_1" >

Beispiel (jeweiliges Pattern 'einkommentieren') :

#include <String.au3>
#include <Array.au3>
#include <Inet.au3>

Local $sPattern

$sSource = _INetGetSource("https://www.satindex.de/tv/1/1/0/")

; Beispielzeile
; <div class="col freqx_1" ><a href="/channel/456/" title="Senderdaten Kabel 1 Schweiz">Kabel 1 Schweiz</a></div>

; -> 1. Pattern von @dieselwiesel (Beitrag #4)
;~ $sPattern = '<div class="col freqx_1">(.*?)</div>'

; -> 2. Pattern von @Velted (Beitrag #6)
$sPattern = '<div class="col freqx_1" >(.*?)</div>'

; -> 3. Pattern von @Moombas (Beitrag #5)
; ==> INFO : PCRE Metacharacter sind \ . ^ $ | [ ( { * + ? #
;      < > = sind keine Metacharacter, d.h. escapen mit \ nicht erforderlich (schadet aber auch nicht)
;~ $sPattern = '\<div class\=\"col freqx_1\"\>(.{0,})\<\/div\>' ; Variante 1

; Abfrage :
$aRegEx = StringRegExp($sSource, $sPattern, 3) ; unter col freqx_1 sind die Sendernamen gelistet
_ArrayDisplay($aRegEx)

Zitat von dieselwiesel

Dachte an _INetGetSource und StringRegExp, funktioniert aber noch nicht so recht.

Entspricht diese Darstellung der Senderliste deinen Vorstellungen ?

#include <Array.au3>
#include <Inet.au3>
Local $sSource = BinaryToString(_INetGetSource("https://www.satindex.de/tv/1/1/0/", 0), 4) ; UTF8
Local $sPattern = '<div class="col freqx_1" >.*?">(.*?)</a></div>'

$aRegEx = StringRegExp($sSource, $sPattern, 3)
_ArrayDisplay($aRegEx)

Hast du schon mal den ChanSort probiert?

Mit dem kannst du bequem deine Sender listen bearbeiten, auch SDX Sender listen ohne Installation.

Download bei Winfuture

Vollständige Übersicht bei Github

Zitat von dieselwiesel

Kann man die SDX ... einlesen und dann per Suchmuster die Zeilen löschen wo es nicht passt?

Nur zum Verständnis :

Du möchtest aus der Fernsehliste.sdx alle Zeilen entfernen, die nicht in der Liste der Sendernamen (also der HTML-Liste) enthalten sind , korrekt ?

Zitat von dieselwiesel

Kann man die SDX z.B. mit FileReadToArray zeilenweise einlesen und dann per Suchmuster die Zeilen löschen wo es nicht passt?

Eine Möglichkeit wäre z.B. , die Daten beider Arrays abzugleichen, die Treffer in ein neues Array einzufügen und dieses zu speichern.

#include <File.au3>
#include <Array.au3>
#include <Inet.au3>

Local $sNETSource, $aNETList, $sNETChannel, $sPattern
Local $aSDXList, $aSDXListNew[0], $sSDXChannel

$sNETSource = BinaryToString(_INetGetSource("https://www.satindex.de/tv/1/1/0/", 0), 4) ; UTF8
$sPattern  = '<div class="col freqx_1" >.*?">(.*?)</a></div>'
$aNETList  = StringRegExp($sNETSource, $sPattern, 3) ; unter col freqx_1 sind die Sendernamen gelistet

; INFO : Aufbau der Fernsehliste.sdx
; ----------------------------------
; Beispielzeile (Zeilenumbruch @LF) :
;   SATCODX103Astra 1 (19.2E)   TMPG20113030001ServusTV0192___     ______220002____________049140000101007_____________ HD Deutschl
; Die Sendernamen sind gesplittet, aber immer an festen Positionen.
; ==> max 8 Zeichen an Position 44..52 und (falls länger) max 12 Zeichen an Position 116..128
; Der Sendername aus der .SDX-Datei ist max. 20 Zeichen lang, z.B. :
;   ServusTV HD Deutschl
; Zu beachten : Die  Senderliste aus dem Netz enthält die vollständigen Namen, also z.B. :
;   ServusTV HD Deutschland -> wird auf 20 Zeichen gekürzt

; Einlesen der Fernsehliste.sdx in ein Array :
Local $aSDXList, $aSDXListNew, $sSDXChannel
_FileReadToArray(@ScriptDir & "\Fernsehliste.sdx", $aSDXList, $FRTA_NOCOUNT)
For $iSDX = 0 To UBound($aSDXList) - 1
    $sSDXChannel = StringStripWS(StringMid($aSDXList[$iSDX], 44, 8) & StringMid($aSDXList[$iSDX], 116, 12), 3)
    For $iNet = 0 To UBound($aNETList) - 1
        $sNETChannel = StringStripWS(StringLeft($aNETList[$iNet], 20), 3)
        If $sSDXChannel = $sNETChannel Then
            _ArrayAdd($aSDXListNew, $aSDXList[$iSDX])
        EndIf
    Next
Next

; Neues Array mit den Treffern :
_ArrayDisplay($aSDXListNew, "Treffer-Array") ; *** nur zur Anzeige beim Test

; ==> Array in eine neue Datei schreiben :
_FileWriteFromArray(@ScriptDir & "\Fernsehliste-Neu.sdx", $aSDXListNew)

Ein mögliches Problem ist, dass die Funktion _FileWriteFromArray als Zeilenabschluss @CRLF anhängt.

Falls nur ein @LF zulässig sein sollte, muss das neue Array manuell gespeichert werden.

Musashi : Ich weiß ja nicht, ob es einen Unterschied zwischen den Daten gibt (nicht geprüft), wenn man das mit inetgetsource ausließt und wenn man die Webseite per Rechtsklick speichert aber bei mir (Speichern) ist dort kein Leerzeichen und damit passt das Regex dort (mit Lerrzeichen) nicht. Geprüft auf der oben angegebenen Seite. Im Anhang meine HTML und auch die jeweiligen Prüfungen.

Noch deutlicher wird es wenn ich nur "<div class="col freqx_1">" als Regex nehme, ohne Leerzeichen 247 Matches, mit Leerzeichen keins.

Macht Inetgetsource also etwas anders?

Zitat von Musashi

Ein mögliches Problem ist, dass die Funktion _FileWriteFromArray als Zeilenabschluss @CRLF anhängt.

Falls nur ein @LF zulässig sein sollte, muss das neue Array manuell gespeichert werden.

Dazu einfach in der Funktion _FileWriteFromArray() (erreichbar in Scite über CTRL-J ) das @CRLF nur durch ein @LF austauschen. Falls das nötig sein sollte....ansonsten die Funktion anpassen bzw. auf eigene Bedürfnisse umschreiben.

Zitat von Moombas

Ich weiß ja nicht, ob es einen Unterschied zwischen den Daten gibt (nicht geprüft), wenn man das mit inetgetsource ausließt und wenn man die Webseite per Rechtsklick speichert

InetRead und _InetGetSource geben die Daten zurück die der Server direkt liefert - also auch das was der Browser als Ausgangsmaterial erhält.

Der Rechtsklick - speichern unter enthält hingegen den HTML-Zustand der Seite wie sie gerade im Browser angezeigt wird.

Z.b. kann Javascript-Code Elemente hinzufügen, ändern etc. Dies wäre im InetRead-Code nicht mit drin da der JS-Code ja nie ausgeführt wird.

Und offensichtlich räumt der Browser den Code auch noch etwas auf und entfernt wohl in diesem Zusammenhang auch unsinnige Leerzeichen.

Im Übrigen ist BinaryToString(_INetGetSource("...", 0), 4) ein bisschen künstlich umständlich.
Im Prinzip ist _InetGetSource mit dem 2. Parameter auf 0 nur ein reines InetRead.
Von daher kann man auch gleich BinaryToString(InetRead("https://www.satindex.de/tv/1/1/0/"), 4) verwenden und braucht dann nicht extra eine UDF hierfür einzubinden.

Das mag dann den Unterschied ausmachen. Danke AspirinJunkie für die Erklärung.

Hi Moombas :

Deine Frage, ob sich InetRead  bzw. _InetGetSource anders verhalten als Rechtsklick - Speichern hat AspirinJunkie ja bereits beantwortet.

(war auch keine Unterstellung, dass Du Deine RegEx nicht geprüft hättest )

Zitat von Andy

Dazu einfach in der Funktion _FileWriteFromArray() (erreichbar in Scite über CTRL-J ) das @CRLF nur durch ein @LF austauschen. Falls das nötig sein sollte....ansonsten die Funktion anpassen bzw. auf eigene Bedürfnisse umschreiben.

Sehe ich auch so, Ich wollte dieselwiesel nur nicht vorschlagen, die Standard-UDF diesbzgl. zu ändern.

Am Besten wäre es natürlich, wenn die Entwickler das per Parameter geregelt hätten. Gleiches gilt auch dafür, ob der letzten Zeile eine Umbruchssequenz angefügt wird oder nicht.

(Es ist bald Weihnachten - da darf sich man so etwas ja mal wünschen )

dieselwiesel :

Falls @CRLF zu Problemen führt, kannst Du, wie von Andy vorgeschlagen, eine modifizierte Variante, z.B. mit einem Funktionsnamen wie _FileWriteFromArrayMod() in Dein Skript einfügen.

Alternativ kannst Du das neue Array auch mit FileOpen -> Zeilen mit FileWrite in eine Datei schreiben.

Prüf mal in Notepad++ welche Codierung die Original-Datei hat (UTF8 etc.).

Ggf. brcuht der TV eine bestimmte Codierung und hat daher damit Probleme.