1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Datei "session.txt" (in einem fest definierten Verzeichnis) überwachen und Folgeaktion auslösen

    • AspirinJunkie
    • 27. August 2014 um 09:39
    Zitat von Andy

    Funktioniert einwandfrei, mal schauen wie ich das (wenn es auch remote funktioniert) in VBA umsetze


    Als erstes: Mein Beileid für den Zwang zu VB...
    Als zweites: Wenn du das umsetzen musst, hast du sicherlich nicht die AutoIt-API-Funktion zur Verfügung.
    Ich hatte das Ganze schon mal ohne die _WinAPI-Funktion direkt mit den nativen DLL-Funktionen gemacht - das wäre als Grundlage für die Überführung wohl besser geeignet: >>Klickmich<<

  • Datei "session.txt" (in einem fest definierten Verzeichnis) überwachen und Folgeaktion auslösen

    • AspirinJunkie
    • 27. August 2014 um 09:08
    Zitat von Andy

    Und ich würde dazu gerne die AutoIt-Umsetzung sehen

    _WinAPI_ShellChangeNotifyRegister - Beispiel
    [autoit]

    #RequireAdmin
    #include <APIShellExConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WinAPI.au3>
    #include <WinAPIShellEx.au3>

    [/autoit] [autoit][/autoit] [autoit]

    HotKeySet("q", raus) ; mit "q" Programm beenden

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $s_PATH = FileGetLongName("D:\Temp")

    [/autoit] [autoit][/autoit] [autoit]

    #Region ShellEvent registrieren
    Global $h_GUI = GUICreate("")
    Global $h_Msg = _WinAPI_RegisterWindowMessage('irgendwas') ; Die Message "irgendwas" wird an das Fenster $h_GUI gesendet wenn ein Event auftritt
    GUIRegisterMsg($h_Msg, 'ReactOnEvents')

    [/autoit] [autoit][/autoit] [autoit]

    Global $h_ShellNotify1 = _WinAPI_ShellChangeNotifyRegister($h_GUI, $h_Msg, $SHCNE_ALLEVENTS, 0x3, $s_PATH)
    #EndRegion ShellEvent registrieren

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Do
    Sleep(100)
    Until 0

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Funktion die aufgerufen wird wenn ein Event auftritt:
    Func ReactOnEvents(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
    Local $s_PATH = DllCall("Shell32.dll", "BOOLEAN", "SHGetPathFromIDListW", "ptr", DllStructCreate("PTR A; PTR", $wParam).A, "wstr", "")[2]

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite(StringFormat("% 20s\t%s\n", GetSHCNEConstNameByValue($lParam), $s_PATH))
    EndFunc ;==>ReactOnEvents

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Ermittelt aus dem Wert der SHCNE-Konstanten den Konstantennamen
    Func GetSHCNEConstNameByValue($value)
    Local Static $a_Consts[][2] = [["ALLEVENTS", 0x7FFFFFFF], ["ASSOCCHANGED", 0x8000000], ["ATTRIBUTES", 0x00000800], ["CREATE", 0x00000002], ["DELETE", 0x00000004], ["DRIVEADD", 0x00000100], ["DRIVEADDGUI", 0x00010000], ["DRIVEREMOVED", 0x00000080], ["EXTENDED_EVENT", 0x04000000], ["FREESPACE", 0x00040000], ["MEDIAINSERTED", 0x00000020], ["MEDIAREMOVED", 0x00000040], ["MKDIR", 0x00000008], ["NETSHARE", 0x00000200], ["NETUNSHARE", 0x00000400], ["RENAMEFOLDER", 0x00020000], ["RENAMEITEM", 0x00000001], ["RMDIR", 0x00000010], ["SERVERDISCONNECT", 0x00004000], ["UPDATEDIR", 0x00001000], ["UPDATEIMAGE", 0x00008000], ["UPDATEITEM", 0x00002000], ["DISKEVENTS", 0x0002381F], ["GLOBALEVENTS", 0x0C0581E0], ["INTERRUPT", 0x80000000]]
    For $i = 0 To UBound($a_Consts) - 1
    If $value = $a_Consts[$i][1] Then Return $a_Consts[$i][0]
    Next
    Return ""
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func raus()
    #forceref $h_ShellNotify1
    _WinAPI_ShellChangeNotifyDeregister($h_ShellNotify1)
    Exit
    EndFunc ;==>raus

    [/autoit] [autoit][/autoit] [autoit][/autoit]

    In dem Beispiel werden alle Events in einem Verzeichnis (nicht rekursiv) getrackt.
    Teste es mal - bei mir funktioniert es.

    Zitat von Andy

    Da das aber (warum auch immer) bei einigen auf div. Servern liegenden Dateien nicht 100%ig funktioniert hat,

    Hier könnte es durchaus Probleme geben. Ich zitiere mal MSDN:

    Zitat

    Registers a window to receive notifications from the file system or Shell, if the file system supports notifications.


    Oscar
    Danke für den Hinweis mit der fertigen UDF. Hab das bisher immer manuell gemacht - so wird es deutlich übersichtlicher.

  • String nach 30 Zeichen splitten?

    • AspirinJunkie
    • 27. August 2014 um 08:01

    Du hast es doch schon fast richtig gehabt.
    Änder lediglich dein RegEx-Pattern in

    Code
    .{30}

    Intuitiver kann eventuell die Variante mit StringMid sein:

    Variante mit StringMid
    [autoit]

    Global $string = "Hallo Autoit.de, das ist ein Beispielstring der aufgeteilt gehört, aber erst nach z.B: 30 Zeichen, hier wird er leider nach allen 9 geteilt.", $result
    Global $d_Chars = 30

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 1 To StringLen($string) Step $d_Chars
    $result &= StringMid($string,$i, $d_Chars) & "-"
    Next

    [/autoit] [autoit][/autoit] [autoit]

    $result = StringTrimRight($result, 1)
    MsgBox(0, "", $result)

    [/autoit]
  • Halbdynamisches Array - verbessert die Performance von Größenänderungen erheblich

    • AspirinJunkie
    • 26. August 2014 um 12:47

    Hab das ganze mal zu einer UDF erweitert (siehe Startpost).

  • Tap - BPM Counter

    • AspirinJunkie
    • 26. August 2014 um 08:33
    Zitat von alpines

    Was ich meinte war das man den Beat selbst nicht genau tippen kann und man folglich nur die Standardabweichung zu einem nicht genauen Beat bestimmen kann.

    Genau deswegen benötigen wir ja erst Maße für die Schätzgüte. Wenn wir in der Lage wären den Beat genau zu tippen bräuchten wir keine Genauigkeitsabschätzung.

    Wir möchten den Wert ermitteln der als bpm im Sequenzer eingestellt war bzw. im Metronom für den Drummer.
    Dieser exakte theoretische Wert den wir ermitteln wollen ist der Erwartungswert.
    Wie machen wir das? - Wir nehmen z.B. 20s aus dem Lied und tippen fleißig mit (wir ziehen eine Stichprobe).
    Die Stichprobe ist durch unser manuelles Tippen, dem miesen Drummer und weitere Einflüsse (normalverteilt) fehlerbehaftet.
    Der Mittelwert dieser Stichprobe ist bei dieser Konstellation dann ein Schätzwert für den exakten Erwartungswert.
    Nun stellt sich aber die Frage: "Wie nah liegt der Schätzwert am Erwartungswert dran?".
    Und für normalverteilte Stichproben ist das simpelste Maß hierfür nunmal der Standardfehler (nicht mit der Standardabweichung verwechseln...).

    Zitat von alpines

    Aber selbstverständlich kann man davon ausgehen das man im Normalfall den Beat erwischt.

    Wir müssen ja auch nicht exakt tippen. Wir müssen nur mehr tippen je schlechter wir treffen um, einen für uns annehmbaren, Standardfehler zu erreichen.

  • Tap - BPM Counter

    • AspirinJunkie
    • 25. August 2014 um 23:04

    Ich gebe zu, dass ich nicht exakt verstanden habe was du sagen wolltest.

    Gehen wir mal von einem Lied aus welches eine absolut exakte Taktung besitzt. Das ist vor allem bei Sequenzer-basierten Stilrichtungen wie Techno oder Hip Hop der Fall.
    Aber auch Rock ist beim Einspielen in der Regel exakt getaktet (Metronom im Ohr des Drummers).
    Jetzt tippen wir den Beat einfach mit. Wir versuchen natürlich exakt den Beat zu treffen werden aber immer etwas zu spät oder zu zeitig tippen.
    Im Mittel treffen wir aber den richtigen Beat. Die Fehler die durch unser Tippen dazukommen verhalten sich dann normalverteilt.
    Daher können wir sowohl die Standardabweichung als auch den Standardfehler als statistisches Maß zur Beurteilung der Schätzgüte heranziehen.

    Gehen wir nun vom erweiterten Fall des Rock-Drummers mit Metronom aus.
    Bis auf Ausnahmen wie Nicholas Barker oder Gene Hoglan wird jeder andere Drummer den Beat nie exakt treffen. Im Mittel bleibt er aber drin und seine Fehler sind ebenfalls normalverteilt.
    Schlechte Drummer haben dabei eine große Standardabweichung, gute eine kleine. Der Mittelwert bleibt unabhängig davon der Selbe.
    Jetzt kommen unsere Tippfehler beim Abtippen hinzu - ebenfalls normalverteilt wie wir ja schon festgestellt haben. Das führt zu einer Überlagerung der beiden Normalverteilungen. Und die Summe zweier Normalverteilungen ergibt wieder eine Normalverteilung.
    Auch in diesem Fall wäre die Anwendung des Standardfehlers also korrekt.

    Falls du immer noch skeptisch bist, kann ich dir gerne noch einen Shapiro-Wilk-Test auf Normalverteilung mit implementieren, damit du jeweils sicher sein kannst, dass der angezeigte Standardfehler ein korrektes Maß zur Beurteilung der Schätzgüte darstellt.

  • ZeitKorrektur Eventlog Sommer-/Winterzeit

    • AspirinJunkie
    • 25. August 2014 um 17:20

    Hatte das bei den Eventlogs mal mit der API-Funktion SystemTimeToTzSpecificLocalTime umgesetzt:

    Eventlog Hoch/Runterfahren
    [autoit]

    #include <GUIConstantsEx.au3>
    #include <ListViewConstants.au3>
    #include <StructureConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    #Region GUI
    Opt("GUIOnEventMode", 1)
    GUICreate("Eventlog reader", 851, 317, 241, 278)
    GUISetOnEvent($GUI_EVENT_CLOSE, "beenden")
    $ListView1 = GUICtrlCreateListView("Datum|Uhrzeit|Event-ID", 8, 28, 408, 278)
    GUICtrlSendMsg(-1, 0x101E, 0, 150)
    GUICtrlSetFont(-1, 8, 400, 0, "Arial")
    $ListView2 = GUICtrlCreateListView("Datum|Uhrzeit|Event-ID", 432, 28, 408, 278)
    GUICtrlSendMsg(-1, 0x101E, 0, 150)
    GUICtrlSetFont(-1, 8, 400, 0, "Arial")
    GUICtrlCreateLabel("Hochgefahren:", 8, 8, 105, 20)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
    GUICtrlCreateLabel("Heruntergefahren:", 440, 8, 114, 20)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
    GUISetState(@SW_SHOW)

    [/autoit] [autoit][/autoit] [autoit]

    Func beenden()
    Exit
    EndFunc ;==>beenden
    #EndRegion GUI

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Global $o_WMI = ObjGet("winmgmts:\\localhost\root\CIMV2")
    Global $s_Query = "Select EventCode, TimeWritten, RecordNumber from Win32_NTLogEvent WHERE Logfile='System' AND (EventCode=6009 OR EventCode=6006)"
    Global $o_Col = $o_WMI.ExecQuery($s_Query, "WQL", 48)

    [/autoit] [autoit][/autoit] [autoit]

    For $o_Item In $o_Col
    With $o_Item
    $a_DT = WMIDateTime2LocalDateTimeString(.TimeWritten)
    If @error Then ContinueLoop
    GUICtrlCreateListViewItem($a_DT[0] & "|" & $a_DT[1] & "|" & .RecordNumber, (.EventCode = 6009) ? $ListView1 : $ListView2)
    EndWith
    Next

    [/autoit] [autoit][/autoit] [autoit]

    ; Message Loop des GUI
    Do
    Sleep(100)
    Until 0

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Wandelt einen WMI-UTC-DateTime-String in Datum- und Zeit-Strings lokaler Zeit in deutscher Notation
    Func WMIDateTime2LocalDateTimeString(Const $s_WMIDT, Const $bMS = False)
    ; By AspirinJunkie
    If Not StringRegExp($s_WMIDT, "^\d{14}\.\d{6}-\d{3}$") Then Return SetError(1, 0, Null)
    Local $tDT = DllStructCreate($tagSYSTEMTIME)
    $tDT.Month = Int(StringMid($s_WMIDT, 5, 2), 1)
    $tDT.Day = Int(StringMid($s_WMIDT, 7, 2), 1)
    $tDT.Year = Int(StringLeft($s_WMIDT, 4), 1)
    $tDT.Hour = Int(StringMid($s_WMIDT, 9, 2), 1)
    $tDT.Minute = Int(StringMid($s_WMIDT, 11, 2), 1)
    $tDT.Second = Int(StringMid($s_WMIDT, 13, 2), 1)
    $tDT.MSeconds = Int(StringMid($s_WMIDT, 16, 6), 1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $tDTL = DllStructCreate($tagSYSTEMTIME)
    DllCall("kernel32.dll", "BOOL", "SystemTimeToTzSpecificLocalTime", "STRUCT*", Null, "STRUCT*", $tDT, "STRUCT*", $tDTL)
    If @error Then Return SetError(2, @error, Null)

    [/autoit] [autoit][/autoit] [autoit]

    Local $a_Ret[] = [StringFormat("%02d.%02d.%04d", $tDTL.Day, $tDTL.Month, $tDTL.Year), StringFormat("%02d:%02d:%02d", $tDTL.Hour, $tDTL.Minute, $tDTL.Second) & ($bMS ? StringFormat(".%06d", $tDTL.MSeconds) : "")]
    Return $a_Ret
    EndFunc ;==>WMIDateTime2LocalDateTimeString

    [/autoit]


    Die Quelle für das Ganze ging während des Servercrashs flöten - im Google-Cache ist es aber noch enthalten:Thread im Google-Cache

    Hier mal als Nachweis, dass die Funktion tatsächlich Sommer/Winterzeit korrekt beachtet:

    Test auf Sommer/Winterzeit der Funktion WMIDateTime2LocalDateTimeString
    [autoit]

    #include <StructureConstants.au3>
    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $s_TimeWinter = "20140101120000.000000-000"
    $a_Ret = WMIDateTime2LocalDateTimeString($s_TimeWinter)
    _ArrayDisplay($a_Ret, "Winterzeit")

    [/autoit] [autoit][/autoit] [autoit]

    $s_TimeWinter = "20140701120000.000000-000"
    $a_Ret = WMIDateTime2LocalDateTimeString($s_TimeWinter)
    _ArrayDisplay($a_Ret, "Sommerzeit")

    [/autoit] [autoit][/autoit] [autoit]

    ; Wandelt einen WMI-UTC-DateTime-String in Datum- und Zeit-Strings lokaler Zeit in deutscher Notation
    Func WMIDateTime2LocalDateTimeString(Const $s_WMIDT, Const $bMS = False)
    ; By AspirinJunkie
    If Not StringRegExp($s_WMIDT, "^\d{14}\.\d{6}-\d{3}$") Then Return SetError(1, 0, Null)
    Local $tDT = DllStructCreate($tagSYSTEMTIME)
    $tDT.Month = Int(StringMid($s_WMIDT, 5, 2), 1)
    $tDT.Day = Int(StringMid($s_WMIDT, 7, 2), 1)
    $tDT.Year = Int(StringLeft($s_WMIDT, 4), 1)
    $tDT.Hour = Int(StringMid($s_WMIDT, 9, 2), 1)
    $tDT.Minute = Int(StringMid($s_WMIDT, 11, 2), 1)
    $tDT.Second = Int(StringMid($s_WMIDT, 13, 2), 1)
    $tDT.MSeconds = Int(StringMid($s_WMIDT, 16, 6), 1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $tDTL = DllStructCreate($tagSYSTEMTIME)
    DllCall("kernel32.dll", "BOOL", "SystemTimeToTzSpecificLocalTime", "STRUCT*", Null, "STRUCT*", $tDT, "STRUCT*", $tDTL)
    If @error Then Return SetError(2, @error, Null)

    [/autoit] [autoit][/autoit] [autoit]

    Local $a_Ret[] = [StringFormat("%02d.%02d.%04d", $tDTL.Day, $tDTL.Month, $tDTL.Year), StringFormat("%02d:%02d:%02d", $tDTL.Hour, $tDTL.Minute, $tDTL.Second) & ($bMS ? StringFormat(".%06d", $tDTL.MSeconds) : "")]
    Return $a_Ret
    EndFunc ;==>WMIDateTime2LocalDateTimeString

    [/autoit]
  • Tap - BPM Counter

    • AspirinJunkie
    • 25. August 2014 um 09:59

    Ich habe mal die robuste Variante umgesetzt:

    Bpm-Counter robust
    [autoit]

    #include <GUIConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode", 1)
    HotKeySet("b", tap)
    HotKeySet("r", reset)

    [/autoit] [autoit][/autoit] [autoit]

    #Region GUI
    GUICreate("Tap - BPM Counter", 258, 146, 192, 124)
    GUISetOnEvent($GUI_EVENT_CLOSE, "raus")

    [/autoit] [autoit][/autoit] [autoit]

    Global $guiBPM = GUICtrlCreateLabel("0", 8, 16, 242, 50, 1)
    GUICtrlSetFont(-1, 24, 800, 0, "Verdana")

    [/autoit] [autoit][/autoit] [autoit]

    Global $guiAcc = GUICtrlCreateLabel("0", 16, 70, 120, 16)

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateButton("Tap", 16, 96, 147, 33)
    GUICtrlSetOnEvent(-1, tap)

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateButton("Reset", 168, 96, 75, 33)
    GUICtrlSetOnEvent(-1, reset)

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState(@SW_SHOW)
    #EndRegion GUI

    [/autoit] [autoit][/autoit] [autoit]

    Do
    Sleep(100)
    Until 0

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func tap()
    GUICtrlSetBkColor($guiBPM, 0x00FF00)
    Local $a_Ret = calcBPM()
    GUICtrlSetData($guiBPM, StringFormat("%5.1f bpm", $a_Ret[0]))
    GUICtrlSetData($guiAcc, StringFormat("±%5.1f bpm", $a_Ret[1]))
    Sleep(75)
    GUICtrlSetBkColor($guiBPM, -1)
    EndFunc ;==>tap

    [/autoit] [autoit][/autoit] [autoit]

    Func reset()
    calcBPM(True)
    GUICtrlSetData($guiBPM, StringFormat("% 5.1f bpm", 0))
    GUICtrlSetData($guiAcc, StringFormat("±%5.1f bpm", 0))
    EndFunc ;==>reset

    [/autoit] [autoit][/autoit] [autoit]

    Func raus()
    Exit
    EndFunc ;==>raus

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Bestimmt fortlaufend die Beats per Minute
    Func calcBPM($b_Reset = False)
    ; by AspirinJunkie
    Local Static $d_TimeStampOld = 0
    Local Static $d_Sum = 0, $d_Sum2 = 0, $d_N = -1
    Local Static $f_StdDev = 1e5, $f_StdErr, $f_Mean

    [/autoit] [autoit][/autoit] [autoit]

    ; Zeitdifferenz ermitteln und für nächste Messung Timestamp zurücksetzen:
    Local $d_TimeStampBackup = $d_TimeStampOld
    Local $d_TimeDiff = TimerDiff($d_TimeStampOld)
    $d_TimeStampOld = TimerInit()

    [/autoit] [autoit][/autoit] [autoit]

    ; Stichprobengröße
    $d_N += 1

    [/autoit] [autoit][/autoit] [autoit]

    ; Falls zurücksetzen Parameter aktiviert wurde
    If $b_Reset Then
    $d_TimeStampOld = 0
    $d_Sum = .0
    $d_Sum2 = .0
    $d_N = -1
    Return True
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; Verhalten bei Initialisierung:
    If $d_N = 0 Then
    Local $a_Ret[] = [0, 0]
    Return $a_Ret
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    $d_Sum += $d_TimeDiff ; Summe
    $d_Sum2 += $d_TimeDiff ^ 2 ; Quadratesumme

    [/autoit] [autoit][/autoit] [autoit]

    If $d_N = 1 Then ; Fall, dass noch keine Standardabweichung bestimmt werden kann da nur 1 Messwert vorliegt
    $f_Mean = $d_Sum
    Local $a_Ret[] = [60000 / $f_Mean, 0]
    Return $a_Ret
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; Test ob Messung ein Ausreißer ist (Doppelklick, Beat verpasst etc.). Check über Bereich Mittelwert +- 3x Standardabweichung
    Local $f_residuum = $d_TimeDiff - $f_Mean
    If Abs($f_residuum) > 3 * $f_StdDev And $d_N > 3 Then ; $d_N > 3 um Fall zu vermeiden dass erstes Paar zufällig zu nah aneinander liegt
    $d_N -= 1
    $d_Sum -= $d_TimeDiff ; Summe
    $d_Sum2 -= $d_TimeDiff ^ 2 ; Quadratesumme
    If $f_residuum < 0 Then $d_TimeStampOld = $d_TimeStampBackup ; Beat zu kurz - alter Timestamp muss wiederhergestellt werden
    Local $a_Ret[] = [60000 / $f_Mean, 60000 / $f_Mean - 60000 / ($f_Mean + $f_StdErr)]
    Return $a_Ret
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ; Mittelwert [bpm]
    $f_Mean = $d_Sum / $d_N
    ; Standardabweichung [bpm]
    $f_StdDev = Sqrt(($d_Sum2 - $d_Sum * $d_Sum / $d_N) / ($d_N - 1))
    ; Standardfehler des Mittelwertes [bpm]
    $f_StdErr = $f_StdDev / Sqrt($d_N)
    ; Rückgabe in bpm
    Local $a_Ret[] = [60000 / $f_Mean, 60000 / $f_Mean - 60000 / ($f_Mean + $f_StdErr)]
    Return $a_Ret
    EndFunc ;==>calcBPM

    [/autoit]


    Nun kann man auch nach einer Pause später einfach wieder einsteigen und auch Doppelklicks oder ähnliche Fehler sollten keine negativen Auswirkungen haben.
    Außerdem gibt es parallel eine Anzeige wie genau man den Bpm-Wert bestimmt hat (Voraussetzung: Normalverteiltes Verhalten - sprich: es gibt nur einen richtigen Bpm-Wert und alle Abweichungen sind zufällige Messabweichungen)

  • PHP Array (auf Seite) in AutoIt übernehmen

    • AspirinJunkie
    • 22. August 2014 um 22:17

    Ist MySQL auf dem Server überhaupt vorhanden?
    Des Weiteren ist auf normalen Webservern der Zugriff auf das DBMS in der Regel nicht von außerhalb gestattet, sondern auf lokalen Zugriff (z.B. über PHP) beschränkt was eine entsprechende Verwendung ohnehin ausschließt.
    Ob es einfacher wird als JSON wage ich einfach mal zu bezweifeln obwohl ich die finalen Daten nicht kenne. Sobald da ein bisschen mehr Verschachtelung drin ist, wird es mit einer relationalen DB ziemlich eklig.
    Spontan fällt mir auch nicht sofort ein wie man das Beispiel sinnvoll so in Tabellen überführt, dass sie in AutoIt ganz einfach wieder in ihre ursprüngliche Struktur überführt werden können.
    Vielleicht zeigst du einfach mal anhand eines etwas erweiterten Beispiels wie du dies in eine DB überführen würdest und mit AutoIt wieder auslesen.
    Weiterhin ist der DB-Ansatz dahingehend problematisch, dass man die Struktur der Daten beim Auslesen vorher kennen muss.
    In wiefern die Daten in ihrer Struktur dynamisch sind weiß ich ich nicht aber mit einem Format wie JSON ist das hingegen kein Problem, da die Struktur sich aus dem String ableitet.

  • PHP Array (auf Seite) in AutoIt übernehmen

    • AspirinJunkie
    • 22. August 2014 um 21:48
    Zitat von Scheffi

    in Autoit laden, so dass ich da auch mit $Array[0][Protocol] zum Beispiel drauf zugreifen kann.

    AutoIt hat von Haus aus keine assoziativen Arrays (Zugriff mit Schlüsselname statt numerischen Index). Statt einem AutoIt-Array müsstest du also auf z.B. das Dicitonary-Objekt ausweichen. Oder du nimmst die aktuelle Beta - da ist der Datentyp Map enthalten welcher ein assoziatives Array in AutoIt darstellt.

    Ansonsten prinzipiell: Um Objekte zwischen Client und Server auszutauschen musst du das Objekt vor der Übertragung erst einmal serialiseren. Das heißt in ein Austauschformat wandeln was der Client versteht.
    JSON wäre ein Beispiel für so ein Austauschformat. PHP hat entsprechende Funktionen um Arrays in JSON zu überführen.
    Bei deinem AutoIt-Skript angekommen musst du den JSON-String in die entsprechende AutoIt-Entsprechung parsen.
    Es gibt zwar im englischen Forum entsprechende Funktionen - aber wie ausgereift diese sind kann ich nicht sagen. Im Zweifelsfall musst du halt selbst einen entsprechenden Parser schreiben.

  • Tap - BPM Counter

    • AspirinJunkie
    • 22. August 2014 um 08:56

    Klein, smart und macht was es soll - :thumbup:

    Kleine Anregung: Wenn man einen Beat ausgelassen hat (vielleicht daneben geklickt) dann kann man wieder von vorne anfangen. Klasse wäre es daher einfach später wieder einzusetzen zu können.
    Das könnte man damit bewerkstelligen, dass nicht die Anzahl der Klicks während der gesamten Zeitdauer verwendet wird, sondern die Mittlung des Abstandes zwischen zwei aufeinander folgenden Beats.
    Wenn man nun ein paar Beats hat, kann ein Auslassen des Beats daran erkannt werden, dass seine Zeit z.B. größer als 1,2x wie das bisherige Mittel ist. Auch Doppelklicks könnte man damit abfangen.

    Wenn du das dann noch statistisch machst, in dem du parallel die Standardabweichung bestimmst, dann kannst du sogar mit angeben wie genau du die bpm bestimmt hast.

  • Textdatei auslesen und in 2 Variabeln umwandeln.

    • AspirinJunkie
    • 21. August 2014 um 16:43

    Du brauchst lediglich 2 Befehle (anklicken für Hilfe):

    [autoit]

    Fileread()
    StringSplit()

    [/autoit]


    Viel Spaß

  • Anzahl der angemeldeten User

    • AspirinJunkie
    • 18. August 2014 um 14:52

    Er führt das Skript lokal auf dem jeweiligen Server aus.

  • Tool hängt sich auf - aber wo?

    • AspirinJunkie
    • 18. August 2014 um 14:47

    Nach dem was ich gelesen habe scheint auch ein Memory-Leak-Bug im Refresher-Objekt vorhanden zu sein.
    Ändere also die CPU-Funktion mal folgendermaßen:

    [autoit]

    Func CPUusage(ByRef $a_CPU)
    Local Static $o_WMI = ObjGet("winmgmts:\\.\root\cimv2")
    Local $x

    [/autoit][autoit][/autoit][autoit]

    For $i In $o_WMI.InstancesOf("Win32_Processor", 0x10 + 0x20)
    $x = $i.LoadPercentage
    If IsNumber($x) Then
    $a_CPU[0] += 1
    $a_CPU[1] += $x
    EndIf
    Next
    EndFunc

    [/autoit]
  • Anzahl der angemeldeten User

    • AspirinJunkie
    • 18. August 2014 um 09:08

    Alternative wäre über WMI:

    [autoit]

    MsgBox(64, "", "Anzahl eingeloggter User: " & getSessionCount())

    [/autoit][autoit][/autoit][autoit]

    Func getSessionCount()
    Local Static $o_WMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!//.")
    Return $o_WMI.InstancesOf("Win32_ComputerSystem", 0x10).count
    EndFunc

    [/autoit]

    bzw. etwas CPU-freundlicher (vor allem bei Mehrfachaufrufen):

    [autoit]

    MsgBox(64, "", "Anzahl eingeloggter User: " & getSessionCount())

    [/autoit][autoit][/autoit][autoit]

    Func getSessionCount()
    Local Static $o_WMI = ObjGet("winmgmts:\\.\root\cimv2")
    Local Static $o_WMIRefresher = ObjCreate("WbemScripting.Swbemrefresher")
    Local Static $o_ComputerSystem = $o_WMIRefresher.AddEnum($o_WMI, "Win32_ComputerSystem").objectSet

    [/autoit][autoit][/autoit][autoit]

    $o_WMIRefresher.Refresh
    Return $o_ComputerSystem.count
    EndFunc

    [/autoit]

    Ich habe die Objekte mal alle als Static deklariert, da ich ja weiß, dass du die Funktion mehrfach aufrufen willst.
    Bin mir aber nicht 100% sicher ob in Win32_ComputerSystem die Sessions stehen oder nicht. Hab das irgendwo mal gelesen. Ich würde empfehlen, es noch einmal gegen zu checken.

  • Tool hängt sich auf - aber wo?

    • AspirinJunkie
    • 15. August 2014 um 14:44
    Zitat von traumhaeftling

    Mein Skript frisst jetzt extrem viel RAM und steigert sich sekündlich. Nach 2 Stunde hat es sich von 40 MB bis fast 100 MB gesteigert.
    War davor nicht so.

    Für mich sieht es nach einem Memory-Leak aus.
    Wenn man folgendes Skript ausführt:

    [autoit]

    $oRecordSet = ObjCreate("ADODB.RecordSet")
    While 1
    $oRecordSet.close
    WEnd

    [/autoit]

    Steigt der Speicher immer weiter. Analog verhält es sich zu .open und der Kombination von beiden.
    Es ist auch irrelevant, ob man das Objekt immer wieder neu erstellt. Folgendes:

    [autoit]

    While 1
    $oRecordSet = ObjCreate("ADODB.RecordSet")
    $oRecordSet.close
    $oRecordSet = 0
    WEnd

    [/autoit]

    erbringt das selbe Ergebnis.
    Es ist aber nicht logisch, da durch das close und das Neubelegen der Werte alles zu diesem Objekt aus dem Speicher verschwinden sollte.

    Interessant ist dabei, dass es vorher bei dir nicht auftrat.
    Spontan fällt mir hierfür kein Grund ein. Ich gehe momentan von einem Bug aus - eher auf AutoIt-Seite.
    Aber eine Lösung habe ich spontan nicht.
    Mach es halt mit der Datenbankverbindung wie in deinem Skript bisher und schaue ob das Problem dann immer noch existiert.

  • Tool hängt sich auf - aber wo?

    • AspirinJunkie
    • 14. August 2014 um 12:18
    Zitat von traumhaeftling

    Allgemein: was würdet ihr am Quelltext verbessern?

    • Du regelst alles über globale Variablen. Warum nicht über Rückgabewerte der Funktionen?
    • Du erstellst die DB-Connection immer wieder neu - muss das sein?
    • In deiner CPUusage erzeugst du immer wieder das WMI-Objekt. Und um die Werte abzufragen immer wieder eine extra Anfrage. Stattdessen das WMI-Objekt nur einmal erzeugen und mit einem WMI-Refresher-Objekt arbeiten.
    • Deine CPU-Berechnung habe ich nicht verstanden. Im Array $array stehen die Auslastungen der einzelnen Cores. Die mittelst du später. Aber beschrieben wird es von der Funktion CPUusage(). Die Werte werden dort aber nicht drangehängt, sondern einfach überschrieben. Das heißt: Du rufst die Funktion mehrere Male innerhalb deiner 2 Minuten auf. Ins Ergebnis fließen aber nur die Werte des allerletzten Aufrufes von CPUUsage ein. Ist das so gewollt?


    Ich habe einfach mal einiges verändert - vielleicht bringt es dich ja weiter:

    Spoiler anzeigen
    [autoit]

    #include <GUIConstants.au3>
    #include <File.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $d_CPU_mean
    Global $server_ID = 0
    Global $timestamp
    Global $d_CPU_mean, $a_RAM, $d_Sessions

    [/autoit] [autoit][/autoit] [autoit]

    ; ServerID dem Computer zuordnen
    For $i = 1 To 13
    If @ComputerName = StringFormat("compute%02d", $i+1) Then $server_ID = $i
    Next
    If @ComputerName = "COMPUTE20" Then $server_ID = 14
    If $server_ID = 0 Then Exit MsgBox(48, "Fehler", "Diesem Computer konnte keine Server-ID zugeordnet werden!")

    [/autoit] [autoit][/autoit] [autoit]

    ; ADODB-Verbindung aufbauen
    Global $ado = ObjCreate("ADODB.Connection")
    $ado.ConnectionString = ("Provider='OraOLEDB.Oracle';Data Source='xxxxx';User Id='xxxx';Password='xxxxx';")
    $ado.Open
    Global $adors = ObjCreate("ADODB.RecordSet")

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    ; CPU-Auslastung ermitteln
    $timestamp = TimerInit()

    [/autoit] [autoit][/autoit] [autoit]

    Global $a_CPU[2] = [0,0]
    While TimerDiff($timestamp) <= 120000
    CPUusage($a_CPU)
    Sleep(20)
    WEnd
    $d_CPU_mean = Round($a_CPU[1] / $a_CPU[0])

    [/autoit] [autoit][/autoit] [autoit]

    $a_RAM = _RAM() ;RAM auslesen
    $d_Sessions = sessions() ; Anzahl Sessions

    [/autoit] [autoit][/autoit] [autoit]

    With $adors
    .ActiveConnection = $ado
    .Source = "INSERT INTO LOGS(DATUM, UHRZEIT, RAM_PROZENT, RAM_GB, CPU, USER_SESSIONS, SERVER_ID) VALUES('" & _
    @YEAR & "." & @MON & "." & @MDAY & "','" & _
    @HOUR & ":" & @MIN & ":" & @SEC & "'," & _
    $a_RAM[0] & "," & _
    $a_RAM[1] & "," & _
    $d_CPU_mean & "," & _
    $d_Sessions & "," & _
    $server_ID & ")"
    .open
    EndWith
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    $adors.close
    $ado.close

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func _RAM() ;RAM auslesung - return: Array[0] = Prozent; Array[0] = Auslastung in GB
    Local $aMem = MemGetStats()
    Local $aMemTot = $aMem[1] - $aMem[2]
    Local $a_Ret[2] = [Round($aMemTot / $aMem[1] * 100), Round($aMemTot / 1048576, 3)]
    Return $a_Ret
    EndFunc ;==>_RAM

    [/autoit] [autoit][/autoit] [autoit]

    ; ermittelt die Summe der CPU-Auslastung. Byref $a_CPU[0] = Anzahl an Messungen; $a_CPU[1] = Summe der Prozentwerte
    Func CPUusage(ByRef $a_CPU)
    Local Static $o_WMI = ObjGet("winmgmts:\\.\root\cimv2")
    Local Static $o_WMIRefresher = ObjCreate("WbemScripting.Swbemrefresher")
    Local Static $o_CPULoadPercentage = $o_WMIRefresher.AddEnum ($o_WMI, "Win32_Processor").objectSet
    Local $x

    [/autoit] [autoit][/autoit] [autoit]

    $o_WMIRefresher.Refresh
    For $i in $o_CPULoadPercentage
    $x = $i.LoadPercentage
    If IsNumber($x) Then
    $a_CPU[0] += 1
    $a_CPU[1] += $x
    EndIf
    Next
    EndFunc ;==>CPUusage

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ====================================================================================================================
    ; Name ..........: sessions
    ; Description ...: liest aus, wie viele User angemeldet sind
    ; Syntax ........: sessions()
    ; Return values .: None
    ; Author ........: Marcel Dias Andrade (PEA3-Fe)
    ; Modified ......: 04.07.2014
    ; ===============================================================================================================================
    Func sessions()
    Local $PID, $Ret = ""
    Local $PID = Run('"' & @ComSpec & '" /c quser', '', @SW_HIDE, 0x2)

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $Ret &= StdoutRead($PID)
    If @error Then ExitLoop
    WEnd
    Local $aAnzahl = StringSplit($Ret, @CRLF, 1) ;$aAnzahl[0]-2 = anzahl der angemeldeten User
    Return $aAnzahl[0] - 2
    EndFunc ;==>sessions

    [/autoit]
  • Vereinsgründung

    • AspirinJunkie
    • 13. August 2014 um 09:24

    Hätte schon Interesse - wohne aber leider bisschen weit entfernt von Berlin.

    Ein Problem sehe ich bei diesem Vorhaben allerdings.
    Ich gehe mal davon aus, dass du den Status der Gemeinnützigkeit anstrebst.
    Diese muss extra beim Finanzamt beantragt werden.
    Die einzige Begründung hierfür die überhaupt denkbar wäre, wäre § 52 (2) 7. AO:

    Zitat

    die Förderung der Erziehung, Volks- und Berufsbildung einschließlich der Studentenhilfe;


    Für uns mag das passend wie die Faust aufs Auge erscheinen.
    Für Finanzämter muss das allerdings nicht unbedingt gelten. Ich schreibe dies, weil ich genau den Fall eines entsprechenden Forums kenne, deren Gemeinnützigkeit nicht erteilt wurde. Leider finde ich die Quelle nicht mehr.
    Die Folge wäre Gewerbe- und Körperschaftssteuer, ein höherer Umsatzsteuersatz von 19% statt 7% und Spenden und Mitgliedsbeiträge können nicht steuerlich abgesetzt werden.

    Zitat von Gun-Food

    Weil nach der Gründungssitzung alle Vorstandsmitglieder PERSÖNLICH beim Amtsgericht zur Eintragung erscheinen müssen.

    Im Normalfall macht man das meines Wissens nach nicht direkt beim Amtsgericht, sondern bei einem Notar. Hier gilt zwar ebenfalls das alle Vorstandsmitglieder persönlich anwesend sein müssen. Allerdings habe ich mal gelesen, dass die Vertretung eines Vorstandsmitgliedes durchaus möglich ist und zwar mit einer notariell beglaubigten Vollmacht.
    Heißt: Ein Mitglied ist aus Stuttgart. Also geht er zu einem Notar in Stuttgart der ihm eine Vollmacht für ein Berliner Vorstandsmitglied ausstellt, welcher ihn bei der Vereinsgründung vertreten darf.

  • Performance-Analyse der neuen Datenstruktur "Map"

    • AspirinJunkie
    • 12. August 2014 um 12:48

    Wie ich bereits schrieb weiß ich nicht wie die Deque in der STL implementiert wird.
    Allgemein kann eine Deque sowohl als Array als auch als List implementiert werden und wird in anderen Sprachen ja auch so implementiert.
    Wenn es aber in der STL, wie du sagtest, auf konstanten Random-Access beschränkt wird ist eine Implementierung als List hingegen natürlich hinfällig.
    In C++ ist es demnach, wie du schon sagtest, also keine Liste.

  • Hilfe bei der Konvertierung einer AutoHotkey Funktion

    • AspirinJunkie
    • 12. August 2014 um 11:09

    Ich finde die Zusammenstellung der Kriterien für eine Auswahl von "richtigen" Fenstern bisschen skurril.
    Damit das deutlicher wird welche Kombinationen zu dieser Auswahl gehören habe ich die logische Verknüpfung mal in Form von If-Verzweigungen auseinander genommen um etwas deutlicher zu machen was gemeint ist:

    [autoit]

    #include <WinAPI.au3>
    #include <WindowsConstants.au3>

    [/autoit][autoit][/autoit][autoit]

    Local $var = WinList()
    For $i = 1 To $var[0][0]
    If Not IsWindow($var[$i][1]) Then ContinueLoop
    ConsoleWrite($var[$i][0] & @CRLF)
    Next

    [/autoit][autoit][/autoit][autoit][/autoit][autoit]

    Func IsWindow($hwnd)
    Local $exStyle = _WinAPI_GetWindowLong($hwnd, $GWL_EXSTYLE)
    If @error Then Return SetError(1, _WinAPI_GetLastError(), _WinAPI_GetLastErrorMessage())

    [/autoit][autoit][/autoit][autoit]

    If (Not _WinAPI_GetWindow($hwnd, $GW_OWNER)) And _ ; Wenn Fenster kein "Unterfenster" eines anderen Fensters ist sondern "eigenständig"
    (Not BitAND($exStyle, $WS_EX_TOOLWINDOW)) Then ; Dann darf der Stil dieses "eigenständigen" Fensters nicht WS_EX_TOOLWINDOW enthalten
    Return True
    ElseIf BitAND($exStyle, $WS_EX_APPWINDOW) Then ; Ansonsten (also wenn es ein Unterfenster ist) dann darf WS_EX_APPWINDOW nicht gesetzt sein
    Return True
    Else
    Return False
    EndIf
    ;~ Return ((Not _WinAPI_GetWindow($hwnd, $GW_OWNER) And (Not BitAND($exStyle, $WS_EX_TOOLWINDOW))) Or BitAND($exStyle, $WS_EX_APPWINDOW)) ? 1 : 0
    EndFunc

    [/autoit]

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™