Beiträge von BugFix

;-- TIME_STAMP   2021-10-19 09:51:42

#cs
    • Au3Wrapper manipulates the file with AutoIt. The SciTE events doesn't work there. TimeStamp doesn't run and is moved by inserting the wrapper region.

    • This script runs after the Au3Wrapper, searches the start of the Wrapper region (#pragmas too) and moves all wrapper lines downwards, starting at line behind the TimeStamp
      The TimeStamp will moved to its right line from property: "TimeStamp.Type.Line"

    • Required:
        "\AutoIt3Wrapper\AutoIt3Wrapper.ini"

        [Other]
        Run_After="C:\CODE\AutoIt\Au3WrapperRunAfter_MoveRegion.exe"

    From "Help - SciTE4AutoIt3":

            Default AutoIt3Wrapper options can be set in AutoIt3Wrapper.ini which is stored in the %LOCALAPPDATA%\AutoIt v3\SciTE\AutoIt3Wrapper folder
            for the Installer version and ...\AutoIt3\SciTE\AutoIt3Wrapper folder for the portable version.
            There is an example ini file in the folder to serve as a template:


            ' This INI sets the Defaults for AutoIt3Wrapper which can be overridden by the Compiler Directives
            ' Use 1/y for Yes and 0/n for No on options like Run_AU3Check
            ' See documentation for an explanation on purpose of the fields and their values


            ' AutoIt section for Aut2Exe and AutoIt3
            [Autoit]
            Aut2Exe=
            Icon=
            OutfileType=
            Compression=
            UseUpx=


            ' Resource update section
            [Res]
            Language=
            Comment=
            Description=
            Fileversion=
            LegalCopyright=
            Field1Name=
            Field1Value=
            Field2Name=
            Field2Value=


            [Other]
            Run_AU3Check=
            AU3Check_Stop_OnWarning=
            AU3Check_Parameter=
            Run_Before=
            Run_After=
            TempDir=
            ShowProgress=

            SciTE_STOPEXECUTE=^{END}

            SciTE_RESTART=^!{END}


#ce

#include <File.au3>
#include <WinAPIConv.au3>
#include <WinAPIConstants.au3>

Global $g_SciTECmd

GUIRegisterMsg(74, "MY_WM_COPYDATA")  ; $WM_COPYDATA = 74


; die vom Au3Wrapper geänderte Datei muss gelesen werden
; im Editor ist zu diesem Zeitpunkt noch der Inhalt vor der Wrapper-Ausführung
; Pfad der aktuell zum Kompilieren in SciTE geöffneten Datei
Global $sFileCurr = _GetCurrentFile()

; ################ Direkter TEST des Skriptes mit <F5> und einer beliebigen au3-Datei mit Wrappereinträgen & verschobenem TimeStamp
;~ Global $sFileCurr = 'C:\CODE\AutoIt\Test\TestWrapper.au3'
; ################

; in welcher Zeile muss der TimeStamp stehen (ohne Property Eintrag: 1)
Global $propTimeStampLine = _GetProperty('TimeStamp.Type.Line')
If $propTimeStampLine = '' Then $propTimeStampLine = 'au3=1'
Global $iLineTimeStamp = StringRegExp($propTimeStampLine, '(?i)au3=(\d)', 1)[0]
If $iLineTimeStamp < 1 Then $iLineTimeStamp = 1

; die Wrapper-Region soll in die Zeile nach dem TimeStamp verschoben werden
Global $iLineWrapper = $iLineTimeStamp +1

; aktuelle Zeilennummern nach Ausführung des Wrappers
Global $iCurrTimeStamp = Null, $iCurrPragmaStart = Null, $iCurrPragmaEnd = Null, $iCurrWrapperStart = Null
Global $iCurrWrapperEnd = Null, $iCurrInclStart = Null, $iCurrInclEnd = Null

; Einlesen der Datei
Global $aRead
_FileReadToArray($sFileCurr, $aRead, 0)

; Zeilen mit Wrapper Start/End und TimeStamp suchen (Wrapper-Start od. pragma od. "Start added" ist immer in erster Zeile, wenn eingefügt)
For $i = 0 To UBound($aRead) -1
    If $iCurrInclStart = Null Then
        If StringRegExp($aRead[$i], '^; \*\*\* Start added by AutoIt3Wrapper \*\*\*') Then $iCurrInclStart = $i
    EndIf
    If $iCurrInclEnd = Null Then
        If StringRegExp($aRead[$i], '^; \*\*\* End added by AutoIt3Wrapper \*\*\*') Then $iCurrInclEnd = $i
    EndIf
    If $iCurrPragmaStart = Null Then
        If StringRegExp($aRead[$i], '^#pragma') Then $iCurrPragmaStart = $i
    Else
        If StringRegExp($aRead[$i], '^#pragma') Then $iCurrPragmaEnd = $i
    EndIf
    If $iCurrWrapperStart = Null Then
        If StringRegExp($aRead[$i], '^#Region ;\*\*\*\* Directives created by AutoIt3Wrapper_GUI \*\*\*\*') Then
            $iCurrWrapperStart = $i
        EndIf
    EndIf
    If $iCurrWrapperEnd = Null Then
        If StringRegExp($aRead[$i], '^#EndRegion ;\*\*\*\* Directives created by AutoIt3Wrapper_GUI \*\*\*\*') Then
            $iCurrWrapperEnd = $i
        EndIf
    EndIf
    If $iCurrTimeStamp = Null Then
        If StringRegExp($aRead[$i], '^;-- TIME_STAMP') Then
            $iCurrTimeStamp = $i
            $sTimeStamp = $aRead[$i]
        EndIf
    EndIf
    ; Bedingungen zum schnellstmöglichen Beenden der Suche (Skript wird nicht bis zum Ende durchsucht)
    If ($iCurrTimeStamp <> Null And $iCurrWrapperStart <> Null And $iCurrWrapperEnd <> Null) Or _                 ; Wrapper-Region und TimeStamp vorhanden
       ($iCurrPragmaStart <> Null And $iCurrTimeStamp <> Null) Or _                                                ; Pragma und TimeStamp
       ($iCurrInclStart <> Null And $iCurrTimeStamp <> Null) Or _                                                ; Include und TimeStamp
       ($iCurrTimeStamp <> Null And $iCurrWrapperStart = Null) Or _                                               ; keine Wrapper-Region eingefügt aber TimeStamp
       ($iCurrTimeStamp = Null And $iCurrWrapperEnd <> Null And $i > ($iCurrWrapperEnd + $iLineTimeStamp)) Or _ ; Wrapper-Region aber kein TimeStamp
       (($iCurrWrapperStart = Null And $iCurrPragmaStart = Null And $iCurrInclStart = Null) And _                ; keine Wrapper/Pragma/Include-Region, kein TimeStamp
       $i > $iLineTimeStamp And $iCurrTimeStamp = Null) Then
        ExitLoop
    EndIf
Next

; der tatsächlich belegte Wrapperbereich
Global $iWrapperStart = $iCurrInclStart <> Null ? $iCurrInclStart : ($iCurrPragmaStart <> Null ? $iCurrPragmaStart : $iCurrWrapperStart)
$iCurrPragmaEnd = $iCurrPragmaEnd <> Null ? $iCurrPragmaEnd : $iCurrPragmaStart
Global $iWrapperEnd = $iCurrWrapperEnd <> Null ? $iCurrWrapperEnd : ($iCurrPragmaEnd <> Null ? $iCurrPragmaEnd : $iCurrInclEnd)
Global $nWrapperLines = $iWrapperStart <> Null ? $iWrapperEnd - $iWrapperStart : 0


If $iWrapperStart = Null Then    ; es wurde keine Wrapper-Region eingefügt
    Exit
Else
    ; im Array den Wrapperbereich verschieben
    Global $iLineLast = $nWrapperLines + ($iLineWrapper -1)
    If $iLineLast < $iCurrTimeStamp Then $iLineLast = $iCurrTimeStamp

    Global $aLinesToMove[$iLineLast - $iWrapperEnd]
    Global $n = 0

    ; zu verschiebene Zeile(n) unterhalb Wrapper-Region sammeln
    For $i = $iWrapperEnd +1 To $iLineLast
        $aLinesToMove[$n] = $aRead[$i]
        $n += 1
    Next

    ; Wrapper-Region zeilenweise nach unten verschieben, beim letzten Eintrag beginnen
    For $i = $iLineLast To UBound($aLinesToMove) Step -1
        $aRead[$i] = $aRead[$i - UBound($aLinesToMove)]
    Next

    ; evtl. Zeile des TimeStamp korrigieren
    Switch UBound($aLinesToMove)
        Case 1
            ; alles OK - nur ein Eintrag, das ist der TimeStamp
        Case Else
            Global $iTmp, $sTmp
            $iTmp = $iCurrTimeStamp -$iWrapperEnd -1    ; Index TimeStamp in Array
            If $iTmp = $iLineTimeStamp -1 Then             ; TimeStamp an richtigem Index
                ; do nothing
            Else
                If $iTmp = 0 Then
                    $sTmp = $aLinesToMove[1]
                    $aLinesToMove[1] = $aLinesToMove[0]
                    $aLinesToMove[0] = $sTmp
                Else
                    $sTmp = $aLinesToMove[$iTmp-1]
                    $aLinesToMove[$iTmp-1] = $aLinesToMove[$iTmp]
                    $aLinesToMove[$iTmp] = $sTmp
                EndIf
            EndIf
    EndSwitch

    ; Zeilen bis zum TimeStamp an richtiger Position eintragen
    For $i = 0 To UBound($aLinesToMove) -1
        $aRead[$i] = $aLinesToMove[$i]
    Next

    ; ############################################################## TEST - nur Anzeige Array-Inhalt
;~     ConsoleWrite('+ =================================================================' & @CRLF)
;~     ConsoleWrite('+ Neuer Array-Inhalt bis incl. der Zeile, in der der TimeStamp war:' & @CRLF)
;~     ConsoleWrite('+ =================================================================' & @CRLF)
;~     For $i = 0 To $iLineLast
;~         ConsoleWrite($aRead[$i] & @CRLF)
;~     Next
    ; ##############################################################################################


    ; Datei mit den Änderungen der Reihenfolge aus Array überschreiben
    Global $hFileCurr = FileOpen($sFileCurr, 2+128) ; $FO_OVERWRITE (2), $FO_UTF8 (128)
    _FileWriteFromArray($hFileCurr, $aRead)
    FileClose($hFileCurr)
EndIf



;===============================================================================
; Function Name....: _GetCurrentFile
; Description......: Gibt den Pfad der aktuell im Editor geöffneten Datei zurück
; Parameter(s).....: keine
; Return Value(s)..: Dateipfad
; Author(s)........: BugFix
;===============================================================================
Func _GetCurrentFile()
    SendSciTE_Command("askfilename:", 1)
    Return StringReplace(StringTrimLeft($g_SciTECmd,StringInStr($g_SciTECmd, ':', 1, 3)), '\\', '\')
EndFunc

;===============================================================================
; Function Name....: _GetProperty
; Description......: Gibt den Wert für eine Property zurück
; Parameter(s).....: Property
; Return Value(s)..: Wert der Property
; Docu.............: http://www.scintilla.org/SciTEDoc.html od. "SciTE-Hilfe" --> "SciTE Documentation"
; Author(s)........: BugFix
;===============================================================================
Func _GetProperty($_sProperty)
    SendSciTE_Command("askproperty:" & $_sProperty, 1)
    Return StringTrimLeft($g_SciTECmd,StringInStr($g_SciTECmd, ':', 1, 4))
EndFunc

#cs    --> Diese Versionen sind für die Verwendung mit Umlauten gedacht. In meinem SciTE liefern sie jedoch immer nur '0' zurück.
;===============================================================================
; Function Name....: _GetCurrentFile
; Description......: Gibt den Pfad der aktuell im Editor geöffneten Datei zurück
; Parameter(s).....: keine
; Return Value(s)..: Dateipfad
; Author(s)........: BugFix, Modified: Bitnugger
;===============================================================================
Func _GetCurrentFile()
    SendSciTE_Command("askfilename:", 1)
    Return StringReplace(StringTrimLeft(_WinAPI_MultiByteToWideChar(String($g_SciTECmd), 65001, $MB_PRECOMPOSED, True), StringInStr($g_SciTECmd, ':', 1, 1)), '\\', '\')
EndFunc  ;==>_GetCurrentFile

;===============================================================================
; Function Name....: _GetProperty
; Description......: Gibt den Wert für eine Property zurück
; Parameter(s).....: Property
; Return Value(s)..: Wert der Property
; Docu.............: http://www.scintilla.org/SciTEDoc.html od. "SciTE-Hilfe" --> "SciTE Documentation"
; Author(s)........: BugFix, Modified: Bitnugger
;===============================================================================
Func _GetProperty($_sProperty)
    SendSciTE_Command("askproperty:" & $_sProperty, 1)
ConsoleWrite('StringTrimLeft($g_SciTECmd, StringInStr($g_SciTECmd... ' & StringTrimLeft($g_SciTECmd, StringInStr($g_SciTECmd, ':', 1, 4)) & @CRLF)
;~     Return StringTrimLeft($g_SciTECmd, StringInStr($g_SciTECmd, ':', 1, 4))
    Return _WinAPI_MultiByteToWideChar(StringTrimLeft($g_SciTECmd, StringInStr($g_SciTECmd, ':', 1, 4)), 65001, $MB_PRECOMPOSED, True)
EndFunc  ;==>_GetProperty
#ce

; by BugFix
Func _GetHwndDirectorExtension()
    Local $hActive = WinGetHandle('[ACTIVE]')
    Local $PIDActive = WinGetProcess($hActive)
    Local $aExtension = WinList("DirectorExtension")
    Local $PIDExt
    For $i = 1 To $aExtension[0][0]
        $PIDExt = WinGetProcess($aExtension[$i][1])
        If $PIDExt = $PIDActive Then Return $aExtension[$i][1]
    Next
EndFunc  ;==>_GetHwndDirectorExtension

; by Jos
Func SendSciTE_Command($_sCmd, $Wait_For_Return_Info = 0)
    Local Static $My_Hwnd = GUICreate("AutoIt3-SciTE interface") ; Create GUI to receive SciTE info
    Local Static $My_Dec_Hwnd = Dec(StringTrimLeft($My_Hwnd, 2)) ; Convert my Gui Handle to decimal
    Local Const $SCI_GETLINE      = 0x0869 ;  2153
    Local Const $WM_COPYDATA      = 0x004A ;    74
    Local Const $WM_GETTEXT       = 0x000D ;    13
    Local Const $WM_GETTEXTLENGTH = 0xE224 ; 57892
    Local $Scite_hwnd = _GetHwndDirectorExtension() ; Get SciTE DIrector Handle
    $_sCmd = ":" & $My_Dec_Hwnd & ":" & $_sCmd              ; Add dec my gui handle to commandline to tell SciTE where to send the return info
    Local $CmdStruct = DllStructCreate('CHAR[' & StringLen($_sCmd) + 1 & ']')
    DllStructSetData($CmdStruct, 1, $_sCmd)
    Local $COPYDATA = DllStructCreate('ULONG_PTR;DWORD;PTR')
    DllStructSetData($COPYDATA, 1, 1)
    DllStructSetData($COPYDATA, 2, StringLen($_sCmd) + 1)
    DllStructSetData($COPYDATA, 3, DllStructGetPtr($CmdStruct))
    $g_SciTECmd = ""
    DllCall('User32.dll', 'None', 'SendMessage', _
            'HWnd', $Scite_hwnd, _
            'Int', $WM_COPYDATA, _
            'HWnd', $My_Hwnd, _
            'Ptr', DllStructGetPtr($COPYDATA))
;~     GUIDelete($My_Hwnd)
    If $Wait_For_Return_Info Then
        For $x = 1 To 10
            If $g_SciTECmd <> "" Then ExitLoop
            Sleep(20)
        Next
        $g_SciTECmd = StringTrimLeft($g_SciTECmd, StringLen(":" & $My_Dec_Hwnd & ":"))
        $g_SciTECmd = StringReplace($g_SciTECmd, "macro:stringinfo:", "")
        Return $g_SciTECmd
    EndIf
EndFunc  ;==>SendSciTE_Command

;~ https://docs.microsoft.com/en-us/windows/desktop/api/Winuser/ns-winuser-tagcopydatastruct
;~ typedef struct tagCOPYDATASTRUCT {
;~   ULONG_PTR dwData; --> ULONG_PTR
;~   DWORD     cbData; --> DWORD
;~   PVOID     lpData; --> PTR
;~ } COPYDATASTRUCT, *PCOPYDATASTRUCT;
Func MY_WM_COPYDATA($hWnd, $msg, $wParam, $lParam)
    Local $COPYDATA = DllStructCreate('ULONG_PTR;DWORD;PTR', $lParam)
    Local $SciTECmdLen = DllStructGetData($COPYDATA, 2)
    Local $CmdStruct = DllStructCreate('CHAR[255]', DllStructGetData($COPYDATA, 3))
    $g_SciTECmd = StringLeft(DllStructGetData($CmdStruct, 1), $SciTECmdLen)
EndFunc  ;==>MY_WM_COPYDATA

-- TIME_STAMP   2019-08-16 10:14:42   v 0.1

--[[---------------
LuaBit v0.4
-------------------
a bitwise operation lib for lua.

http://luaforge.net/projects/bit/

How to use:
-------------------
 bit.bnot(n)                -- bitwise not (~n)
 bit.band(m, n)             -- bitwise and (m & n)
 bit.bor(m, n)              -- bitwise or (m | n)
 bit.bxor(m, n)             -- bitwise xor (m ^ n)
 bit.brshift(n, bits)       -- right shift (n >> bits)
 bit.blshift(n, bits)       -- left shift (n << bits)
 bit.blogic_rshift(n, bits) -- logic right shift(zero fill >>>)

Please note that bit.brshift and bit.blshift only support number within
32 bits.

2 utility functions are provided too:
 bit.tobits(n) -- convert n into a bit table(which is a 1/0 sequence)
               -- high bits first
 bit.tonumb(bit_tbl) -- convert a bit table into a number
-------------------

Under the MIT license.

copyright(c) 2006~2007 hanzhao (abrash_han@hotmail.com)



2016 - The function table.getn is deprecated!
added:   table_getn instead of table.getn                                   by @BugFix (autoit@bug-fix.info)
changed: bit.band, bit.bor, bit.bxor now accepts more than two parameters   by @BugFix (autoit@bug-fix.info)
--]]---------------

do
    local function table_getn(_t)
        local n = 0
        for _, __ in pairs(_t) do
            n = n + 1
        end
        return n
    end
    ------------------------
    -- bit lib implementions

    local function check_int(n)
        -- checking not float
        if(n - math.floor(n) > 0) then
            error("trying to use bitwise operation on non-integer!")
        end
    end

    local function to_bits(n)
        check_int(n)
        if(n < 0) then
            -- negative
            return to_bits(bit.bnot(math.abs(n)) + 1)
        end
        -- to bits table
        local tbl = {}
        local cnt = 1
        while (n > 0) do
            local last = math.mod(n,2)
            if(last == 1) then
                tbl[cnt] = 1
            else
                tbl[cnt] = 0
            end
            n = (n-last)/2
            cnt = cnt + 1
        end
        return tbl
    end

    local function tbl_to_number(tbl)
        -- local n = table.getn(tbl)
        local n = table_getn(tbl)
        local rslt = 0
        local power = 1
        for i = 1, n do
            rslt = rslt + tbl[i]*power
            power = power*2
        end
        return rslt
    end

    local function expand(tbl_m, tbl_n)
        local big = {}
        local small = {}
        -- if(table.getn(tbl_m) > table.getn(tbl_n)) then
        if(table_getn(tbl_m) > table_getn(tbl_n)) then
            big = tbl_m
            small = tbl_n
        else
            big = tbl_n
            small = tbl_m
        end
        -- expand small
        -- for i = table.getn(small) + 1, table.getn(big) do
        for i = table_getn(small) + 1, table_getn(big) do
            small[i] = 0
        end
    end

    local function bit_or(m, n)
        local tbl_m = to_bits(m)
        local tbl_n = to_bits(n)
        expand(tbl_m, tbl_n)
        local tbl = {}
        -- local rslt = math.max(table.getn(tbl_m), table.getn(tbl_n))
        local rslt = math.max(table_getn(tbl_m), table_getn(tbl_n))
        for i = 1, rslt do
            if(tbl_m[i]== 0 and tbl_n[i] == 0) then
                tbl[i] = 0
            else
                tbl[i] = 1
            end
        end
        return tbl_to_number(tbl)
    end

    local function bit_or_multi(...)
        local args = {...}
        if #args == 1 then return args[1] end
        local res = args[1]
        for i = 2, #args do
            res = bit_or(res, args[i])
        end
        return res
    end

    local function bit_and(m, n)
        local tbl_m = to_bits(m)
        local tbl_n = to_bits(n)
        expand(tbl_m, tbl_n)
        local tbl = {}
        -- local rslt = math.max(table.getn(tbl_m), table.getn(tbl_n))
        local rslt = math.max(table_getn(tbl_m), table_getn(tbl_n))
        for i = 1, rslt do
            if(tbl_m[i]== 0 or tbl_n[i] == 0) then
                tbl[i] = 0
            else
                tbl[i] = 1
            end
        end
        return tbl_to_number(tbl)
    end

    local function bit_and_multi(...)
        local args = {...}
        if #args == 1 then return args[1] end
        local res = args[1]
        for i = 2, #args do
            res = bit_and(res, args[i])
        end
        return res
    end

    local function bit_not(n)
        local tbl = to_bits(n)
        -- local size = math.max(table.getn(tbl), 32)
        local size = math.max(table_getn(tbl), 32)
        for i = 1, size do
            if(tbl[i] == 1) then
                tbl[i] = 0
            else
                tbl[i] = 1
            end
        end
        return tbl_to_number(tbl)
    end

    local function bit_xor(m, n)
        local tbl_m = to_bits(m)
        local tbl_n = to_bits(n)
        expand(tbl_m, tbl_n)
        local tbl = {}
        -- local rslt = math.max(table.getn(tbl_m), table.getn(tbl_n))
        local rslt = math.max(table_getn(tbl_m), table_getn(tbl_n))
        for i = 1, rslt do
            if(tbl_m[i] ~= tbl_n[i]) then
                tbl[i] = 1
            else
                tbl[i] = 0
            end
        end
 --table.foreach(tbl, print)
        return tbl_to_number(tbl)
    end

    local function bit_xor_multi(...)
        local args = {...}
        if #args == 1 then return args[1] end
        local res = args[1]
        for i = 2, #args do
            res = bit_xor(res, args[i])
        end
        return res
    end

    local function bit_rshift(n, bits)
        check_int(n)
        local high_bit = 0
        if(n < 0) then
            -- negative
            n = bit_not(math.abs(n)) + 1
            high_bit = 2147483648 -- 0x80000000
        end
        for i=1, bits do
            n = n/2
            n = bit_or(math.floor(n), high_bit)
        end
        return math.floor(n)
    end

    -- logic rightshift assures zero filling shift
    local function bit_logic_rshift(n, bits)
        check_int(n)
        if(n < 0) then
            -- negative
            n = bit_not(math.abs(n)) + 1
        end
        for i=1, bits do
            n = n/2
        end
        return math.floor(n)
    end

    local function bit_lshift(n, bits)
        check_int(n)
        if(n < 0) then
            -- negative
            n = bit_not(math.abs(n)) + 1
        end
        for i=1, bits do
            n = n*2
        end
        return bit_and(n, 4294967295) -- 0xFFFFFFFF
    end

    local function bit_xor2(m, n)
        local rhs = bit_or(bit_not(m), bit_not(n))
        local lhs = bit_or(m, n)
        local rslt = bit_and(lhs, rhs)
        return rslt
    end

    --------------------
    -- bit lib interface

    bit = {
        -- bit operations
        bnot = bit_not,
--         band = bit_and,
        band = bit_and_multi,
--         bor  = bit_or,
        bor  = bit_or_multi,
--         bxor = bit_xor,
        bxor = bit_xor_multi,
        brshift = bit_rshift,
        blshift = bit_lshift,
        bxor2 = bit_xor2,
        blogic_rshift = bit_logic_rshift,

        -- utility func
        tobits = to_bits,
        tonumb = tbl_to_number,
    }

    return bit

end

--[[
for i = 1, 100 do
 for j = 1, 100 do
  if(bit.bxor(i, j) ~= bit.bxor2(i, j)) then
   error("bit.xor failed.")
  end
 end
end
--]]

#======================================================================== TIMESTAMP & BACKUP =======

#~ TimeStamp, which file type and line in script: type=#line-number
TimeStamp.Type.Line=au3=1|lua=1|py=3

#~ Coding-Cookie (if exists) should use which line (1 or 2)
#~ will moved after setting time stamp to its correct line
Coding.Cookie=lua=2|py=2

#~ Use version-backup for following file types:  EXT|EXT..
Version.BackUp.Files=au3|lua

#~ Ignore backup for files from these folders/drives (pipe-delimited list)
#~ not case sensitive
#~ i.e.: =C:\Program Files|C:\Program Files (x86)|E:
Version.Backup.Exclude.Dirs=

#~ Ignore backup for files with these names (or string pattern), (pipe-delimited list)
#~ not case sensitive
#~ i.e.
#~         file name starts with 'Test': "^Test"
#~         file name ends with 'Test': "Test$"
#~ If the exception is to apply only to a specific file type, append suffix. This is checked separately.
#~ i.e.
#~     Lua - file name starts with 'Test': "^Test.lua"        --> checks file name for find("^Test") and compares the file type "lua"
Version.Backup.Exclude.Files=

#~ optional general prefix for backup folder
Version.Prefix=BUVer_

#~ Path for version backup folder [VER_DIR]:
#~ URGENT!:        Path NOT in quotation!
#~                NO following backslash!
#~        "Version.Path.*=default"    - creates subdirectory in current script folder (likewise if property does not exist or has no value)
#~        Folder name:    $(Version.Path.ext)\$(Version.Prefix)FILENAME.EXT\
#~        File name:        \FILENAME[Version-Number].EXT
Version.Path.au3=C:\Code\VersionBackup\au3
Version.Path.lua=C:\Code\VersionBackup\lua

#======================================================================== \TIMESTAMP & BACKUP ======

-- TIME_STAMP   2021-11-12 10:16:58   v 0.3
-- coding:utf-8


--[[
    event: OnBeforeSave


SciTEUser.properties:

#======================================================================== TIMESTAMP & BACKUP =======

#~ TimeStamp, which file type and line in script: type=#line-number
TimeStamp.Type.Line=au3=1|lua=1|py=3

#~ Coding-Cookie (if exists) should use which line (1 or 2)
#~ will moved after setting time stamp to its correct line
Coding.Cookie=lua=2|py=2

#~ Use version-backup for following file types:  EXT|EXT..
Version.BackUp.Files=au3|lua

#~ Ignore backup for files from these folders/drives (pipe-delimited list)
#~ not case sensitive
#~ i.e.: =C:\Program Files|C:\Program Files (x86)|E:
Version.Backup.Exclude.Dirs=

#~ Ignore backup for files with these names (or string pattern), (pipe-delimited list)
#~ not case sensitive
#~ i.e.
#~         file name starts with 'Test': "^Test"
#~         file name ends with 'Test': "Test$"
#~ If the exception is to apply only to a specific file type, append suffix. This is checked separately.
#~ i.e.
#~     Lua - file name starts with 'Test': "^Test.lua"        --> checks file name for find("^Test") and compares the file type "lua"
Version.Backup.Exclude.Files=

#~ optional general prefix for backup folder
Version.Prefix=BUVer_

#~ Path for version backup folder [VER_DIR]:
#~ URGENT!:        Path NOT in quotation!
#~                NO following backslash!
#~        "Version.Path.*=default"    - creates subdirectory in current script folder (likewise if property does not exist or has no value)
#~        Folder name:    $(Version.Path.ext)\$(Version.Prefix)FILENAME.EXT\
#~        File name:        \FILENAME[Version-Number].EXT
Version.Path.au3=C:\Code\VersionBackup\au3
Version.Path.lua=C:\Code\VersionBackup\lua
#======================================================================== \TIMESTAMP & BACKUP ======
]]

--    v 0.3    fixed:    Incorrect use of Lua comments with additional characters ("--~" or others)
--    v 0.2    added:    CheckExclude()


local ct = require "CommonTools"  -- min v 0.4

TimeStamp = EventClass:new(Common)

TimeStamp.OnBeforeSave = function(self, _file)
    local tFile = {Dir = props['FileDir'], Name = props['FileName'], Ext = props['FileExt']:lower()}
    local tSetStamp, tCookie = {}, {}     -- File types to set time-stamp/move coding-cookie
    for ext, line in (props['TimeStamp.Type.Line']):gmatch('([^|=]+)=([^|]+)') do tSetStamp[ext] = line -1 end
    for ext, line in (props['Coding.Cookie']):gmatch('([^|=]+)=([^|]+)') do tCookie[ext] = line -1 end
    local tWriteBackup = {}  -- File types to write version backup
    for ext in (props['Version.BackUp.Files']):gmatch('([^|]+)') do tWriteBackup[ext] = true end
    -- check excludes
    if self:CheckExclude(tFile) then tWriteBackup[tFile.Ext] = nil end
    -- check conditions to call the function
    if tFile.Ext == nil or (tSetStamp[tFile.Ext] == nil and tWriteBackup[tFile.Ext] == nil) then return nil end

    -- call function
    self:Insert(tFile, tSetStamp[tFile.Ext], tCookie[tFile.Ext], (tWriteBackup[tFile.Ext] ~= nil))
    return nil
end


TimeStamp.CheckExclude = function(self, _tFile)
    local propExDirs, tExDirs = props['Version.Backup.Exclude.Dirs'], {}
    if propExDirs ~= '' then tExDirs = ct:Split(propExDirs, '|', true) end
    local propExFiles, tExFiles = props['Version.Backup.Exclude.Files'], {}
    if propExFiles ~= '' then tExFiles = ct:Split(propExFiles, '|', true) end
    if #tExDirs > 0 then
        for i=1, #tExDirs do
            if tExDirs[i]:lower():find('^'.._tFile.Dir:lower()) then return true end
        end
    end
    if #tExFiles > 0 then
        for i=1, #tExFiles do
            local ext = tExFiles[i]:lower():match('%.(%w+)$')
            if ext ~= nil then
                if ext == _tFile.Ext then
                    local name = tExFiles[i]:lower():match('^(.+)%.'..ext..'$')
                    if _tFile.Name:lower():find(name) then return true end
                end
            else
                if _tFile.Name:lower():find(tExFiles[i]:lower()) then return true end
            end
        end
    end
    return false
end


TimeStamp.SaveToVersionFolder =    function (self, _tFile, _sVer)
    local sSaveFolder = props['Version.Path.'.._tFile.Ext]:lower()
    if sSaveFolder == '' then sSaveFolder = 'default' end
    local sPrefix = props['Version.Prefix']
    local sVerFolder = sPrefix.._tFile.Name..'.'.._tFile.Ext..'\\'
    local sVerFile = _tFile.Name..'['.._sVer:sub(3, _sVer:len())..']'..'.'.._tFile.Ext
    if sSaveFolder == 'default' then sSaveFolder = _tFile.Dir..'\\' end
    local len = sSaveFolder:len()
    if sSaveFolder:sub(len, len) ~= '\\' then sSaveFolder = sSaveFolder..'\\' end
    if not ct:FileExists(sSaveFolder..sVerFolder) then ct:FolderCreate(sSaveFolder..sVerFolder) end
    if ct:FileExists(sSaveFolder..sVerFolder..sVerFile) then return nil end
    local fh = io.open(sSaveFolder..sVerFolder..sVerFile, "wb")
    local text = editor:GetText()
    fh:write(text)
    fh:close()
    return
end


TimeStamp.Insert = function (self, _tFile, _lineStamp, _lineCookie, _bBackup)
    local firstVisible, lineDiff = editor.FirstVisibleLine, 0

    local sCmntChar = ct:EditorGetCommentChar(_tFile.Ext)
    if sCmntChar:find('^--') then sCmntChar = '' end -- the time stamps starts as default with "--"
    local pattCmntChar = ct:EscapeMagic(sCmntChar)
    if _tFile.Ext == 'au3' then sCmntChar = ';' pattCmntChar = ';' end  -- avoid multi char comment like ";~"
    local len_eol, _, eol = ct:EditorGetEOL()
    local caret = editor.CurrentPos

    -- Checks (for max. 50 lines) if TimeStamp and/or coding-cookie exists and stores the informations
    local lineNum, lineText, lineLen, lineHome, lineCookie
    for l = 0, 49 do
        lineText, lineLen = editor:GetLine(l)
        if lineLen == nil then break end
        lineHome = editor:PositionFromLine(l)

        local a, y = lineText:find("^"..pattCmntChar.."%-+ TIME_STAMP.*()"..eol)
        if y ~= nil then
            lineNum = l
            break
        end
    end

    if lineNum == nil then  -- none time stamp exists
        lineText = ''
        lineLen = 0
        lineHome = editor:PositionFromLine(_lineStamp)
    end

    if _tFile.Ext ~= 'au3' then lineCookie = ct:EditorCodingCookieLine(50) end
    editor:BeginUndoAction()
    local mustSave, space, bStampNew, bFirst = 0, '   ', false, false
    local sVer, sVerMain, sVerSub = '', 0, 0

    if lineNum ~= nil then    -- if time stamp exists, check for main/sub number
        sVerMain, sVerSub = lineText:match('%s-v%s(%d+)%.(%d+)')
        if _bBackup == true then
            local verMark = lineText:match("([vVn])"..eol)
            if sVerMain ~= nil then
                if verMark == 'V' then
                    sVer = 'v '..tostring(tonumber(sVerMain) +1)..'.0'
                elseif verMark == 'v' then
                    sVer = 'v '..sVerMain..'.'..tostring(tonumber(sVerSub) +1)
                elseif verMark == 'n' or verMark == nil then
                    sVer = 'v '..sVerMain..'.'..sVerSub
                end
                mustSave = 1
            else            -- time stamp has no version number
                space = ''
            end
        end
    else                    -- none time stamp exists
        bStampNew = true
        lineNum = _lineStamp
        if _bBackup == false then
            space = ''
        else   -- first backup
            editor:SetSel(0,1)                        -- is it marked to avoid backup in this case?
            if editor:GetSelText() == '*' then         -- with asterisk at first editor position: no backup will saved, only time stamp are print
                space = ''
                editor:ReplaceSel('')
                bFirst = true
            else
                sVer = 'v 0.1'
                mustSave = 1
            end
        end
    end
    local stamp = sCmntChar.."-- TIME_STAMP   "..ct:OSDate().." "..ct:OSTime()..space..sVer..eol
    if bFirst == true then caret = caret - stamp:len() end

    if bStampNew == true then
        lineDiff = 1
        editor:InsertText(editor:PositionFromLine(lineNum), stamp)
    else
        local stampLineEnd = lineHome + lineLen
        editor:SetSel(lineHome, stampLineEnd)
        editor:ReplaceSel(stamp)
    end

    -- is TimeStamp in line from property --> if not, move it
    if lineNum ~= _lineStamp then
        ct:EditorMoveLine(lineNum, _lineStamp-lineNum)    -- target.line - current.line = count_to_move (-up/+down)
    end

    -- if coding cookie exists, be sure it has the line as set in properties, cookie has priority
    if lineCookie ~= nil then
        lineCookie = ct:EditorCodingCookieLine(50)    -- might have been moved --> search again
        if (lineCookie ~= _lineCookie) then ct:EditorMoveLine(lineCookie, _lineCookie-lineCookie) end
    end

    editor.FirstVisibleLine = firstVisible + lineDiff

    if mustSave == 1 then self:SaveToVersionFolder(_tFile, sVer) end
    if lineDiff == 1 then caret = caret + stamp:len() end
    editor:SetSel(caret,caret)
    editor:EndUndoAction()
end

; PC auf dem Programme gestartet werden sollen
; Skript als Task bei PC-Start ausführen

; Freigabe
$Share = "\\PC1\Run\"


While True
    Sleep(5000)
    If FileExists($Share & 'P1.txt') Then
        _Run_Prog('P1')
    ElseIf FileExists($Share & 'P2.txt') Then
        _Run_Prog('P2')
    EndIf
WEnd

Func _Run_Prog($_p)
    ; zu startende Programme (Bsp.)
    Local $P1 = 'notepad.exe'
    Local $P2 = 'calc.exe'
    Switch $_p
        Case 'P1'
            ShellExecute($P1)   ; oder Run() mit Parametern - z.B. SW_HIDE
        Case 'P2'
            ShellExecute($P2)
    EndSwitch
    FileDelete($Share & $_p & '.txt')
EndFunc

#include <WinAPIProc.au3>
#include <WinAPISys.au3>


#cs
#include <Array.au3>

$aTest = _GetSelectionFromTopMostExplorer()
_ArrayDisplay($aTest)

$aTest = _GetSelectionFromTopMostExplorer(False)
_ArrayDisplay($aTest)
#ce


; #FUNCTION# ====================================================================================================================
; Name ..........: _GetSelectionFromTopMostExplorer
; Description ...: Gets an array with selected files from the top most explorer window
; Syntax ........: _GetSelectionFromTopMostExplorer([$_bDir = True])
; Parameters ....: $_bDir    - [optional] Returns the full path (Default 'True'). With 'False' will only the filename returned.
; Return values .: Array with selected files. Counter at $ar[0]
; Requires.......: _GetTopmostHwndFromProcess()
; Author ........: BugFix
; ===============================================================================================================================
Func _GetSelectionFromTopMostExplorer($_bDir=True)
    Local $oShell = ObjCreate("Shell.Application")
    Local $oIE, $sPath = '', $oShellWindows = $oShell.Windows
    Local $oDoc, $bIE = False, $oFV
    For $i = 0 To $oShellWindows.Count -1  ; all opened explorer and internet explorer windows
        $oIE = $oShellWindows($i)
        $oDoc = $oIE.Document
        If _GetTopmostHwndFromProcess('explorer.exe', 'CabinetWClass') = $oIE.Hwnd Then
            If StringRegExp(ObjName($oDoc), "IShellFolderViewDual.") Then       ; be sure it's the explorer object
                $sPath = StringReplace(StringReplace(StringTrimLeft($oIE.LocationURL, 8), '%20', ' '), '/', '\') ; extract windows path from file-url
                $sPath = StringRegExpReplace($sPath, '(\\)$', '')  ; "C:\" --> "C:"
                $bIE = True   ; flag: found explorer
            EndIf
        EndIf
    Next
    Local $aSelection[500] = [0]
    If $bIE Then
        $oFV = $oIE.Document             ; File-Browser (ShellFolderView)
        If Not $_bDir Then $sPath = ''
        For $oFI In $oFV.SelectedItems   ; selected elements there
            $aSelection[0] += 1
            If $aSelection[0] > UBound($aSelection) Then ReDim $aSelection[UBound($aSelection) +500]
            $aSelection[$aSelection[0]] = StringFormat('%s%s%s',  $sPath, ($_bDir ? '\' : ''), $oFI.Name)
        Next
    EndIf
    If $aSelection[0] = 0 Then
        ReDim $aSelection[1]
    Else
        ReDim $aSelection[$aSelection[0]+1]
    EndIf
    Return $aSelection
EndFunc  ;==>_GetSelectionFromTopMostExplorer



; #FUNCTION# ====================================================================================================================
; Name ..........: _GetTopmostHwndFromProcess
; Description ...: Returns the handle of the top most window of a specific process
; Syntax ........: _GetTopmostHwndFromProcess($_vProcess)
; Parameters ....: $_vProcess           The Process name or PID
;                  $_sClass             The classname of windows that will created by the specific process
; Return values .: Success              The handle of the top most window
;                  Failure              0, set @error = 1 (process does not exists)
;                                              @error = 2 (there is no window for this)
; Author ........: BugFix
; ===============================================================================================================================
Func _GetTopmostHwndFromProcess($_vProcess, $_sClass)
    Local $aProc[2][2] = [[1],['',$_vProcess]]
    If IsString($_vProcess) Then
        $aProc = ProcessList($_vProcess)
        If $aProc[0][0] = 0 Then
            Return SetError(1,0,0)
        EndIf
    Else
        If Not ProcessExists($_vProcess) Then Return SetError(1,0,0)
    EndIf
    ; get the highest z-order
    Local $hWnd = 0, $aWin = _WinAPI_EnumDesktopWindows(_WinAPI_GetThreadDesktop(_WinAPI_GetCurrentThreadId()), False)
    For $i = 1 To $aWin[0][0]
        If $aWin[$i][1] = $_sClass Then ; first found window of this class has the highest z-order
            $hWnd = $aWin[$i][0]
            ExitLoop
        EndIf
    Next
    If $hWnd = 0 Then Return SetError(2,0,0)
    Local $tPID = DllStructCreate("int PID")
    For $i = 1 To $aProc[0][0]
        DllCall("user32.dll", "int", "GetWindowThreadProcessId", "hwnd", $hWnd, "ptr", DllStructGetPtr($tPID))
        If $tPID.PID = $aProc[$i][1] Then Return $hWnd
    Next
    Return 0
EndFunc  ;==>_GetTopmostHwndFromProcess