Mauszeiger soll auf OK-Button in MSGBox "springen"

hipfzwirgel

Hallo Gemeinde,

bei einer MSGBOX mit nur einem Ok-Button(z.B. Flag 4096) ist dieser der Standard-Button. Soweit so gut. Es nervt mich aber kollossal, dass der Mauszeiger das zu ignorieren scheint, denn er
springt nicht auf den Button. Hat die MSGBOX mehrere Buttons und ich definiere einen davon als Standard springt der Mauszeiger darauf. Kann ich dieses Verhalten für den ersten Fall i-wie
"erzwingen"? Es geht nur um eine INFO-MSGBOX die am Programmanfang direkt aufgeht. Zu diesem Zeitpunkt hat der User die Maus wegen des Proggi-Starts sowieso noch in der Hand und bräuchte nur klicken, damit das Proggi weiter macht...

**BugFix**

Zitat von hipfzwirgel

Es geht nur um eine INFO-MSGBOX die am Programmanfang direkt aufgeht. Zu diesem Zeitpunkt hat der User die Maus wegen des Proggi-Starts sowieso noch in der Hand und bräuchte nur klicken, damit das Proggi weiter macht...

Wenn der Inhalt der MsgBox ohne jeden Einfluß auf das Programm ist, setze doch ein Timeout von 1s (oder länger, wenn mehr zu Lesen ist).

Es ist nicht möglich die Position des Buttons abzufragen und die Maus dorthin zu bewegen, weil das Skript pausiert, bis die MsgBox wieder verschwindet.

Alternative: Bastele dir eine eigene MsgBox, wenn dir die Mausposition so wichtig ist.

Du kannst natürlich die User auch animieren mal über den Tellerrand zu gucken und festzustellen, dass es eine Tastatur gibt, bei der mit einem ENTER die MsgBox zugeht.

**Musashi**

Zitat von hipfzwirgel

Hat die MSGBOX mehrere Buttons und ich definiere einen davon als Standard springt der Mauszeiger darauf.

Also bei mir nicht :

AutoIt

#include <MsgBoxConstants.au3>
; Messagebox, mit YES/NO/CANCELButton :
;   $MB_YESNOCANCEL (3) ==> Yes, No, and Cancel
; Button 3 - hier CANCEL(Abbrechen) vorselektiert
MsgBox(BitOR($MB_SYSTEMMODAL, $MB_YESNOCANCEL, $MB_DEFBUTTON3), "Messagebox YESNOCANCEL", "Infotext")

EDIT : Ich sehe, dass BugFix bereits geantwortet hat - einfach ENTER drücken .

**Musashi**

hipfzwirgel :

Melba23 hat diesbzgl. eine interessante UDF erstellt, ggf. hilft Dir die ja weiter.

siehe : extended-message-box-new-version-2-aug-18

hipfzwirgel

Also erstmal: vielen lieben Dank für die Antworten.

@ Bugfix:

die Message-Box hat ohnehin schon einen Timeout. Es ging mir nur generell darum, das der User wenn er das Proggi startet
ja sowieso die Maus in der Hand hat. Da ist es ja nur folgerichtig, das er einfach klicken kann und das Proggi macht weiter.

@ Musashi:

ja die UDF benutze ich bereits. Zukünftig werde ich eben vermehrt damit die Msgbox-en erstellen. Damit funzt der Fokus und der Mauszeiger springt auf den Button...

Fall somit erledigt...

**Oscar**

Zitat von hipfzwirgel

Fall somit erledigt

Nur um mal zu zeigen, dass man das auch mit der Standard-MsgBox machen kann (_Timer-UDF missbrauchen):

AutoIt

#include <StructureConstants.au3>
#include <Timers.au3>
#include <WinAPIConv.au3>

Global $hDummy = GUICreate('dummy')
Global $iTimer =  _Timer_SetTimer($hDummy, 100, '_TimerFunc')
MsgBox(0, 'Messagebox', 'Infotext')

Func _TimerFunc($hWnd, $iMsg, $iIDTimer, $iTime)
    Local $hWin = WinGetHandle('Messagebox')
    If Not IsHWnd($hWin) Then Return
    Local $aCtrlPos = ControlGetPos($hWin, '', '[CLASS:Button; INSTANCE:1]')
    If @error Then Return
    Local $tPoint = DllStructCreate($tagPOINT)
    $tPoint.x = $aCtrlPos[0] + $aCtrlPos[2] / 2
    $tPoint.y = $aCtrlPos[1] + $aCtrlPos[3] / 2
    _WinAPI_ClientToScreen($hWin, $tPoint)
    MouseMove($tPoint.x, $tPoint.y, 0)
    _Timer_KillAllTimers($hDummy)
EndFunc

Alles anzeigen

**Musashi**

Zitat von Oscar

Nur um mal zu zeigen, dass man das auch mit der Standard-MsgBox machen kann (_Timer-UDF missbrauchen):

So geht es natürlich auch .