Hallo Leute,
bitte um Hilfe bei Aufrufen von Funktionen aus der dhcpsapi.dll (DHCP Server Management API)
Es geht dabei um die Funktionen DhcpEnumServers und DhcpEnumSubnetClients.
Das Problem liegt beim Definieren der Funktionsübergabeparameter mittels DllStructCreate.
Erster rudimentärer Versuch...
[autoit]
$dwRet = DllCall("dhcpsapi.dll", "DWORD","DhcpEnumServers", _
"dword",0, _
"int", 0, _
"int", 0, _
"int", 0
)
vielen Dank!
Hi,
was willst du überhaupt machen?
Ggf. gibt es dafür geeignetere und "sicherere" Methoden als API-Calls, bspw. WMI
Etwas davon ist hier schon vorhanden: http://www.autoitscript.com/forum/topic/74…ntinfo-wrapper/
Vielleicht hilft dir das schon.
Ich kann das leider nicht testen, aber so hätte ich das versucht:
Global Const $tagDHCPDS_SERVER = "DWORD Version;ptr ServerName;DWORD ServerAddress;DWORD Flags;DWORD State;ptr DsLocation;DWORD DsLocType;"
Global Const $tagDHCPDS_SERVERS = "DWORD Flags;DWORD NumElements;ptr Servers;"
Func _DhcpEnumServers()
Local $aRet = DllCall("Dhcpsapi.dll", "DWORD", "DhcpEnumServers", "DWORD", 0, "ptr", 0, "ptr*", 0, "ptr", 0, "ptr", 0)
If $aRet[0] <> 0 Then
Return SetError(1, $aRet[0])
EndIf
Local $iNum = DllStructCreate("DWORD NumElements", $aRet[3] + 4)
Local $tagDHCP_Temp = $tagDHCPDS_SERVERS
For $i = 1 To $iNum
$tagDHCP_Temp &= $tagDHCPDS_SERVER
Next
Local $tDHCP_Servers = DllStructCreate($tagDHCP_Temp, $aRet[3])
Local $aData[$iNum][4]
For $i = 0 To $iNum - 1
$aData[$i][0] = DllStructCreate("wchar[256]", DllStructGetData($tDHCP_Servers, 4 + $i * 7))
$aData[$i][0] = DllStructGetData($aData[$i][0], 1)
$aData[$i][1] = DllStructGetData($tDHCP_Servers, 5 + $i * 7)
$aData[$i][1] = _inet_ntoa($aData[$i][1])
$aData[$i][2] = DllStructGetData($tDHCP_Servers, 6 + $i * 7)
$aData[$i][3] = DllStructCreate("wchar[256]", DllStructGetData($tDHCP_Servers, 8 + $i * 7))
$aData[$i][3] = DllStructGetData($aData[$i][3], 1)
Next
;DllCall("Dhcpsapi.dll", "none", "DhcpRpcFreeMemory", "ptr", $aRet[3])
Return $aData
EndFunc ;==>_DhcpEnumServers
Func _inet_ntoa($pIn_Addr) ;only IPv4 (deprecated) --> use _inet_ntop() instead
Local $aRet = DllCall("ws2_32.dll", "str", "inet_ntoa", "ptr", $pIn_Addr)
Return $aRet[0]
EndFunc ;==>_inet_ntoa
#include <Array.au3>
Global $aDHCPServerInfo = _DhcpEnumServers()
If @error Then
MsgBox(16, "Error", "Error: " & @extended)
Else
_ArrayDisplay($aDHCPServerInfo, "Arraydisplay", "", 0, Default, "ServerName|ServerAddress|Flags|DsLocation")
EndIfHallo,
wenn man mit der DHCPSAPI.DLL arbeitet muss man, als erste Funktion immer DhcpDsInit aufrufen damit der Speicher vorbereitet wird und als letzte Funktion immer DhcpDsCleanup aufrufen damit der Speicher wieder aufgeräumt wird.
Das folgende Script ist getestet und funktioniert!
#include <Array.au3>
$tagString = "struct;WCHAR Text[1024];endstruct"
$tagDHCPDS_SERVER = "struct;DWORD Version;PTR ServerName;DWORD ServerAddress;DWORD Flags;DWORD State;PTR DsLocation;DWORD DsLocType;endstruct"
$tagDHCPDS_SERVERS = "struct;DWORD Flags;DWORD NumElements;PTR Servers;endstruct"
Local $bInitOk = False
Local $aDHCPServer[1][2] = [[0]]
$hDHCPAPI = DllOpen("DHCPSAPI.DLL")
DllCall($hDHCPAPI, "DWORD", "DhcpDsInit") ; https://msdn.microsoft.com/en-us/library/windows/desktop/aa813372(v=vs.85).aspx
$bInitOk = Not @error
If Not $bInitOk Then Exit
$aDLLRetVal = DllCall($hDHCPAPI, "DWORD", "DhcpEnumServers", "DWORD", 0, "PTR", Null, "PTR*", Null, "PTR", Null, "PTR", Null)
If IsArray($aDLLRetVal) Then
$tDHCPDS_SERVERS = DllStructCreate($tagDHCPDS_SERVERS, $aDLLRetVal[3])
$aDHCPServer[0][0] = DllStructGetData($tDHCPDS_SERVERS, "NumElements")
; Array für DHCPDS_SERVER struct aufbauen
$atagDHCPDS_SERVER = ""
For $i = 1 To $aDHCPServer[0][0]
$atagDHCPDS_SERVER &= StringRegExpReplace($tagDHCPDS_SERVER, "\s+(.*?);", " $1_" & $i & ";") & ";"
Next
$atDHCPDS_SERVER = DllStructCreate($atagDHCPDS_SERVER, DllStructGetData($tDHCPDS_SERVERS, "Servers"))
; Namen und IP in $aDHCPServer aufnehmen
For $i = 1 To $aDHCPServer[0][0]
$tString = DllStructCreate($tagString, DllStructGetData($atDHCPDS_SERVER, "ServerName_" & $i))
_ArrayAdd($aDHCPServer, DllStructGetData($tString, "Text") & "|" & _dw2ip(DllStructGetData($atDHCPDS_SERVER, "ServerAddress_" & $i)))
Next
EndIf
_ArrayDisplay($aDHCPServer)
DllCall($hDHCPAPI, "NONE", "DhcpDsCleanup") ; https://msdn.microsoft.com/en-us/library/windows/desktop/aa813371(v=vs.85).aspx
DllClose($hDHCPAPI)
Func _dw2ip($dwAddr)
$dwAddr = Hex($dwAddr, 8)
Return Int("0x" & StringMid($dwAddr, 1, 2)) & "." & Int("0x" & StringMid($dwAddr, 3, 2)) & "." & Int("0x" & StringMid($dwAddr, 5, 2)) & "." & Int("0x" & StringMid($dwAddr, 7, 2))
EndFunc ;==>_dw2ip