Ich benötige einen Denkanstoss beim kopieren von Dateien

Hi @Dreamworker

Mit dem Auslesen der csv hast du jetzt kein Problem, oder? Du hast also nur den Dateinamen und musst die Datei suchen. Da bietet sich _FileListToArrayRec an. Solange nicht mehrfach die gleichen Dateinamen auf dem Computer hast, kein Problem. Ansonsten..

Mit _ArraySearch oder _ArrayFindAll kannst du in dem Array, dass dann so aussieht, wie du es beschreibst, nach den Dateinamen aus deiner csv suchen.

Nein eigentlich brauchst du keine Filterdatei. Ich sehe auch nicht, dass das sinnvoll sein kann. Filter kannst du auch bei _FilelisttoArrayRec mitgeben..

Du machst damit einmal eine Suche in dem Bereich, in dem deine Bilder liegen können und speicherst das in einem Array.
Dann gehst du in einer Schleife deine Einträge aus der csv durch und suchst die im Arrray.

Beispiel
Eintrag aus csv: img23.jpg

(Dein Array:)
c:\unterordner1\unterordner2\img1.jpg
c:\unterordner2\img23.jpg
c:\unterordner\unterordner\unterordner\img3.jpg

Da wird dir bspw. bei _ArraySearch und deinem Array der Indexwert (die Stelle im Array) ausgegeben, mit der du dann weiterarbeiten kannst. Dann hast du kompletten Pfad der Datei. Das kannst du dir erst einmal zwischenspeichern oder gleich deine gewünschte Kopie vornehmen.

Du sagst, die Dateien könnten in unterschiedlichen Verzeichnissen liegen... sind diese Verzeichnisse Unterverzeichnisse oder sind sie verstreut auf verschieden Pfaden/Partitionen?

Ich mache solche Aktionen gerne mit Everything... bzw. mit dem Komandozeilen-Tool es.exe, dass du auch auf dieser Seite findest.

Beispiel:
> es.exe -h
-r Search the database using a basic POSIX regular expression.
-i Does a case sensitive search.
-w Does a whole word search.
-p Does a full path search.
-h --help Display this help.
-n <num> Limit the amount of results shown to <num>.
-s Sort by full path.

; alle Bilder aus dem Verzeichnis "f:\Eigene Dateien\Pictures\Fun\" inkl. aller Unterverzeichnisse nach Bildern durchsuchen, die mit "img" beginnen und mit ".jpg" enden
> es.exe -p "f:\Eigene Dateien\Pictures\Fun\*img*.jpg"
F:\Eigene Dateien\Pictures\Fun\Fun - JPG\Ichhasseallekriminellen.jpg
F:\Eigene Dateien\Pictures\Fun\Fun - JPG\Katzenfalle.jpg
F:\Eigene Dateien\Pictures\Fun\Fun - Linux\linux_users_what_i_really_do.jpg
...

oder die Ausgabe direkt in eine Datei umleiten...

> es.exe -p "f:\Eigene Dateien\Pictures\Fun\*img*.jpg" >> c:\pics.txt

Alternativ kannst du natürlich auch es.exe via AutoIt starten und die Ausgabe von Stdout in ein Array einlesen...

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3> ; Required for _ArrayDisplay only.


;-- TIME_STAMP   2016-12-12 08:54:13


Example()


Func Example()
	;Local $iPID = Run(@ComSpec & ' /C DIR "' & $sFilePath & $sFilter & '" /B /A-D /S', $sFilePath, @SW_HIDE, $STDOUT_CHILD)
	;Hilfe anzeigen
	;Local $iPID = Run('es.exe -h', '', @SW_HIDE, $STDOUT_CHILD)
	;
	Local $iPID = Run('es.exe -p "f:\Eigene Dateien\Pictures\*Aqua*.jpg"', '', @SW_HIDE, $STDOUT_CHILD)
	ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iPID --> " & $iPID & @CRLF)
	; If you want to search with files that contains unicode characters, then use the /U commandline parameter.


	; Wait until the process has closed using the PID returned by Run.
	ProcessWaitClose($iPID)


	; Read the Stdout stream of the PID returned by Run. This can also be done in a while loop. Look at the example for StderrRead.
	Local $sOutput = StdoutRead($iPID)
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sOutput --> " & $sOutput & @CRLF)


	; Use StringSplit to split the output of StdoutRead to an array. All carriage returns (@CRLF) are stripped and @CRLF (line feed) is used as the delimiter.
	Local $aArray = StringSplit(StringTrimRight(StringStripCR($sOutput), StringLen(@CRLF)), @CRLF)
	If @error Then
		MsgBox($MB_SYSTEMMODAL, "", "It appears there was an error trying to find all the files in the current script directory.")
	Else
		; Display the results.
		_ArrayDisplay($aArray)
	EndIf
EndFunc   ;==>Example

es_example.png

Auch für die csv wären Arrays von Vorteil..
Leider kann ich dir nicht sicher helfen, weil ich hier in letzter Zeit gelernt habe, wie vermurkst csv-Dateien sein können.
Wenn es in etwa so ausschlaut:

img1.jpg;img2.jpg;img99.jpg
img11.jpg;img15.jpg

Dann würde ich es mit FileRead einlesen und das Ergebnis mit StringSplit (Semikolon als Trennzeichen) in ein Array splitten.

Das sollte dir die beiden Arrays geben :

EDIT: Hab grad die zwischenzeitlichen Antworten gelesen und das entsprechend ergänzt

#include <file.au3>
#include <array.au3> ; wird nur für _Arraydisplay am Ende gebraucht! kann dann eventuell entfernt werden
$file = "C:\test.csv" ; einzulesende csv Datei
$arTmpFiles=FileReadToArray($file);Datei einlesen
local $arFiles[UBound($arTmpFiles)],$count,$sDelimeter=@TAB
for $i=0 to UBound($arTmpFiles)-1 step 1;Durch alles einträge laufen
	$result=StringRegExp($arTmpFiles[$i],"\d*"&$sDelimeter&"(?:.*?)"&$sDelimeter&"(.*?)"&$sDelimeter&"(\d*)"&$sDelimeter,1);Den Namen und den Stern auslesen
	if Not @error then;Wenn gefunden
		if $result[1]="1" then;Wenn Sterne=1
			$arFiles[$count]=$result[0];eintragen
			$count+=1;counter ist nur, um am ende die größe festzulegen und nicht funde somit zu filtern
		endif
	endif
next
ReDim $arFiles[$count]
;$arSearch=_findFilesWithString("D:\Desktop","\\((?!\\).*?)img((?!\\).*?)\.jpg$");Nutzt den gesamten Pfad im RegExp
$arSearch=_findFilesWithString("D:\Desktop","(.*?)img(.*?)\.jpg$")
_ArrayDisplay($arFiles)
_ArrayDisplay($arSearch)
for $i=0 to UBound($arFiles)-1 step 1;arFiles durchlaufen
	$index=_ArraySearch($arSearch,$arFiles[$i]&".jpg");Nach dem Dateinamen suchen
	if $index>-1 then;Wenn gefunden ausgeben
		ConsoleWrite($arFiles[$i]&" -> "&$arSearch[$index][0]&@crlf)
	endif
next
Func _findFilesWithString($path,$pattern)
	;ConsoleWrite("Searching: "&$path&@crlf)
	$hSearch=FileFindFirstFile($path&"\*");Suche starten
	local $arResult[0][2];Array erstellen
	if $hSearch<>-1 then
		While 1
			$sFileName = FileFindNextFile($hSearch);Datei suchen
			If @error Then ExitLoop
			if @extended then
				$arTmp=_findFilesWithString($path&"\"&$sFileName,$pattern);Unterordner durchsuchen
				if UBound($arTmp)>0 then;Bei Fund
					ReDim $arResult[UBound($arResult)+UBound($arTmp)][2];Array vergrößern
					for $i=0 to UBound($arTmp)-1 step 1;und die Gefudnenen Dateien hinzufügen
						$arResult[UBound($arResult)+$i-UBound($arTmp)][0]=$arTmp[$i][0]
						$arResult[UBound($arResult)+$i-UBound($arTmp)][1]=$arTmp[$i][1]
					next
				endif
			else
				;if StringRegExp($path&"\"&$sFileName,$pattern,0) then;Dafür den gesamten Pfad im RegExp beachten
				if StringRegExp($sFileName,$pattern,0) then;Wenn die Datei dem Pattern entspricht
					ReDim $arResult[UBound($arResult)+1][2];Array vergrößern
					$arResult[UBound($arResult)-1][0]=$path&"\"&$sFileName;Datei reinschreiben
					$arResult[UBound($arResult)-1][1]=$sFileName;Datei reinschreiben
				endif
			endif
		WEnd
	endif
	return $arResult
EndFunc

Habs nen bisschen Kommentiert

Das Pattern (.*?)img(.*?)\.jpg$ findet alle Dateien die Folgendem entsprechen: irgendwas (.*?) gefolgt von img gefolgt von irgendwas gefolgt von einem .jpg
Das $ sagt, dass das .jpg am Ende stehen muss. Soll das img am Anfang stehen kannst du das erste (.*?) weglassen.

MfG Kanashius

\d steht für eine Zahl, das * dafür, dass es beliebig viele sind. Also wird dort die erste Spalte mit der Nummer gesucht.Die Spalten werden durch $sDelimeter getrennt. Dort musst du unbedingt das Trennzeichen der Spalten in der CSV-Datei angeben (Momentan TAB, kann aber auch ; sein. Einfach die CSV mit notepad oder ähnlichem aufmachen und nachsehen.)

Richtig wäre also:
"\d*"&$sDelimeter&"(?:.*?)"&$sDelimeter&"\d{4}-SUN-(.*?)"&$sDelimeter&"(\d*)"&$sDelimeter

\d{4}-SUN-(.*?) sucht nach 4 Zahlen gefolgt von -SUN-. Alles danach in der Spalte wird dann genommen.

Du musst UNBEDINGT das Trennzeichen wissen und bei $sDelimeter=@TAB zuweisen.

PS:
Dein Pattern findet folgendes:
"\SUN*"&$sDelimeter&"(?:.*?)"&$sDelimeter&"(.*?)"&$sDelimeter&"(\d*)"&$sDelimeter
Ein nicht Whitespacebuchstaben gefolgt von U gefolgt von beliebig vielen N -NEUE SPALTE- irgendwas, ohne match -NEUE SPALTE- irgendwas -NEUE SPALTE- beliebig viele Zahlen -NEUE SPALTE-

if $index>-1 then;Wenn gefunden ausgeben
ConsoleWrite($arFiles[$i]&" -> "&$arSearch[$index][0]&@crlf)
endif

die brauchst du nicht auslesen. Ich lasse nur die variablen in der schleife ausgeben. Du kannst das consolewrite dort wegnehmen und die variablen anderweitig nutzen. Also in der for-schleife.
$arFiles[$i] ist der name der erst ausgegeben wird und
$arSearch[$index][0] ist der pfad+dateiname der gefunden wurde
$arSearch[$index][1] ist der dateiname der gefunden wurde

Also FileCopy($arSearch[$index][0],$input1&"\"&$arSearch[$index][1])
Statt der inputbox kannst du auch fileselectfolder nutzen