Automatische Tastenkombination auf bestimmtes Programm in der Taskleiste

Knightfire

Hallo Zusammen,

durch Goolge bin ich auf eure Seite aufmerksam geworden und ich möchte mein Glück als IT Anwender, aber nicht Programmierer versuchen.

Folgende Problematik: Auf Arbeit setzen wir ein Verwaltungsprogramm an, wo ich mich als User mit der Tastenkombi STRG+W abmelden kann, sodass sich ein anderer User neu anmelden muss. Leider geht dies nicht automatisch nach X-Minuten Inaktivität, sondern nur, wenn ich die Kombi drücke. Das vergessen aber leider viele Kollegen uns so arbeitet man oft unter falschem Namen.

Gibt es eine Möglichkeit, extern von dem Programm, nach einer Zeit "X", automatisch die benannte Tastenkombi zu drücken? Diese sollte sich evtl auch nur auf das eine Programm auswirken, welches ja evtl. in der Taskleiste minimiert ist.

Habt ihr da eine Idee?

Mein nicht-programmierer Weg wäre folgender:

1. Zeit ist abgelaufen
2. Entsprechendes Programm in der Vordergrund holen
3. Tastenkombi ausführen

--> Warum Schritt 2? Weil evtl. ein anderes Programm, welches aktuell in oberster Reihe ist, auch auf diese Tastenkombi reagiert.

Danke für eure Mühe

**alpines**

Wenn es wirklich so einfach ist wie du es beschrieben hast, dann könnte man das ganz so lösen.
Das ist nur ein Ansatz, da ich nicht weiß wie die Software darauf reagiert und welche anderen Faktoren man noch alle hat aber du kannst es ja mal testen und berichten.

AutoIt

#include <WinAPISys.au3>


Global Const $I_IDLE_TIME = 10 * 60 * 1000 ;10 Minuten * 60 Sekunden * 1000 Millisekunden
Global Const $S_WINDOW_TITLE = "Titel des Programmfensters"


Global $bWaitReset = False


While Sleep(1000)
	$iIdleTime = _WinAPI_GetIdleTime()


	If $iIdleTime > $I_IDLE_TIME and Not $bWaitReset Then
		$bWaitReset = True


		Do
			WinActivate($S_WINDOW_TITLE)
			Sleep(250)
		Until WinActive($S_WINDOW_TITLE)


		Sleep(1000)


		ControlSend($S_WINDOW_TITLE, "", "", "{LCTRL down}{w down}")
		ControlSend($S_WINDOW_TITLE, "", "", "{LCTRL up}{w up}")


		WinSetState($S_WINDOW_TITLE, "", @SW_MINIMIZE)
	ElseIf $bWaitReset = True
		If $iIdleTime <= 5000 Then $bWaitReset = False
	EndIf
WEnd

Alles anzeigen

Knightfire

Auch wenn ich nur Bahnhof verstehe, probiere ich es einmal. Die Inhalte sind ja ähnlich zu HTML (Entschuldigung, falls das eine Beleidigung ist). Das sollte ich testen können.

**alpines**

Zitat von Knightfire

Auch wenn ich nur Bahnhof verstehe, probiere ich es einmal.

So schwierig ist das auch nicht. Was das Script so im groben macht kann ich dir ja kurz beschreiben.

Die Konstante I_IDLE_TIME bezeichnet (in ms) wie lange der PC inaktiv sein muss um die Aktion auszuführen.
Die Konstante S_WINDOW_TITLE bezeichnet den Titel des Fensters an dem die Befehle gesendet werden sollen.
Die Variable bWaitReset ist dafür gedacht, dass man nicht direkt nochmal in die If-Abfrage reinspringt (obwohl man sich den ganzen Krempel dafür eigentlich sparen kann).

Danach folgt auch schon die Hauptschleife.
_WinAPI_GetIdleTime holt die Idle-Time die Windows reported. Diese misst in ms den Zeitunterschied zwischen jetzt und der letzten Interaktion am PC.
Die If-Abfrage ist glaube ich selbsterklärend und der Rest der danach kommt ist ja auch klar. Fenster aktivieren, Tasten senden, wieder minimieren.

Das ist so die grobe Struktur, wenn es nicht passt, kannst du es ja noch ändern. Hilfe dafür bekommst du von uns