GUICtrlCreateSlider
Erstellt ein Slider-Control für die GUI.
GUICtrlCreateSlider ( left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
Parameter
| left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
| top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
| width | [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite). |
| height | [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe). |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : $TBS_AUTOTICKS |
| exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Um den Wert des Controls zu erhalten, siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate...() Funktionen.
Um die Schieberposition zu aktualisieren, verwendet man GUICtrlSetData().
Die Min. und Max. Werte setzt man mit GUICtrlSetLimit().
Um weitere Stile zusätzlich zum Standardstil zu verwenden, benutzt man BitOR($GUI_SS_DEFAULT_SLIDER, newstyle, ... ).
Um die oben angegebenen Werte verwenden zu können, muss #include <SliderConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKAUTO. (Größe und Position werden entsprechend dem neuen Fenster angepasst.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
GUICreate("Slider", 220, 100, 100, 200)
GUISetBkColor(0x00E0FFFF) ; Ändert die Hintergrundfarbe
Local $idSlider1 = GUICtrlCreateSlider(10, 10, 200, 20)
GUICtrlSetLimit(-1, 200, 0) ; Ändert den Min/Max Wert
Local $idButton = GUICtrlCreateButton("Wert?", 75, 70, 70, 20)
GUISetState(@SW_SHOW)
GUICtrlSetData($idSlider1, 45) ; Setzt den Cursor
Local $idMsg
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
$idMsg = GUIGetMsg()
If $idMsg = $idButton Then
MsgBox($MB_SYSTEMMODAL, "slider1", GUICtrlRead($idSlider1), 2)
EndIf
Until $idMsg = $GUI_EVENT_CLOSE
EndFunc ;==>Example