GUISwitch
Ändert die Wahl des aktuellen Fensters, auf welches GUI-Funktionen angewendet werden können.
GUISwitch ( winhandle [, tabitemID] )
Parameter
| winhandle | Der Handle des Fensters, zu dem gewechselt wird. |
| tabitemID | [optional] Control-ID des Tab-Controls, welches ausgewählt werden soll. |
Rückgabewert
| Erfolg: | Das Handle des vorherigen GUI. |
| Fehler: | Ein Null-Handle. |
Bemerkungen
Viele der GUI-spezifischen Funktionen arbeiten mit dem "aktuellen" Fenster - das ist üblicherweise das zuletzt mit GUICreate() erstellte Fenster. Die Funktion GUISwitch erlaubt es, ein anderes Fenster zum "aktuellen" Fenster (für die Bearbeitung) zu machen. Das bedeutet aber nicht, dass dieses gewählte Fenster daraufhin aktiv ist. Hierfür muss WinActivate() benutzt werden.
TabitemID ist zu benutzen, um neue Controls in dem angegebenen tabitem zu erstellen. Es darf nicht vergessen werden, das tabitem mit der Funktion GUICtrlCreateTabItem("") zu schließen.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICreate, GUICtrlCreateTabItem, GUIDelete
Beispiel
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $hGUIParent1 = GUICreate("Parent1")
GUICtrlCreateTab(10, 10)
Local $iTabItem = GUICtrlCreateTabItem("Tab1")
GUICtrlCreateTabItem("Tab2")
GUICtrlCreateTabItem("")
Local $hGUIParent2 = GUICreate("Parent2", -1, -1, 100, 100)
GUISwitch($hGUIParent2)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
GUISwitch($hGUIParent1, $iTabItem)
GUICtrlCreateButton("OK", 50, 50, 50)
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW, $hGUIParent1)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
GUIDelete($hGUIParent1)
GUIDelete($hGUIParent2)
EndFunc ;==>Example