Funktionreferenz

_GDIPlus_BitmapApplyEffectEx

Beschreibung anzeigen in

Ändert eine Bitmap durch anwenden eines näher definierten Effekts

#include <GDIPlus.au3>
_GDIPlus_BitmapApplyEffectEx ( $hBitmap, $hEffect [, $iX = 0 [, $iY = 0 [, $iW = 0 [, $iH = 0]]]] )

Parameter

$hBitmap Handle zu einer Bitmap auf die der Effekt angewendet wird
$hEffect Handle zu dem anzuwendenden Effekt
$iX [optional] Die X Koordinate der oberen linken Ecke des Bereichs auf die der Effekt angewendet wird
$iY [optional] Die Y Koordinate der oberen linken Ecke des Bereichs auf die der Effekt angewendet wird
$iW [optional] Definiert die Breite des Bereichs auf den der Effekt angewendet wird
$iH [optional] Definiert die Höhe des Bereichs auf den der Effekt angewendet wird

Rückgabewert

Erfolg: True.
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.
@error: -1 - GDIPlus.dll unterstüzt diese Funktion nicht.
10 - Falsche Parameter.

Bemerkungen

Übergebe 0 um anzugeben, dass der Effekt die gesamte Bitmap betreffen soll (Standard).

Verwandte Funktionen

_GDIPlus_BitmapApplyEffect, _GDIPlus_EffectCreate

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    If Not _GDIPlus_Startup() Or @extended < 6 Then
        MsgBox($MB_SYSTEMMODAL, "FEHLER", "GDIPlus.dll v1.1 ist nicht verfügbar")
        Return
    EndIf

    Local $sFile = FileOpenDialog("Bitte ein Bild auswählen", "", "Bilder (*.bmp;*.png;*.jpg;*.gif;*.tif)")
    If @error Or Not FileExists($sFile) Then Return

    Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)
    Local $iImgW = _GDIPlus_ImageGetWidth($hImage)
    Local $iImgH = _GDIPlus_ImageGetHeight($hImage)

    Local $iWidth = 600
    Local $iHeight = $iImgH * 600 / $iImgW

    Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    GUISetState(@SW_SHOW)

    Local $hEffect = _GDIPlus_EffectCreateHueSaturationLightness(0, -100, 0)
    _GDIPlus_BitmapApplyEffectEx($hImage, $hEffect, $iImgW * 0.25, $iImgH * 0.25, $iImgW * 0.5, $iImgH * 0.5)

    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GDIPlus_EffectDispose($hEffect)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Example