Ändert eine Bitmap indem ein Effekt angewendet wird
#include <GDIPlus.au3>
_GDIPlus_BitmapApplyEffect ( $hBitmap, $hEffect [, $tRECT = Null] )
$hBitmap | Handle zu einer Bitmap an welcher der Effekt angewendet werden soll. |
$hEffect | Handle zu dem Effekt der angewendet werden soll. |
$tRECT | [optional] eine $tagRECT Struktur die den Bereich der eingegebenen Bitmap definiert, auf den der Effekt angewendet werden soll. |
Erfolg: | True. |
Fehler: | False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten. |
@error: | -1 - GDIPlus.dll unterstützt diese Funktion nicht 10 - Falsche Parameter. |
Übergebe Null als $tRECT Parameter um anzugeben, dass der Effekt auf die gesamte Bitmap angewendet werden soll (Standard).
$tagRECT, _GDIPlus_BitmapApplyEffectEx, _GDIPlus_EffectCreate
Suche nach GdipBitmapApplyEffect in der MSDN Bibliothek.
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
_Example()
Func _Example()
If Not _GDIPlus_Startup() Or @extended < 6 Then
MsgBox($MB_SYSTEMMODAL, "FEHLER", "GDIPlus.dll v1.1 ist nicht verfügbar")
Return
EndIf
Local $sFile = FileOpenDialog("Bitte ein Bild auswählen", "", "Bilder (*.bmp;*.png;*.jpg;*.gif;*.tif)")
If @error Or Not FileExists($sFile) Then Return
Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)
Local $iImgW = _GDIPlus_ImageGetWidth($hImage)
Local $iImgH = _GDIPlus_ImageGetHeight($hImage)
Local $iWidth = 600
Local $iHeight = $iImgH * 600 / $iImgW
Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
GUISetState(@SW_SHOW)
Local $hEffect = _GDIPlus_EffectCreateHueSaturationLightness(0, -100, 0)
Local $tRECT = DllStructCreate($tagRECT)
$tRECT.Left = $iImgW * 0.25
$tRECT.Top = $iImgH * 0.25
$tRECT.Right = $tRECT.Left + $iImgW * 0.5
$tRECT.Bottom = $tRECT.Top + $iImgH * 0.5
_GDIPlus_BitmapApplyEffect($hImage, $hEffect, $tRECT)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
_GDIPlus_EffectDispose($hEffect)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
EndFunc ;==>_Example