Funktionreferenz


_GDIPlus_BitmapCreateFromHICON32

Beschreibung anzeigen in

Erstellt ein Bitmap Objekt basierend auf einem 32bit Icon

#include <GDIPlus.au3>
_GDIPlus_BitmapCreateFromHICON32 ( $hIcon )

Parameter

$hIcon Handle zu einem Icon

Rückgabewert

Erfolg: ein Handle zu einem neuen Bitmap Objekt.
Fehler: 0 und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Bemerkungen

Wenn du mit dem Bitmap Objekt fertig bist, rufe _GDIPlus_ImageDispose() auf um die Ressourcen freizugeben.

Verwandte Funktionen

_GDIPlus_ImageDispose, _WinAPI_LoadIcon, _WinAPI_LoadImage

Siehe auch

Suche nach GdipCreateBitmapFromHICON in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIIcons.au3>
#include <WinAPIShellEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hIcon, $hBitmap

    ; Create GUI
    $hGUI = GUICreate("GDI+", 168, 168)
    GUISetState()

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;Create a graphics object from a window handle
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hIcon = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 32, 48, 48)

    $hBitmap = _GDIPlus_BitmapCreateFromHICON32($hIcon)

    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 60, 60)

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Clean up resources
    _WinAPI_DestroyIcon($hIcon)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example