_GDIPlus_EffectCreateLevels
Beschreibung anzeigen in
Erstellt ein Level-Klasseneffektobjekt
#include <GDIPlus.au3>
_GDIPlus_EffectCreateLevels ( [$iHighlight = 100 [, $iMidtone = 0 [, $iShadow = 0]]] )
Parameter
| $iHighlight | [optional] Integer (Ganzzahl) im Bereich von 0 bis 100, die angibt, welche Pixel aufgehellt werden sollen. |
| $iMidtone | [optional] Integer (Ganzzahl) im Bereich von -100 bis 100, die angibt, wie stark ein Bild aufgehellt oder abgedunkelt werden soll. |
| $iShadow | [optional] Integer (Ganzzahl) im Bereich von 0 bis 100, die angibt, welche Pixel abgedunkelt werden sollen. |
Rückgabewert
| Erfolg: | Ein Handle für ein Effektobjekt. |
| Fehler: | 0 und setzt das @error Flag auf ungleich 0, das @extended Flag kann den GPSTATUS-Fehlercode ($GDIP_ERR* siehe GPIPlusConstants.au3) enthalten. |
| @error: | -1 - GDIPlus.dll unterstützt diese Funktion nicht. 10 - Ungültige Parameter. |
Bemerkungen
Es ist _GDIPlus_EffectDispose () aufzurufen, um die Ressourcen im Anschluss wieder freizugeben.
Verwandte Funktionen
_GDIPlus_EffectCreate, _GDIPlus_EffectDispose
Beispiel
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
_Example()
Func _Example()
If Not _GDIPlus_Startup() Or @extended < 6 Then
MsgBox($MB_SYSTEMMODAL, "FEHLER", "GDIPlus.dll v1.1 ist nicht verfügbar")
Return
EndIf
Local $sFile = FileOpenDialog("Bitte ein Bild auswählen", "", "Bilder (*.bmp;*.png;*.jpg;*.gif;*.tif)")
If @error Or Not FileExists($sFile) Then Return
Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)
Local $iWidth = 600
Local $iHeight = _GDIPlus_ImageGetHeight($hImage) * 600 / _GDIPlus_ImageGetWidth($hImage)
Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
GUISetState(@SW_SHOW)
Local $hEffect = _GDIPlus_EffectCreateLevels(60, -50, 20)
_GDIPlus_BitmapApplyEffect($hImage, $hEffect)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
_GDIPlus_EffectDispose($hEffect)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
EndFunc ;==>_Example