Funktionreferenz


_GDIPlus_PathBrushSetSurroundColor


Sets the surround color for a path gradient brush

#include <GDIPlus.au3>
_GDIPlus_PathBrushSetSurroundColor ( $hPathGradientBrush, $iARGB )

Parameter

$hPathGradientBrush Pointer to a PathGradientBrush object
$iARGB Alpha, Red, Green and Blue components of the new surrounding colors

Rückgabewert

Success: True.
Failure: False and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GPIP_ERR* see GPIPlusConstants.au3).

Bemerkungen

None.

Verwandte Funktionen

_GDIPlus_PathBrushSetSurroundColorsWithCount

Siehe auch

Suche nach GdipSetPathGradientSurroundColorsWithCount in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGui = GUICreate("GDI+", 200, 180)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFF00)
    _GDIPlus_PathBrushSetCenterPoint($hBrush, 90, 80)
    _GDIPlus_PathBrushSetSurroundColor($hBrush, 0xFF0000FF)

    _GDIPlus_PathBrushSetGammaCorrection($hBrush, True)

    Local $aRect = _GDIPlus_PathBrushGetRect($hBrush)
    _GDIPlus_GraphicsFillRect($hGraphics, $aRect[0], $aRect[1], $aRect[2], $aRect[3], $hBrush)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Gibt die Ressourcen frei
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example