Funktionreferenz


_GUICtrlButton_GetTextMargin

Beschreibung anzeigen in

Ermittelt die benötigten Ränder um Text in einem Button-Control zu zeichnen

#include <GuiButton.au3>
_GUICtrlButton_GetTextMargin ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - linker Rand um den Text zu zeichnen
    [1] - oberer Rand um den Text zu zeichnen
    [2] - rechter Rand um den Text zu zeichnen
    [3] - unterer Rand um den Text zu zeichnen

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlButton_SetTextMargin

Siehe auch

Suche nach BCM_GETTEXTMARGIN in der MSDN Bibliothek.

Beispiel

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $y = 70, $a_idBtn[6], $aMargins

    GUICreate("Buttons", 510, 400)
    $g_idMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $a_idBtn[0] = GUICtrlCreateButton("Button 1", 10, 10, 90, 50)
    _GUICtrlButton_SetTextMargin($a_idBtn[0], 10, 5, 10, 5)

    For $x = 1 To 5
        $a_idBtn[$x] = GUICtrlCreateButton("Button" & $x + 1, 10, $y, 90, 50)
        $y += 60
    Next

    For $x = 0 To 5
        $aMargins = _GUICtrlButton_GetTextMargin($a_idBtn[$x])
        MemoWrite("Button " & $x + 1 & " Ränder:" & @CRLF & @TAB & _
                "Links.: " & $aMargins[0] & @TAB & "Oben..: " & $aMargins[1] & @CRLF & @TAB & _
                "Rechts: " & $aMargins[2] & @TAB & "Unten.: " & $aMargins[3] & @CRLF)
    Next

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>Example

; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite