_GUICtrlEdit_GetCueBanner
Beschreibung anzeigen in
Gibt den Cue-Banner Text zurück welcher im Edit-Control angezeigt wird
#include <GuiEdit.au3>
_GUICtrlEdit_GetCueBanner ( $hWnd )
Parameter
| $hWnd | Control ID/Handle des Controls |
Rückgabewert
| Erfolg: | Der Cue-Banner Text. |
| Fehler: | Ein leerer String "". |
Bemerkungen
Der Cue-Banner ist der Text der angezeigt wird, wenn in einem Edit-Control nichts ausgewählt wurde.
Windows Vista oder höher.
Verwandte Funktionen
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
Local $hGUI = GUICreate('Beispiel', 300, 150)
GUISetFont(9, 400, 0, 'Segoe UI')
Local $idUsername = GUICtrlCreateInput('', 10, 10, 125, 25)
_GUICtrlEdit_SetCueBanner($idUsername, "Suche Ordner")
Local $idPassword = GUICtrlCreateInput('', 10, 40, 125, 25)
_GUICtrlEdit_SetCueBanner($idPassword, "Suche...")
Local $idButton_Close = GUICtrlCreateButton("Schließen", 210, 120, 85, 25)
ControlFocus($hGUI, "", $idButton_Close)
GUISetState(@SW_SHOW, $hGUI)
MsgBox($MB_SYSTEMMODAL, "", _GUICtrlEdit_GetCueBanner($idPassword))
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
EndSwitch
WEnd
GUIDelete($hGUI)
EndFunc ;==>Example