_GUICtrlHeader_GetItemImage

Beschreibung anzeigen in

Ermittelt den Index eines Bildes innerhalb der Imagelist

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemImage ( $hWnd, $iIndex )

Parameter

$hWnd	Handle des Controls
$iIndex	0-basierender Itemindex

Rückgabewert

Gibt einen 0-basierenden Index des Bildes zurück.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    Local $hGui, $hHeader, $hImage

    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Header Ermittelt bzw. setzt ItemImage (v" & @AutoItVersion & ")", 450, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Erstellt eine Imagelist mit Bildern
    Local $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 0", 100, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 100, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 100, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 100)

    ; Zeigt das Bild von Spalte 0
    _MemoWrite("Bild von Spalte 0: " & _GUICtrlHeader_GetItemImage($hHeader, 0))

    Sleep(1000)

    ; Setzt das Bild von Spalte 0
    _GUICtrlHeader_SetItemImage($hHeader, 0, 2)

    ; Zeigt das Bild von Spalte 0
    _MemoWrite("Bild von Spalte 0: " & _GUICtrlHeader_GetItemImage($hHeader, 0))

    _MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc   ;==>Example

Example 2 : Header Set ItemImage to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo, True) ; OK also if run in different mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 1, $sFromTo)

    ; Show column 0 image
    _MemoWrite(">>> Column 0 image: " & _GUICtrlHeader_GetItemImage($hHeader, 0))

    ; Set column 0 image
    _GUICtrlHeader_SetItemImage($hHeader, 0, 1)
    If @error Then
        _MemoWrite("_GUICtrlHeader_SetItemImage()" & " @error = " & @error & @CRLF & _
            @TAB & "cannot be set by an external process")

    EndIf

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example

Funktionreferenz