_GUICtrlHeader_HitTest

Beschreibung anzeigen in

Testet einen Punkt, um zu ermitteln, welches Item sich an dem festgelegten Punkt befindet

#include <GuiHeader.au3>
_GUICtrlHeader_HitTest ( $hWnd, $iX, $iY )

Parameter

$hWnd	Handle des Controls
$iX	zu testende X-Position
$iY	zu testende Y-Position

Rückgabewert

Erfolg: Array mit dem folgenden Format:
    [ 0] - 0-basierender Index des Items an der festgelegten Position oder -1 falls kein Item gefunden wurde
    [ 1] - Falls True befindet sich die Position im Fenster des Controls, aber nicht auf einem Item
    [ 2] - Falls True befindet sich die Position im begrenzenden Rechteck des Controls
    [ 3] - Falls True befindet sich die Position zwischen zwei Items
    [ 4] - Falls True befindet sich die Position auf einem Item welches die Breite 0 hat
    [ 5] - Falls True befindet sich die Position über einem Filterbereich
    [ 6] - Falls True befindet sich die Position auf dem Filterbutton
    [ 7] - Falls True befindet sich die Position über dem begrenzenden Rechteck des Controls
    [ 8] - Falls True befindet sich die Position unterhalb des begrenzenden Rechtecks des Controls
    [ 9] - Falls True befindet sich die Position rechts des begrenzenden Rechtecks des Controls
    [10] - Falls True befindet sich die Position links des begrenzenden Rechtecks des Controls

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Header: Hit Test (v" & @AutoItVersion & ")", 400, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    GUISetState(@SW_SHOW)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 0", 100)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 100)

    ; Testet einen Punkt (Spalte 1), um zu ermitteln, welches Item sich an dem festgelegten Punkt befindet.
    Local $aHT = _GUICtrlHeader_HitTest($hHeader, 110, 10)
    _MemoWrite("Itemindex ................................: " & $aHT[0])
    _MemoWrite("Im Fenster ...............................: " & $aHT[1])
    _MemoWrite("Im Rechteck des Controls ...........: " & $aHT[2])
    _MemoWrite("Zwischen zwei Items ......................: " & $aHT[3])
    _MemoWrite("Auf einem Item welches die Breite 0 hat: " & $aHT[4])
    _MemoWrite("Über einem Filterbereich .................: " & $aHT[5])
    _MemoWrite("Auf dem Filterbutton .....................: " & $aHT[6])
    _MemoWrite("Über dem begrenzenden Rechteck ...........: " & $aHT[7])
    _MemoWrite("Unterhalb des begrenzenden Rechtecks .....: " & $aHT[8])
    _MemoWrite("Rechts des begrenzenden Rechtecks ........: " & $aHT[9])
    _MemoWrite("Links des begrenzenden Rechtecks .........: " & $aHT[10])

    _MemoMsgBoxStatus("", -1, $hGui) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc   ;==>Example

Example 2 : Header Hit Test from an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo) ; OK if run in different Mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 0, $sFromTo)

    ; Do a hit test on column 2
    Local $aHT = _GUICtrlHeader_HitTest($hHeader, 250, 10)
    _MemoWrite("Item index ...................: " & $aHT[0])
    _MemoWrite("In client window .............: " & $aHT[1])
    _MemoWrite("In control rectangle .........: " & $aHT[2])
    _MemoWrite("On divider ...................: " & $aHT[3])
    _MemoWrite("On zero width divider ........: " & $aHT[4])
    _MemoWrite("Over filter area .............: " & $aHT[5])
    _MemoWrite("Over filter button ...........: " & $aHT[6])
    _MemoWrite("Above bounding rectangle .....: " & $aHT[7])
    _MemoWrite("Below bounding rectangle .....: " & $aHT[8])
    _MemoWrite("To right of bounding rectangle: " & $aHT[9])
    _MemoWrite("To left of bounding rectangle : " & $aHT[10])

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example