Sortiert eine Listbox, wenn diese den Stil $LBS_SORT besitzt
#include <GuiListBox.au3>
_GUICtrlListBox_Sort ( $hWnd )
$hWnd | Control-ID / Handle des Controls |
Erfolg: | True |
Fehler: | False |
Sortiert eine Listbox, wenn diese den Stil $LBS_SORT besitzt.
Könnte hilfreich sein, wenn man _GUICtrlListBox_InsertString() verwendet.
- - - - - - - - Erklärung der Controls - - - - - - - -
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $sText, $idListBox
; Erstellt eine GUI
GUICreate("ListBox: Sortieren", 400, 296)
$idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_MULTIPLESEL, $LBS_SORT))
GUISetState(@SW_SHOW)
; Fügt Strings hinzu
_GUICtrlListBox_BeginUpdate($idListBox)
For $iI = 1 To 9
$sText = StringFormat("%03d : Zufallstring ", Random(1, 100, 1))
For $iX = 1 To Random(1, 20, 1)
$sText &= Chr(Random(65, 90, 1))
Next
_GUICtrlListBox_AddString($idListBox, $sText)
Next
_GUICtrlListBox_InsertString($idListBox, "Dies ist ein Test", 0) ; Autosortieren funktioniert nicht, wenn ein String eingefügt wird
_GUICtrlListBox_EndUpdate($idListBox)
; Sortiert eine Listbox
MsgBox($MB_SYSTEMMODAL, "Information", "Daten sortieren")
_GUICtrlListBox_Sort($idListBox)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example